configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.4.0dev],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2021-02-14"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT6
  17 if test x$USE_QT6 = xno ; then
  18 LYX_CHECK_QT5
  19 fi
  20 # Check how the files should be packaged
  21 AC_CANONICAL_TARGET
  22 LYX_USE_PACKAGING
  23 # We need to define these variables here and the no-define option of
  24 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  25 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  26
  27 dnl Default maintainer mode to true for development versions
  28 if test "${enable_maintainer_mode+set}" != set; then
  29   enable_maintainer_mode=$lyx_devel_version
  30 fi
  31 AM_MAINTAINER_MODE
  32 AM_SILENT_RULES([yes])
  33 # Automake is pulling the historical V7 format. This tar format supports
  34 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  35 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  36 save_PACKAGE=$PACKAGE
  37 AM_INIT_AUTOMAKE([foreign dist-xz no-define 1.14 tar-ustar subdir-objects])
  38 PACKAGE=$save_PACKAGE
  39
  40 ### Set the execute permissions of the various scripts correctly
  41 for file in config/install-sh ; do
  42   chmod 755 ${srcdir}/${file}
  43 done
  44
  45 # Find a suitable python interpreter
  46 LYX_PATH_PYTHON23([2.7.0], [3.5.0])
  47 # do the usual python setup stuff
  48 AM_PATH_PYTHON
  49
  50 # Tools for creating libraries (note that we do not use libtool)
  51 AM_PROG_AR
  52 AC_PROG_RANLIB
  53 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  54 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  55 AC_SUBST([ARFLAGS], [cr])
  56
  57 ### Check for a C++ compiler
  58 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  59 dnl if it is not set. We do not use autoconf defaults.
  60 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  61 if ! test "$lyx_has_CXXFLAGS" = yes; then
  62   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  63   CXXFLAGS=" "
  64 fi
  65 LYX_PROG_CXX
  66 if ! test "$lyx_has_CXXFLAGS" = yes; then
  67   unset CXXFLAGS
  68 fi
  69 AC_LANG(C++)
  70
  71 ### Objective-C compiler
  72 AC_PROG_OBJC
  73 _AM_DEPENDENCIES([OBJC])
  74
  75 ### Add extra directories to check for libraries.
  76 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  77 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  78 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  79
  80 ### Add extra directories to check for include files.
  81 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  82 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  83 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  84
  85 ### Add both includes and libraries
  86 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  87 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  88   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  89   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  90 ])
  91
  92 ### These are needed in windows
  93 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  94 AC_SUBST(LIBSHLWAPI)
  95 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  96 AC_SUBST(LIBPSAPI)
  97 AC_CHECK_LIB(gdi32, main)
  98 AC_CHECK_LIB(ole32, main)
  99
 100 LYX_USE_INCLUDED_NOD
 101 LYX_USE_INCLUDED_BOOST
 102
 103 ### we need to know the byte order for unicode conversions
 104 AC_C_BIGENDIAN
 105
 106 # Nice to have when an assertion triggers
 107 LYX_CHECK_CALLSTACK_PRINTING
 108
 109 # C++14 only
 110 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 111
 112 # Needed for our char_type
 113 AC_CHECK_SIZEOF(wchar_t)
 114
 115 # Taken from gettext, needed for libiconv
 116 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 117    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 118       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 119 if test $gt_cv_c_wchar_t = yes; then
 120   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 121   HAVE_WCHAR_T=1
 122 else
 123   HAVE_WCHAR_T=0
 124 fi
 125 AC_SUBST([HAVE_WCHAR_T])
 126
 127 # Needed for Mingw-w64
 128 AC_TYPE_LONG_LONG_INT
 129
 130 ### We need iconv for unicode support (Qt frontend requires it too)
 131 LYX_USE_INCLUDED_ICONV
 132
 133 ### check for compression support
 134 LYX_USE_INCLUDED_ZLIB
 135
 136 ### check whether we build and install the supplied dtl programs
 137 LYX_BUILD_INCLUDED_DTL
 138
 139 ### check for file magic support (currently optional)
 140 AC_CHECK_HEADERS(magic.h,
 141  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 142   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 143    is correctly installed on your system.
 144    Falling back to builtin file format detection.]))],
 145  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 146    is correctly installed on your system.
 147    Falling back to builtin file format detection.])])
 148
 149 ### setup the qt frontend.
 150 dnl The code below is not in a macro, because this would cause big
 151 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 152 QT_DO_IT_ALL([4.5.0])
 153 AC_SUBST([FRONTENDS_SUBDIRS], [qt])
 154 FRONTEND_INFO="${FRONTEND_INFO}\
 155   Qt Frontend:\n\
 156       Qt version:\t   ${QTLIB_VERSION}\n"
 157
 158 # fix the value of the prefixes.
 159 test "x$prefix" = xNONE && prefix=$default_prefix
 160 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 161 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 162   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 163    causes problems with the Makefiles. The installation will be done in
 164    directory \"`pwd`/installprefix\" instead. Please move its contents to
 165    the right place after installation.])
 166   prefix=`pwd`/installprefix
 167 fi
 168
 169 ### Setup po directory
 170 AM_NLS
 171 if test $USE_NLS = "yes" ; then
 172   AC_DEFINE(ENABLE_NLS, 1,
 173     [Define to 1 if translation of program messages to the user's native language
 174    is requested.])dnl'
 175 fi
 176 AM_PO_SUBDIRS
 177
 178 # some standard header files
 179 AC_HEADER_MAJOR
 180 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 181
 182 # some standard types
 183 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 184 AC_TYPE_OFF_T
 185 AC_TYPE_PID_T
 186 AC_TYPE_SIZE_T
 187 AC_TYPE_UID_T
 188
 189 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 190
 191 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 192 # Check the form of mkdir()
 193 AC_FUNC_MKDIR
 194 AC_FUNC_SELECT_ARGTYPES
 195
 196 LYX_CHECK_SPELL_ENGINES
 197 LYX_USE_INCLUDED_MYTHES
 198
 199 LYX_CHECK_WITH_SAXON
 200
 201 lyx_client_subdir=true
 202 dnl LIBS already contains some X extra libs that may interfere.
 203 save_LIBS="$LIBS"
 204 LIBS=
 205 AC_CHECK_FUNCS(fcntl,
 206   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 207    AC_SEARCH_LIBS([socket], [socket network], [],
 208      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 209                 [], [-lnsl])])],
 210   [lyx_client_subdir=false])
 211 AC_SUBST(SOCKET_LIBS,$LIBS)
 212 LIBS="$save_LIBS"
 213 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 214
 215 lyx_win_res=false;
 216 case ${host} in
 217     *mingw*|*cygwin*) lyx_win_res=true;;
 218     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 219 esac
 220 if test "x$lyx_win_res" = "xtrue"; then
 221     AC_CHECK_TOOL(RC, windres,)
 222     if test -z "$RC"; then
 223       AC_MSG_ERROR([Could not find a resource compiler])
 224     fi
 225 fi
 226 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 227 LYX_SET_VERSION_INFO
 228
 229
 230 ### Some information on what just happened
 231 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 232 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 233 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 234 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 235 VERSION_INFO="Configuration\n\
 236   Host type:               ${host}\n\
 237   Special build flags:     ${lyx_flags}\n\
 238   Bundled libraries:       ${lyx_included_libs}\n\
 239   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 240   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 241   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 242   Linker flags:            ${AM_LDFLAGS}\n\
 243   Linker user flags:       ${LDFLAGS}\n\
 244 ${FRONTEND_INFO}\
 245   Packaging:               ${lyx_use_packaging}\n\
 246   LyX binary dir:          ${real_bindir}\n\
 247   LyX files dir:           ${real_pkgdatadir}\n"
 248
 249 AC_SUBST(VERSION_INFO)
 250 AC_SUBST(AM_CPPFLAGS)
 251 AC_SUBST(AM_CXXFLAGS)
 252 AC_SUBST(AM_LDFLAGS)
 253 AC_SUBST(real_pkgdatadir)
 254
 255 ## Some config.h stuff
 256
 257 AH_TOP([
 258 /* -*- C++ -*- */
 259 /*
 260  * \file config.h
 261  * This file is part of LyX, the document processor.
 262  * Licence details can be found in the file COPYING.
 263  *
 264  * This is the compilation configuration file for LyX.
 265  * It was generated by autoconfs configure.
 266  * You might want to change some of the defaults if something goes wrong
 267  * during the compilation.
 268  */
 269
 270 #ifndef _CONFIG_H
 271 #define _CONFIG_H
 272 ])
 273
 274 AH_BOTTOM([
 275 /************************************************************
 276  ** You should not need to change anything beyond this point */
 277
 278 #ifndef HAVE_STRERROR
 279 #if defined(__cplusplus)
 280 extern "C"
 281 #endif
 282 char * strerror(int n);
 283 #endif
 284
 285 #define BOOST_USER_CONFIG <config.h>
 286
 287 #if !defined(ENABLE_ASSERTIONS)
 288 #  define BOOST_DISABLE_ASSERTS 1
 289 #endif
 290 #define BOOST_ENABLE_ASSERT_HANDLER 1
 291
 292 #define BOOST_DISABLE_THREADS 1
 293 #define BOOST_NO_WREGEX 1
 294 #define BOOST_NO_WSTRING 1
 295
 296 #ifdef __CYGWIN__
 297 #  define _DEFAULT_SOURCE
 298 #  define NOMINMAX
 299 #  define BOOST_POSIX 1
 300 #  define BOOST_POSIX_API 1
 301 #  define BOOST_POSIX_PATH 1
 302 #endif
 303
 304 #ifdef __sparc__
 305 #  ifndef __BIG_ENDIAN__
 306 #    define __BIG_ENDIAN__ 1
 307 #  endif
 308 #endif
 309
 310 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 311 #  define USE_WCHAR_T
 312 #endif
 313
 314 #endif
 315 ])
 316
 317 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 318 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 319 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 320
 321 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 322         "${lyx_abs_top_srcdir}", [Top source directory])
 323 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 324         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 325 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 326         "${lyx_abs_installed_datadir}",[Hard system support directory])
 327 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 328         "${version_suffix}",[Program version suffix])
 329
 330 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 331 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 332 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 333 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 334 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 335 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 336 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 337 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 338
 339 AC_CONFIG_FILES([Makefile \
 340       lyx.1:lyx.1in \
 341       3rdparty/Makefile \
 342       3rdparty/boost/Makefile \
 343       3rdparty/dtl/Makefile \
 344       3rdparty/hunspell/Makefile \
 345       3rdparty/mythes/Makefile \
 346       3rdparty/nod/Makefile \
 347       3rdparty/libiconv/Makefile \
 348       $ICONV_ICONV_H_IN \
 349       3rdparty/zlib/Makefile \
 350       autotests/Makefile \
 351       config/Makefile \
 352       development/Makefile \
 353       development/MacOSX/Makefile \
 354       development/MacOSX/Info.plist \
 355       development/MacOSX/lyxrc.dist \
 356       development/MacOSX/spotlight/Makefile \
 357       development/cygwin/Makefile \
 358       development/cygwin/lyxrc.dist \
 359       development/lyx.spec \
 360       lib/lyx.desktop-temp:lib/lyx.desktop.in
 361       lib/Makefile \
 362       lib/doc/Makefile \
 363       lib/lyx2lyx/lyx2lyx_version.py \
 364       lib/lyx2lyx/Makefile \
 365       m4/Makefile \
 366       po/Makefile.in \
 367       sourcedoc/Doxyfile \
 368       sourcedoc/Makefile \
 369       src/client/Makefile \
 370       src/client/lyxclient.1:src/client/lyxclient.1in \
 371       src/Makefile \
 372       src/tex2lyx/Makefile \
 373       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 374       src/convert/Makefile \
 375       src/support/Makefile \
 376       src/frontends/Makefile \
 377       src/frontends/qt/Makefile
 378 ])
 379
 380
 381 AC_OUTPUT
 382
 383 # show version information
 384 echo
 385 printf "$VERSION_INFO"
 386 echo
 387
 388 # Display a final warning if there has been a LYX_WARNING
 389 LYX_CHECK_WARNINGS
 390
 391 cat <<EOF
 392 Configuration of LyX was successful.
 393 Type 'make' to compile the program,
 394 and then 'make install' to install it.
 395 EOF