configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2014-04-14"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 # Check how the files should be packaged
  17 AC_CANONICAL_TARGET
  18 LYX_USE_PACKAGING
  19 # We need to define these variables here and the no-define option of
  20 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  22
  23 dnl Default maintainer mode to true for development versions
  24 if test "${enable_maintainer_mode+set}" != set; then
  25   enable_maintainer_mode=$lyx_devel_version
  26 fi
  27 AM_MAINTAINER_MODE
  28
  29 save_PACKAGE=$PACKAGE
  30 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  31 dnl which are the versions where subdir-objects can beused.
  32 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  33 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  34 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8] LYX_OBJECTS_LAYOUT)
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36 PACKAGE=$save_PACKAGE
  37
  38 LYX_CHECK_GIT_COMMIT
  39
  40 # Allow to build some parts of the code as one big chunk
  41 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  42 AC_ARG_ENABLE(monolithic-build,
  43   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  44                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  45   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  46    test "$enable_monolithic_build" = no && enable_monolithic_build=
  47    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  48    for i in $enable_monolithic_build ; do
  49        eval "enable_monolithic_$i=yes"
  50    done
  51    IFS="$ac_save_ifs"],
  52   [enable_monolithic_build=])
  53
  54 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  55 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  56 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  61
  62 ### Set the execute permissions of the various scripts correctly
  63 for file in config/install-sh ; do
  64   chmod 755 ${srcdir}/${file}
  65 done
  66
  67 AM_PATH_PYTHON(2.4.0,, :)
  68 AC_PROG_RANLIB
  69
  70 ### Check for a C++ compiler
  71 LYX_PROG_CXX
  72 AC_LANG(C++)
  73
  74 ### Objective-C compiler
  75 AC_PROG_OBJC
  76 _AM_DEPENDENCIES([OBJC])
  77
  78 ### Add extra directories to check for libraries.
  79 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  80 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  81 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  82
  83 ### Add extra directories to check for include files.
  84 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  85 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  86 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  87
  88 ### Add both includes and libraries
  89 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  90 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  91 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  92   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  93
  94 ### These are needed in windows
  95 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  96 AC_SUBST(LIBSHLWAPI)
  97 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  98 AC_SUBST(LIBPSAPI)
  99 AC_CHECK_LIB(gdi32, main)
 100
 101 LYX_USE_INCLUDED_BOOST
 102 LYX_USE_INCLUDED_MYTHES
 103
 104 ### we need to know the byte order for unicode conversions
 105 AC_C_BIGENDIAN
 106
 107 # Needed for our char_type
 108 AC_CHECK_SIZEOF(wchar_t)
 109
 110 ### We need iconv for unicode support (Qt4 frontend requires it too)
 111 AM_ICONV
 112 if test "$am_cv_func_iconv" = no; then
 113   AC_MSG_ERROR([cannot find required library iconv.])
 114 else
 115   LIBS="$LIBS $LIBICONV"
 116 fi
 117
 118 ### check for compression support
 119 AC_CHECK_HEADERS(zlib.h,
 120  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 121  [LYX_LIB_ERROR(zlib.h,zlib)])
 122
 123 ### check for file magic support (currently optional)
 124 AC_CHECK_HEADERS(magic.h,
 125  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 126   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 127    is correctly installed on your system.
 128    Falling back to builtin file format detection.]))],
 129  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 130    is correctly installed on your system.
 131    Falling back to builtin file format detection.])])
 132
 133 ### setup the qt frontend.
 134 dnl The code below is not in a macro, because this would cause big
 135 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 136 QT_DO_IT_ALL([4.5.0])
 137 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 138 FRONTEND_INFO="${FRONTEND_INFO}\
 139   Qt Frontend:\n\
 140       Qt version:\t\t${QTLIB_VERSION}\n"
 141
 142 # fix the value of the prefixes.
 143 test "x$prefix" = xNONE && prefix=$default_prefix
 144 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 145 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 146   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 147    causes problems with the Makefiles. The installation will be done in
 148    directory \"`pwd`/installprefix\" instead. Please move its contents to
 149    the right place after installation.])
 150   prefix=`pwd`/installprefix
 151 fi
 152
 153 ### Setup po directory
 154 AM_PO_SUBDIRS
 155 AM_NLS
 156 if test $USE_NLS = "yes" ; then
 157   AC_DEFINE(ENABLE_NLS, 1,
 158     [Define to 1 if translation of program messages to the user's native language
 159    is requested.])dnl'
 160 fi
 161
 162 # some standard header files
 163 AC_HEADER_MAJOR
 164 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 165
 166 # some standard types
 167 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 168 AC_TYPE_OFF_T
 169 AC_TYPE_PID_T
 170 AC_TYPE_SIZE_T
 171 AC_TYPE_UID_T
 172 # Taken from gettext
 173 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 174    [AC_TRY_COMPILE([#include <stddef.h>
 175       wchar_t foo = (wchar_t)'\0';], ,
 176       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 177 if test $gt_cv_c_wchar_t = yes; then
 178   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 179 fi
 180
 181 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 182
 183 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 184 # Check the form of mkdir()
 185 AC_FUNC_MKDIR
 186 AC_FUNC_SELECT_ARGTYPES
 187
 188 LYX_CHECK_SPELL_ENGINES
 189
 190 lyx_client_subdir=true
 191 dnl AC_LANG_PUSH(C)
 192 dnl LIBS already contains some X extra libs that may interfere.
 193 save_LIBS="$LIBS"
 194 LIBS=
 195 AC_CHECK_FUNCS(fcntl,
 196   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 197    AC_SEARCH_LIBS([socket], [socket], [],
 198      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 199                 [], [-lnsl])])],
 200   [lyx_client_subdir=false])
 201 AC_SUBST(SOCKET_LIBS,$LIBS)
 202 LIBS="$save_LIBS"
 203 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 204 dnl AC_LANG_POP(C)
 205
 206 lyx_win_res=false;
 207 case ${host} in
 208     *mingw*|*cygwin*) lyx_win_res=true;;
 209 esac
 210 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 211 LYX_SET_VERSION_INFO
 212
 213
 214 ### Some information on what just happened
 215 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 216 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 217 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 218 VERSION_INFO="Configuration\n\
 219   Host type:                    ${host}\n\
 220   Special build flags:         ${lyx_flags}\n\
 221   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 222   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 223   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 224   Linker flags:                 ${AM_LDFLAGS}\n\
 225   Linker user flags:            ${LDFLAGS}\n\
 226 ${FRONTEND_INFO}\
 227   Packaging:                    ${lyx_use_packaging}\n\
 228   LyX binary dir:               ${real_bindir}\n\
 229   LyX files dir:                ${real_pkgdatadir}\n"
 230
 231 AC_SUBST(VERSION_INFO)
 232 AC_SUBST(AM_CPPFLAGS)
 233 AC_SUBST(AM_CXXFLAGS)
 234 AC_SUBST(AM_CFLAGS)
 235 AC_SUBST(AM_LDFLAGS)
 236 AC_SUBST(real_pkgdatadir)
 237
 238 ## Some config.h stuff
 239
 240 AH_TOP([
 241 /* -*- C++ -*- */
 242 /*
 243  * \file config.h
 244  * This file is part of LyX, the document processor.
 245  * Licence details can be found in the file COPYING.
 246  *
 247  * This is the compilation configuration file for LyX.
 248  * It was generated by autoconfs configure.
 249  * You might want to change some of the defaults if something goes wrong
 250  * during the compilation.
 251  */
 252
 253 #ifndef _CONFIG_H
 254 #define _CONFIG_H
 255 ])
 256
 257 AH_BOTTOM([
 258 /************************************************************
 259  ** You should not need to change anything beyond this point */
 260
 261 #ifndef HAVE_STRERROR
 262 #if defined(__cplusplus)
 263 extern "C"
 264 #endif
 265 char * strerror(int n);
 266 #endif
 267
 268 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 269 #  define USE_BOOST_FORMAT 1
 270 #else
 271 #  define USE_BOOST_FORMAT 0
 272 #endif
 273
 274 #define BOOST_USER_CONFIG <config.h>
 275
 276 #if !defined(ENABLE_ASSERTIONS)
 277 #  define BOOST_DISABLE_ASSERTS 1
 278 #endif
 279 #define BOOST_ENABLE_ASSERT_HANDLER 1
 280
 281 #define BOOST_DISABLE_THREADS 1
 282 #define BOOST_NO_WREGEX 1
 283 #define BOOST_NO_WSTRING 1
 284 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 285
 286 // TR1 regex not supported in GCC <= 4.5
 287 #ifndef LYX_USE_TR1
 288 #  if __GNUC__ == 4
 289 #    define LYX_USE_TR1
 290 #  endif
 291 #endif
 292
 293 #ifdef __CYGWIN__
 294 #  define NOMINMAX
 295 #  define BOOST_POSIX 1
 296 #  define BOOST_POSIX_API 1
 297 #  define BOOST_POSIX_PATH 1
 298 #endif
 299
 300 #ifdef __sparc__
 301 #  ifndef __BIG_ENDIAN__
 302 #    define __BIG_ENDIAN__ 1
 303 #  endif
 304 #endif
 305
 306 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 307 #  define USE_WCHAR_T
 308 #endif
 309
 310 #endif
 311 ])
 312
 313 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 314 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 315 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 316
 317 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 318         "${lyx_abs_top_srcdir}", [Top source directory])
 319 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 320         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 321 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 322         "${lyx_abs_installed_datadir}",[Hard system support directory])
 323 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 324         "${version_suffix}",[Program version suffix])
 325
 326 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 327 AC_DEFINE_UNQUOTED([LYX_GIT_COMMIT_HASH], "$lyxgitcommit", [Git commit])
 328 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 329 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 330 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 331 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 332 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 333 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 334 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 335
 336 AC_CONFIG_FILES([Makefile \
 337       lyx.1:lyx.1in \
 338       boost/Makefile \
 339       config/Makefile \
 340       development/Makefile \
 341       development/MacOSX/Makefile \
 342       development/MacOSX/Info.plist \
 343       development/MacOSX/lyxrc.dist \
 344       development/MacOSX/spotlight/Makefile \
 345       development/cygwin/Makefile \
 346       development/cygwin/lyxrc.dist \
 347       development/lyx.spec \
 348       lib/lyx.desktop-temp:lib/lyx.desktop.in
 349       lib/Makefile \
 350       lib/doc/Makefile \
 351       lib/lyx2lyx/lyx2lyx_version.py \
 352       lib/lyx2lyx/Makefile \
 353       m4/Makefile \
 354       po/Makefile.in \
 355       sourcedoc/Doxyfile \
 356       sourcedoc/Makefile \
 357       src/client/Makefile \
 358       src/client/lyxclient.1:src/client/lyxclient.1in \
 359       src/Makefile \
 360       src/tex2lyx/Makefile \
 361       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 362       src/support/Makefile \
 363       src/frontends/Makefile \
 364       src/frontends/qt4/Makefile
 365 ])
 366
 367
 368 AC_OUTPUT
 369
 370 # show version information
 371 echo
 372 printf "$VERSION_INFO"
 373 echo
 374
 375 # Display a final warning if there has been a LYX_WARNING
 376 LYX_CHECK_WARNINGS
 377
 378 cat <<EOF
 379 Configuration of LyX was successful.
 380 Type 'make' to compile the program,
 381 and then 'make install' to install it.
 382 EOF