configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.3.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2016-04-16"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 # Automake is pulling the historical V7 format. This tar format supports
  36 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  37 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  39 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  40 PACKAGE=$save_PACKAGE
  41
  42 # Allow to build some parts of the code as one big chunk
  43 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  44 AC_ARG_ENABLE(monolithic-build,
  45   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  46                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  47   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  48    test "$enable_monolithic_build" = no && enable_monolithic_build=
  49    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  50    for i in $enable_monolithic_build ; do
  51        eval "enable_monolithic_$i=yes"
  52    done
  53    IFS="$ac_save_ifs"],
  54   [enable_monolithic_build=])
  55
  56 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  63
  64 ### Set the execute permissions of the various scripts correctly
  65 for file in config/install-sh ; do
  66   chmod 755 ${srcdir}/${file}
  67 done
  68
  69 # Find a suitable python interpreter
  70 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  71 # do the usual python setup stuff
  72 AM_PATH_PYTHON
  73
  74 # Tools for creating libraries (note that we do not use libtool)
  75 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  76 AC_PROG_RANLIB
  77 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  78 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  79 AC_SUBST([ARFLAGS], [cr])
  80
  81 ### Check for a C++ compiler
  82 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  83 dnl if it is not set. We do not use autoconf defaults.
  84 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  85 if ! test "$lyx_has_CXXFLAGS" = yes; then
  86   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  87   CXXFLAGS=" "
  88 fi
  89 LYX_PROG_CXX
  90 if ! test "$lyx_has_CXXFLAGS" = yes; then
  91   unset CXXFLAGS
  92 fi
  93 AC_LANG(C++)
  94
  95 ### Objective-C compiler
  96 AC_PROG_OBJC
  97 _AM_DEPENDENCIES([OBJC])
  98
  99 ### Add extra directories to check for libraries.
 100 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 101 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 102 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 103
 104 ### Add extra directories to check for include files.
 105 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 107 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 108
 109 ### Add both includes and libraries
 110 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 111 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 112   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 113   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 114 ])
 115
 116 ### These are needed in windows
 117 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 118 AC_SUBST(LIBSHLWAPI)
 119 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 120 AC_SUBST(LIBPSAPI)
 121 AC_CHECK_LIB(gdi32, main)
 122 AC_CHECK_LIB(ole32, main)
 123
 124 LYX_USE_INCLUDED_BOOST
 125 LYX_USE_INCLUDED_MYTHES
 126
 127 ### we need to know the byte order for unicode conversions
 128 AC_C_BIGENDIAN
 129
 130 # Nice to have when an assertion triggers
 131 LYX_CHECK_CALLSTACK_PRINTING
 132
 133 # C++14 only
 134 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 135
 136 # Needed for our char_type
 137 AC_CHECK_SIZEOF(wchar_t)
 138
 139 # Taken from gettext, needed for libiconv
 140 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 141    [AC_TRY_COMPILE([#include <stddef.h>
 142       wchar_t foo = (wchar_t)'\0';], ,
 143       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 144 if test $gt_cv_c_wchar_t = yes; then
 145   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 146   HAVE_WCHAR_T=1
 147 else
 148   HAVE_WCHAR_T=0
 149 fi
 150 AC_SUBST([HAVE_WCHAR_T])
 151
 152 # Needed for Mingw-w64
 153 AC_TYPE_LONG_LONG_INT
 154 if test "$ac_cv_type_long_long_int" = yes; then
 155   AC_CHECK_SIZEOF(long)
 156   AC_CHECK_SIZEOF(long long)
 157 fi
 158
 159 ### We need iconv for unicode support (Qt4 frontend requires it too)
 160 LYX_USE_INCLUDED_ICONV
 161
 162 ### check for compression support
 163 LYX_USE_INCLUDED_ZLIB
 164
 165 ### check for file magic support (currently optional)
 166 AC_CHECK_HEADERS(magic.h,
 167  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 168   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 169    is correctly installed on your system.
 170    Falling back to builtin file format detection.]))],
 171  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 172    is correctly installed on your system.
 173    Falling back to builtin file format detection.])])
 174
 175 ### setup the qt frontend.
 176 dnl The code below is not in a macro, because this would cause big
 177 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 178 QT_DO_IT_ALL([4.5.0])
 179 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 180 FRONTEND_INFO="${FRONTEND_INFO}\
 181   Qt Frontend:\n\
 182       Qt version:\t   ${QTLIB_VERSION}\n"
 183
 184 # fix the value of the prefixes.
 185 test "x$prefix" = xNONE && prefix=$default_prefix
 186 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 187 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 188   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 189    causes problems with the Makefiles. The installation will be done in
 190    directory \"`pwd`/installprefix\" instead. Please move its contents to
 191    the right place after installation.])
 192   prefix=`pwd`/installprefix
 193 fi
 194
 195 ### Setup po directory
 196 AM_NLS
 197 if test $USE_NLS = "yes" ; then
 198   AC_DEFINE(ENABLE_NLS, 1,
 199     [Define to 1 if translation of program messages to the user's native language
 200    is requested.])dnl'
 201 fi
 202 AM_PO_SUBDIRS
 203
 204 # some standard header files
 205 AC_HEADER_MAJOR
 206 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 207
 208 # some standard types
 209 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 210 AC_TYPE_OFF_T
 211 AC_TYPE_PID_T
 212 AC_TYPE_SIZE_T
 213 AC_TYPE_UID_T
 214
 215 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 216
 217 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 218 # Check the form of mkdir()
 219 AC_FUNC_MKDIR
 220 AC_FUNC_SELECT_ARGTYPES
 221
 222 LYX_CHECK_SPELL_ENGINES
 223
 224 lyx_client_subdir=true
 225 dnl AC_LANG_PUSH(C)
 226 dnl LIBS already contains some X extra libs that may interfere.
 227 save_LIBS="$LIBS"
 228 LIBS=
 229 AC_CHECK_FUNCS(fcntl,
 230   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 231    AC_SEARCH_LIBS([socket], [socket network], [],
 232      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 233                 [], [-lnsl])])],
 234   [lyx_client_subdir=false])
 235 AC_SUBST(SOCKET_LIBS,$LIBS)
 236 LIBS="$save_LIBS"
 237 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 238 dnl AC_LANG_POP(C)
 239
 240 lyx_win_res=false;
 241 case ${host} in
 242     *mingw*|*cygwin*) lyx_win_res=true;;
 243     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 244 esac
 245 if test "x$lyx_win_res" = "xtrue"; then
 246     AC_CHECK_TOOL(RC, windres,)
 247     if test -z "$RC"; then
 248       AC_ERROR([Could not find a resource compiler])
 249     fi
 250 fi
 251 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 252 LYX_SET_VERSION_INFO
 253
 254
 255 ### Some information on what just happened
 256 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 257 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 258 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 259 VERSION_INFO="Configuration\n\
 260   Host type:               ${host}\n\
 261   Special build flags:     ${lyx_flags}\n\
 262   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 263   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 264   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 265   Linker flags:            ${AM_LDFLAGS}\n\
 266   Linker user flags:       ${LDFLAGS}\n\
 267 ${FRONTEND_INFO}\
 268   Packaging:               ${lyx_use_packaging}\n\
 269   LyX binary dir:          ${real_bindir}\n\
 270   LyX files dir:           ${real_pkgdatadir}\n"
 271
 272 AC_SUBST(VERSION_INFO)
 273 AC_SUBST(AM_CPPFLAGS)
 274 AC_SUBST(AM_CXXFLAGS)
 275 AC_SUBST(AM_LDFLAGS)
 276 AC_SUBST(real_pkgdatadir)
 277
 278 ## Some config.h stuff
 279
 280 AH_TOP([
 281 /* -*- C++ -*- */
 282 /*
 283  * \file config.h
 284  * This file is part of LyX, the document processor.
 285  * Licence details can be found in the file COPYING.
 286  *
 287  * This is the compilation configuration file for LyX.
 288  * It was generated by autoconfs configure.
 289  * You might want to change some of the defaults if something goes wrong
 290  * during the compilation.
 291  */
 292
 293 #ifndef _CONFIG_H
 294 #define _CONFIG_H
 295 ])
 296
 297 AH_BOTTOM([
 298 /************************************************************
 299  ** You should not need to change anything beyond this point */
 300
 301 #ifndef HAVE_STRERROR
 302 #if defined(__cplusplus)
 303 extern "C"
 304 #endif
 305 char * strerror(int n);
 306 #endif
 307
 308 #define BOOST_USER_CONFIG <config.h>
 309
 310 #if !defined(ENABLE_ASSERTIONS)
 311 #  define BOOST_DISABLE_ASSERTS 1
 312 #endif
 313 #define BOOST_ENABLE_ASSERT_HANDLER 1
 314
 315 #define BOOST_DISABLE_THREADS 1
 316 #define BOOST_NO_WREGEX 1
 317 #define BOOST_NO_WSTRING 1
 318
 319 #ifdef __CYGWIN__
 320 #  define _DEFAULT_SOURCE
 321 #  define NOMINMAX
 322 #  define BOOST_POSIX 1
 323 #  define BOOST_POSIX_API 1
 324 #  define BOOST_POSIX_PATH 1
 325 #endif
 326
 327 #ifdef __sparc__
 328 #  ifndef __BIG_ENDIAN__
 329 #    define __BIG_ENDIAN__ 1
 330 #  endif
 331 #endif
 332
 333 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 334 #  define USE_WCHAR_T
 335 #endif
 336
 337 #ifdef HAVE_LONG_LONG_INT
 338 #if SIZEOF_LONG_LONG > SIZEOF_LONG
 339 #define LYX_USE_LONG_LONG
 340 #endif
 341 #endif
 342
 343 #endif
 344 ])
 345
 346 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 347 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 348 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 349
 350 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 351         "${lyx_abs_top_srcdir}", [Top source directory])
 352 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 353         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 354 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 355         "${lyx_abs_installed_datadir}",[Hard system support directory])
 356 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 357         "${version_suffix}",[Program version suffix])
 358
 359 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 360 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 361 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 362 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 363 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 364 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 365 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 366 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 367
 368 AC_CONFIG_FILES([Makefile \
 369       lyx.1:lyx.1in \
 370       3rdparty/Makefile \
 371       3rdparty/boost/Makefile \
 372       3rdparty/hunspell/Makefile \
 373       3rdparty/libiconv/Makefile \
 374       $ICONV_ICONV_H_IN \
 375       3rdparty/zlib/Makefile \
 376       autotests/Makefile \
 377       config/Makefile \
 378       development/Makefile \
 379       development/MacOSX/Makefile \
 380       development/MacOSX/Info.plist \
 381       development/MacOSX/lyxrc.dist \
 382       development/MacOSX/spotlight/Makefile \
 383       development/cygwin/Makefile \
 384       development/cygwin/lyxrc.dist \
 385       development/lyx.spec \
 386       lib/lyx.desktop-temp:lib/lyx.desktop.in
 387       lib/Makefile \
 388       lib/doc/Makefile \
 389       lib/lyx2lyx/lyx2lyx_version.py \
 390       lib/lyx2lyx/Makefile \
 391       m4/Makefile \
 392       po/Makefile.in \
 393       sourcedoc/Doxyfile \
 394       sourcedoc/Makefile \
 395       src/client/Makefile \
 396       src/client/lyxclient.1:src/client/lyxclient.1in \
 397       src/Makefile \
 398       src/tex2lyx/Makefile \
 399       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 400       src/support/Makefile \
 401       src/frontends/Makefile \
 402       src/frontends/qt4/Makefile
 403 ])
 404
 405
 406 AC_OUTPUT
 407
 408 # show version information
 409 echo
 410 printf "$VERSION_INFO"
 411 echo
 412
 413 # Display a final warning if there has been a LYX_WARNING
 414 LYX_CHECK_WARNINGS
 415
 416 cat <<EOF
 417 Configuration of LyX was successful.
 418 Type 'make' to compile the program,
 419 and then 'make install' to install it.
 420 EOF