configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.3.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2016-04-16"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 # Automake is pulling the historical V7 format. This tar format supports
  36 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  37 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  39 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  40 PACKAGE=$save_PACKAGE
  41
  42 # Allow to build some parts of the code as one big chunk
  43 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  44 AC_ARG_ENABLE(monolithic-build,
  45   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  46                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  47   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  48    test "$enable_monolithic_build" = no && enable_monolithic_build=
  49    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  50    for i in $enable_monolithic_build ; do
  51        eval "enable_monolithic_$i=yes"
  52    done
  53    IFS="$ac_save_ifs"],
  54   [enable_monolithic_build=])
  55
  56 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  63
  64 ### Set the execute permissions of the various scripts correctly
  65 for file in config/install-sh ; do
  66   chmod 755 ${srcdir}/${file}
  67 done
  68
  69 # Find a suitable python interpreter
  70 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  71 # do the usual python setup stuff
  72 AM_PATH_PYTHON
  73
  74 # Tools for creating libraries (note that we do not use libtool)
  75 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  76 AC_PROG_RANLIB
  77
  78 ### Check for a C++ compiler
  79 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  80 dnl if it is not set. We do not use autoconf defaults.
  81 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  82 if ! test "$lyx_has_CXXFLAGS" = yes; then
  83   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  84   CXXFLAGS=" "
  85 fi
  86 LYX_PROG_CXX
  87 if ! test "$lyx_has_CXXFLAGS" = yes; then
  88   unset CXXFLAGS
  89 fi
  90 AC_LANG(C++)
  91
  92 ### Objective-C compiler
  93 AC_PROG_OBJC
  94 _AM_DEPENDENCIES([OBJC])
  95
  96 ### Add extra directories to check for libraries.
  97 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  98 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  99 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 100
 101 ### Add extra directories to check for include files.
 102 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 104 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 105
 106 ### Add both includes and libraries
 107 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 108 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 109   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 110   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 111 ])
 112
 113 ### These are needed in windows
 114 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 115 AC_SUBST(LIBSHLWAPI)
 116 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 117 AC_SUBST(LIBPSAPI)
 118 AC_CHECK_LIB(gdi32, main)
 119 AC_CHECK_LIB(ole32, main)
 120
 121 LYX_USE_INCLUDED_BOOST
 122 LYX_USE_INCLUDED_MYTHES
 123
 124 ### we need to know the byte order for unicode conversions
 125 AC_C_BIGENDIAN
 126
 127 # Nice to have when an assertion triggers
 128 LYX_CHECK_CALLSTACK_PRINTING
 129
 130 # Needed for our char_type
 131 AC_CHECK_SIZEOF(wchar_t)
 132
 133 # Needed for Mingw-w64
 134 AC_TYPE_LONG_LONG_INT
 135 if test "$ac_cv_type_long_long_int" = yes; then
 136   AC_CHECK_SIZEOF(long)
 137   AC_CHECK_SIZEOF(long long)
 138 fi
 139
 140 ### We need iconv for unicode support (Qt4 frontend requires it too)
 141 AM_ICONV
 142 if test "$am_cv_func_iconv" = no; then
 143   AC_MSG_ERROR([cannot find required library iconv.])
 144 else
 145   LIBS="$LIBS $LIBICONV"
 146 fi
 147
 148 ### check for compression support
 149 LYX_USE_INCLUDED_ZLIB
 150
 151 ### check for file magic support (currently optional)
 152 AC_CHECK_HEADERS(magic.h,
 153  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 154   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 155    is correctly installed on your system.
 156    Falling back to builtin file format detection.]))],
 157  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 158    is correctly installed on your system.
 159    Falling back to builtin file format detection.])])
 160
 161 ### setup the qt frontend.
 162 dnl The code below is not in a macro, because this would cause big
 163 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 164 QT_DO_IT_ALL([4.5.0])
 165 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 166 FRONTEND_INFO="${FRONTEND_INFO}\
 167   Qt Frontend:\n\
 168       Qt version:\t   ${QTLIB_VERSION}\n"
 169
 170 # fix the value of the prefixes.
 171 test "x$prefix" = xNONE && prefix=$default_prefix
 172 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 173 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 174   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 175    causes problems with the Makefiles. The installation will be done in
 176    directory \"`pwd`/installprefix\" instead. Please move its contents to
 177    the right place after installation.])
 178   prefix=`pwd`/installprefix
 179 fi
 180
 181 ### Setup po directory
 182 AM_NLS
 183 if test $USE_NLS = "yes" ; then
 184   AC_DEFINE(ENABLE_NLS, 1,
 185     [Define to 1 if translation of program messages to the user's native language
 186    is requested.])dnl'
 187 fi
 188 AM_PO_SUBDIRS
 189
 190 # some standard header files
 191 AC_HEADER_MAJOR
 192 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 193
 194 # some standard types
 195 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 196 AC_TYPE_OFF_T
 197 AC_TYPE_PID_T
 198 AC_TYPE_SIZE_T
 199 AC_TYPE_UID_T
 200 # Taken from gettext
 201 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 202    [AC_TRY_COMPILE([#include <stddef.h>
 203       wchar_t foo = (wchar_t)'\0';], ,
 204       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 205 if test $gt_cv_c_wchar_t = yes; then
 206   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 207 fi
 208
 209 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 210
 211 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 212 # Check the form of mkdir()
 213 AC_FUNC_MKDIR
 214 AC_FUNC_SELECT_ARGTYPES
 215
 216 LYX_CHECK_SPELL_ENGINES
 217
 218 lyx_client_subdir=true
 219 dnl AC_LANG_PUSH(C)
 220 dnl LIBS already contains some X extra libs that may interfere.
 221 save_LIBS="$LIBS"
 222 LIBS=
 223 AC_CHECK_FUNCS(fcntl,
 224   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 225    AC_SEARCH_LIBS([socket], [socket network], [],
 226      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 227                 [], [-lnsl])])],
 228   [lyx_client_subdir=false])
 229 AC_SUBST(SOCKET_LIBS,$LIBS)
 230 LIBS="$save_LIBS"
 231 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 232 dnl AC_LANG_POP(C)
 233
 234 lyx_win_res=false;
 235 case ${host} in
 236     *mingw*|*cygwin*) lyx_win_res=true;;
 237 esac
 238 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 239 LYX_SET_VERSION_INFO
 240
 241
 242 ### Some information on what just happened
 243 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 244 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 245 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 246 VERSION_INFO="Configuration\n\
 247   Host type:               ${host}\n\
 248   Special build flags:     ${lyx_flags}\n\
 249   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 250   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 251   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 252   Linker flags:            ${AM_LDFLAGS}\n\
 253   Linker user flags:       ${LDFLAGS}\n\
 254 ${FRONTEND_INFO}\
 255   Packaging:               ${lyx_use_packaging}\n\
 256   LyX binary dir:          ${real_bindir}\n\
 257   LyX files dir:           ${real_pkgdatadir}\n"
 258
 259 AC_SUBST(VERSION_INFO)
 260 AC_SUBST(AM_CPPFLAGS)
 261 AC_SUBST(AM_CXXFLAGS)
 262 AC_SUBST(AM_LDFLAGS)
 263 AC_SUBST(real_pkgdatadir)
 264
 265 ## Some config.h stuff
 266
 267 AH_TOP([
 268 /* -*- C++ -*- */
 269 /*
 270  * \file config.h
 271  * This file is part of LyX, the document processor.
 272  * Licence details can be found in the file COPYING.
 273  *
 274  * This is the compilation configuration file for LyX.
 275  * It was generated by autoconfs configure.
 276  * You might want to change some of the defaults if something goes wrong
 277  * during the compilation.
 278  */
 279
 280 #ifndef _CONFIG_H
 281 #define _CONFIG_H
 282 ])
 283
 284 AH_BOTTOM([
 285 /************************************************************
 286  ** You should not need to change anything beyond this point */
 287
 288 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 289 #define LYX_USE_CXX11
 290 #endif
 291
 292 #ifndef HAVE_STRERROR
 293 #if defined(__cplusplus)
 294 extern "C"
 295 #endif
 296 char * strerror(int n);
 297 #endif
 298
 299 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 300 #  define USE_BOOST_FORMAT 1
 301 #else
 302 #  define USE_BOOST_FORMAT 0
 303 #endif
 304
 305 #define BOOST_USER_CONFIG <config.h>
 306
 307 #if !defined(ENABLE_ASSERTIONS)
 308 #  define BOOST_DISABLE_ASSERTS 1
 309 #endif
 310 #define BOOST_ENABLE_ASSERT_HANDLER 1
 311
 312 #define BOOST_DISABLE_THREADS 1
 313 #define BOOST_NO_WREGEX 1
 314 #define BOOST_NO_WSTRING 1
 315 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 316
 317 #ifdef __CYGWIN__
 318 #  define NOMINMAX
 319 #  define BOOST_POSIX 1
 320 #  define BOOST_POSIX_API 1
 321 #  define BOOST_POSIX_PATH 1
 322 #endif
 323
 324 #ifdef __sparc__
 325 #  ifndef __BIG_ENDIAN__
 326 #    define __BIG_ENDIAN__ 1
 327 #  endif
 328 #endif
 329
 330 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 331 #  define USE_WCHAR_T
 332 #endif
 333
 334 #ifdef HAVE_LONG_LONG_INT
 335 #if SIZEOF_LONG_LONG > SIZEOF_LONG
 336 #define LYX_USE_LONG_LONG
 337 #endif
 338 #endif
 339
 340 #endif
 341 ])
 342
 343 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 344 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 345 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 346
 347 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 348         "${lyx_abs_top_srcdir}", [Top source directory])
 349 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 350         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 351 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 352         "${lyx_abs_installed_datadir}",[Hard system support directory])
 353 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 354         "${version_suffix}",[Program version suffix])
 355
 356 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 357 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 358 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 359 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 360 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 361 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 362 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 363 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 364
 365 AC_CONFIG_FILES([Makefile \
 366       lyx.1:lyx.1in \
 367       3rdparty/Makefile \
 368       3rdparty/boost/Makefile \
 369       3rdparty/hunspell/Makefile \
 370       3rdparty/libiconv/Makefile \
 371       3rdparty/zlib/Makefile \
 372       autotests/Makefile \
 373       config/Makefile \
 374       development/Makefile \
 375       development/MacOSX/Makefile \
 376       development/MacOSX/Info.plist \
 377       development/MacOSX/lyxrc.dist \
 378       development/MacOSX/spotlight/Makefile \
 379       development/cygwin/Makefile \
 380       development/cygwin/lyxrc.dist \
 381       development/lyx.spec \
 382       lib/lyx.desktop-temp:lib/lyx.desktop.in
 383       lib/Makefile \
 384       lib/doc/Makefile \
 385       lib/lyx2lyx/lyx2lyx_version.py \
 386       lib/lyx2lyx/Makefile \
 387       m4/Makefile \
 388       po/Makefile.in \
 389       sourcedoc/Doxyfile \
 390       sourcedoc/Makefile \
 391       src/client/Makefile \
 392       src/client/lyxclient.1:src/client/lyxclient.1in \
 393       src/Makefile \
 394       src/tex2lyx/Makefile \
 395       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 396       src/support/Makefile \
 397       src/frontends/Makefile \
 398       src/frontends/qt4/Makefile
 399 ])
 400
 401
 402 AC_OUTPUT
 403
 404 # show version information
 405 echo
 406 printf "$VERSION_INFO"
 407 echo
 408
 409 # Display a final warning if there has been a LYX_WARNING
 410 LYX_CHECK_WARNINGS
 411
 412 cat <<EOF
 413 Configuration of LyX was successful.
 414 Type 'make' to compile the program,
 415 and then 'make install' to install it.
 416 EOF