configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2014-04-14"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8] LYX_OBJECTS_LAYOUT)
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  37 PACKAGE=$save_PACKAGE
  38
  39 # Allow to build some parts of the code as one big chunk
  40 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  41 AC_ARG_ENABLE(monolithic-build,
  42   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  43                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  44   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  45    test "$enable_monolithic_build" = no && enable_monolithic_build=
  46    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  47    for i in $enable_monolithic_build ; do
  48        eval "enable_monolithic_$i=yes"
  49    done
  50    IFS="$ac_save_ifs"],
  51   [enable_monolithic_build=])
  52
  53 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  54 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  55 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  56 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  60
  61 ### Set the execute permissions of the various scripts correctly
  62 for file in config/install-sh ; do
  63   chmod 755 ${srcdir}/${file}
  64 done
  65
  66 AM_PATH_PYTHON(2.4.0,, :)
  67 AC_PROG_RANLIB
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 AC_LANG(C++)
  72
  73 ### Objective-C compiler
  74 AC_PROG_OBJC
  75 _AM_DEPENDENCIES([OBJC])
  76
  77 ### Add extra directories to check for libraries.
  78 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  79 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  80 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  81
  82 ### Add extra directories to check for include files.
  83 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  84 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  85 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  86
  87 ### Add both includes and libraries
  88 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  89 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  90 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  91   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  92
  93 ### These are needed in windows
  94 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  95 AC_SUBST(LIBSHLWAPI)
  96 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  97 AC_SUBST(LIBPSAPI)
  98 AC_CHECK_LIB(gdi32, main)
  99
 100 LYX_USE_INCLUDED_BOOST
 101 LYX_USE_INCLUDED_MYTHES
 102
 103 ### we need to know the byte order for unicode conversions
 104 AC_C_BIGENDIAN
 105
 106 # Nice to have when an assertion triggers
 107 LYX_CHECK_CALLSTACK_PRINTING
 108
 109 # Needed for our char_type
 110 AC_CHECK_SIZEOF(wchar_t)
 111
 112 ### We need iconv for unicode support (Qt4 frontend requires it too)
 113 AM_ICONV
 114 if test "$am_cv_func_iconv" = no; then
 115   AC_MSG_ERROR([cannot find required library iconv.])
 116 else
 117   LIBS="$LIBS $LIBICONV"
 118 fi
 119
 120 ### check for compression support
 121 AC_CHECK_HEADERS(zlib.h,
 122  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 123  [LYX_LIB_ERROR(zlib.h,zlib)])
 124
 125 ### check for file magic support (currently optional)
 126 AC_CHECK_HEADERS(magic.h,
 127  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 128   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 129    is correctly installed on your system.
 130    Falling back to builtin file format detection.]))],
 131  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 132    is correctly installed on your system.
 133    Falling back to builtin file format detection.])])
 134
 135 ### setup the qt frontend.
 136 dnl The code below is not in a macro, because this would cause big
 137 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 138 QT_DO_IT_ALL([4.5.0])
 139 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 140 FRONTEND_INFO="${FRONTEND_INFO}\
 141   Qt Frontend:\n\
 142       Qt version:\t\t${QTLIB_VERSION}\n"
 143
 144 # fix the value of the prefixes.
 145 test "x$prefix" = xNONE && prefix=$default_prefix
 146 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 147 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 148   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 149    causes problems with the Makefiles. The installation will be done in
 150    directory \"`pwd`/installprefix\" instead. Please move its contents to
 151    the right place after installation.])
 152   prefix=`pwd`/installprefix
 153 fi
 154
 155 ### Setup po directory
 156 AM_PO_SUBDIRS
 157 AM_NLS
 158 if test $USE_NLS = "yes" ; then
 159   AC_DEFINE(ENABLE_NLS, 1,
 160     [Define to 1 if translation of program messages to the user's native language
 161    is requested.])dnl'
 162 fi
 163
 164 # some standard header files
 165 AC_HEADER_MAJOR
 166 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 167
 168 # some standard types
 169 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 170 AC_TYPE_OFF_T
 171 AC_TYPE_PID_T
 172 AC_TYPE_SIZE_T
 173 AC_TYPE_UID_T
 174 # Taken from gettext
 175 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 176    [AC_TRY_COMPILE([#include <stddef.h>
 177       wchar_t foo = (wchar_t)'\0';], ,
 178       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 179 if test $gt_cv_c_wchar_t = yes; then
 180   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 181 fi
 182
 183 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 184
 185 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 186 # Check the form of mkdir()
 187 AC_FUNC_MKDIR
 188 AC_FUNC_SELECT_ARGTYPES
 189
 190 LYX_CHECK_SPELL_ENGINES
 191
 192 lyx_client_subdir=true
 193 dnl AC_LANG_PUSH(C)
 194 dnl LIBS already contains some X extra libs that may interfere.
 195 save_LIBS="$LIBS"
 196 LIBS=
 197 AC_CHECK_FUNCS(fcntl,
 198   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 199    AC_SEARCH_LIBS([socket], [socket], [],
 200      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 201                 [], [-lnsl])])],
 202   [lyx_client_subdir=false])
 203 AC_SUBST(SOCKET_LIBS,$LIBS)
 204 LIBS="$save_LIBS"
 205 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 206 dnl AC_LANG_POP(C)
 207
 208 lyx_win_res=false;
 209 case ${host} in
 210     *mingw*|*cygwin*) lyx_win_res=true;;
 211 esac
 212 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 213 LYX_SET_VERSION_INFO
 214
 215
 216 ### Some information on what just happened
 217 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 218 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 219 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 220 VERSION_INFO="Configuration\n\
 221   Host type:                    ${host}\n\
 222   Special build flags:         ${lyx_flags}\n\
 223   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 224   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 225   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 226   Linker flags:                 ${AM_LDFLAGS}\n\
 227   Linker user flags:            ${LDFLAGS}\n\
 228 ${FRONTEND_INFO}\
 229   Packaging:                    ${lyx_use_packaging}\n\
 230   LyX binary dir:               ${real_bindir}\n\
 231   LyX files dir:                ${real_pkgdatadir}\n"
 232
 233 AC_SUBST(VERSION_INFO)
 234 AC_SUBST(AM_CPPFLAGS)
 235 AC_SUBST(AM_CXXFLAGS)
 236 AC_SUBST(AM_CFLAGS)
 237 AC_SUBST(AM_LDFLAGS)
 238 AC_SUBST(real_pkgdatadir)
 239
 240 ## Some config.h stuff
 241
 242 AH_TOP([
 243 /* -*- C++ -*- */
 244 /*
 245  * \file config.h
 246  * This file is part of LyX, the document processor.
 247  * Licence details can be found in the file COPYING.
 248  *
 249  * This is the compilation configuration file for LyX.
 250  * It was generated by autoconfs configure.
 251  * You might want to change some of the defaults if something goes wrong
 252  * during the compilation.
 253  */
 254
 255 #ifndef _CONFIG_H
 256 #define _CONFIG_H
 257 ])
 258
 259 AH_BOTTOM([
 260 /************************************************************
 261  ** You should not need to change anything beyond this point */
 262
 263 #ifndef HAVE_STRERROR
 264 #if defined(__cplusplus)
 265 extern "C"
 266 #endif
 267 char * strerror(int n);
 268 #endif
 269
 270 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 271 #  define USE_BOOST_FORMAT 1
 272 #else
 273 #  define USE_BOOST_FORMAT 0
 274 #endif
 275
 276 #define BOOST_USER_CONFIG <config.h>
 277
 278 #if !defined(ENABLE_ASSERTIONS)
 279 #  define BOOST_DISABLE_ASSERTS 1
 280 #endif
 281 #define BOOST_ENABLE_ASSERT_HANDLER 1
 282
 283 #define BOOST_DISABLE_THREADS 1
 284 #define BOOST_NO_WREGEX 1
 285 #define BOOST_NO_WSTRING 1
 286 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 287
 288 #ifdef __CYGWIN__
 289 #  define NOMINMAX
 290 #  define BOOST_POSIX 1
 291 #  define BOOST_POSIX_API 1
 292 #  define BOOST_POSIX_PATH 1
 293 #endif
 294
 295 #ifdef __sparc__
 296 #  ifndef __BIG_ENDIAN__
 297 #    define __BIG_ENDIAN__ 1
 298 #  endif
 299 #endif
 300
 301 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 302 #  define USE_WCHAR_T
 303 #endif
 304
 305 #endif
 306 ])
 307
 308 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 309 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 310 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 311
 312 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 313         "${lyx_abs_top_srcdir}", [Top source directory])
 314 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 315         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 316 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 317         "${lyx_abs_installed_datadir}",[Hard system support directory])
 318 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 319         "${version_suffix}",[Program version suffix])
 320
 321 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 322 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 323 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 324 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 325 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 326 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 327 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 328 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 329
 330 AC_CONFIG_FILES([Makefile \
 331       lyx.1:lyx.1in \
 332       boost/Makefile \
 333       config/Makefile \
 334       development/Makefile \
 335       development/MacOSX/Makefile \
 336       development/MacOSX/Info.plist \
 337       development/MacOSX/lyxrc.dist \
 338       development/MacOSX/spotlight/Makefile \
 339       development/cygwin/Makefile \
 340       development/cygwin/lyxrc.dist \
 341       development/lyx.spec \
 342       lib/lyx.desktop-temp:lib/lyx.desktop.in
 343       lib/Makefile \
 344       lib/doc/Makefile \
 345       lib/lyx2lyx/lyx2lyx_version.py \
 346       lib/lyx2lyx/Makefile \
 347       m4/Makefile \
 348       po/Makefile.in \
 349       sourcedoc/Doxyfile \
 350       sourcedoc/Makefile \
 351       src/client/Makefile \
 352       src/client/lyxclient.1:src/client/lyxclient.1in \
 353       src/Makefile \
 354       src/tex2lyx/Makefile \
 355       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 356       src/support/Makefile \
 357       src/frontends/Makefile \
 358       src/frontends/qt4/Makefile
 359 ])
 360
 361
 362 AC_OUTPUT
 363
 364 # show version information
 365 echo
 366 printf "$VERSION_INFO"
 367 echo
 368
 369 # Display a final warning if there has been a LYX_WARNING
 370 LYX_CHECK_WARNINGS
 371
 372 cat <<EOF
 373 Configuration of LyX was successful.
 374 Type 'make' to compile the program,
 375 and then 'make install' to install it.
 376 EOF