configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 # The list of languages known to LyX
  26 # This is needed by GNU gettext
  27 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  28
  29 # fix the value of the prefixes.
  30 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  31 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  32
  33 ### Set the execute permissions of the various scripts correctly
  34 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  35   chmod 755 ${srcdir}/${file}
  36 done
  37
  38 ### Check for programs
  39 AC_PROG_MAKE_SET
  40 AC_PROG_INSTALL
  41 #AC_PROG_RANLIB
  42 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  43 if test "x$KPSEWHICH" = xkpsewhich ; then
  44     AC_DEFINE(HAVE_KPSEWHICH, 1,
  45     [Define this if you have the kpsewhich program working on your system.])
  46 fi
  47 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  48
  49 # Work around a problem in automake 1.4: when invoking install-strip,
  50 # INSTALL_PROGRAM is changed to 'install -s', and since
  51 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  52 # which returns an error condition when stripping fails.
  53 INSTALL_SCRIPT='${INSTALL}'
  54
  55 ### we will also need a C compiler to compile GNU gettext
  56 AC_PROG_CC
  57
  58 ### check for special systems
  59 AC_ISC_POSIX
  60 AC_AIX
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTENDS
  64
  65 ### Check for a C++ compiler
  66 LYX_PROG_CXX
  67 ### Some checks on what the C++ compiler can(not) do
  68 AC_LANG(C++)
  69 dnl we do not need that currently (and probably all our supported
  70 dnl compiler allow that)
  71 dnl LYX_CXX_PARTIAL
  72 LYX_CXX_EXPLICIT
  73 LYX_CXX_GLOBAL_CSTD
  74 LYX_STD_COUNT
  75 dnl we disable rtti for now
  76 dnl LYX_CXX_RTTI
  77 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  78 LYX_CXX_STL_MODERN_STREAMS
  79
  80 ### and now some special lyx flags.
  81 AC_ARG_ENABLE(assertions,
  82   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  83   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  84         enable_assertions=yes;
  85     else
  86         enable_assertions=no;
  87     fi;])
  88 if test "x$enable_assertions" = xyes ; then
  89    lyx_flags="$lyx_flags assertions"
  90    AC_DEFINE(ENABLE_ASSERTIONS,1,
  91     [Define if you want assertions to be enabled in the code])
  92 fi
  93
  94 ### Library Files
  95 dnl by testing these we check if it is ok to have
  96 dnl -lc and -lm as args to the compiler
  97 AC_CHECK_LIB(m, sin)
  98 AC_CHECK_LIB(c, fopen)
  99
 100 ### Add extra directories to check for libraries.
 101 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 103 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 104
 105 ### Add extra directories to check for include files.
 106 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 107 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 108 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 109
 110 ### Add both includes and libraries
 111 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 112 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 113 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 114   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 115
 116 AC_ARG_WITH(aiksaurus,
 117   [  --without-aiksaurus     do not use the Aiksaurus library],
 118   [lyx_use_aiksaurus=$withval])
 119 if test x$lyx_use_aiksaurus != xno; then
 120 AC_CHECK_LIB(Aiksaurus, main,
 121         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 122          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 123         ],,"-lbz2")
 124 AC_CHECK_HEADER(Aiksaurus.h,[
 125   ac_cv_header_aiksaurus_h=yes
 126   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 127 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 128   ac_cv_header_aiksaurus_h=yes
 129   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 130 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 131 fi
 132 AC_SUBST(AIKSAURUS_LIBS)
 133
 134 LYX_USE_INCLUDED_BOOST
 135
 136 ### Setup libtool
 137 AC_DISABLE_SHARED
 138 AC_LIBTOOL_WIN32_DLL
 139 #AM_PROG_LIBTOOL
 140 LYX_PROG_LIBTOOL
 141
 142 ### Check if we want spell libraries, prefer new aspell
 143 CHECK_WITH_ASPELL
 144 if test "$USING_ASPELL" != "yes"; then
 145         CHECK_WITH_PSPELL
 146 fi
 147
 148 ### Check for some Cygwin-specific details.
 149 CHECK_WITH_CYGWIN
 150
 151 ### Check for X libraries
 152 AC_PATH_XTRA
 153 case $have_x in
 154   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 155        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 156   no) LYX_ERROR(dnl
 157 [Cannot find X window libraries and/or headers. Check your installation.
 158   If you use a Linux system, check that you have installed
 159   the development tools.]);;
 160   disable) ;;
 161 esac
 162
 163 ### check which frontend we want to use
 164
 165 dnl if the gtk frontend has been specified, then xforms is needed too
 166 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 167   FRONTENDS="$FRONTENDS xforms"
 168 fi
 169
 170 dnl The code below is not in a macro, because this would cause big
 171 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 172 for frontend in $FRONTENDS ; do
 173   case "$frontend" in
 174     xforms)
 175           XFORMS_DO_IT_ALL
 176           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 177           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 178           RPM_FRONTEND="xforms"
 179           FRONTEND_INFO="${FRONTEND_INFO}\
 180   XForms Frontend:\n\
 181       libXpm version:\t\t${XPM_VERSION}\n\
 182       libforms version:\t\t${XFORMS_VERSION}\n"
 183           ;;
 184   dnl   gnome)
 185   dnl     XFORMS_DO_IT_ALL
 186   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 187   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 188   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 189
 190   dnl     FRONTEND="xforms gnome"
 191   dnl     FRONTEND_GUILIB="gnome/*.lo"
 192   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 193   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 194   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 195   dnl   ;;
 196     gtk)
 197           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 198           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 199           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 200           RPM_FRONTEND="gtk"
 201           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 202           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 203           FRONTEND_INFO="${FRONTEND_INFO}\
 204   GTK Frontend:\n\
 205     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 206     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 207           ;;
 208
 209     qt)
 210           QT_DO_IT_ALL
 211           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 212           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 213           RPM_FRONTEND="qt"
 214           FRONTEND_INFO="${FRONTEND_INFO}\
 215   Qt Frontend:\n\
 216       Qt version:\t\t${QT_VERSION}\n"
 217 dnl qt build will fail without moc or uic
 218           if test -z "$MOC"; then
 219             LYX_ERROR([moc binary not found !])
 220           fi
 221           if test -z "$UIC"; then
 222             LYX_ERROR([uic binary not found !])
 223           fi
 224       ;;
 225     *)
 226           LYX_ERROR(Unknown frontend '$frontend');;
 227   esac
 228 done
 229
 230 ### Check how the files should be packaged
 231 LYX_USE_PACKAGING
 232 # fix the value of the prefixes.
 233 test "x$prefix" = xNONE && prefix=$default_prefix
 234 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 235
 236 ### Setup GNU gettext
 237 dnl GNU gettext is written in C
 238 AC_LANG_PUSH(C)
 239 # Some tests that may be useful for gettext
 240 AC_C_CONST
 241 AC_C_INLINE
 242 # Do the real setup now
 243 AM_GNU_GETTEXT
 244 # a hack for those who try to change LyX, but do not have gettext installed
 245 case  "${XGETTEXT}" in
 246  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 247 esac
 248
 249 AC_SUBST(LINGUAS)
 250
 251 AC_LANG_POP(C)
 252
 253 # some standard header files
 254 AC_HEADER_DIRENT
 255 AC_HEADER_MAJOR
 256 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 257
 258 # some standard structures
 259 AC_HEADER_STAT
 260 AC_HEADER_TIME
 261
 262 # some standard types
 263 AC_TYPE_MODE_T
 264 AC_TYPE_OFF_T
 265 AC_TYPE_PID_T
 266 AC_TYPE_SIGNAL
 267 AC_TYPE_SIZE_T
 268 AC_TYPE_UID_T
 269
 270 AC_CHECK_FUNCS(strerror)
 271 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 272 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 273
 274 # Check the form of mkdir()
 275 AC_FUNC_MKDIR
 276
 277 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 278     case "${enableval}" in
 279         yes) use_compression=true ;;
 280         no) use_compression=false ;;
 281         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 282     esac
 283 ],[use_compression=true])
 284 if test $use_compression=true ; then
 285         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 286         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 287         if test $use_compression = true ; then
 288                 AC_DEFINE(USE_COMRESSION, 1, [Define as 1 if you want to support compressed files.])
 289                 lyx_flags="$lyx_flags compression"
 290         fi
 291 fi
 292 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 293 AC_MSG_CHECKING([whether to support compressed files])
 294 AC_MSG_RESULT($use_compression)
 295
 296
 297 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 298 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 299 dnl We aim to remove this eventually, since we should test as much as
 300 dnl possible with the compiler which will use the functions (JMarc)
 301 AC_LANG_PUSH(C)
 302 AC_CHECK_FUNCS(mkfifo mkstemp mktemp lstat readlink)
 303 AC_LANG_POP(C)
 304
 305 AC_FUNC_SELECT_ARGTYPES
 306
 307 ### Some information on what just happened
 308 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 309 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 310 VERSION_INFO="Configuration\n\
 311   Host type:                      ${host}\n\
 312   Special build flags:           ${lyx_flags}\n\
 313   C   Compiler:                   ${CC}\n\
 314   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 315   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 316   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 317   Linker flags:                   ${LDFLAGS}\n\
 318 ${FRONTEND_INFO}\
 319   Packaging:                      ${lyx_use_packaging}\n\
 320   LyX binary dir:                 ${real_bindir}\n\
 321   LyX files dir:                  ${real_datadir}\n"
 322
 323
 324 AC_SUBST(VERSION_INFO)
 325 AC_SUBST(RPM_FRONTEND)
 326
 327 ## Some config.h stuff
 328
 329 AH_TOP([
 330 /* -*- C++ -*- */
 331 /*
 332  * \file config.h
 333  * This file is part of LyX, the document processor.
 334  * Licence details can be found in the file COPYING.
 335  *
 336  * This is the compilation configuration file for LyX.
 337  * It was generated by autoconfs configure.
 338  * You might want to change some of the defaults if something goes wrong
 339  * during the compilation.
 340  */
 341
 342 #ifndef _CONFIG_H
 343 #define _CONFIG_H
 344 ])
 345
 346 AH_BOTTOM([
 347 /************************************************************
 348  ** You should not need to change anything beyond this point */
 349
 350 #ifndef HAVE_STRERROR
 351 #if defined(__cplusplus)
 352 extern "C"
 353 #endif
 354 char * strerror(int n);
 355 #endif
 356
 357 #ifdef HAVE_MKSTEMP
 358 #ifndef HAVE_DECL_MKSTEMP
 359 #if defined(__cplusplus)
 360 extern "C"
 361 #endif
 362 int mkstemp(char*);
 363 #endif
 364 #endif
 365
 366 #ifdef __EMX__
 367 #include "support/os2_defines.h"
 368 #endif
 369
 370 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 371 #define USE_BOOST_FORMAT 1
 372 #else
 373 #define USE_BOOST_FORMAT 0
 374 #endif
 375
 376 #define BOOST_USER_CONFIG <config.h>
 377
 378 #if defined(ENABLE_ASSERTIONS)
 379 #define BOOST_ENABLE_ASSERT_HANDLER 1
 380 #else
 381 #define BOOST_DISABLE_ASSERTS 1
 382 #endif
 383
 384 #define BOOST_DISABLE_THREADS 1
 385 #define BOOST_NO_WREGEX 1
 386 #define BOOST_NO_WSTRING 1
 387
 388 #endif
 389 ])
 390
 391 ### Finish the work.
 392 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 393 AC_CONFIG_FILES([Makefile  m4/Makefile \
 394        boost/Makefile \
 395        boost/libs/Makefile \
 396        boost/libs/filesystem/Makefile \
 397        boost/libs/filesystem/src/Makefile \
 398        boost/libs/regex/Makefile \
 399        boost/libs/regex/src/Makefile \
 400        boost/libs/signals/Makefile \
 401        boost/libs/signals/src/Makefile \
 402        config/Makefile \
 403        development/Makefile \
 404        development/lyx.spec \
 405        lib/Makefile \
 406        lib/doc/Makefile \
 407        intl/Makefile \
 408        po/Makefile.in \
 409        sourcedoc/Doxyfile \
 410        sourcedoc/Makefile \
 411        src/client/Makefile \
 412        src/Makefile \
 413        src/version.C-tmp:src/version.C.in \
 414        src/tex2lyx/Makefile \
 415        src/mathed/Makefile \
 416        src/graphics/Makefile \
 417        src/insets/Makefile \
 418        src/support/Makefile \
 419        src/frontends/Makefile \
 420        src/frontends/controllers/Makefile \
 421        src/frontends/xforms/Makefile \
 422        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 423        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 424        src/frontends/xforms/forms/Makefile \
 425        src/frontends/gtk/Makefile \
 426        src/frontends/gtk/gimages/Makefile \
 427        src/frontends/gtk/glade/Makefile \
 428        src/frontends/qt2/Makefile \
 429        src/frontends/qt2/moc/Makefile \
 430        src/frontends/qt2/ui/Makefile \
 431        src/frontends/qt2/ui/moc/Makefile \
 432        src/frontends/gnome/Makefile \
 433 ])
 434
 435 AC_OUTPUT
 436 # show version information
 437 echo
 438 printf "$VERSION_INFO"
 439 echo
 440
 441 # Display a final warning if there has been a LYX_ERROR
 442 LYX_CHECK_ERRORS