configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2014-04-14"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 # Check how the files should be packaged
  17 AC_CANONICAL_TARGET
  18 LYX_USE_PACKAGING
  19 # We need to define these variables here and the no-define option of
  20 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  22
  23 dnl Default maintainer mode to true for development versions
  24 if test "${enable_maintainer_mode+set}" != set; then
  25   enable_maintainer_mode=$lyx_devel_version
  26 fi
  27 AM_MAINTAINER_MODE
  28
  29 save_PACKAGE=$PACKAGE
  30 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  31 dnl which are the versions where subdir-objects can beused.
  32 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  33 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  34 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8] LYX_OBJECTS_LAYOUT)
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36 PACKAGE=$save_PACKAGE
  37
  38 LYX_CHECK_GIT_COMMIT
  39
  40 # Allow to build some parts of the code as one big chunk
  41 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  42 AC_ARG_ENABLE(monolithic-build,
  43   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  44                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  45   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  46    test "$enable_monolithic_build" = no && enable_monolithic_build=
  47    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  48    for i in $enable_monolithic_build ; do
  49        eval "enable_monolithic_$i=yes"
  50    done
  51    IFS="$ac_save_ifs"],
  52   [enable_monolithic_build=])
  53
  54 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  55 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  56 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  61
  62 ### Set the execute permissions of the various scripts correctly
  63 for file in config/install-sh ; do
  64   chmod 755 ${srcdir}/${file}
  65 done
  66
  67 AM_PATH_PYTHON(2.4.0,, :)
  68 AC_PROG_RANLIB
  69
  70 ### Check for a C++ compiler
  71 LYX_PROG_CXX
  72 AC_LANG(C++)
  73
  74 ### Objective-C compiler
  75 AC_PROG_OBJC
  76 _AM_DEPENDENCIES([OBJC])
  77
  78 ### Add extra directories to check for libraries.
  79 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  80 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  81 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  82
  83 ### Add extra directories to check for include files.
  84 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  85 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  86 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  87
  88 ### Add both includes and libraries
  89 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  90 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  91 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  92   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  93
  94 ### These are needed in windows
  95 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  96 AC_SUBST(LIBSHLWAPI)
  97 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  98 AC_SUBST(LIBPSAPI)
  99 AC_CHECK_LIB(gdi32, main)
 100
 101 LYX_USE_INCLUDED_BOOST
 102 LYX_USE_INCLUDED_MYTHES
 103
 104 ### we need to know the byte order for unicode conversions
 105 AC_C_BIGENDIAN
 106
 107 # Nice to have when an assertion triggers
 108 LYX_CHECK_CALLSTACK_PRINTING
 109
 110 # Needed for our char_type
 111 AC_CHECK_SIZEOF(wchar_t)
 112
 113 ### We need iconv for unicode support (Qt4 frontend requires it too)
 114 AM_ICONV
 115 if test "$am_cv_func_iconv" = no; then
 116   AC_MSG_ERROR([cannot find required library iconv.])
 117 else
 118   LIBS="$LIBS $LIBICONV"
 119 fi
 120
 121 ### check for compression support
 122 AC_CHECK_HEADERS(zlib.h,
 123  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 124  [LYX_LIB_ERROR(zlib.h,zlib)])
 125
 126 ### check for file magic support (currently optional)
 127 AC_CHECK_HEADERS(magic.h,
 128  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 129   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 130    is correctly installed on your system.
 131    Falling back to builtin file format detection.]))],
 132  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 133    is correctly installed on your system.
 134    Falling back to builtin file format detection.])])
 135
 136 ### setup the qt frontend.
 137 dnl The code below is not in a macro, because this would cause big
 138 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 139 QT_DO_IT_ALL([4.5.0])
 140 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 141 FRONTEND_INFO="${FRONTEND_INFO}\
 142   Qt Frontend:\n\
 143       Qt version:\t\t${QTLIB_VERSION}\n"
 144
 145 # fix the value of the prefixes.
 146 test "x$prefix" = xNONE && prefix=$default_prefix
 147 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 148 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 149   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 150    causes problems with the Makefiles. The installation will be done in
 151    directory \"`pwd`/installprefix\" instead. Please move its contents to
 152    the right place after installation.])
 153   prefix=`pwd`/installprefix
 154 fi
 155
 156 ### Setup po directory
 157 AM_PO_SUBDIRS
 158 AM_NLS
 159 if test $USE_NLS = "yes" ; then
 160   AC_DEFINE(ENABLE_NLS, 1,
 161     [Define to 1 if translation of program messages to the user's native language
 162    is requested.])dnl'
 163 fi
 164
 165 # some standard header files
 166 AC_HEADER_MAJOR
 167 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 168
 169 # some standard types
 170 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 171 AC_TYPE_OFF_T
 172 AC_TYPE_PID_T
 173 AC_TYPE_SIZE_T
 174 AC_TYPE_UID_T
 175 # Taken from gettext
 176 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 177    [AC_TRY_COMPILE([#include <stddef.h>
 178       wchar_t foo = (wchar_t)'\0';], ,
 179       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 180 if test $gt_cv_c_wchar_t = yes; then
 181   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 182 fi
 183
 184 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 185
 186 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 187 # Check the form of mkdir()
 188 AC_FUNC_MKDIR
 189 AC_FUNC_SELECT_ARGTYPES
 190
 191 LYX_CHECK_SPELL_ENGINES
 192
 193 lyx_client_subdir=true
 194 dnl AC_LANG_PUSH(C)
 195 dnl LIBS already contains some X extra libs that may interfere.
 196 save_LIBS="$LIBS"
 197 LIBS=
 198 AC_CHECK_FUNCS(fcntl,
 199   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 200    AC_SEARCH_LIBS([socket], [socket], [],
 201      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 202                 [], [-lnsl])])],
 203   [lyx_client_subdir=false])
 204 AC_SUBST(SOCKET_LIBS,$LIBS)
 205 LIBS="$save_LIBS"
 206 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 207 dnl AC_LANG_POP(C)
 208
 209 lyx_win_res=false;
 210 case ${host} in
 211     *mingw*|*cygwin*) lyx_win_res=true;;
 212 esac
 213 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 214 LYX_SET_VERSION_INFO
 215
 216
 217 ### Some information on what just happened
 218 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 219 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 220 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 221 VERSION_INFO="Configuration\n\
 222   Host type:                    ${host}\n\
 223   Special build flags:         ${lyx_flags}\n\
 224   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 225   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 226   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 227   Linker flags:                 ${AM_LDFLAGS}\n\
 228   Linker user flags:            ${LDFLAGS}\n\
 229 ${FRONTEND_INFO}\
 230   Packaging:                    ${lyx_use_packaging}\n\
 231   LyX binary dir:               ${real_bindir}\n\
 232   LyX files dir:                ${real_pkgdatadir}\n"
 233
 234 AC_SUBST(VERSION_INFO)
 235 AC_SUBST(AM_CPPFLAGS)
 236 AC_SUBST(AM_CXXFLAGS)
 237 AC_SUBST(AM_CFLAGS)
 238 AC_SUBST(AM_LDFLAGS)
 239 AC_SUBST(real_pkgdatadir)
 240
 241 ## Some config.h stuff
 242
 243 AH_TOP([
 244 /* -*- C++ -*- */
 245 /*
 246  * \file config.h
 247  * This file is part of LyX, the document processor.
 248  * Licence details can be found in the file COPYING.
 249  *
 250  * This is the compilation configuration file for LyX.
 251  * It was generated by autoconfs configure.
 252  * You might want to change some of the defaults if something goes wrong
 253  * during the compilation.
 254  */
 255
 256 #ifndef _CONFIG_H
 257 #define _CONFIG_H
 258 ])
 259
 260 AH_BOTTOM([
 261 /************************************************************
 262  ** You should not need to change anything beyond this point */
 263
 264 #ifndef HAVE_STRERROR
 265 #if defined(__cplusplus)
 266 extern "C"
 267 #endif
 268 char * strerror(int n);
 269 #endif
 270
 271 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 272 #  define USE_BOOST_FORMAT 1
 273 #else
 274 #  define USE_BOOST_FORMAT 0
 275 #endif
 276
 277 #define BOOST_USER_CONFIG <config.h>
 278
 279 #if !defined(ENABLE_ASSERTIONS)
 280 #  define BOOST_DISABLE_ASSERTS 1
 281 #endif
 282 #define BOOST_ENABLE_ASSERT_HANDLER 1
 283
 284 #define BOOST_DISABLE_THREADS 1
 285 #define BOOST_NO_WREGEX 1
 286 #define BOOST_NO_WSTRING 1
 287 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 288
 289 // TR1 regex not supported in GCC <= 4.5
 290 #ifndef LYX_USE_TR1
 291 #  if __GNUC__ == 4
 292 #    define LYX_USE_TR1
 293 #  endif
 294 #endif
 295
 296 #ifdef __CYGWIN__
 297 #  define NOMINMAX
 298 #  define BOOST_POSIX 1
 299 #  define BOOST_POSIX_API 1
 300 #  define BOOST_POSIX_PATH 1
 301 #endif
 302
 303 #ifdef __sparc__
 304 #  ifndef __BIG_ENDIAN__
 305 #    define __BIG_ENDIAN__ 1
 306 #  endif
 307 #endif
 308
 309 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 310 #  define USE_WCHAR_T
 311 #endif
 312
 313 #endif
 314 ])
 315
 316 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 317 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 318 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 319
 320 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 321         "${lyx_abs_top_srcdir}", [Top source directory])
 322 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 323         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 324 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 325         "${lyx_abs_installed_datadir}",[Hard system support directory])
 326 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 327         "${version_suffix}",[Program version suffix])
 328
 329 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 330 AC_DEFINE_UNQUOTED([LYX_GIT_COMMIT_HASH], "$lyxgitcommit", [Git commit])
 331 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 332 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 333 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 334 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 335 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 336 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 337 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 338
 339 AC_CONFIG_FILES([Makefile \
 340       lyx.1:lyx.1in \
 341       boost/Makefile \
 342       config/Makefile \
 343       development/Makefile \
 344       development/MacOSX/Makefile \
 345       development/MacOSX/Info.plist \
 346       development/MacOSX/lyxrc.dist \
 347       development/MacOSX/spotlight/Makefile \
 348       development/cygwin/Makefile \
 349       development/cygwin/lyxrc.dist \
 350       development/lyx.spec \
 351       lib/lyx.desktop-temp:lib/lyx.desktop.in
 352       lib/Makefile \
 353       lib/doc/Makefile \
 354       lib/lyx2lyx/lyx2lyx_version.py \
 355       lib/lyx2lyx/Makefile \
 356       m4/Makefile \
 357       po/Makefile.in \
 358       sourcedoc/Doxyfile \
 359       sourcedoc/Makefile \
 360       src/client/Makefile \
 361       src/client/lyxclient.1:src/client/lyxclient.1in \
 362       src/Makefile \
 363       src/tex2lyx/Makefile \
 364       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 365       src/support/Makefile \
 366       src/frontends/Makefile \
 367       src/frontends/qt4/Makefile
 368 ])
 369
 370
 371 AC_OUTPUT
 372
 373 # show version information
 374 echo
 375 printf "$VERSION_INFO"
 376 echo
 377
 378 # Display a final warning if there has been a LYX_WARNING
 379 LYX_CHECK_WARNINGS
 380
 381 cat <<EOF
 382 Configuration of LyX was successful.
 383 Type 'make' to compile the program,
 384 and then 'make install' to install it.
 385 EOF