configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 ### Set the execute permissions of the various scripts correctly
  26 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  27   chmod 755 ${srcdir}/${file}
  28 done
  29
  30 ### Check for programs
  31 AC_PROG_MAKE_SET
  32 AC_PROG_INSTALL
  33 #AC_PROG_RANLIB
  34 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  35 if test "x$KPSEWHICH" = xkpsewhich ; then
  36     AC_DEFINE(HAVE_KPSEWHICH, 1,
  37     [Define this if you have the kpsewhich program working on your system.])
  38 fi
  39 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  40
  41 # Check for installed python
  42 AM_PATH_PYTHON(1.5.2,, :)
  43
  44 # Work around a problem in automake 1.4: when invoking install-strip,
  45 # INSTALL_PROGRAM is changed to 'install -s', and since
  46 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  47 # which returns an error condition when stripping fails.
  48 INSTALL_SCRIPT='${INSTALL}'
  49
  50 ### we will also need a C compiler to compile GNU gettext
  51 AC_PROG_CC
  52
  53 ### check for special systems
  54 AC_ISC_POSIX
  55 AC_AIX
  56
  57 ### check which frontend we want to use
  58 LYX_USE_FRONTENDS
  59
  60 ### Check for a C++ compiler
  61 LYX_PROG_CXX
  62 ### Some checks on what the C++ compiler can(not) do
  63 AC_LANG(C++)
  64 dnl we do not need that currently (and probably all our supported
  65 dnl compiler allow that)
  66 dnl LYX_CXX_PARTIAL
  67 LYX_CXX_EXPLICIT
  68 LYX_CXX_GLOBAL_CSTD
  69 LYX_STD_COUNT
  70 dnl we disable rtti for now
  71 dnl LYX_CXX_RTTI
  72 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  73 LYX_CXX_STL_MODERN_STREAMS
  74
  75 ### and now some special lyx flags.
  76 AC_ARG_ENABLE(assertions,
  77   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  78   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  79         enable_assertions=yes;
  80     else
  81         enable_assertions=no;
  82     fi;])
  83 if test "x$enable_assertions" = xyes ; then
  84    lyx_flags="assertions $lyx_flags"
  85    AC_DEFINE(ENABLE_ASSERTIONS,1,
  86     [Define if you want assertions to be enabled in the code])
  87 fi
  88
  89 ### Library Files
  90 dnl by testing these we check if it is ok to have
  91 dnl -lc and -lm as args to the compiler
  92 AC_CHECK_LIB(m, sin)
  93 AC_CHECK_LIB(c, fopen)
  94
  95 ### Add extra directories to check for libraries.
  96 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  97 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  98 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  99
 100 ### Add extra directories to check for include files.
 101 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 103 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 104
 105 ### Add both includes and libraries
 106 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 107 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 108 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 109   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 110
 111 AC_ARG_WITH(aiksaurus,
 112   [  --without-aiksaurus     do not use the Aiksaurus library],
 113   [lyx_use_aiksaurus=$withval])
 114 if test x$lyx_use_aiksaurus != xno; then
 115 AC_CHECK_LIB(Aiksaurus, main,
 116         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 117          AIKSAURUS_LIBS="-lAiksaurus"
 118          lyx_flags="aiksaurus $lyx_flags"
 119         ])
 120 AC_CHECK_HEADER(Aiksaurus.h,[
 121   ac_cv_header_aiksaurus_h=yes
 122   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 123 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 124   ac_cv_header_aiksaurus_h=yes
 125   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 126 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 127 fi
 128 AC_SUBST(AIKSAURUS_LIBS)
 129
 130 LYX_USE_INCLUDED_BOOST
 131
 132 ### Setup libtool
 133 AC_DISABLE_SHARED
 134 AC_LIBTOOL_WIN32_DLL
 135 #AM_PROG_LIBTOOL
 136 LYX_PROG_LIBTOOL
 137
 138 ### Check for some Cygwin-specific details.
 139 CHECK_WITH_CYGWIN
 140
 141 ### Check for X libraries
 142 AC_PATH_XTRA
 143 case $have_x in
 144   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 145        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 146   no) LYX_ERROR(dnl
 147 [Cannot find X window libraries and/or headers. Check your installation.
 148   If you use a Linux system, check that you have installed
 149   the development tools.]);;
 150   disable) ;;
 151 esac
 152
 153 ### check which frontend we want to use
 154
 155 dnl if the gtk frontend has been specified, then xforms is needed too
 156 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 157   FRONTENDS="xforms $FRONTENDS"
 158   noxformsbin=yes
 159 fi
 160
 161 dnl The code below is not in a macro, because this would cause big
 162 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 163 for frontend in $FRONTENDS ; do
 164   case "$frontend" in
 165     xforms)
 166           XFORMS_DO_IT_ALL
 167           if test -z "$noxformsbin" ; then
 168             FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 169           fi
 170           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 171           RPM_FRONTEND="xforms"
 172           FRONTEND_INFO="${FRONTEND_INFO}\
 173   XForms Frontend:\n\
 174       libXpm version:\t\t${XPM_VERSION}\n\
 175       libforms version:\t\t${XFORMS_VERSION}\n"
 176           ;;
 177   dnl   gnome)
 178   dnl     XFORMS_DO_IT_ALL
 179   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 180   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 181   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 182
 183   dnl     FRONTEND="xforms gnome"
 184   dnl     FRONTEND_GUILIB="gnome/*.lo"
 185   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 186   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 187   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 188   dnl   ;;
 189     gtk)
 190           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 191           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 192           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 193           RPM_FRONTEND="gtk"
 194           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 195           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 196           FRONTEND_INFO="${FRONTEND_INFO}\
 197   GTK Frontend:\n\
 198     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 199     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 200           ;;
 201
 202     qt)
 203           QT_DO_IT_ALL
 204           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 205           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 206           RPM_FRONTEND="qt"
 207           FRONTEND_INFO="${FRONTEND_INFO}\
 208   Qt Frontend:\n\
 209       Qt version:\t\t${QT_VERSION}\n"
 210 dnl qt build will fail without moc or uic
 211           if test -z "$MOC"; then
 212             LYX_ERROR([moc binary not found !])
 213           fi
 214           if test -z "$UIC"; then
 215             LYX_ERROR([uic binary not found !])
 216           fi
 217       ;;
 218     *)
 219           LYX_ERROR(Unknown frontend '$frontend');;
 220   esac
 221 done
 222
 223 ### Check how the files should be packaged
 224 LYX_USE_PACKAGING
 225 # fix the value of the prefixes.
 226 test "x$prefix" = xNONE && prefix=$default_prefix
 227 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 228 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 229   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 230    causes problems with the Makefiles. The installation will be done in
 231    directory \"`pwd`/installprefix\" instead. Please move its contents to
 232    the right place after installation.])
 233   prefix=`pwd`/installprefix
 234 fi
 235
 236 ### Setup GNU gettext
 237 dnl GNU gettext is written in C
 238 AC_LANG_PUSH(C)
 239 AM_GNU_GETTEXT
 240 AC_LANG_POP(C)
 241
 242 # some standard header files
 243 AC_HEADER_DIRENT
 244 AC_HEADER_MAJOR
 245 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h)
 246
 247 # some standard structures
 248 AC_HEADER_STAT
 249 AC_HEADER_TIME
 250
 251 # some standard types
 252 AC_TYPE_MODE_T
 253 AC_TYPE_OFF_T
 254 AC_TYPE_PID_T
 255 AC_TYPE_SIGNAL
 256 AC_TYPE_SIZE_T
 257 AC_TYPE_UID_T
 258
 259 AC_CHECK_FUNCS(strerror)
 260 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 261 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 262
 263 # Check the form of mkdir()
 264 AC_FUNC_MKDIR
 265
 266 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 267     case "${enableval}" in
 268         yes) use_compression=true ;;
 269         no) use_compression=false ;;
 270         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 271     esac
 272 ],[use_compression=true])
 273 if test $use_compression=true ; then
 274         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 275         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 276         if test $use_compression = true ; then
 277                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 278                 lyx_flags="compression $lyx_flags"
 279         fi
 280 fi
 281 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 282 AC_MSG_CHECKING([whether to support compressed files])
 283 AC_MSG_RESULT($use_compression)
 284
 285
 286 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 287 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 288 dnl We aim to remove this eventually, since we should test as much as
 289 dnl possible with the compiler which will use the functions (JMarc)
 290 AC_LANG_PUSH(C)
 291 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 292 AC_LANG_POP(C)
 293
 294 LYX_CHECK_SPELL_ENGINES
 295
 296 lyx_client_subdir=true
 297 AC_LANG_PUSH(C)
 298 AC_CHECK_FUNCS(fcntl,, [lyx_client_subdir=false])
 299 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 300 AC_LANG_POP(C)
 301
 302
 303 AC_FUNC_SELECT_ARGTYPES
 304
 305 ### Some information on what just happened
 306 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 307 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 308 VERSION_INFO="Configuration\n\
 309   Host type:                      ${host}\n\
 310   Special build flags:            ${lyx_flags}\n\
 311   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 312   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 313   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 314   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 315   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 316   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 317   Linker flags:                   ${AM_LDFLAGS}\n\
 318   Linker user flags:              ${LDFLAGS}\n\
 319 ${FRONTEND_INFO}\
 320   Packaging:                      ${lyx_use_packaging}\n\
 321   LyX binary dir:                 ${real_bindir}\n\
 322   LyX files dir:                  ${real_datadir}\n"
 323
 324
 325 AC_SUBST(VERSION_INFO)
 326 AC_SUBST(RPM_FRONTEND)
 327 AC_SUBST(AM_CPPFLAGS)
 328 AC_SUBST(AM_CXXFLAGS)
 329 AC_SUBST(AM_CFLAGS)
 330 AC_SUBST(AM_LDFLAGS)
 331
 332 ## Some config.h stuff
 333
 334 AH_TOP([
 335 /* -*- C++ -*- */
 336 /*
 337  * \file config.h
 338  * This file is part of LyX, the document processor.
 339  * Licence details can be found in the file COPYING.
 340  *
 341  * This is the compilation configuration file for LyX.
 342  * It was generated by autoconfs configure.
 343  * You might want to change some of the defaults if something goes wrong
 344  * during the compilation.
 345  */
 346
 347 #ifndef _CONFIG_H
 348 #define _CONFIG_H
 349 ])
 350
 351 AH_BOTTOM([
 352 /************************************************************
 353  ** You should not need to change anything beyond this point */
 354
 355 #ifndef HAVE_STRERROR
 356 #if defined(__cplusplus)
 357 extern "C"
 358 #endif
 359 char * strerror(int n);
 360 #endif
 361
 362 #ifdef HAVE_MKSTEMP
 363 #ifndef HAVE_DECL_MKSTEMP
 364 #if defined(__cplusplus)
 365 extern "C"
 366 #endif
 367 int mkstemp(char*);
 368 #endif
 369 #endif
 370
 371 #ifdef __EMX__
 372 #include "support/os2_defines.h"
 373 #endif
 374
 375 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 376 #define USE_BOOST_FORMAT 1
 377 #else
 378 #define USE_BOOST_FORMAT 0
 379 #endif
 380
 381 #define BOOST_USER_CONFIG <config.h>
 382
 383 #if defined(ENABLE_ASSERTIONS)
 384 #define BOOST_ENABLE_ASSERT_HANDLER 1
 385 #else
 386 #define BOOST_DISABLE_ASSERTS 1
 387 #endif
 388
 389 #define BOOST_DISABLE_THREADS 1
 390 #define BOOST_NO_WREGEX 1
 391 #define BOOST_NO_WSTRING 1
 392
 393 #ifdef __CYGWIN__
 394 #define BOOST_POSIX 1
 395 #endif
 396
 397 #endif
 398 ])
 399
 400 ### Finish the work.
 401 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 402 AC_CONFIG_FILES([Makefile  m4/Makefile \
 403        boost/Makefile \
 404        boost/libs/Makefile \
 405        boost/libs/filesystem/Makefile \
 406        boost/libs/filesystem/src/Makefile \
 407        boost/libs/regex/Makefile \
 408        boost/libs/regex/src/Makefile \
 409        boost/libs/signals/Makefile \
 410        boost/libs/signals/src/Makefile \
 411        config/Makefile \
 412        development/Makefile \
 413        development/lyx.spec \
 414        lib/Makefile \
 415        lib/doc/Makefile \
 416        lib/lyx2lyx/Makefile \
 417        intl/Makefile \
 418        po/Makefile.in \
 419        sourcedoc/Doxyfile \
 420        sourcedoc/Makefile \
 421        src/client/Makefile \
 422        src/Makefile \
 423        src/version.C-tmp:src/version.C.in \
 424        src/tex2lyx/Makefile \
 425        src/mathed/Makefile \
 426        src/graphics/Makefile \
 427        src/insets/Makefile \
 428        src/support/Makefile \
 429        src/support/tests/Makefile \
 430        src/frontends/Makefile \
 431        src/frontends/controllers/Makefile \
 432        src/frontends/xforms/Makefile \
 433        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 434        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 435        src/frontends/xforms/forms/Makefile \
 436        src/frontends/gtk/Makefile \
 437        src/frontends/gtk/gimages/Makefile \
 438        src/frontends/gtk/glade/Makefile \
 439        src/frontends/qt2/Makefile \
 440        src/frontends/qt2/moc/Makefile \
 441        src/frontends/qt2/ui/Makefile \
 442        src/frontends/qt2/ui/moc/Makefile \
 443 ])
 444
 445 AC_OUTPUT
 446 # show version information
 447 echo
 448 printf "$VERSION_INFO"
 449 echo
 450
 451 # Display a final warning if there has been a LYX_ERROR
 452 LYX_CHECK_ERRORS