configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.5.0~devel],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2024-04-01"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT6
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29 AM_SILENT_RULES([yes])
  30 # Automake is pulling the historical V7 format. This tar format supports
  31 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  32 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  33 save_PACKAGE=$PACKAGE
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-define 1.14 tar-ustar subdir-objects])
  35 PACKAGE=$save_PACKAGE
  36
  37 ### Set the execute permissions of the various scripts correctly
  38 for file in config/install-sh ; do
  39   chmod 755 ${srcdir}/${file}
  40 done
  41
  42 # Find a suitable python interpreter
  43 AM_PATH_PYTHON([3.8.0])
  44
  45 # Tools for creating libraries (note that we do not use libtool)
  46 AM_PROG_AR
  47 AC_PROG_RANLIB
  48 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  49 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  50 AC_SUBST([ARFLAGS], [cr])
  51
  52 ### Check for a C++ compiler
  53 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  54 dnl if it is not set. We do not use autoconf defaults.
  55 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  56 if ! test "$lyx_has_CXXFLAGS" = yes; then
  57   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  58   CXXFLAGS=" "
  59 fi
  60 LYX_PROG_CXX
  61 if ! test "$lyx_has_CXXFLAGS" = yes; then
  62   unset CXXFLAGS
  63 fi
  64 AC_LANG(C++)
  65
  66 ### Objective-C compiler
  67 AC_PROG_OBJC
  68 _AM_DEPENDENCIES([OBJC])
  69
  70 ### Add extra directories to check for libraries.
  71 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  72 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  73 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  74
  75 ### Add extra directories to check for include files.
  76 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  77 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  78 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  79
  80 ### Add both includes and libraries
  81 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  82 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  83   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  84   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  85 ])
  86
  87 ### These are needed in windows
  88 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  89 AC_SUBST(LIBSHLWAPI)
  90 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  91 AC_SUBST(LIBPSAPI)
  92 AC_CHECK_LIB(gdi32, main)
  93 AC_CHECK_LIB(ole32, main)
  94
  95 LYX_USE_INCLUDED_NOD
  96 LYX_USE_INCLUDED_BOOST
  97
  98 ### we need to know the byte order for unicode conversions
  99 AC_C_BIGENDIAN
 100
 101 # Nice to have when an assertion triggers
 102 LYX_CHECK_CALLSTACK_PRINTING
 103
 104 # C++14 only
 105 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 106
 107 # Needed for our char_type
 108 AC_CHECK_SIZEOF(wchar_t)
 109
 110 # Taken from gettext, needed for libiconv
 111 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 112    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 113       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 114 if test $gt_cv_c_wchar_t = yes; then
 115   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 116   HAVE_WCHAR_T=1
 117 else
 118   HAVE_WCHAR_T=0
 119 fi
 120 AC_SUBST([HAVE_WCHAR_T])
 121
 122 # Needed for Mingw-w64
 123 AC_TYPE_LONG_LONG_INT
 124
 125 ### We need iconv for unicode support (Qt frontend requires it too)
 126 LYX_USE_INCLUDED_ICONV
 127
 128 ### check for compression support
 129 LYX_USE_INCLUDED_ZLIB
 130
 131 ### check whether we build and install the supplied dtl programs
 132 LYX_BUILD_INCLUDED_DTL
 133
 134 ### check for file magic support (currently optional)
 135 AC_CHECK_HEADERS(magic.h,
 136  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 137   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 138    is correctly installed on your system.
 139    Falling back to builtin file format detection.]))],
 140  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 141    is correctly installed on your system.
 142    Falling back to builtin file format detection.])])
 143
 144 ### setup the qt frontend.
 145 dnl The code below is not in a macro, because this would cause big
 146 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 147 QT_DO_IT_ALL([5.0.0])
 148 AC_SUBST([FRONTENDS_SUBDIRS], [qt])
 149 FRONTEND_INFO="${FRONTEND_INFO}\
 150   Qt Frontend:\n\
 151       Qt version:\t   ${QTLIB_VERSION}\n"
 152
 153 # fix the value of the prefixes.
 154 test "x$prefix" = xNONE && prefix=$default_prefix
 155 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 156 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 157   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 158    causes problems with the Makefiles. The installation will be done in
 159    directory \"`pwd`/installprefix\" instead. Please move its contents to
 160    the right place after installation.])
 161   prefix=`pwd`/installprefix
 162 fi
 163
 164 ### Setup po directory
 165 AM_NLS
 166 if test $USE_NLS = "yes" ; then
 167   AC_DEFINE(ENABLE_NLS, 1,
 168     [Define to 1 if translation of program messages to the user's native language
 169    is requested.])dnl'
 170 fi
 171 AM_PO_SUBDIRS
 172
 173 # some standard header files
 174 AC_HEADER_MAJOR
 175 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 176
 177 # some standard types
 178 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 179 AC_TYPE_OFF_T
 180 AC_TYPE_PID_T
 181 AC_TYPE_SIZE_T
 182 AC_TYPE_UID_T
 183
 184 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 185
 186 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 187 # Check the form of mkdir()
 188 AC_FUNC_MKDIR
 189 AC_FUNC_SELECT_ARGTYPES
 190
 191 if test "$lyx_use_packaging" = "macosx" ; then
 192   LYX_CHECK_MACOS_DEPLOYMENT_TARGET
 193 fi
 194
 195 LYX_CHECK_SPELL_ENGINES
 196 LYX_USE_INCLUDED_MYTHES
 197
 198 LYX_CHECK_WITH_SAXON
 199 LYX_CHECK_WITH_XSLT_SHEETS
 200
 201 lyx_client_subdir=true
 202 dnl LIBS already contains some X extra libs that may interfere.
 203 save_LIBS="$LIBS"
 204 LIBS=
 205 AC_CHECK_FUNCS(fcntl,
 206   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 207    AC_SEARCH_LIBS([socket], [socket network], [],
 208      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 209                 [], [-lnsl])])],
 210   [lyx_client_subdir=false])
 211 AC_SUBST(SOCKET_LIBS,$LIBS)
 212 LIBS="$save_LIBS"
 213 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 214
 215 lyx_win_res=false;
 216 case ${host} in
 217     *mingw*|*cygwin*) lyx_win_res=true;;
 218     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 219 esac
 220 if test "x$lyx_win_res" = "xtrue"; then
 221     AC_CHECK_TOOL(RC, windres,)
 222     if test -z "$RC"; then
 223       AC_MSG_ERROR([Could not find a resource compiler])
 224     fi
 225 fi
 226 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 227 LYX_SET_VERSION_INFO
 228
 229
 230 ### Some information on what just happened
 231 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 232 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 233 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 234 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 235 VERSION_INFO="Configuration\n\
 236   Host type:               ${host}\n\
 237   Special build flags:     ${lyx_flags}\n\
 238   Bundled libraries:       ${lyx_included_libs}\n\
 239   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 240   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 241   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 242   Linker flags:            ${AM_LDFLAGS}\n\
 243   Linker user flags:       ${LDFLAGS}\n\
 244 ${FRONTEND_INFO}\
 245   Packaging:               ${lyx_use_packaging}\n\
 246   LyX binary dir:          ${real_bindir}\n\
 247   LyX files dir:           ${real_pkgdatadir}\n"
 248
 249 AC_SUBST(VERSION_INFO)
 250 AC_SUBST(AM_CPPFLAGS)
 251 AC_SUBST(AM_CXXFLAGS)
 252 AC_SUBST(AM_LDFLAGS)
 253 AC_SUBST(real_pkgdatadir)
 254
 255 ## Some config.h stuff
 256
 257 AH_TOP([
 258 /* -*- C++ -*- */
 259 /*
 260  * \file config.h
 261  * This file is part of LyX, the document processor.
 262  * Licence details can be found in the file COPYING.
 263  *
 264  * This is the compilation configuration file for LyX.
 265  * It was generated by autoconfs configure.
 266  * You might want to change some of the defaults if something goes wrong
 267  * during the compilation.
 268  */
 269
 270 #ifndef _CONFIG_H
 271 #define _CONFIG_H
 272 ])
 273
 274 AH_BOTTOM([
 275 /************************************************************
 276  ** You should not need to change anything beyond this point */
 277
 278 #ifndef HAVE_STRERROR
 279 #if defined(__cplusplus)
 280 extern "C"
 281 #endif
 282 char * strerror(int n);
 283 #endif
 284
 285 #define BOOST_USER_CONFIG <config.h>
 286
 287 #if !defined(ENABLE_ASSERTIONS)
 288 #  define BOOST_DISABLE_ASSERTS 1
 289 #endif
 290 #define BOOST_ENABLE_ASSERT_HANDLER 1
 291
 292 #define BOOST_DISABLE_THREADS 1
 293 #define BOOST_NO_WREGEX 1
 294 #define BOOST_NO_WSTRING 1
 295
 296 #ifdef __CYGWIN__
 297 #  define _DEFAULT_SOURCE
 298 #  define NOMINMAX
 299 #  define BOOST_POSIX 1
 300 #  define BOOST_POSIX_API 1
 301 #  define BOOST_POSIX_PATH 1
 302 #endif
 303
 304 #ifdef __sparc__
 305 #  ifndef __BIG_ENDIAN__
 306 #    define __BIG_ENDIAN__ 1
 307 #  endif
 308 #endif
 309
 310 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 311 #  define USE_WCHAR_T
 312 #endif
 313
 314
 315 #endif
 316 ])
 317
 318 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 319 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 320 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 321
 322 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 323         "${lyx_abs_top_srcdir}", [Top source directory])
 324 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 325         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 326 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 327         "${lyx_abs_installed_datadir}",[Hard system support directory])
 328 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 329         "${version_suffix}",[Program version suffix])
 330
 331 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 332 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 333 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 334 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 335 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 336 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 337 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 338 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 339
 340 AC_CONFIG_FILES([Makefile \
 341       lyx.1:lyx.1in \
 342       3rdparty/Makefile \
 343       3rdparty/boost/Makefile \
 344       3rdparty/dtl/Makefile \
 345       3rdparty/hunspell/Makefile \
 346       3rdparty/mythes/Makefile \
 347       3rdparty/nod/Makefile \
 348       3rdparty/libiconv/Makefile \
 349       $ICONV_ICONV_H_IN \
 350       3rdparty/zlib/Makefile \
 351       autotests/Makefile \
 352       config/Makefile \
 353       development/Makefile \
 354       development/MacOSX/Makefile \
 355       development/MacOSX/Info.plist \
 356       development/MacOSX/lyxrc.dist \
 357       development/MacOSX/spotlight/Makefile \
 358       development/cygwin/Makefile \
 359       development/cygwin/lyxrc.dist \
 360       development/lyx.spec \
 361       lib/lyx.desktop-temp:lib/lyx.desktop.in
 362       lib/Makefile \
 363       lib/doc/Makefile \
 364       lib/lyx2lyx/lyx2lyx_version.py \
 365       lib/lyx2lyx/Makefile \
 366       m4/Makefile \
 367       po/Makefile.in \
 368       sourcedoc/Doxyfile \
 369       sourcedoc/Makefile \
 370       src/client/Makefile \
 371       src/client/lyxclient.1:src/client/lyxclient.1in \
 372       src/Makefile \
 373       src/tex2lyx/Makefile \
 374       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 375       src/convert/Makefile \
 376       src/support/Makefile \
 377       src/frontends/Makefile \
 378       src/frontends/qt/Makefile
 379 ])
 380
 381
 382 AC_OUTPUT
 383
 384 # show version information
 385 echo
 386 printf "$VERSION_INFO"
 387 echo
 388
 389 # Display a final warning if there has been a LYX_WARNING
 390 LYX_CHECK_WARNINGS
 391
 392 cat <<EOF
 393 Configuration of LyX was successful.
 394 Type 'make' to compile the program,
 395 and then 'make install' to install it.
 396 EOF