configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.1.0rc1,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2014-03-24"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 # Check how the files should be packaged
  17 AC_CANONICAL_TARGET
  18 LYX_USE_PACKAGING
  19 # We need to define these variables here and the no-define option of
  20 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  22
  23 dnl Default maintainer mode to true for development versions
  24 if test "${enable_maintainer_mode+set}" != set; then
  25   enable_maintainer_mode=$lyx_devel_version
  26 fi
  27 AM_MAINTAINER_MODE
  28
  29 save_PACKAGE=$PACKAGE
  30 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8])
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32 PACKAGE=$save_PACKAGE
  33
  34 # Allow to build some parts of the code as one big chunk
  35 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt4])
  36 AC_ARG_ENABLE(monolithic-build,
  37   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  38                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  39   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  40    test "$enable_monolithic_build" = no && enable_monolithic_build=
  41    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  42    for i in $enable_monolithic_build ; do
  43        eval "enable_monolithic_$i=yes"
  44    done
  45    IFS="$ac_save_ifs"],
  46   [enable_monolithic_build=])
  47
  48 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  49 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  50 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  51 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  52 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  53 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  54 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT4, test "x$enable_monolithic_frontend_qt4" = "xyes")
  55
  56 ### Set the execute permissions of the various scripts correctly
  57 for file in config/install-sh ; do
  58   chmod 755 ${srcdir}/${file}
  59 done
  60
  61 AM_PATH_PYTHON(2.4.0,, :)
  62 AC_PROG_RANLIB
  63
  64 ### Check for a C++ compiler
  65 LYX_PROG_CXX
  66 AC_LANG(C++)
  67
  68 ### Objective-C compiler
  69 AC_PROG_OBJC
  70 _AM_DEPENDENCIES([OBJC])
  71
  72 ### Add extra directories to check for libraries.
  73 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  74 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  75 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  76
  77 ### Add extra directories to check for include files.
  78 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  79 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  80 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  81
  82 ### Add both includes and libraries
  83 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  84 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  85 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  86   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  87
  88 ### These are needed in windows
  89 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  90 AC_SUBST(LIBSHLWAPI)
  91 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  92 AC_SUBST(LIBPSAPI)
  93 AC_CHECK_LIB(gdi32, main)
  94
  95 LYX_USE_INCLUDED_BOOST
  96 LYX_USE_INCLUDED_MYTHES
  97
  98 ### we need to know the byte order for unicode conversions
  99 AC_C_BIGENDIAN
 100
 101 # Needed for our char_type
 102 AC_CHECK_SIZEOF(wchar_t)
 103
 104 ### We need iconv for unicode support (Qt4 frontend requires it too)
 105 AM_ICONV
 106 if test "$am_cv_func_iconv" = no; then
 107   AC_MSG_ERROR([cannot find required library iconv.])
 108 else
 109   LIBS="$LIBS $LIBICONV"
 110 fi
 111
 112 ### check for compression support
 113 AC_CHECK_HEADERS(zlib.h,
 114  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 115  [LYX_LIB_ERROR(zlib.h,zlib)])
 116
 117 ### check for file magic support (currently optional)
 118 AC_CHECK_HEADERS(magic.h,
 119  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 120   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 121    is correctly installed on your system.
 122    Falling back to builtin file format detection.]))],
 123  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 124    is correctly installed on your system.
 125    Falling back to builtin file format detection.])])
 126
 127 ### setup the qt4 frontend.
 128 dnl The code below is not in a macro, because this would cause big
 129 dnl problems with the AC_REQUIRE contained in QT4_DO_IT_ALL.
 130 QT4_DO_IT_ALL([4.5.0])
 131 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 132 FRONTEND_INFO="${FRONTEND_INFO}\
 133   Qt 4 Frontend:\n\
 134       Qt 4 version:\t\t${QT4_VERSION}\n"
 135
 136 # fix the value of the prefixes.
 137 test "x$prefix" = xNONE && prefix=$default_prefix
 138 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 139 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 140   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 141    causes problems with the Makefiles. The installation will be done in
 142    directory \"`pwd`/installprefix\" instead. Please move its contents to
 143    the right place after installation.])
 144   prefix=`pwd`/installprefix
 145 fi
 146
 147 ### Setup po directory
 148 AM_PO_SUBDIRS
 149 AM_NLS
 150 if test $USE_NLS = "yes" ; then
 151   AC_DEFINE(ENABLE_NLS, 1,
 152     [Define to 1 if translation of program messages to the user's native language
 153    is requested.])dnl'
 154 fi
 155
 156 # some standard header files
 157 AC_HEADER_MAJOR
 158 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 159
 160 # some standard types
 161 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 162 AC_TYPE_OFF_T
 163 AC_TYPE_PID_T
 164 AC_TYPE_SIZE_T
 165 AC_TYPE_UID_T
 166 # Taken from gettext
 167 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 168    [AC_TRY_COMPILE([#include <stddef.h>
 169       wchar_t foo = (wchar_t)'\0';], ,
 170       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 171 if test $gt_cv_c_wchar_t = yes; then
 172   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 173 fi
 174
 175 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 176
 177 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 178 # Check the form of mkdir()
 179 AC_FUNC_MKDIR
 180 AC_FUNC_SELECT_ARGTYPES
 181
 182 LYX_CHECK_SPELL_ENGINES
 183
 184 lyx_client_subdir=true
 185 dnl AC_LANG_PUSH(C)
 186 dnl LIBS already contains some X extra libs that may interfere.
 187 save_LIBS="$LIBS"
 188 LIBS=
 189 AC_CHECK_FUNCS(fcntl,
 190   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 191    AC_SEARCH_LIBS([socket], [socket], [],
 192      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 193                 [], [-lnsl])])],
 194   [lyx_client_subdir=false])
 195 AC_SUBST(SOCKET_LIBS,$LIBS)
 196 LIBS="$save_LIBS"
 197 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 198 dnl AC_LANG_POP(C)
 199
 200 lyx_win_res=false;
 201 case ${host} in
 202     *mingw*|*cygwin*) lyx_win_res=true;;
 203 esac
 204 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 205 LYX_SET_VERSION_INFO
 206
 207
 208 ### Some information on what just happened
 209 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 210 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 211 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 212 VERSION_INFO="Configuration\n\
 213   Host type:                    ${host}\n\
 214   Special build flags:         ${lyx_flags}\n\
 215   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 216   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 217   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 218   Linker flags:                 ${AM_LDFLAGS}\n\
 219   Linker user flags:            ${LDFLAGS}\n\
 220 ${FRONTEND_INFO}\
 221   Packaging:                    ${lyx_use_packaging}\n\
 222   LyX binary dir:               ${real_bindir}\n\
 223   LyX files dir:                ${real_pkgdatadir}\n"
 224
 225 AC_SUBST(VERSION_INFO)
 226 AC_SUBST(AM_CPPFLAGS)
 227 AC_SUBST(AM_CXXFLAGS)
 228 AC_SUBST(AM_CFLAGS)
 229 AC_SUBST(AM_LDFLAGS)
 230 AC_SUBST(real_pkgdatadir)
 231
 232 ## Some config.h stuff
 233
 234 AH_TOP([
 235 /* -*- C++ -*- */
 236 /*
 237  * \file config.h
 238  * This file is part of LyX, the document processor.
 239  * Licence details can be found in the file COPYING.
 240  *
 241  * This is the compilation configuration file for LyX.
 242  * It was generated by autoconfs configure.
 243  * You might want to change some of the defaults if something goes wrong
 244  * during the compilation.
 245  */
 246
 247 #ifndef _CONFIG_H
 248 #define _CONFIG_H
 249 ])
 250
 251 AH_BOTTOM([
 252 /************************************************************
 253  ** You should not need to change anything beyond this point */
 254
 255 #ifndef HAVE_STRERROR
 256 #if defined(__cplusplus)
 257 extern "C"
 258 #endif
 259 char * strerror(int n);
 260 #endif
 261
 262 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 263 #  define USE_BOOST_FORMAT 1
 264 #else
 265 #  define USE_BOOST_FORMAT 0
 266 #endif
 267
 268 #define BOOST_USER_CONFIG <config.h>
 269
 270 #if !defined(ENABLE_ASSERTIONS)
 271 #  define BOOST_DISABLE_ASSERTS 1
 272 #endif
 273 #define BOOST_ENABLE_ASSERT_HANDLER 1
 274
 275 #define BOOST_DISABLE_THREADS 1
 276 #define BOOST_NO_WREGEX 1
 277 #define BOOST_NO_WSTRING 1
 278
 279 // TR1 regex not supported in GCC <= 4.5
 280 #ifndef LYX_USE_TR1
 281 #  if __GNUC__ == 4
 282 #    define LYX_USE_TR1
 283 #  endif
 284 #endif
 285
 286 #ifdef __CYGWIN__
 287 #  define NOMINMAX
 288 #  define BOOST_POSIX 1
 289 #  define BOOST_POSIX_API 1
 290 #  define BOOST_POSIX_PATH 1
 291 #endif
 292
 293 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 294 #  define USE_WCHAR_T
 295 #endif
 296
 297 #endif
 298 ])
 299
 300 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 301 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 302 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 303
 304 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 305         "${lyx_abs_top_srcdir}", [Top source directory])
 306 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 307         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 308 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 309         "${lyx_abs_installed_datadir}",[Hard system support directory])
 310 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 311         "${version_suffix}",[Program version suffix])
 312
 313 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 314 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 315 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 316 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 317 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 318 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 319 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 320 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 321
 322 AC_CONFIG_FILES([Makefile \
 323       lyx.1:lyx.1in \
 324       boost/Makefile \
 325       config/Makefile \
 326       development/Makefile \
 327       development/MacOSX/Makefile \
 328       development/MacOSX/Info.plist \
 329       development/MacOSX/lyxrc.dist \
 330       development/MacOSX/spotlight/Makefile \
 331       development/cygwin/Makefile \
 332       development/cygwin/lyxrc.dist \
 333       development/lyx.spec \
 334       lib/lyx.desktop-temp:lib/lyx.desktop.in
 335       lib/Makefile \
 336       lib/doc/Makefile \
 337       lib/lyx2lyx/lyx2lyx_version.py \
 338       lib/lyx2lyx/Makefile \
 339       m4/Makefile \
 340       po/Makefile.in \
 341       sourcedoc/Doxyfile \
 342       sourcedoc/Makefile \
 343       src/client/Makefile \
 344       src/client/lyxclient.1:src/client/lyxclient.1in \
 345       src/Makefile \
 346       src/tex2lyx/Makefile \
 347       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 348       src/support/Makefile \
 349       src/frontends/Makefile \
 350       src/frontends/qt4/Makefile
 351 ])
 352
 353
 354 AC_OUTPUT
 355
 356 # show version information
 357 echo
 358 printf "$VERSION_INFO"
 359 echo
 360
 361 # Display a final warning if there has been a LYX_WARNING
 362 LYX_CHECK_WARNINGS
 363
 364 cat <<EOF
 365 Configuration of LyX was successful.
 366 Type 'make' to compile the program,
 367 and then 'make install' to install it.
 368 EOF