configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.4.0-alpha3],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2021-02-14"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29 AM_SILENT_RULES([yes])
  30 # Automake is pulling the historical V7 format. This tar format supports
  31 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  32 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  33 save_PACKAGE=$PACKAGE
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-define 1.14 tar-ustar subdir-objects])
  35 PACKAGE=$save_PACKAGE
  36
  37 ### Set the execute permissions of the various scripts correctly
  38 for file in config/install-sh ; do
  39   chmod 755 ${srcdir}/${file}
  40 done
  41
  42 # Find a suitable python interpreter
  43 LYX_PATH_PYTHON23([2.7.0], [3.5.0])
  44 # do the usual python setup stuff
  45 AM_PATH_PYTHON
  46
  47 # Tools for creating libraries (note that we do not use libtool)
  48 AM_PROG_AR
  49 AC_PROG_RANLIB
  50 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  51 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  52 AC_SUBST([ARFLAGS], [cr])
  53
  54 ### Check for a C++ compiler
  55 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  56 dnl if it is not set. We do not use autoconf defaults.
  57 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  58 if ! test "$lyx_has_CXXFLAGS" = yes; then
  59   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  60   CXXFLAGS=" "
  61 fi
  62 LYX_PROG_CXX
  63 if ! test "$lyx_has_CXXFLAGS" = yes; then
  64   unset CXXFLAGS
  65 fi
  66 AC_LANG(C++)
  67
  68 ### Objective-C compiler
  69 AC_PROG_OBJC
  70 _AM_DEPENDENCIES([OBJC])
  71
  72 ### Add extra directories to check for libraries.
  73 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  74 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  75 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  76
  77 ### Add extra directories to check for include files.
  78 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  79 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  80 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  81
  82 ### Add both includes and libraries
  83 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  84 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  85   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  86   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  87 ])
  88
  89 ### These are needed in windows
  90 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  91 AC_SUBST(LIBSHLWAPI)
  92 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  93 AC_SUBST(LIBPSAPI)
  94 AC_CHECK_LIB(gdi32, main)
  95 AC_CHECK_LIB(ole32, main)
  96
  97 LYX_USE_INCLUDED_NOD
  98 LYX_USE_INCLUDED_BOOST
  99
 100 ### we need to know the byte order for unicode conversions
 101 AC_C_BIGENDIAN
 102
 103 # Nice to have when an assertion triggers
 104 LYX_CHECK_CALLSTACK_PRINTING
 105
 106 # C++14 only
 107 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 108
 109 # Needed for our char_type
 110 AC_CHECK_SIZEOF(wchar_t)
 111
 112 # Taken from gettext, needed for libiconv
 113 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 114    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 115       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 116 if test $gt_cv_c_wchar_t = yes; then
 117   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 118   HAVE_WCHAR_T=1
 119 else
 120   HAVE_WCHAR_T=0
 121 fi
 122 AC_SUBST([HAVE_WCHAR_T])
 123
 124 # Needed for Mingw-w64
 125 AC_TYPE_LONG_LONG_INT
 126
 127 ### We need iconv for unicode support (Qt frontend requires it too)
 128 LYX_USE_INCLUDED_ICONV
 129
 130 ### check for compression support
 131 LYX_USE_INCLUDED_ZLIB
 132
 133 ### check whether we build and install the supplied dtl programs
 134 LYX_BUILD_INCLUDED_DTL
 135
 136 ### check for file magic support (currently optional)
 137 AC_CHECK_HEADERS(magic.h,
 138  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 139   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 140    is correctly installed on your system.
 141    Falling back to builtin file format detection.]))],
 142  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 143    is correctly installed on your system.
 144    Falling back to builtin file format detection.])])
 145
 146 ### setup the qt frontend.
 147 dnl The code below is not in a macro, because this would cause big
 148 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 149 QT_DO_IT_ALL([4.5.0])
 150 AC_SUBST([FRONTENDS_SUBDIRS], [qt])
 151 FRONTEND_INFO="${FRONTEND_INFO}\
 152   Qt Frontend:\n\
 153       Qt version:\t   ${QTLIB_VERSION}\n"
 154
 155 # fix the value of the prefixes.
 156 test "x$prefix" = xNONE && prefix=$default_prefix
 157 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 158 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 159   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 160    causes problems with the Makefiles. The installation will be done in
 161    directory \"`pwd`/installprefix\" instead. Please move its contents to
 162    the right place after installation.])
 163   prefix=`pwd`/installprefix
 164 fi
 165
 166 ### Setup po directory
 167 AM_NLS
 168 if test $USE_NLS = "yes" ; then
 169   AC_DEFINE(ENABLE_NLS, 1,
 170     [Define to 1 if translation of program messages to the user's native language
 171    is requested.])dnl'
 172 fi
 173 AM_PO_SUBDIRS
 174
 175 # some standard header files
 176 AC_HEADER_MAJOR
 177 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 178
 179 # some standard types
 180 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 181 AC_TYPE_OFF_T
 182 AC_TYPE_PID_T
 183 AC_TYPE_SIZE_T
 184 AC_TYPE_UID_T
 185
 186 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 187
 188 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 189 # Check the form of mkdir()
 190 AC_FUNC_MKDIR
 191 AC_FUNC_SELECT_ARGTYPES
 192
 193 LYX_CHECK_SPELL_ENGINES
 194 LYX_USE_INCLUDED_MYTHES
 195
 196 lyx_client_subdir=true
 197 dnl LIBS already contains some X extra libs that may interfere.
 198 save_LIBS="$LIBS"
 199 LIBS=
 200 AC_CHECK_FUNCS(fcntl,
 201   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 202    AC_SEARCH_LIBS([socket], [socket network], [],
 203      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 204                 [], [-lnsl])])],
 205   [lyx_client_subdir=false])
 206 AC_SUBST(SOCKET_LIBS,$LIBS)
 207 LIBS="$save_LIBS"
 208 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 209
 210 lyx_win_res=false;
 211 case ${host} in
 212     *mingw*|*cygwin*) lyx_win_res=true;;
 213     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 214 esac
 215 if test "x$lyx_win_res" = "xtrue"; then
 216     AC_CHECK_TOOL(RC, windres,)
 217     if test -z "$RC"; then
 218       AC_MSG_ERROR([Could not find a resource compiler])
 219     fi
 220 fi
 221 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 222 LYX_SET_VERSION_INFO
 223
 224
 225 ### Some information on what just happened
 226 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 227 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 228 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 229 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 230 VERSION_INFO="Configuration\n\
 231   Host type:               ${host}\n\
 232   Special build flags:     ${lyx_flags}\n\
 233   Bundled libraries:       ${lyx_included_libs}\n\
 234   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 235   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 236   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 237   Linker flags:            ${AM_LDFLAGS}\n\
 238   Linker user flags:       ${LDFLAGS}\n\
 239 ${FRONTEND_INFO}\
 240   Packaging:               ${lyx_use_packaging}\n\
 241   LyX binary dir:          ${real_bindir}\n\
 242   LyX files dir:           ${real_pkgdatadir}\n"
 243
 244 AC_SUBST(VERSION_INFO)
 245 AC_SUBST(AM_CPPFLAGS)
 246 AC_SUBST(AM_CXXFLAGS)
 247 AC_SUBST(AM_LDFLAGS)
 248 AC_SUBST(real_pkgdatadir)
 249
 250 ## Some config.h stuff
 251
 252 AH_TOP([
 253 /* -*- C++ -*- */
 254 /*
 255  * \file config.h
 256  * This file is part of LyX, the document processor.
 257  * Licence details can be found in the file COPYING.
 258  *
 259  * This is the compilation configuration file for LyX.
 260  * It was generated by autoconfs configure.
 261  * You might want to change some of the defaults if something goes wrong
 262  * during the compilation.
 263  */
 264
 265 #ifndef _CONFIG_H
 266 #define _CONFIG_H
 267 ])
 268
 269 AH_BOTTOM([
 270 /************************************************************
 271  ** You should not need to change anything beyond this point */
 272
 273 #ifndef HAVE_STRERROR
 274 #if defined(__cplusplus)
 275 extern "C"
 276 #endif
 277 char * strerror(int n);
 278 #endif
 279
 280 #define BOOST_USER_CONFIG <config.h>
 281
 282 #if !defined(ENABLE_ASSERTIONS)
 283 #  define BOOST_DISABLE_ASSERTS 1
 284 #endif
 285 #define BOOST_ENABLE_ASSERT_HANDLER 1
 286
 287 #define BOOST_DISABLE_THREADS 1
 288 #define BOOST_NO_WREGEX 1
 289 #define BOOST_NO_WSTRING 1
 290
 291 #ifdef __CYGWIN__
 292 #  define _DEFAULT_SOURCE
 293 #  define NOMINMAX
 294 #  define BOOST_POSIX 1
 295 #  define BOOST_POSIX_API 1
 296 #  define BOOST_POSIX_PATH 1
 297 #endif
 298
 299 #ifdef __sparc__
 300 #  ifndef __BIG_ENDIAN__
 301 #    define __BIG_ENDIAN__ 1
 302 #  endif
 303 #endif
 304
 305 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 306 #  define USE_WCHAR_T
 307 #endif
 308
 309 #endif
 310 ])
 311
 312 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 313 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 314 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 315
 316 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 317         "${lyx_abs_top_srcdir}", [Top source directory])
 318 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 319         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 320 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 321         "${lyx_abs_installed_datadir}",[Hard system support directory])
 322 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 323         "${version_suffix}",[Program version suffix])
 324
 325 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 326 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 327 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 328 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 329 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 330 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 331 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 332 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 333
 334 AC_CONFIG_FILES([Makefile \
 335       lyx.1:lyx.1in \
 336       3rdparty/Makefile \
 337       3rdparty/boost/Makefile \
 338       3rdparty/dtl/Makefile \
 339       3rdparty/hunspell/Makefile \
 340       3rdparty/mythes/Makefile \
 341       3rdparty/nod/Makefile \
 342       3rdparty/libiconv/Makefile \
 343       $ICONV_ICONV_H_IN \
 344       3rdparty/zlib/Makefile \
 345       autotests/Makefile \
 346       config/Makefile \
 347       development/Makefile \
 348       development/MacOSX/Makefile \
 349       development/MacOSX/Info.plist \
 350       development/MacOSX/lyxrc.dist \
 351       development/MacOSX/spotlight/Makefile \
 352       development/cygwin/Makefile \
 353       development/cygwin/lyxrc.dist \
 354       development/lyx.spec \
 355       lib/lyx.desktop-temp:lib/lyx.desktop.in
 356       lib/Makefile \
 357       lib/doc/Makefile \
 358       lib/lyx2lyx/lyx2lyx_version.py \
 359       lib/lyx2lyx/Makefile \
 360       m4/Makefile \
 361       po/Makefile.in \
 362       sourcedoc/Doxyfile \
 363       sourcedoc/Makefile \
 364       src/client/Makefile \
 365       src/client/lyxclient.1:src/client/lyxclient.1in \
 366       src/Makefile \
 367       src/tex2lyx/Makefile \
 368       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 369       src/convert/Makefile \
 370       src/support/Makefile \
 371       src/frontends/Makefile \
 372       src/frontends/qt/Makefile
 373 ])
 374
 375
 376 AC_OUTPUT
 377
 378 # show version information
 379 echo
 380 printf "$VERSION_INFO"
 381 echo
 382
 383 # Display a final warning if there has been a LYX_WARNING
 384 LYX_CHECK_WARNINGS
 385
 386 cat <<EOF
 387 Configuration of LyX was successful.
 388 Type 'make' to compile the program,
 389 and then 'make install' to install it.
 390 EOF