configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.5.0svn,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_SUBST(LYX_DATE, ["Fri, Jul 13, 2006"])
   5 AC_PREREQ(2.52)
   6 AC_CONFIG_SRCDIR(src/main.C)
   7 AC_CONFIG_HEADERS([src/config.h])
   8
   9 AC_CONFIG_AUX_DIR(config)
  10
  11 # First check the version
  12 LYX_CHECK_VERSION
  13 LYX_VERSION_SUFFIX
  14 # Check how the files should be packaged
  15 AC_CANONICAL_TARGET
  16 LYX_USE_PACKAGING
  17 # We need to define these variables here and the no-define option of
  18 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  19 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  20
  21 dnl default maintainer mode to true for development versions
  22 if test "${enable_maintainer_mode+set}" != set; then
  23   enable_maintainer_mode=$lyx_devel_version
  24 fi
  25 AM_MAINTAINER_MODE
  26
  27 save_PACKAGE=$PACKAGE
  28 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
  29 PACKAGE=$save_PACKAGE
  30
  31 ### Set the execute permissions of the various scripts correctly
  32 for file in config/install-sh config/mkinstalldirs ; do
  33   chmod 755 ${srcdir}/${file}
  34 done
  35
  36 ### Check for programs
  37 AC_PROG_MAKE_SET
  38 AC_PROG_INSTALL
  39
  40 AC_PROG_AWK
  41 test "$AWK" = gawk && AWK="gawk --posix"
  42
  43 #AC_PROG_RANLIB
  44 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  45 if test "x$KPSEWHICH" = xkpsewhich ; then
  46     AC_DEFINE(HAVE_KPSEWHICH, 1,
  47     [Define this if you have the kpsewhich program working on your system.])
  48 fi
  49 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  50
  51 # Check for installed python
  52 AM_PATH_PYTHON(2.3,, :)
  53
  54 # Work around a problem in automake 1.4: when invoking install-strip,
  55 # INSTALL_PROGRAM is changed to 'install -s', and since
  56 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  57 # which returns an error condition when stripping fails.
  58 INSTALL_SCRIPT='${INSTALL}'
  59
  60 ### we will also need a C compiler to compile GNU gettext
  61 AC_PROG_CC
  62
  63 ### check for special systems
  64 AC_ISC_POSIX
  65 AC_AIX
  66
  67 ### we need to know the byte order for unicode conversions
  68 AC_C_BIGENDIAN
  69
  70 ### check which frontend we want to use
  71 LYX_USE_FRONTENDS
  72
  73 ### Check for a C++ compiler
  74 LYX_PROG_CXX
  75 ### Some checks on what the C++ compiler can(not) do
  76 AC_LANG(C++)
  77 dnl we do not need that currently (and probably all our supported
  78 dnl compiler allow that)
  79 dnl LYX_CXX_PARTIAL
  80 LYX_CXX_EXPLICIT
  81 LYX_CXX_GLOBAL_CSTD
  82 LYX_STD_COUNT
  83 dnl we disable rtti for now
  84 dnl LYX_CXX_RTTI
  85 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  86 LYX_CXX_STL_MODERN_STREAMS
  87
  88 ### and now some special lyx flags.
  89 AC_ARG_ENABLE(assertions,
  90   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  91   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  92         enable_assertions=yes;
  93     else
  94         enable_assertions=no;
  95     fi;])
  96 if test "x$enable_assertions" = xyes ; then
  97    lyx_flags="assertions $lyx_flags"
  98    AC_DEFINE(ENABLE_ASSERTIONS,1,
  99     [Define if you want assertions to be enabled in the code])
 100 fi
 101
 102 ### Library Files
 103 dnl by testing these we check if it is ok to have
 104 dnl -lc and -lm as args to the compiler
 105 AC_CHECK_LIB(m, sin)
 106 AC_CHECK_LIB(c, fopen)
 107
 108 ### Add extra directories to check for libraries.
 109 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 110 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 111 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 112
 113 ### Add extra directories to check for include files.
 114 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 115 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 116 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 117
 118 ### Add both includes and libraries
 119 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 120 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 121 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 122   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 123
 124 ### These are needed in windows
 125 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 126 AC_SUBST(LIBSHLWAPI)
 127 AC_CHECK_LIB(gdi32, main)
 128
 129 AC_ARG_WITH(aiksaurus,
 130   [  --without-aiksaurus     do not use the Aiksaurus library],
 131   [lyx_use_aiksaurus=$withval])
 132 if test x$lyx_use_aiksaurus != xno; then
 133 AC_CHECK_LIB(Aiksaurus, main,
 134         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 135          AIKSAURUS_LIBS="-lAiksaurus"
 136          lyx_flags="aiksaurus $lyx_flags"
 137         ])
 138 AC_CHECK_HEADER(Aiksaurus.h,[
 139   ac_cv_header_aiksaurus_h=yes
 140   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 141 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 142   ac_cv_header_aiksaurus_h=yes
 143   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 144 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 145 fi
 146 AC_SUBST(AIKSAURUS_LIBS)
 147
 148 LYX_USE_INCLUDED_BOOST
 149
 150 # Needed for our char_type
 151 AC_CHECK_SIZEOF(wchar_t)
 152
 153 ### Setup libtool
 154 dnl Dirty trick ahead: disable libtool checking for a fortran compiler
 155 dnl see http://permalink.gmane.org/gmane.comp.gnu.libtool.general/6699
 156 dnl Note that this will reportedly not be needed with libtool 2.0
 157 m4_undefine([AC_PROG_F77])
 158 m4_defun([AC_PROG_F77],[])
 159 AC_DISABLE_SHARED
 160 AC_LIBTOOL_WIN32_DLL
 161 #AM_PROG_LIBTOOL
 162 LYX_PROG_LIBTOOL
 163
 164 ### Check for X libraries
 165 AC_PATH_XTRA
 166 case $have_x in
 167   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 168        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 169   no) LYX_ERROR(dnl
 170 [Cannot find X window libraries and/or headers. Check your installation.
 171   If you use a Linux system, check that you have installed
 172   the development tools.]);;
 173   disable) ;;
 174 esac
 175
 176 ### check which frontend we want to use
 177
 178 dnl The code below is not in a macro, because this would cause big
 179 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 180 for frontend in $FRONTENDS ; do
 181   case "$frontend" in
 182     gtk)
 183           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
 184           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 185           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 186           RPM_FRONTEND="gtk"
 187           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 188           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 189           FRONTEND_INFO="${FRONTEND_INFO}\
 190   GTK Frontend:\n\
 191     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 192     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 193           ;;
 194
 195     qt4)
 196           QT4_DO_IT_ALL
 197           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
 198           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
 199           RPM_FRONTEND="qt4"
 200           FRONTEND_INFO="${FRONTEND_INFO}\
 201   Qt 4 Frontend:\n\
 202       Qt 4 version:\t\t${QT4_VERSION}\n"
 203 dnl qt 4 build will fail without moc or uic
 204           if test -z "$MOC4"; then
 205             LYX_ERROR([moc 4 binary not found !])
 206           fi
 207           if test -z "$UIC4"; then
 208             LYX_ERROR([uic 4 binary not found !])
 209           fi
 210           if test -z "$QT4_LIB"; then
 211             LYX_ERROR([qt 4 library not found !])
 212           fi
 213       ;;
 214     *)
 215           LYX_ERROR(Unknown frontend '$frontend');;
 216   esac
 217 done
 218
 219 # fix the value of the prefixes.
 220 test "x$prefix" = xNONE && prefix=$default_prefix
 221 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 222 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 223   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 224    causes problems with the Makefiles. The installation will be done in
 225    directory \"`pwd`/installprefix\" instead. Please move its contents to
 226    the right place after installation.])
 227   prefix=`pwd`/installprefix
 228 fi
 229
 230 ### We need iconv for unicode support
 231 AM_ICONV
 232 if test "$am_cv_func_iconv" = no; then
 233   LYX_ERROR([Cannot find required library iconv])
 234 fi
 235
 236 ### Setup GNU gettext
 237 dnl GNU gettext is written in C
 238 AC_LANG_PUSH(C)
 239 AM_GNU_GETTEXT
 240 AC_LANG_POP(C)
 241
 242 # some standard header files
 243 AC_HEADER_DIRENT
 244 AC_HEADER_MAJOR
 245 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 246
 247 # some standard structures
 248 AC_HEADER_STAT
 249 AC_HEADER_TIME
 250
 251 # some standard types
 252 AC_TYPE_MODE_T
 253 AC_TYPE_OFF_T
 254 AC_TYPE_PID_T
 255 AC_TYPE_SIGNAL
 256 AC_TYPE_SIZE_T
 257 AC_TYPE_UID_T
 258
 259 AC_CHECK_FUNCS(strerror)
 260 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 261 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 262
 263 # Check the form of mkdir()
 264 AC_FUNC_MKDIR
 265
 266 # check for compression support
 267 AC_CHECK_HEADERS(zlib.h,
 268  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 269  [LYX_LIB_ERROR(zlib.h,zlib)])
 270
 271 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 272 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 273 dnl We aim to remove this eventually, since we should test as much as
 274 dnl possible with the compiler which will use the functions (JMarc)
 275 AC_LANG_PUSH(C)
 276 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 277 AC_LANG_POP(C)
 278
 279 LYX_CHECK_SPELL_ENGINES
 280
 281 lyx_client_subdir=true
 282 AC_LANG_PUSH(C)
 283 dnl LIBS already contains some X extra libs that may interfere.
 284 save_LIBS="$LIBS"
 285 LIBS=
 286 AC_CHECK_FUNCS(fcntl,
 287   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 288    AC_SEARCH_LIBS([socket], [socket], [],
 289      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 290                 [], [-lnsl])])],
 291   [lyx_client_subdir=false])
 292 AC_SUBST(SOCKET_LIBS,$LIBS)
 293 LIBS="$save_LIBS"
 294 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 295 AC_LANG_POP(C)
 296
 297 AC_FUNC_SELECT_ARGTYPES
 298
 299 ### Some information on what just happened
 300 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 301 real_pkgdatadir=`eval "echo \`eval \"echo ${pkgdatadir}\"\`"`
 302 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 303 VERSION_INFO="Configuration\n\
 304   Host type:                      ${host}\n\
 305   Special build flags:            ${lyx_flags}\n\
 306   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 307   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 308   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 309   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 310   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 311   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 312   Linker flags:                   ${AM_LDFLAGS}\n\
 313   Linker user flags:              ${LDFLAGS}\n\
 314 ${FRONTEND_INFO}\
 315   Packaging:                      ${lyx_use_packaging}\n\
 316   LyX binary dir:                 ${real_bindir}\n\
 317   LyX files dir:                  ${real_pkgdatadir}\n"
 318
 319 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 320 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 321 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_pkgdatadir})
 322
 323 AC_SUBST(VERSION_INFO)
 324 AC_SUBST(RPM_FRONTEND)
 325 AC_SUBST(AM_CPPFLAGS)
 326 AC_SUBST(AM_CXXFLAGS)
 327 AC_SUBST(AM_CFLAGS)
 328 AC_SUBST(AM_LDFLAGS)
 329 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 330 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 331 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 332
 333 ## Some config.h stuff
 334
 335 AH_TOP([
 336 /* -*- C++ -*- */
 337 /*
 338  * \file config.h
 339  * This file is part of LyX, the document processor.
 340  * Licence details can be found in the file COPYING.
 341  *
 342  * This is the compilation configuration file for LyX.
 343  * It was generated by autoconfs configure.
 344  * You might want to change some of the defaults if something goes wrong
 345  * during the compilation.
 346  */
 347
 348 #ifndef _CONFIG_H
 349 #define _CONFIG_H
 350 ])
 351
 352 AH_BOTTOM([
 353 /************************************************************
 354  ** You should not need to change anything beyond this point */
 355
 356 #ifndef HAVE_STRERROR
 357 #if defined(__cplusplus)
 358 extern "C"
 359 #endif
 360 char * strerror(int n);
 361 #endif
 362
 363 #ifdef HAVE_MKSTEMP
 364 #ifndef HAVE_DECL_MKSTEMP
 365 #if defined(__cplusplus)
 366 extern "C"
 367 #endif
 368 int mkstemp(char*);
 369 #endif
 370 #endif
 371
 372 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 373 #  define USE_BOOST_FORMAT 1
 374 #else
 375 #  define USE_BOOST_FORMAT 0
 376 #endif
 377
 378 #define BOOST_USER_CONFIG <config.h>
 379
 380 #if !defined(ENABLE_ASSERTIONS)
 381 #  define BOOST_DISABLE_ASSERTS 1
 382 #endif
 383 #define BOOST_ENABLE_ASSERT_HANDLER 1
 384
 385 #define BOOST_DISABLE_THREADS 1
 386 #define BOOST_NO_WREGEX 1
 387 #define BOOST_NO_WSTRING 1
 388
 389 #ifdef __CYGWIN__
 390 #  define BOOST_POSIX 1
 391 #  define BOOST_POSIX_API 1
 392 #  define BOOST_POSIX_PATH 1
 393 #endif
 394
 395 #if defined(HAVE_NEWAPIS_H)
 396 #  define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 397 #endif
 398
 399 #endif
 400 ])
 401
 402 ### Finish the work.
 403 AC_CONFIG_FILES([Makefile  m4/Makefile \
 404        boost/Makefile \
 405        boost/libs/Makefile \
 406        boost/libs/filesystem/Makefile \
 407        boost/libs/filesystem/src/Makefile \
 408        boost/libs/iostreams/Makefile \
 409        boost/libs/iostreams/src/Makefile \
 410        boost/libs/regex/Makefile \
 411        boost/libs/regex/src/Makefile \
 412        boost/libs/signals/Makefile \
 413        boost/libs/signals/src/Makefile \
 414        config/Makefile \
 415        development/Makefile \
 416        development/lyx.spec \
 417        lib/Makefile \
 418        lib/doc/Makefile \
 419        lib/lyx2lyx/lyx2lyx_version.py \
 420        lib/lyx2lyx/Makefile \
 421        intl/Makefile \
 422        po/Makefile.in \
 423        sourcedoc/Doxyfile \
 424        sourcedoc/Makefile \
 425        src/client/Makefile \
 426        src/Makefile \
 427        src/version.C-tmp:src/version.C.in \
 428        src/tex2lyx/Makefile \
 429        src/mathed/Makefile \
 430        src/graphics/Makefile \
 431        src/insets/Makefile \
 432        src/support/Makefile \
 433        src/support/tests/Makefile \
 434        src/frontends/Makefile \
 435        src/frontends/controllers/Makefile \
 436        src/frontends/controllers/tests/Makefile \
 437        src/frontends/gtk/Makefile \
 438        src/frontends/gtk/gimages/Makefile \
 439        src/frontends/gtk/glade/Makefile \
 440        src/frontends/qt4/Makefile \
 441        src/frontends/qt4/ui/Makefile \
 442 ])
 443
 444 AC_OUTPUT
 445 # show version information
 446 echo
 447 printf "$VERSION_INFO"
 448 echo
 449
 450 # Display a final warning if there has been a LYX_ERROR
 451 LYX_CHECK_ERRORS