configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.4.0dev],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2021-02-14"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT6
  17 if test x$USE_QT6 = xno ; then
  18 LYX_CHECK_QT5
  19 fi
  20 # Check how the files should be packaged
  21 AC_CANONICAL_TARGET
  22 LYX_USE_PACKAGING
  23 # We need to define these variables here and the no-define option of
  24 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  25 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  26
  27 dnl Default maintainer mode to true for development versions
  28 if test "${enable_maintainer_mode+set}" != set; then
  29   enable_maintainer_mode=$lyx_devel_version
  30 fi
  31 AM_MAINTAINER_MODE
  32 AM_SILENT_RULES([yes])
  33 # Automake is pulling the historical V7 format. This tar format supports
  34 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  35 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  36 save_PACKAGE=$PACKAGE
  37 AM_INIT_AUTOMAKE([foreign dist-xz no-define 1.14 tar-ustar subdir-objects])
  38 PACKAGE=$save_PACKAGE
  39
  40 ### Set the execute permissions of the various scripts correctly
  41 for file in config/install-sh ; do
  42   chmod 755 ${srcdir}/${file}
  43 done
  44
  45 # Find a suitable python interpreter
  46 LYX_PATH_PYTHON23([2.7.0], [3.5.0])
  47 # do the usual python setup stuff
  48 AM_PATH_PYTHON
  49
  50 # Tools for creating libraries (note that we do not use libtool)
  51 AM_PROG_AR
  52 AC_PROG_RANLIB
  53 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  54 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  55 AC_SUBST([ARFLAGS], [cr])
  56
  57 ### Check for a C++ compiler
  58 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  59 dnl if it is not set. We do not use autoconf defaults.
  60 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  61 if ! test "$lyx_has_CXXFLAGS" = yes; then
  62   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  63   CXXFLAGS=" "
  64 fi
  65 LYX_PROG_CXX
  66 if ! test "$lyx_has_CXXFLAGS" = yes; then
  67   unset CXXFLAGS
  68 fi
  69 AC_LANG(C++)
  70
  71 ### Objective-C compiler
  72 AC_PROG_OBJC
  73 _AM_DEPENDENCIES([OBJC])
  74
  75 ### Add extra directories to check for libraries.
  76 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  77 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  78 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  79
  80 ### Add extra directories to check for include files.
  81 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  82 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  83 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  84
  85 ### Add both includes and libraries
  86 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  87 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  88   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  89   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  90 ])
  91
  92 ### These are needed in windows
  93 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  94 AC_SUBST(LIBSHLWAPI)
  95 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  96 AC_SUBST(LIBPSAPI)
  97 AC_CHECK_LIB(gdi32, main)
  98 AC_CHECK_LIB(ole32, main)
  99
 100 LYX_USE_INCLUDED_NOD
 101 LYX_USE_INCLUDED_BOOST
 102
 103 ### we need to know the byte order for unicode conversions
 104 AC_C_BIGENDIAN
 105
 106 # Nice to have when an assertion triggers
 107 LYX_CHECK_CALLSTACK_PRINTING
 108
 109 # C++14 only
 110 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 111
 112 # Needed for our char_type
 113 AC_CHECK_SIZEOF(wchar_t)
 114
 115 # Taken from gettext, needed for libiconv
 116 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 117    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 118       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 119 if test $gt_cv_c_wchar_t = yes; then
 120   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 121   HAVE_WCHAR_T=1
 122 else
 123   HAVE_WCHAR_T=0
 124 fi
 125 AC_SUBST([HAVE_WCHAR_T])
 126
 127 # Needed for Mingw-w64
 128 AC_TYPE_LONG_LONG_INT
 129
 130 ### We need iconv for unicode support (Qt frontend requires it too)
 131 LYX_USE_INCLUDED_ICONV
 132
 133 ### check for compression support
 134 LYX_USE_INCLUDED_ZLIB
 135
 136 ### check whether we build and install the supplied dtl programs
 137 LYX_BUILD_INCLUDED_DTL
 138
 139 ### check for file magic support (currently optional)
 140 AC_CHECK_HEADERS(magic.h,
 141  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 142   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 143    is correctly installed on your system.
 144    Falling back to builtin file format detection.]))],
 145  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 146    is correctly installed on your system.
 147    Falling back to builtin file format detection.])])
 148
 149 ### setup the qt frontend.
 150 dnl The code below is not in a macro, because this would cause big
 151 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 152 QT_DO_IT_ALL([4.5.0])
 153 AC_SUBST([FRONTENDS_SUBDIRS], [qt])
 154 FRONTEND_INFO="${FRONTEND_INFO}\
 155   Qt Frontend:\n\
 156       Qt version:\t   ${QTLIB_VERSION}\n"
 157
 158 # fix the value of the prefixes.
 159 test "x$prefix" = xNONE && prefix=$default_prefix
 160 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 161 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 162   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 163    causes problems with the Makefiles. The installation will be done in
 164    directory \"`pwd`/installprefix\" instead. Please move its contents to
 165    the right place after installation.])
 166   prefix=`pwd`/installprefix
 167 fi
 168
 169 ### Setup po directory
 170 AM_NLS
 171 if test $USE_NLS = "yes" ; then
 172   AC_DEFINE(ENABLE_NLS, 1,
 173     [Define to 1 if translation of program messages to the user's native language
 174    is requested.])dnl'
 175 fi
 176 AM_PO_SUBDIRS
 177
 178 # some standard header files
 179 AC_HEADER_MAJOR
 180 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 181
 182 # some standard types
 183 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 184 AC_TYPE_OFF_T
 185 AC_TYPE_PID_T
 186 AC_TYPE_SIZE_T
 187 AC_TYPE_UID_T
 188
 189 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 190
 191 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 192 # Check the form of mkdir()
 193 AC_FUNC_MKDIR
 194 AC_FUNC_SELECT_ARGTYPES
 195
 196 if test "$lyx_use_packaging" = "macosx" ; then
 197   LYX_CHECK_MACOS_DEPLOYMENT_TARGET
 198 fi
 199
 200 LYX_CHECK_SPELL_ENGINES
 201 LYX_USE_INCLUDED_MYTHES
 202
 203 LYX_CHECK_WITH_SAXON
 204 LYX_CHECK_WITH_XSLT_SHEETS
 205
 206 lyx_client_subdir=true
 207 dnl LIBS already contains some X extra libs that may interfere.
 208 save_LIBS="$LIBS"
 209 LIBS=
 210 AC_CHECK_FUNCS(fcntl,
 211   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 212    AC_SEARCH_LIBS([socket], [socket network], [],
 213      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 214                 [], [-lnsl])])],
 215   [lyx_client_subdir=false])
 216 AC_SUBST(SOCKET_LIBS,$LIBS)
 217 LIBS="$save_LIBS"
 218 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 219
 220 lyx_win_res=false;
 221 case ${host} in
 222     *mingw*|*cygwin*) lyx_win_res=true;;
 223     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 224 esac
 225 if test "x$lyx_win_res" = "xtrue"; then
 226     AC_CHECK_TOOL(RC, windres,)
 227     if test -z "$RC"; then
 228       AC_MSG_ERROR([Could not find a resource compiler])
 229     fi
 230 fi
 231 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 232 LYX_SET_VERSION_INFO
 233
 234
 235 ### Some information on what just happened
 236 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 237 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 238 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 239 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 240 VERSION_INFO="Configuration\n\
 241   Host type:               ${host}\n\
 242   Special build flags:     ${lyx_flags}\n\
 243   Bundled libraries:       ${lyx_included_libs}\n\
 244   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 245   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 246   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 247   Linker flags:            ${AM_LDFLAGS}\n\
 248   Linker user flags:       ${LDFLAGS}\n\
 249 ${FRONTEND_INFO}\
 250   Packaging:               ${lyx_use_packaging}\n\
 251   LyX binary dir:          ${real_bindir}\n\
 252   LyX files dir:           ${real_pkgdatadir}\n"
 253
 254 AC_SUBST(VERSION_INFO)
 255 AC_SUBST(AM_CPPFLAGS)
 256 AC_SUBST(AM_CXXFLAGS)
 257 AC_SUBST(AM_LDFLAGS)
 258 AC_SUBST(real_pkgdatadir)
 259
 260 ## Some config.h stuff
 261
 262 AH_TOP([
 263 /* -*- C++ -*- */
 264 /*
 265  * \file config.h
 266  * This file is part of LyX, the document processor.
 267  * Licence details can be found in the file COPYING.
 268  *
 269  * This is the compilation configuration file for LyX.
 270  * It was generated by autoconfs configure.
 271  * You might want to change some of the defaults if something goes wrong
 272  * during the compilation.
 273  */
 274
 275 #ifndef _CONFIG_H
 276 #define _CONFIG_H
 277 ])
 278
 279 AH_BOTTOM([
 280 /************************************************************
 281  ** You should not need to change anything beyond this point */
 282
 283 #ifndef HAVE_STRERROR
 284 #if defined(__cplusplus)
 285 extern "C"
 286 #endif
 287 char * strerror(int n);
 288 #endif
 289
 290 #define BOOST_USER_CONFIG <config.h>
 291
 292 #if !defined(ENABLE_ASSERTIONS)
 293 #  define BOOST_DISABLE_ASSERTS 1
 294 #endif
 295 #define BOOST_ENABLE_ASSERT_HANDLER 1
 296
 297 #define BOOST_DISABLE_THREADS 1
 298 #define BOOST_NO_WREGEX 1
 299 #define BOOST_NO_WSTRING 1
 300
 301 #ifdef __CYGWIN__
 302 #  define _DEFAULT_SOURCE
 303 #  define NOMINMAX
 304 #  define BOOST_POSIX 1
 305 #  define BOOST_POSIX_API 1
 306 #  define BOOST_POSIX_PATH 1
 307 #endif
 308
 309 #ifdef __sparc__
 310 #  ifndef __BIG_ENDIAN__
 311 #    define __BIG_ENDIAN__ 1
 312 #  endif
 313 #endif
 314
 315 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 316 #  define USE_WCHAR_T
 317 #endif
 318
 319 #endif
 320 ])
 321
 322 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 323 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 324 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 325
 326 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 327         "${lyx_abs_top_srcdir}", [Top source directory])
 328 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 329         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 330 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 331         "${lyx_abs_installed_datadir}",[Hard system support directory])
 332 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 333         "${version_suffix}",[Program version suffix])
 334
 335 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 336 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 337 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 338 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 339 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 340 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 341 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 342 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 343
 344 AC_CONFIG_FILES([Makefile \
 345       lyx.1:lyx.1in \
 346       3rdparty/Makefile \
 347       3rdparty/boost/Makefile \
 348       3rdparty/dtl/Makefile \
 349       3rdparty/hunspell/Makefile \
 350       3rdparty/mythes/Makefile \
 351       3rdparty/nod/Makefile \
 352       3rdparty/libiconv/Makefile \
 353       $ICONV_ICONV_H_IN \
 354       3rdparty/zlib/Makefile \
 355       autotests/Makefile \
 356       config/Makefile \
 357       development/Makefile \
 358       development/MacOSX/Makefile \
 359       development/MacOSX/Info.plist \
 360       development/MacOSX/lyxrc.dist \
 361       development/MacOSX/spotlight/Makefile \
 362       development/cygwin/Makefile \
 363       development/cygwin/lyxrc.dist \
 364       development/lyx.spec \
 365       lib/lyx.desktop-temp:lib/lyx.desktop.in
 366       lib/Makefile \
 367       lib/doc/Makefile \
 368       lib/lyx2lyx/lyx2lyx_version.py \
 369       lib/lyx2lyx/Makefile \
 370       m4/Makefile \
 371       po/Makefile.in \
 372       sourcedoc/Doxyfile \
 373       sourcedoc/Makefile \
 374       src/client/Makefile \
 375       src/client/lyxclient.1:src/client/lyxclient.1in \
 376       src/Makefile \
 377       src/tex2lyx/Makefile \
 378       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 379       src/convert/Makefile \
 380       src/support/Makefile \
 381       src/frontends/Makefile \
 382       src/frontends/qt/Makefile
 383 ])
 384
 385
 386 AC_OUTPUT
 387
 388 # show version information
 389 echo
 390 printf "$VERSION_INFO"
 391 echo
 392
 393 # Display a final warning if there has been a LYX_WARNING
 394 LYX_CHECK_WARNINGS
 395
 396 cat <<EOF
 397 Configuration of LyX was successful.
 398 Type 'make' to compile the program,
 399 and then 'make install' to install it.
 400 EOF