configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.3.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2016-04-16"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 # Automake is pulling the historical V7 format. This tar format supports
  36 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  37 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  39 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  40 PACKAGE=$save_PACKAGE
  41
  42 # Allow to build some parts of the code as one big chunk
  43 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  44 AC_ARG_ENABLE(monolithic-build,
  45   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  46                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  47   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  48    test "$enable_monolithic_build" = no && enable_monolithic_build=
  49    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  50    for i in $enable_monolithic_build ; do
  51        eval "enable_monolithic_$i=yes"
  52    done
  53    IFS="$ac_save_ifs"],
  54   [enable_monolithic_build=])
  55
  56 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  63
  64 ### Set the execute permissions of the various scripts correctly
  65 for file in config/install-sh ; do
  66   chmod 755 ${srcdir}/${file}
  67 done
  68
  69 # Find a suitable python interpreter
  70 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  71 # do the usual python setup stuff
  72 AM_PATH_PYTHON
  73
  74 # Tools for creating libraries (note that we do not use libtool)
  75 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  76 AC_PROG_RANLIB
  77 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  78 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  79 AC_SUBST([ARFLAGS], [cr])
  80
  81 ### Check for a C++ compiler
  82 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  83 dnl if it is not set. We do not use autoconf defaults.
  84 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  85 if ! test "$lyx_has_CXXFLAGS" = yes; then
  86   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  87   CXXFLAGS=" "
  88 fi
  89 LYX_PROG_CXX
  90 if ! test "$lyx_has_CXXFLAGS" = yes; then
  91   unset CXXFLAGS
  92 fi
  93 AC_LANG(C++)
  94
  95 ### Objective-C compiler
  96 AC_PROG_OBJC
  97 _AM_DEPENDENCIES([OBJC])
  98
  99 ### Add extra directories to check for libraries.
 100 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 101 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 102 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 103
 104 ### Add extra directories to check for include files.
 105 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 107 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 108
 109 ### Add both includes and libraries
 110 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 111 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 112   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 113   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 114 ])
 115
 116 ### These are needed in windows
 117 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 118 AC_SUBST(LIBSHLWAPI)
 119 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 120 AC_SUBST(LIBPSAPI)
 121 AC_CHECK_LIB(gdi32, main)
 122 AC_CHECK_LIB(ole32, main)
 123
 124 LYX_USE_INCLUDED_BOOST
 125 LYX_USE_INCLUDED_MYTHES
 126
 127 ### we need to know the byte order for unicode conversions
 128 AC_C_BIGENDIAN
 129
 130 # Nice to have when an assertion triggers
 131 LYX_CHECK_CALLSTACK_PRINTING
 132
 133 # Needed for our char_type
 134 AC_CHECK_SIZEOF(wchar_t)
 135
 136 # Taken from gettext, needed for libiconv
 137 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 138    [AC_TRY_COMPILE([#include <stddef.h>
 139       wchar_t foo = (wchar_t)'\0';], ,
 140       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 141 if test $gt_cv_c_wchar_t = yes; then
 142   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 143   HAVE_WCHAR_T=1
 144 else
 145   HAVE_WCHAR_T=0
 146 fi
 147 AC_SUBST([HAVE_WCHAR_T])
 148
 149 # Needed for Mingw-w64
 150 AC_TYPE_LONG_LONG_INT
 151 if test "$ac_cv_type_long_long_int" = yes; then
 152   AC_CHECK_SIZEOF(long)
 153   AC_CHECK_SIZEOF(long long)
 154 fi
 155
 156 ### We need iconv for unicode support (Qt4 frontend requires it too)
 157 LYX_USE_INCLUDED_ICONV
 158
 159 ### check for compression support
 160 LYX_USE_INCLUDED_ZLIB
 161
 162 ### check for file magic support (currently optional)
 163 AC_CHECK_HEADERS(magic.h,
 164  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 165   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 166    is correctly installed on your system.
 167    Falling back to builtin file format detection.]))],
 168  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 169    is correctly installed on your system.
 170    Falling back to builtin file format detection.])])
 171
 172 ### setup the qt frontend.
 173 dnl The code below is not in a macro, because this would cause big
 174 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 175 QT_DO_IT_ALL([4.5.0])
 176 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 177 FRONTEND_INFO="${FRONTEND_INFO}\
 178   Qt Frontend:\n\
 179       Qt version:\t   ${QTLIB_VERSION}\n"
 180
 181 # fix the value of the prefixes.
 182 test "x$prefix" = xNONE && prefix=$default_prefix
 183 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 184 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 185   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 186    causes problems with the Makefiles. The installation will be done in
 187    directory \"`pwd`/installprefix\" instead. Please move its contents to
 188    the right place after installation.])
 189   prefix=`pwd`/installprefix
 190 fi
 191
 192 ### Setup po directory
 193 AM_NLS
 194 if test $USE_NLS = "yes" ; then
 195   AC_DEFINE(ENABLE_NLS, 1,
 196     [Define to 1 if translation of program messages to the user's native language
 197    is requested.])dnl'
 198 fi
 199 AM_PO_SUBDIRS
 200
 201 # some standard header files
 202 AC_HEADER_MAJOR
 203 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 204
 205 # some standard types
 206 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 207 AC_TYPE_OFF_T
 208 AC_TYPE_PID_T
 209 AC_TYPE_SIZE_T
 210 AC_TYPE_UID_T
 211
 212 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 213
 214 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 215 # Check the form of mkdir()
 216 AC_FUNC_MKDIR
 217 AC_FUNC_SELECT_ARGTYPES
 218
 219 LYX_CHECK_SPELL_ENGINES
 220
 221 lyx_client_subdir=true
 222 dnl AC_LANG_PUSH(C)
 223 dnl LIBS already contains some X extra libs that may interfere.
 224 save_LIBS="$LIBS"
 225 LIBS=
 226 AC_CHECK_FUNCS(fcntl,
 227   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 228    AC_SEARCH_LIBS([socket], [socket network], [],
 229      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 230                 [], [-lnsl])])],
 231   [lyx_client_subdir=false])
 232 AC_SUBST(SOCKET_LIBS,$LIBS)
 233 LIBS="$save_LIBS"
 234 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 235 dnl AC_LANG_POP(C)
 236
 237 lyx_win_res=false;
 238 case ${host} in
 239     *mingw*|*cygwin*) lyx_win_res=true;;
 240 esac
 241 if test "x$lyx_win_res" = "xtrue"; then
 242     AC_CHECK_TOOL(RC, windres,)
 243     if test -z "$RC"; then
 244       AC_ERROR([Could not find a resource compiler])
 245     fi
 246 fi
 247 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 248 LYX_SET_VERSION_INFO
 249
 250
 251 ### Some information on what just happened
 252 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 253 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 254 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 255 VERSION_INFO="Configuration\n\
 256   Host type:               ${host}\n\
 257   Special build flags:     ${lyx_flags}\n\
 258   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 259   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 260   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 261   Linker flags:            ${AM_LDFLAGS}\n\
 262   Linker user flags:       ${LDFLAGS}\n\
 263 ${FRONTEND_INFO}\
 264   Packaging:               ${lyx_use_packaging}\n\
 265   LyX binary dir:          ${real_bindir}\n\
 266   LyX files dir:           ${real_pkgdatadir}\n"
 267
 268 AC_SUBST(VERSION_INFO)
 269 AC_SUBST(AM_CPPFLAGS)
 270 AC_SUBST(AM_CXXFLAGS)
 271 AC_SUBST(AM_LDFLAGS)
 272 AC_SUBST(real_pkgdatadir)
 273
 274 ## Some config.h stuff
 275
 276 AH_TOP([
 277 /* -*- C++ -*- */
 278 /*
 279  * \file config.h
 280  * This file is part of LyX, the document processor.
 281  * Licence details can be found in the file COPYING.
 282  *
 283  * This is the compilation configuration file for LyX.
 284  * It was generated by autoconfs configure.
 285  * You might want to change some of the defaults if something goes wrong
 286  * during the compilation.
 287  */
 288
 289 #ifndef _CONFIG_H
 290 #define _CONFIG_H
 291 ])
 292
 293 AH_BOTTOM([
 294 /************************************************************
 295  ** You should not need to change anything beyond this point */
 296
 297 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 298 #define LYX_USE_CXX11
 299 #endif
 300
 301 #ifndef HAVE_STRERROR
 302 #if defined(__cplusplus)
 303 extern "C"
 304 #endif
 305 char * strerror(int n);
 306 #endif
 307
 308 #define BOOST_USER_CONFIG <config.h>
 309
 310 #if !defined(ENABLE_ASSERTIONS)
 311 #  define BOOST_DISABLE_ASSERTS 1
 312 #endif
 313 #define BOOST_ENABLE_ASSERT_HANDLER 1
 314
 315 #define BOOST_DISABLE_THREADS 1
 316 #define BOOST_NO_WREGEX 1
 317 #define BOOST_NO_WSTRING 1
 318 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 319
 320 #ifdef __CYGWIN__
 321 #  define NOMINMAX
 322 #  define BOOST_POSIX 1
 323 #  define BOOST_POSIX_API 1
 324 #  define BOOST_POSIX_PATH 1
 325 #endif
 326
 327 #ifdef __sparc__
 328 #  ifndef __BIG_ENDIAN__
 329 #    define __BIG_ENDIAN__ 1
 330 #  endif
 331 #endif
 332
 333 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 334 #  define USE_WCHAR_T
 335 #endif
 336
 337 #ifdef HAVE_LONG_LONG_INT
 338 #if SIZEOF_LONG_LONG > SIZEOF_LONG
 339 #define LYX_USE_LONG_LONG
 340 #endif
 341 #endif
 342
 343 #endif
 344 ])
 345
 346 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 347 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 348 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 349
 350 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 351         "${lyx_abs_top_srcdir}", [Top source directory])
 352 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 353         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 354 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 355         "${lyx_abs_installed_datadir}",[Hard system support directory])
 356 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 357         "${version_suffix}",[Program version suffix])
 358
 359 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 360 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 361 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 362 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 363 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 364 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 365 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 366 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 367
 368 AC_CONFIG_FILES([Makefile \
 369       lyx.1:lyx.1in \
 370       3rdparty/Makefile \
 371       3rdparty/boost/Makefile \
 372       3rdparty/hunspell/Makefile \
 373       3rdparty/libiconv/Makefile \
 374       $ICONV_ICONV_H_IN \
 375       3rdparty/zlib/Makefile \
 376       autotests/Makefile \
 377       config/Makefile \
 378       development/Makefile \
 379       development/MacOSX/Makefile \
 380       development/MacOSX/Info.plist \
 381       development/MacOSX/lyxrc.dist \
 382       development/MacOSX/spotlight/Makefile \
 383       development/cygwin/Makefile \
 384       development/cygwin/lyxrc.dist \
 385       development/lyx.spec \
 386       lib/lyx.desktop-temp:lib/lyx.desktop.in
 387       lib/Makefile \
 388       lib/doc/Makefile \
 389       lib/lyx2lyx/lyx2lyx_version.py \
 390       lib/lyx2lyx/Makefile \
 391       m4/Makefile \
 392       po/Makefile.in \
 393       sourcedoc/Doxyfile \
 394       sourcedoc/Makefile \
 395       src/client/Makefile \
 396       src/client/lyxclient.1:src/client/lyxclient.1in \
 397       src/Makefile \
 398       src/tex2lyx/Makefile \
 399       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 400       src/support/Makefile \
 401       src/frontends/Makefile \
 402       src/frontends/qt4/Makefile
 403 ])
 404
 405
 406 AC_OUTPUT
 407
 408 # show version information
 409 echo
 410 printf "$VERSION_INFO"
 411 echo
 412
 413 # Display a final warning if there has been a LYX_WARNING
 414 LYX_CHECK_WARNINGS
 415
 416 cat <<EOF
 417 Configuration of LyX was successful.
 418 Type 'make' to compile the program,
 419 and then 'make install' to install it.
 420 EOF