configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.4.0dev],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2018-02-24"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29 AM_SILENT_RULES([yes])
  30 # Automake is pulling the historical V7 format. This tar format supports
  31 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  32 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  33 save_PACKAGE=$PACKAGE
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-define 1.14 tar-ustar subdir-objects])
  35 PACKAGE=$save_PACKAGE
  36
  37 ### Set the execute permissions of the various scripts correctly
  38 for file in config/install-sh ; do
  39   chmod 755 ${srcdir}/${file}
  40 done
  41
  42 # Find a suitable python interpreter
  43 LYX_PATH_PYTHON23([2.7.0], [3.5.0])
  44 # do the usual python setup stuff
  45 AM_PATH_PYTHON
  46
  47 # Tools for creating libraries (note that we do not use libtool)
  48 AM_PROG_AR
  49 AC_PROG_RANLIB
  50 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  51 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  52 AC_SUBST([ARFLAGS], [cr])
  53
  54 ### Check for a C++ compiler
  55 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  56 dnl if it is not set. We do not use autoconf defaults.
  57 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  58 if ! test "$lyx_has_CXXFLAGS" = yes; then
  59   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  60   CXXFLAGS=" "
  61 fi
  62 LYX_PROG_CXX
  63 if ! test "$lyx_has_CXXFLAGS" = yes; then
  64   unset CXXFLAGS
  65 fi
  66 AC_LANG(C++)
  67
  68 ### Objective-C compiler
  69 AC_PROG_OBJC
  70 _AM_DEPENDENCIES([OBJC])
  71
  72 ### Add extra directories to check for libraries.
  73 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  74 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  75 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  76
  77 ### Add extra directories to check for include files.
  78 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  79 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  80 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  81
  82 ### Add both includes and libraries
  83 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  84 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  85   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  86   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  87 ])
  88
  89 ### These are needed in windows
  90 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  91 AC_SUBST(LIBSHLWAPI)
  92 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  93 AC_SUBST(LIBPSAPI)
  94 AC_CHECK_LIB(gdi32, main)
  95 AC_CHECK_LIB(ole32, main)
  96
  97 LYX_USE_INCLUDED_BOOST
  98
  99 ### we need to know the byte order for unicode conversions
 100 AC_C_BIGENDIAN
 101
 102 # Nice to have when an assertion triggers
 103 LYX_CHECK_CALLSTACK_PRINTING
 104
 105 # C++14 only
 106 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 107
 108 # Needed for our char_type
 109 AC_CHECK_SIZEOF(wchar_t)
 110
 111 # Taken from gettext, needed for libiconv
 112 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 113    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 114       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 115 if test $gt_cv_c_wchar_t = yes; then
 116   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 117   HAVE_WCHAR_T=1
 118 else
 119   HAVE_WCHAR_T=0
 120 fi
 121 AC_SUBST([HAVE_WCHAR_T])
 122
 123 # Needed for Mingw-w64
 124 AC_TYPE_LONG_LONG_INT
 125
 126 ### We need iconv for unicode support (Qt frontend requires it too)
 127 LYX_USE_INCLUDED_ICONV
 128
 129 ### check for compression support
 130 LYX_USE_INCLUDED_ZLIB
 131
 132 ### check whether we build and install the supplied dtl programs
 133 LYX_BUILD_INCLUDED_DTL
 134
 135 ### check for file magic support (currently optional)
 136 AC_CHECK_HEADERS(magic.h,
 137  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 138   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 139    is correctly installed on your system.
 140    Falling back to builtin file format detection.]))],
 141  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 142    is correctly installed on your system.
 143    Falling back to builtin file format detection.])])
 144
 145 ### setup the qt frontend.
 146 dnl The code below is not in a macro, because this would cause big
 147 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 148 QT_DO_IT_ALL([4.5.0])
 149 AC_SUBST([FRONTENDS_SUBDIRS], [qt])
 150 FRONTEND_INFO="${FRONTEND_INFO}\
 151   Qt Frontend:\n\
 152       Qt version:\t   ${QTLIB_VERSION}\n"
 153
 154 # fix the value of the prefixes.
 155 test "x$prefix" = xNONE && prefix=$default_prefix
 156 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 157 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 158   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 159    causes problems with the Makefiles. The installation will be done in
 160    directory \"`pwd`/installprefix\" instead. Please move its contents to
 161    the right place after installation.])
 162   prefix=`pwd`/installprefix
 163 fi
 164
 165 ### Setup po directory
 166 AM_NLS
 167 if test $USE_NLS = "yes" ; then
 168   AC_DEFINE(ENABLE_NLS, 1,
 169     [Define to 1 if translation of program messages to the user's native language
 170    is requested.])dnl'
 171 fi
 172 AM_PO_SUBDIRS
 173
 174 # some standard header files
 175 AC_HEADER_MAJOR
 176 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 177
 178 # some standard types
 179 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 180 AC_TYPE_OFF_T
 181 AC_TYPE_PID_T
 182 AC_TYPE_SIZE_T
 183 AC_TYPE_UID_T
 184
 185 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 186
 187 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 188 # Check the form of mkdir()
 189 AC_FUNC_MKDIR
 190 AC_FUNC_SELECT_ARGTYPES
 191
 192 LYX_CHECK_SPELL_ENGINES
 193 LYX_USE_INCLUDED_MYTHES
 194
 195 lyx_client_subdir=true
 196 dnl LIBS already contains some X extra libs that may interfere.
 197 save_LIBS="$LIBS"
 198 LIBS=
 199 AC_CHECK_FUNCS(fcntl,
 200   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 201    AC_SEARCH_LIBS([socket], [socket network], [],
 202      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 203                 [], [-lnsl])])],
 204   [lyx_client_subdir=false])
 205 AC_SUBST(SOCKET_LIBS,$LIBS)
 206 LIBS="$save_LIBS"
 207 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 208
 209 lyx_win_res=false;
 210 case ${host} in
 211     *mingw*|*cygwin*) lyx_win_res=true;;
 212     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 213 esac
 214 if test "x$lyx_win_res" = "xtrue"; then
 215     AC_CHECK_TOOL(RC, windres,)
 216     if test -z "$RC"; then
 217       AC_MSG_ERROR([Could not find a resource compiler])
 218     fi
 219 fi
 220 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 221 LYX_SET_VERSION_INFO
 222
 223
 224 ### Some information on what just happened
 225 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 226 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 227 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 228 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 229 VERSION_INFO="Configuration\n\
 230   Host type:               ${host}\n\
 231   Special build flags:     ${lyx_flags}\n\
 232   Bundled libraries:       ${lyx_included_libs}\n\
 233   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 234   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 235   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 236   Linker flags:            ${AM_LDFLAGS}\n\
 237   Linker user flags:       ${LDFLAGS}\n\
 238 ${FRONTEND_INFO}\
 239   Packaging:               ${lyx_use_packaging}\n\
 240   LyX binary dir:          ${real_bindir}\n\
 241   LyX files dir:           ${real_pkgdatadir}\n"
 242
 243 AC_SUBST(VERSION_INFO)
 244 AC_SUBST(AM_CPPFLAGS)
 245 AC_SUBST(AM_CXXFLAGS)
 246 AC_SUBST(AM_LDFLAGS)
 247 AC_SUBST(real_pkgdatadir)
 248
 249 ## Some config.h stuff
 250
 251 AH_TOP([
 252 /* -*- C++ -*- */
 253 /*
 254  * \file config.h
 255  * This file is part of LyX, the document processor.
 256  * Licence details can be found in the file COPYING.
 257  *
 258  * This is the compilation configuration file for LyX.
 259  * It was generated by autoconfs configure.
 260  * You might want to change some of the defaults if something goes wrong
 261  * during the compilation.
 262  */
 263
 264 #ifndef _CONFIG_H
 265 #define _CONFIG_H
 266 ])
 267
 268 AH_BOTTOM([
 269 /************************************************************
 270  ** You should not need to change anything beyond this point */
 271
 272 #ifndef HAVE_STRERROR
 273 #if defined(__cplusplus)
 274 extern "C"
 275 #endif
 276 char * strerror(int n);
 277 #endif
 278
 279 #define BOOST_USER_CONFIG <config.h>
 280
 281 #if !defined(ENABLE_ASSERTIONS)
 282 #  define BOOST_DISABLE_ASSERTS 1
 283 #endif
 284 #define BOOST_ENABLE_ASSERT_HANDLER 1
 285
 286 #define BOOST_DISABLE_THREADS 1
 287 #define BOOST_NO_WREGEX 1
 288 #define BOOST_NO_WSTRING 1
 289
 290 #ifdef __CYGWIN__
 291 #  define _DEFAULT_SOURCE
 292 #  define NOMINMAX
 293 #  define BOOST_POSIX 1
 294 #  define BOOST_POSIX_API 1
 295 #  define BOOST_POSIX_PATH 1
 296 #endif
 297
 298 #ifdef __sparc__
 299 #  ifndef __BIG_ENDIAN__
 300 #    define __BIG_ENDIAN__ 1
 301 #  endif
 302 #endif
 303
 304 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 305 #  define USE_WCHAR_T
 306 #endif
 307
 308 #endif
 309 ])
 310
 311 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 312 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 313 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 314
 315 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 316         "${lyx_abs_top_srcdir}", [Top source directory])
 317 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 318         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 319 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 320         "${lyx_abs_installed_datadir}",[Hard system support directory])
 321 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 322         "${version_suffix}",[Program version suffix])
 323
 324 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 325 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 326 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 327 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 328 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 329 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 330 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 331 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 332
 333 AC_CONFIG_FILES([Makefile \
 334       lyx.1:lyx.1in \
 335       3rdparty/Makefile \
 336       3rdparty/boost/Makefile \
 337       3rdparty/dtl/Makefile \
 338       3rdparty/hunspell/Makefile \
 339       3rdparty/mythes/Makefile \
 340       3rdparty/libiconv/Makefile \
 341       $ICONV_ICONV_H_IN \
 342       3rdparty/zlib/Makefile \
 343       autotests/Makefile \
 344       config/Makefile \
 345       development/Makefile \
 346       development/MacOSX/Makefile \
 347       development/MacOSX/Info.plist \
 348       development/MacOSX/lyxrc.dist \
 349       development/MacOSX/spotlight/Makefile \
 350       development/cygwin/Makefile \
 351       development/cygwin/lyxrc.dist \
 352       development/lyx.spec \
 353       lib/lyx.desktop-temp:lib/lyx.desktop.in
 354       lib/Makefile \
 355       lib/doc/Makefile \
 356       lib/lyx2lyx/lyx2lyx_version.py \
 357       lib/lyx2lyx/Makefile \
 358       m4/Makefile \
 359       po/Makefile.in \
 360       sourcedoc/Doxyfile \
 361       sourcedoc/Makefile \
 362       src/client/Makefile \
 363       src/client/lyxclient.1:src/client/lyxclient.1in \
 364       src/Makefile \
 365       src/tex2lyx/Makefile \
 366       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 367       src/convert/Makefile \
 368       src/support/Makefile \
 369       src/frontends/Makefile \
 370       src/frontends/qt/Makefile
 371 ])
 372
 373
 374 AC_OUTPUT
 375
 376 # show version information
 377 echo
 378 printf "$VERSION_INFO"
 379 echo
 380
 381 # Display a final warning if there has been a LYX_WARNING
 382 LYX_CHECK_WARNINGS
 383
 384 cat <<EOF
 385 Configuration of LyX was successful.
 386 Type 'make' to compile the program,
 387 and then 'make install' to install it.
 388 EOF