configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.4.0dev],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2018-02-24"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29 AM_SILENT_RULES([yes])
  30 # Automake is pulling the historical V7 format. This tar format supports
  31 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  32 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  33 save_PACKAGE=$PACKAGE
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-define 1.14 tar-ustar subdir-objects])
  35 PACKAGE=$save_PACKAGE
  36
  37 ### Set the execute permissions of the various scripts correctly
  38 for file in config/install-sh ; do
  39   chmod 755 ${srcdir}/${file}
  40 done
  41
  42 # Find a suitable python interpreter
  43 LYX_PATH_PYTHON23([2.7.0], [3.5.0])
  44 # do the usual python setup stuff
  45 AM_PATH_PYTHON
  46
  47 # Tools for creating libraries (note that we do not use libtool)
  48 AM_PROG_AR
  49 AC_PROG_RANLIB
  50 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  51 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  52 AC_SUBST([ARFLAGS], [cr])
  53
  54 ### Check for a C++ compiler
  55 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  56 dnl if it is not set. We do not use autoconf defaults.
  57 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  58 if ! test "$lyx_has_CXXFLAGS" = yes; then
  59   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  60   CXXFLAGS=" "
  61 fi
  62 LYX_PROG_CXX
  63 if ! test "$lyx_has_CXXFLAGS" = yes; then
  64   unset CXXFLAGS
  65 fi
  66 AC_LANG(C++)
  67
  68 ### Objective-C compiler
  69 AC_PROG_OBJC
  70 _AM_DEPENDENCIES([OBJC])
  71
  72 ### Add extra directories to check for libraries.
  73 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  74 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  75 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  76
  77 ### Add extra directories to check for include files.
  78 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  79 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  80 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  81
  82 ### Add both includes and libraries
  83 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  84 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  85   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  86   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  87 ])
  88
  89 ### These are needed in windows
  90 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  91 AC_SUBST(LIBSHLWAPI)
  92 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  93 AC_SUBST(LIBPSAPI)
  94 AC_CHECK_LIB(gdi32, main)
  95 AC_CHECK_LIB(ole32, main)
  96
  97 ### we need to know the byte order for unicode conversions
  98 AC_C_BIGENDIAN
  99
 100 # Nice to have when an assertion triggers
 101 LYX_CHECK_CALLSTACK_PRINTING
 102
 103 # C++14 only
 104 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 105
 106 # Needed for our char_type
 107 AC_CHECK_SIZEOF(wchar_t)
 108
 109 # Taken from gettext, needed for libiconv
 110 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 111    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 112       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 113 if test $gt_cv_c_wchar_t = yes; then
 114   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 115   HAVE_WCHAR_T=1
 116 else
 117   HAVE_WCHAR_T=0
 118 fi
 119 AC_SUBST([HAVE_WCHAR_T])
 120
 121 # Needed for Mingw-w64
 122 AC_TYPE_LONG_LONG_INT
 123
 124 ### We need iconv for unicode support (Qt frontend requires it too)
 125 LYX_USE_INCLUDED_ICONV
 126
 127 ### check for compression support
 128 LYX_USE_INCLUDED_ZLIB
 129
 130 ### check whether we build and install the supplied dtl programs
 131 LYX_BUILD_INCLUDED_DTL
 132
 133 ### check for file magic support (currently optional)
 134 AC_CHECK_HEADERS(magic.h,
 135  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 136   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 137    is correctly installed on your system.
 138    Falling back to builtin file format detection.]))],
 139  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 140    is correctly installed on your system.
 141    Falling back to builtin file format detection.])])
 142
 143 ### setup the qt frontend.
 144 dnl The code below is not in a macro, because this would cause big
 145 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 146 QT_DO_IT_ALL([4.5.0])
 147 AC_SUBST([FRONTENDS_SUBDIRS], [qt])
 148 FRONTEND_INFO="${FRONTEND_INFO}\
 149   Qt Frontend:\n\
 150       Qt version:\t   ${QTLIB_VERSION}\n"
 151
 152 # fix the value of the prefixes.
 153 test "x$prefix" = xNONE && prefix=$default_prefix
 154 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 155 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 156   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 157    causes problems with the Makefiles. The installation will be done in
 158    directory \"`pwd`/installprefix\" instead. Please move its contents to
 159    the right place after installation.])
 160   prefix=`pwd`/installprefix
 161 fi
 162
 163 ### Setup po directory
 164 AM_NLS
 165 if test $USE_NLS = "yes" ; then
 166   AC_DEFINE(ENABLE_NLS, 1,
 167     [Define to 1 if translation of program messages to the user's native language
 168    is requested.])dnl'
 169 fi
 170 AM_PO_SUBDIRS
 171
 172 # some standard header files
 173 AC_HEADER_MAJOR
 174 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 175
 176 # some standard types
 177 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 178 AC_TYPE_OFF_T
 179 AC_TYPE_PID_T
 180 AC_TYPE_SIZE_T
 181 AC_TYPE_UID_T
 182
 183 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 184
 185 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 186 # Check the form of mkdir()
 187 AC_FUNC_MKDIR
 188 AC_FUNC_SELECT_ARGTYPES
 189
 190 LYX_CHECK_SPELL_ENGINES
 191 LYX_USE_INCLUDED_MYTHES
 192
 193 lyx_client_subdir=true
 194 dnl LIBS already contains some X extra libs that may interfere.
 195 save_LIBS="$LIBS"
 196 LIBS=
 197 AC_CHECK_FUNCS(fcntl,
 198   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 199    AC_SEARCH_LIBS([socket], [socket network], [],
 200      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 201                 [], [-lnsl])])],
 202   [lyx_client_subdir=false])
 203 AC_SUBST(SOCKET_LIBS,$LIBS)
 204 LIBS="$save_LIBS"
 205 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 206
 207 lyx_win_res=false;
 208 case ${host} in
 209     *mingw*|*cygwin*) lyx_win_res=true;;
 210     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 211 esac
 212 if test "x$lyx_win_res" = "xtrue"; then
 213     AC_CHECK_TOOL(RC, windres,)
 214     if test -z "$RC"; then
 215       AC_MSG_ERROR([Could not find a resource compiler])
 216     fi
 217 fi
 218 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 219 LYX_SET_VERSION_INFO
 220
 221
 222 ### Some information on what just happened
 223 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 224 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 225 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 226 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 227 VERSION_INFO="Configuration\n\
 228   Host type:               ${host}\n\
 229   Special build flags:     ${lyx_flags}\n\
 230   Bundled libraries:       ${lyx_included_libs}\n\
 231   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 232   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 233   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 234   Linker flags:            ${AM_LDFLAGS}\n\
 235   Linker user flags:       ${LDFLAGS}\n\
 236 ${FRONTEND_INFO}\
 237   Packaging:               ${lyx_use_packaging}\n\
 238   LyX binary dir:          ${real_bindir}\n\
 239   LyX files dir:           ${real_pkgdatadir}\n"
 240
 241 AC_SUBST(VERSION_INFO)
 242 AC_SUBST(AM_CPPFLAGS)
 243 AC_SUBST(AM_CXXFLAGS)
 244 AC_SUBST(AM_LDFLAGS)
 245 AC_SUBST(real_pkgdatadir)
 246
 247 ## Some config.h stuff
 248
 249 AH_TOP([
 250 /* -*- C++ -*- */
 251 /*
 252  * \file config.h
 253  * This file is part of LyX, the document processor.
 254  * Licence details can be found in the file COPYING.
 255  *
 256  * This is the compilation configuration file for LyX.
 257  * It was generated by autoconfs configure.
 258  * You might want to change some of the defaults if something goes wrong
 259  * during the compilation.
 260  */
 261
 262 #ifndef _CONFIG_H
 263 #define _CONFIG_H
 264 ])
 265
 266 AH_BOTTOM([
 267 /************************************************************
 268  ** You should not need to change anything beyond this point */
 269
 270 #ifndef HAVE_STRERROR
 271 #if defined(__cplusplus)
 272 extern "C"
 273 #endif
 274 char * strerror(int n);
 275 #endif
 276
 277 #ifdef __CYGWIN__
 278 #  define _DEFAULT_SOURCE
 279 #  define NOMINMAX
 280 #endif
 281
 282 #ifdef __sparc__
 283 #  ifndef __BIG_ENDIAN__
 284 #    define __BIG_ENDIAN__ 1
 285 #  endif
 286 #endif
 287
 288 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 289 #  define USE_WCHAR_T
 290 #endif
 291
 292 #endif
 293 ])
 294
 295 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 296 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 297 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 298
 299 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 300         "${lyx_abs_top_srcdir}", [Top source directory])
 301 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 302         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 303 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 304         "${lyx_abs_installed_datadir}",[Hard system support directory])
 305 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 306         "${version_suffix}",[Program version suffix])
 307
 308 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 309 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 310 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 311 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 312 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 313 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 314 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 315 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 316
 317 AC_CONFIG_FILES([Makefile \
 318       lyx.1:lyx.1in \
 319       3rdparty/Makefile \
 320       3rdparty/dtl/Makefile \
 321       3rdparty/hunspell/Makefile \
 322       3rdparty/mythes/Makefile \
 323       3rdparty/libiconv/Makefile \
 324       $ICONV_ICONV_H_IN \
 325       3rdparty/zlib/Makefile \
 326       autotests/Makefile \
 327       config/Makefile \
 328       development/Makefile \
 329       development/MacOSX/Makefile \
 330       development/MacOSX/Info.plist \
 331       development/MacOSX/lyxrc.dist \
 332       development/MacOSX/spotlight/Makefile \
 333       development/cygwin/Makefile \
 334       development/cygwin/lyxrc.dist \
 335       development/lyx.spec \
 336       lib/lyx.desktop-temp:lib/lyx.desktop.in
 337       lib/Makefile \
 338       lib/doc/Makefile \
 339       lib/lyx2lyx/lyx2lyx_version.py \
 340       lib/lyx2lyx/Makefile \
 341       m4/Makefile \
 342       po/Makefile.in \
 343       sourcedoc/Doxyfile \
 344       sourcedoc/Makefile \
 345       src/client/Makefile \
 346       src/client/lyxclient.1:src/client/lyxclient.1in \
 347       src/Makefile \
 348       src/tex2lyx/Makefile \
 349       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 350       src/convert/Makefile \
 351       src/support/Makefile \
 352       src/frontends/Makefile \
 353       src/frontends/qt/Makefile
 354 ])
 355
 356
 357 AC_OUTPUT
 358
 359 # show version information
 360 echo
 361 printf "$VERSION_INFO"
 362 echo
 363
 364 # Display a final warning if there has been a LYX_WARNING
 365 LYX_CHECK_WARNINGS
 366
 367 cat <<EOF
 368 Configuration of LyX was successful.
 369 Type 'make' to compile the program,
 370 and then 'make install' to install it.
 371 EOF