configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.4.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2018-02-24"])
   7 AC_PREREQ(2.65)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29 AM_SILENT_RULES([yes])
  30 # Automake is pulling the historical V7 format. This tar format supports
  31 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  32 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  33 save_PACKAGE=$PACKAGE
  34 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar subdir-objects])
  35 PACKAGE=$save_PACKAGE
  36
  37 ### Set the execute permissions of the various scripts correctly
  38 for file in config/install-sh ; do
  39   chmod 755 ${srcdir}/${file}
  40 done
  41
  42 # Find a suitable python interpreter
  43 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  44 # do the usual python setup stuff
  45 AM_PATH_PYTHON
  46
  47 # Tools for creating libraries (note that we do not use libtool)
  48 AM_PROG_AR
  49 AC_PROG_RANLIB
  50 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  51 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  52 AC_SUBST([ARFLAGS], [cr])
  53
  54 ### Check for a C++ compiler
  55 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  56 dnl if it is not set. We do not use autoconf defaults.
  57 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  58 if ! test "$lyx_has_CXXFLAGS" = yes; then
  59   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  60   CXXFLAGS=" "
  61 fi
  62 LYX_PROG_CXX
  63 if ! test "$lyx_has_CXXFLAGS" = yes; then
  64   unset CXXFLAGS
  65 fi
  66 AC_LANG(C++)
  67
  68 ### Objective-C compiler
  69 AC_PROG_OBJC
  70 _AM_DEPENDENCIES([OBJC])
  71
  72 ### Add extra directories to check for libraries.
  73 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  74 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  75 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  76
  77 ### Add extra directories to check for include files.
  78 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  79 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  80 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  81
  82 ### Add both includes and libraries
  83 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  84 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  85   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  86   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  87 ])
  88
  89 ### These are needed in windows
  90 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  91 AC_SUBST(LIBSHLWAPI)
  92 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  93 AC_SUBST(LIBPSAPI)
  94 AC_CHECK_LIB(gdi32, main)
  95 AC_CHECK_LIB(ole32, main)
  96
  97 LYX_USE_INCLUDED_BOOST
  98
  99 ### we need to know the byte order for unicode conversions
 100 AC_C_BIGENDIAN
 101
 102 # Nice to have when an assertion triggers
 103 LYX_CHECK_CALLSTACK_PRINTING
 104
 105 # C++14 only
 106 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 107
 108 # Needed for our char_type
 109 AC_CHECK_SIZEOF(wchar_t)
 110
 111 # Taken from gettext, needed for libiconv
 112 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 113    [AC_TRY_COMPILE([#include <stddef.h>
 114       wchar_t foo = (wchar_t)'\0';], ,
 115       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 116 if test $gt_cv_c_wchar_t = yes; then
 117   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 118   HAVE_WCHAR_T=1
 119 else
 120   HAVE_WCHAR_T=0
 121 fi
 122 AC_SUBST([HAVE_WCHAR_T])
 123
 124 # Needed for Mingw-w64
 125 AC_TYPE_LONG_LONG_INT
 126 if test "$ac_cv_type_long_long_int" = yes; then
 127   AC_CHECK_SIZEOF(long)
 128   AC_CHECK_SIZEOF(long long)
 129 fi
 130
 131 ### We need iconv for unicode support (Qt4 frontend requires it too)
 132 LYX_USE_INCLUDED_ICONV
 133
 134 ### check for compression support
 135 LYX_USE_INCLUDED_ZLIB
 136
 137 ### check for file magic support (currently optional)
 138 AC_CHECK_HEADERS(magic.h,
 139  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 140   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 141    is correctly installed on your system.
 142    Falling back to builtin file format detection.]))],
 143  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 144    is correctly installed on your system.
 145    Falling back to builtin file format detection.])])
 146
 147 ### setup the qt frontend.
 148 dnl The code below is not in a macro, because this would cause big
 149 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 150 QT_DO_IT_ALL([4.5.0])
 151 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 152 FRONTEND_INFO="${FRONTEND_INFO}\
 153   Qt Frontend:\n\
 154       Qt version:\t   ${QTLIB_VERSION}\n"
 155
 156 # fix the value of the prefixes.
 157 test "x$prefix" = xNONE && prefix=$default_prefix
 158 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 159 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 160   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 161    causes problems with the Makefiles. The installation will be done in
 162    directory \"`pwd`/installprefix\" instead. Please move its contents to
 163    the right place after installation.])
 164   prefix=`pwd`/installprefix
 165 fi
 166
 167 ### Setup po directory
 168 AM_NLS
 169 if test $USE_NLS = "yes" ; then
 170   AC_DEFINE(ENABLE_NLS, 1,
 171     [Define to 1 if translation of program messages to the user's native language
 172    is requested.])dnl'
 173 fi
 174 AM_PO_SUBDIRS
 175
 176 # some standard header files
 177 AC_HEADER_MAJOR
 178 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 179
 180 # some standard types
 181 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 182 AC_TYPE_OFF_T
 183 AC_TYPE_PID_T
 184 AC_TYPE_SIZE_T
 185 AC_TYPE_UID_T
 186
 187 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 188
 189 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 190 # Check the form of mkdir()
 191 AC_FUNC_MKDIR
 192 AC_FUNC_SELECT_ARGTYPES
 193
 194 LYX_CHECK_SPELL_ENGINES
 195 LYX_USE_INCLUDED_MYTHES
 196
 197 lyx_client_subdir=true
 198 dnl AC_LANG_PUSH(C)
 199 dnl LIBS already contains some X extra libs that may interfere.
 200 save_LIBS="$LIBS"
 201 LIBS=
 202 AC_CHECK_FUNCS(fcntl,
 203   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 204    AC_SEARCH_LIBS([socket], [socket network], [],
 205      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 206                 [], [-lnsl])])],
 207   [lyx_client_subdir=false])
 208 AC_SUBST(SOCKET_LIBS,$LIBS)
 209 LIBS="$save_LIBS"
 210 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 211 dnl AC_LANG_POP(C)
 212
 213 lyx_win_res=false;
 214 case ${host} in
 215     *mingw*|*cygwin*) lyx_win_res=true;;
 216     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 217 esac
 218 if test "x$lyx_win_res" = "xtrue"; then
 219     AC_CHECK_TOOL(RC, windres,)
 220     if test -z "$RC"; then
 221       AC_ERROR([Could not find a resource compiler])
 222     fi
 223 fi
 224 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 225 LYX_SET_VERSION_INFO
 226
 227
 228 ### Some information on what just happened
 229 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 230 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 231 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 232 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 233 VERSION_INFO="Configuration\n\
 234   Host type:               ${host}\n\
 235   Special build flags:     ${lyx_flags}\n\
 236   Bundled libraries:       ${lyx_included_libs}\n\
 237   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 238   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 239   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 240   Linker flags:            ${AM_LDFLAGS}\n\
 241   Linker user flags:       ${LDFLAGS}\n\
 242 ${FRONTEND_INFO}\
 243   Packaging:               ${lyx_use_packaging}\n\
 244   LyX binary dir:          ${real_bindir}\n\
 245   LyX files dir:           ${real_pkgdatadir}\n"
 246
 247 AC_SUBST(VERSION_INFO)
 248 AC_SUBST(AM_CPPFLAGS)
 249 AC_SUBST(AM_CXXFLAGS)
 250 AC_SUBST(AM_LDFLAGS)
 251 AC_SUBST(real_pkgdatadir)
 252
 253 ## Some config.h stuff
 254
 255 AH_TOP([
 256 /* -*- C++ -*- */
 257 /*
 258  * \file config.h
 259  * This file is part of LyX, the document processor.
 260  * Licence details can be found in the file COPYING.
 261  *
 262  * This is the compilation configuration file for LyX.
 263  * It was generated by autoconfs configure.
 264  * You might want to change some of the defaults if something goes wrong
 265  * during the compilation.
 266  */
 267
 268 #ifndef _CONFIG_H
 269 #define _CONFIG_H
 270 ])
 271
 272 AH_BOTTOM([
 273 /************************************************************
 274  ** You should not need to change anything beyond this point */
 275
 276 #ifndef HAVE_STRERROR
 277 #if defined(__cplusplus)
 278 extern "C"
 279 #endif
 280 char * strerror(int n);
 281 #endif
 282
 283 #define BOOST_USER_CONFIG <config.h>
 284
 285 #if !defined(ENABLE_ASSERTIONS)
 286 #  define BOOST_DISABLE_ASSERTS 1
 287 #endif
 288 #define BOOST_ENABLE_ASSERT_HANDLER 1
 289
 290 #define BOOST_DISABLE_THREADS 1
 291 #define BOOST_NO_WREGEX 1
 292 #define BOOST_NO_WSTRING 1
 293
 294 #ifdef __CYGWIN__
 295 #  define _DEFAULT_SOURCE
 296 #  define NOMINMAX
 297 #  define BOOST_POSIX 1
 298 #  define BOOST_POSIX_API 1
 299 #  define BOOST_POSIX_PATH 1
 300 #endif
 301
 302 #ifdef __sparc__
 303 #  ifndef __BIG_ENDIAN__
 304 #    define __BIG_ENDIAN__ 1
 305 #  endif
 306 #endif
 307
 308 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 309 #  define USE_WCHAR_T
 310 #endif
 311
 312 #ifdef HAVE_LONG_LONG_INT
 313 #if SIZEOF_LONG_LONG > SIZEOF_LONG
 314 #define LYX_USE_LONG_LONG
 315 #endif
 316 #endif
 317
 318 #endif
 319 ])
 320
 321 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 322 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 323 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 324
 325 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 326         "${lyx_abs_top_srcdir}", [Top source directory])
 327 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 328         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 329 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 330         "${lyx_abs_installed_datadir}",[Hard system support directory])
 331 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 332         "${version_suffix}",[Program version suffix])
 333
 334 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 335 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 336 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 337 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 338 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 339 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 340 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 341 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 342
 343 AC_CONFIG_FILES([Makefile \
 344       lyx.1:lyx.1in \
 345       3rdparty/Makefile \
 346       3rdparty/boost/Makefile \
 347       3rdparty/hunspell/Makefile \
 348       3rdparty/mythes/Makefile \
 349       3rdparty/libiconv/Makefile \
 350       $ICONV_ICONV_H_IN \
 351       3rdparty/zlib/Makefile \
 352       autotests/Makefile \
 353       config/Makefile \
 354       development/Makefile \
 355       development/MacOSX/Makefile \
 356       development/MacOSX/Info.plist \
 357       development/MacOSX/lyxrc.dist \
 358       development/MacOSX/spotlight/Makefile \
 359       development/cygwin/Makefile \
 360       development/cygwin/lyxrc.dist \
 361       development/lyx.spec \
 362       lib/lyx.desktop-temp:lib/lyx.desktop.in
 363       lib/Makefile \
 364       lib/doc/Makefile \
 365       lib/lyx2lyx/lyx2lyx_version.py \
 366       lib/lyx2lyx/Makefile \
 367       m4/Makefile \
 368       po/Makefile.in \
 369       sourcedoc/Doxyfile \
 370       sourcedoc/Makefile \
 371       src/client/Makefile \
 372       src/client/lyxclient.1:src/client/lyxclient.1in \
 373       src/Makefile \
 374       src/tex2lyx/Makefile \
 375       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 376       src/convert/Makefile \
 377       src/support/Makefile \
 378       src/frontends/Makefile \
 379       src/frontends/qt4/Makefile
 380 ])
 381
 382
 383 AC_OUTPUT
 384
 385 # show version information
 386 echo
 387 printf "$VERSION_INFO"
 388 echo
 389
 390 # Display a final warning if there has been a LYX_WARNING
 391 LYX_CHECK_WARNINGS
 392
 393 cat <<EOF
 394 Configuration of LyX was successful.
 395 Type 'make' to compile the program,
 396 and then 'make install' to install it.
 397 EOF