configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2014-04-14"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8] LYX_OBJECTS_LAYOUT)
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  37 PACKAGE=$save_PACKAGE
  38
  39 # Allow to build some parts of the code as one big chunk
  40 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  41 AC_ARG_ENABLE(monolithic-build,
  42   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  43                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  44   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  45    test "$enable_monolithic_build" = no && enable_monolithic_build=
  46    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  47    for i in $enable_monolithic_build ; do
  48        eval "enable_monolithic_$i=yes"
  49    done
  50    IFS="$ac_save_ifs"],
  51   [enable_monolithic_build=])
  52
  53 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  54 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  55 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  56 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  60
  61 ### Set the execute permissions of the various scripts correctly
  62 for file in config/install-sh ; do
  63   chmod 755 ${srcdir}/${file}
  64 done
  65
  66 # Find a suitable python interpreter
  67 LYX_PATH_PYTHON
  68 # do the usual python setup stuff
  69 AM_PATH_PYTHON
  70 AC_PROG_RANLIB
  71
  72 ### Check for a C++ compiler
  73 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  74 dnl if it is not set. We do not use autoconf defaults.
  75 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  76 if ! test "$lyx_has_CXXFLAGS" = yes; then
  77   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  78   CXXFLAGS=" "
  79 fi
  80 LYX_PROG_CXX
  81 if ! test "$lyx_has_CXXFLAGS" = yes; then
  82   unset CXXFLAGS
  83 fi
  84 AC_LANG(C++)
  85
  86 ### Objective-C compiler
  87 AC_PROG_OBJC
  88 _AM_DEPENDENCIES([OBJC])
  89
  90 ### Add extra directories to check for libraries.
  91 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  92 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  93 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  94
  95 ### Add extra directories to check for include files.
  96 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  97 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  98 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  99
 100 ### Add both includes and libraries
 101 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 102 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 103   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 104   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 105 ])
 106
 107 ### These are needed in windows
 108 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 109 AC_SUBST(LIBSHLWAPI)
 110 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 111 AC_SUBST(LIBPSAPI)
 112 AC_CHECK_LIB(gdi32, main)
 113
 114 LYX_USE_INCLUDED_BOOST
 115 LYX_USE_INCLUDED_MYTHES
 116
 117 ### we need to know the byte order for unicode conversions
 118 AC_C_BIGENDIAN
 119
 120 # Nice to have when an assertion triggers
 121 LYX_CHECK_CALLSTACK_PRINTING
 122
 123 # Needed for our char_type
 124 AC_CHECK_SIZEOF(wchar_t)
 125
 126 ### We need iconv for unicode support (Qt4 frontend requires it too)
 127 AM_ICONV
 128 if test "$am_cv_func_iconv" = no; then
 129   AC_MSG_ERROR([cannot find required library iconv.])
 130 else
 131   LIBS="$LIBS $LIBICONV"
 132 fi
 133
 134 ### check for compression support
 135 AC_CHECK_HEADERS(zlib.h,
 136  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 137  [LYX_LIB_ERROR(zlib.h,zlib)])
 138
 139 ### check for file magic support (currently optional)
 140 AC_CHECK_HEADERS(magic.h,
 141  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 142   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 143    is correctly installed on your system.
 144    Falling back to builtin file format detection.]))],
 145  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 146    is correctly installed on your system.
 147    Falling back to builtin file format detection.])])
 148
 149 ### setup the qt frontend.
 150 dnl The code below is not in a macro, because this would cause big
 151 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 152 QT_DO_IT_ALL([4.5.0])
 153 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 154 FRONTEND_INFO="${FRONTEND_INFO}\
 155   Qt Frontend:\n\
 156       Qt version:\t   ${QTLIB_VERSION}\n"
 157
 158 # fix the value of the prefixes.
 159 test "x$prefix" = xNONE && prefix=$default_prefix
 160 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 161 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 162   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 163    causes problems with the Makefiles. The installation will be done in
 164    directory \"`pwd`/installprefix\" instead. Please move its contents to
 165    the right place after installation.])
 166   prefix=`pwd`/installprefix
 167 fi
 168
 169 ### Setup po directory
 170 AM_PO_SUBDIRS
 171 AM_NLS
 172 if test $USE_NLS = "yes" ; then
 173   AC_DEFINE(ENABLE_NLS, 1,
 174     [Define to 1 if translation of program messages to the user's native language
 175    is requested.])dnl'
 176 fi
 177
 178 # some standard header files
 179 AC_HEADER_MAJOR
 180 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 181
 182 # some standard types
 183 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 184 AC_TYPE_OFF_T
 185 AC_TYPE_PID_T
 186 AC_TYPE_SIZE_T
 187 AC_TYPE_UID_T
 188 # Taken from gettext
 189 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 190    [AC_TRY_COMPILE([#include <stddef.h>
 191       wchar_t foo = (wchar_t)'\0';], ,
 192       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 193 if test $gt_cv_c_wchar_t = yes; then
 194   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 195 fi
 196
 197 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 198
 199 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 200 # Check the form of mkdir()
 201 AC_FUNC_MKDIR
 202 AC_FUNC_SELECT_ARGTYPES
 203
 204 LYX_CHECK_SPELL_ENGINES
 205
 206 lyx_client_subdir=true
 207 dnl AC_LANG_PUSH(C)
 208 dnl LIBS already contains some X extra libs that may interfere.
 209 save_LIBS="$LIBS"
 210 LIBS=
 211 AC_CHECK_FUNCS(fcntl,
 212   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 213    AC_SEARCH_LIBS([socket], [socket], [],
 214      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 215                 [], [-lnsl])])],
 216   [lyx_client_subdir=false])
 217 AC_SUBST(SOCKET_LIBS,$LIBS)
 218 LIBS="$save_LIBS"
 219 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 220 dnl AC_LANG_POP(C)
 221
 222 lyx_win_res=false;
 223 case ${host} in
 224     *mingw*|*cygwin*) lyx_win_res=true;;
 225 esac
 226 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 227 LYX_SET_VERSION_INFO
 228
 229
 230 ### Some information on what just happened
 231 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 232 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 233 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 234 VERSION_INFO="Configuration\n\
 235   Host type:               ${host}\n\
 236   Special build flags:     ${lyx_flags}\n\
 237   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 238   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 239   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 240   Linker flags:            ${AM_LDFLAGS}\n\
 241   Linker user flags:       ${LDFLAGS}\n\
 242 ${FRONTEND_INFO}\
 243   Packaging:               ${lyx_use_packaging}\n\
 244   LyX binary dir:          ${real_bindir}\n\
 245   LyX files dir:           ${real_pkgdatadir}\n"
 246
 247 AC_SUBST(VERSION_INFO)
 248 AC_SUBST(AM_CPPFLAGS)
 249 AC_SUBST(AM_CXXFLAGS)
 250 AC_SUBST(AM_LDFLAGS)
 251 AC_SUBST(real_pkgdatadir)
 252
 253 ## Some config.h stuff
 254
 255 AH_TOP([
 256 /* -*- C++ -*- */
 257 /*
 258  * \file config.h
 259  * This file is part of LyX, the document processor.
 260  * Licence details can be found in the file COPYING.
 261  *
 262  * This is the compilation configuration file for LyX.
 263  * It was generated by autoconfs configure.
 264  * You might want to change some of the defaults if something goes wrong
 265  * during the compilation.
 266  */
 267
 268 #ifndef _CONFIG_H
 269 #define _CONFIG_H
 270 ])
 271
 272 AH_BOTTOM([
 273 /************************************************************
 274  ** You should not need to change anything beyond this point */
 275
 276 #ifndef HAVE_STRERROR
 277 #if defined(__cplusplus)
 278 extern "C"
 279 #endif
 280 char * strerror(int n);
 281 #endif
 282
 283 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 284 #  define USE_BOOST_FORMAT 1
 285 #else
 286 #  define USE_BOOST_FORMAT 0
 287 #endif
 288
 289 #define BOOST_USER_CONFIG <config.h>
 290
 291 #if !defined(ENABLE_ASSERTIONS)
 292 #  define BOOST_DISABLE_ASSERTS 1
 293 #endif
 294 #define BOOST_ENABLE_ASSERT_HANDLER 1
 295
 296 #define BOOST_DISABLE_THREADS 1
 297 #define BOOST_NO_WREGEX 1
 298 #define BOOST_NO_WSTRING 1
 299 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 300
 301 #ifdef __CYGWIN__
 302 #  define NOMINMAX
 303 #  define BOOST_POSIX 1
 304 #  define BOOST_POSIX_API 1
 305 #  define BOOST_POSIX_PATH 1
 306 #endif
 307
 308 #ifdef __sparc__
 309 #  ifndef __BIG_ENDIAN__
 310 #    define __BIG_ENDIAN__ 1
 311 #  endif
 312 #endif
 313
 314 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 315 #  define USE_WCHAR_T
 316 #endif
 317
 318 #endif
 319 ])
 320
 321 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 322 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 323 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 324
 325 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 326         "${lyx_abs_top_srcdir}", [Top source directory])
 327 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 328         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 329 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 330         "${lyx_abs_installed_datadir}",[Hard system support directory])
 331 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 332         "${version_suffix}",[Program version suffix])
 333
 334 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 335 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 336 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 337 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 338 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 339 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 340 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 341 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 342
 343 AC_CONFIG_FILES([Makefile \
 344       lyx.1:lyx.1in \
 345       boost/Makefile \
 346       config/Makefile \
 347       development/Makefile \
 348       development/MacOSX/Makefile \
 349       development/MacOSX/Info.plist \
 350       development/MacOSX/lyxrc.dist \
 351       development/MacOSX/spotlight/Makefile \
 352       development/cygwin/Makefile \
 353       development/cygwin/lyxrc.dist \
 354       development/lyx.spec \
 355       lib/lyx.desktop-temp:lib/lyx.desktop.in
 356       lib/Makefile \
 357       lib/doc/Makefile \
 358       lib/lyx2lyx/lyx2lyx_version.py \
 359       lib/lyx2lyx/Makefile \
 360       m4/Makefile \
 361       po/Makefile.in \
 362       sourcedoc/Doxyfile \
 363       sourcedoc/Makefile \
 364       src/client/Makefile \
 365       src/client/lyxclient.1:src/client/lyxclient.1in \
 366       src/Makefile \
 367       src/tex2lyx/Makefile \
 368       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 369       src/support/Makefile \
 370       src/frontends/Makefile \
 371       src/frontends/qt4/Makefile
 372 ])
 373
 374
 375 AC_OUTPUT
 376
 377 # show version information
 378 echo
 379 printf "$VERSION_INFO"
 380 echo
 381
 382 # Display a final warning if there has been a LYX_WARNING
 383 LYX_CHECK_WARNINGS
 384
 385 cat <<EOF
 386 Configuration of LyX was successful.
 387 Type 'make' to compile the program,
 388 and then 'make install' to install it.
 389 EOF