configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.4.0dev],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2021-02-14"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT6
  17 if test x$USE_QT6 = xno ; then
  18 LYX_CHECK_QT5
  19 fi
  20 # Check how the files should be packaged
  21 AC_CANONICAL_TARGET
  22 LYX_USE_PACKAGING
  23 # We need to define these variables here and the no-define option of
  24 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  25 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  26
  27 dnl Default maintainer mode to true for development versions
  28 if test "${enable_maintainer_mode+set}" != set; then
  29   enable_maintainer_mode=$lyx_devel_version
  30 fi
  31 AM_MAINTAINER_MODE
  32 AM_SILENT_RULES([yes])
  33 # Automake is pulling the historical V7 format. This tar format supports
  34 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  35 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  36 save_PACKAGE=$PACKAGE
  37 AM_INIT_AUTOMAKE([foreign dist-xz no-define 1.14 tar-ustar subdir-objects])
  38 PACKAGE=$save_PACKAGE
  39
  40 ### Set the execute permissions of the various scripts correctly
  41 for file in config/install-sh ; do
  42   chmod 755 ${srcdir}/${file}
  43 done
  44
  45 # Find a suitable python interpreter
  46 LYX_PATH_PYTHON23([2.7.0], [3.5.0])
  47 # do the usual python setup stuff
  48 AM_PATH_PYTHON
  49
  50 # Tools for creating libraries (note that we do not use libtool)
  51 AM_PROG_AR
  52 AC_PROG_RANLIB
  53 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  54 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  55 AC_SUBST([ARFLAGS], [cr])
  56
  57 ### Check for a C++ compiler
  58 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  59 dnl if it is not set. We do not use autoconf defaults.
  60 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  61 if ! test "$lyx_has_CXXFLAGS" = yes; then
  62   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  63   CXXFLAGS=" "
  64 fi
  65 LYX_PROG_CXX
  66 if ! test "$lyx_has_CXXFLAGS" = yes; then
  67   unset CXXFLAGS
  68 fi
  69 AC_LANG(C++)
  70
  71 ### Objective-C compiler
  72 AC_PROG_OBJC
  73 _AM_DEPENDENCIES([OBJC])
  74
  75 ### Add extra directories to check for libraries.
  76 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  77 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  78 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  79
  80 ### Add extra directories to check for include files.
  81 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  82 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  83 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  84
  85 ### Add both includes and libraries
  86 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  87 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  88   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  89   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  90 ])
  91
  92 ### These are needed in windows
  93 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  94 AC_SUBST(LIBSHLWAPI)
  95 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  96 AC_SUBST(LIBPSAPI)
  97 AC_CHECK_LIB(gdi32, main)
  98 AC_CHECK_LIB(ole32, main)
  99
 100 LYX_USE_INCLUDED_NOD
 101 LYX_USE_INCLUDED_BOOST
 102
 103 ### we need to know the byte order for unicode conversions
 104 AC_C_BIGENDIAN
 105
 106 # Nice to have when an assertion triggers
 107 LYX_CHECK_CALLSTACK_PRINTING
 108
 109 # C++14 only
 110 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 111
 112 # Needed for our char_type
 113 AC_CHECK_SIZEOF(wchar_t)
 114
 115 # Taken from gettext, needed for libiconv
 116 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 117    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 118       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 119 if test $gt_cv_c_wchar_t = yes; then
 120   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 121   HAVE_WCHAR_T=1
 122 else
 123   HAVE_WCHAR_T=0
 124 fi
 125 AC_SUBST([HAVE_WCHAR_T])
 126
 127 # Needed for Mingw-w64
 128 AC_TYPE_LONG_LONG_INT
 129
 130 ### We need iconv for unicode support (Qt frontend requires it too)
 131 LYX_USE_INCLUDED_ICONV
 132
 133 ### check for compression support
 134 LYX_USE_INCLUDED_ZLIB
 135
 136 ### check whether we build and install the supplied dtl programs
 137 LYX_BUILD_INCLUDED_DTL
 138
 139 ### check for file magic support (currently optional)
 140 AC_CHECK_HEADERS(magic.h,
 141  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 142   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 143    is correctly installed on your system.
 144    Falling back to builtin file format detection.]))],
 145  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 146    is correctly installed on your system.
 147    Falling back to builtin file format detection.])])
 148
 149 ### setup the qt frontend.
 150 dnl The code below is not in a macro, because this would cause big
 151 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 152 QT_DO_IT_ALL([4.5.0])
 153 AC_SUBST([FRONTENDS_SUBDIRS], [qt])
 154 FRONTEND_INFO="${FRONTEND_INFO}\
 155   Qt Frontend:\n\
 156       Qt version:\t   ${QTLIB_VERSION}\n"
 157
 158 # fix the value of the prefixes.
 159 test "x$prefix" = xNONE && prefix=$default_prefix
 160 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 161 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 162   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 163    causes problems with the Makefiles. The installation will be done in
 164    directory \"`pwd`/installprefix\" instead. Please move its contents to
 165    the right place after installation.])
 166   prefix=`pwd`/installprefix
 167 fi
 168
 169 ### Setup po directory
 170 AM_NLS
 171 if test $USE_NLS = "yes" ; then
 172   AC_DEFINE(ENABLE_NLS, 1,
 173     [Define to 1 if translation of program messages to the user's native language
 174    is requested.])dnl'
 175 fi
 176 AM_PO_SUBDIRS
 177
 178 # some standard header files
 179 AC_HEADER_MAJOR
 180 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 181
 182 # some standard types
 183 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 184 AC_TYPE_OFF_T
 185 AC_TYPE_PID_T
 186 AC_TYPE_SIZE_T
 187 AC_TYPE_UID_T
 188
 189 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 190
 191 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 192 # Check the form of mkdir()
 193 AC_FUNC_MKDIR
 194 AC_FUNC_SELECT_ARGTYPES
 195
 196 LYX_CHECK_SPELL_ENGINES
 197 LYX_USE_INCLUDED_MYTHES
 198
 199 lyx_client_subdir=true
 200 dnl LIBS already contains some X extra libs that may interfere.
 201 save_LIBS="$LIBS"
 202 LIBS=
 203 AC_CHECK_FUNCS(fcntl,
 204   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 205    AC_SEARCH_LIBS([socket], [socket network], [],
 206      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 207                 [], [-lnsl])])],
 208   [lyx_client_subdir=false])
 209 AC_SUBST(SOCKET_LIBS,$LIBS)
 210 LIBS="$save_LIBS"
 211 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 212
 213 lyx_win_res=false;
 214 case ${host} in
 215     *mingw*|*cygwin*) lyx_win_res=true;;
 216     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 217 esac
 218 if test "x$lyx_win_res" = "xtrue"; then
 219     AC_CHECK_TOOL(RC, windres,)
 220     if test -z "$RC"; then
 221       AC_MSG_ERROR([Could not find a resource compiler])
 222     fi
 223 fi
 224 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 225 LYX_SET_VERSION_INFO
 226
 227
 228 ### Some information on what just happened
 229 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 230 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 231 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 232 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 233 VERSION_INFO="Configuration\n\
 234   Host type:               ${host}\n\
 235   Special build flags:     ${lyx_flags}\n\
 236   Bundled libraries:       ${lyx_included_libs}\n\
 237   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 238   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 239   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 240   Linker flags:            ${AM_LDFLAGS}\n\
 241   Linker user flags:       ${LDFLAGS}\n\
 242 ${FRONTEND_INFO}\
 243   Packaging:               ${lyx_use_packaging}\n\
 244   LyX binary dir:          ${real_bindir}\n\
 245   LyX files dir:           ${real_pkgdatadir}\n"
 246
 247 AC_SUBST(VERSION_INFO)
 248 AC_SUBST(AM_CPPFLAGS)
 249 AC_SUBST(AM_CXXFLAGS)
 250 AC_SUBST(AM_LDFLAGS)
 251 AC_SUBST(real_pkgdatadir)
 252
 253 ## Some config.h stuff
 254
 255 AH_TOP([
 256 /* -*- C++ -*- */
 257 /*
 258  * \file config.h
 259  * This file is part of LyX, the document processor.
 260  * Licence details can be found in the file COPYING.
 261  *
 262  * This is the compilation configuration file for LyX.
 263  * It was generated by autoconfs configure.
 264  * You might want to change some of the defaults if something goes wrong
 265  * during the compilation.
 266  */
 267
 268 #ifndef _CONFIG_H
 269 #define _CONFIG_H
 270 ])
 271
 272 AH_BOTTOM([
 273 /************************************************************
 274  ** You should not need to change anything beyond this point */
 275
 276 #ifndef HAVE_STRERROR
 277 #if defined(__cplusplus)
 278 extern "C"
 279 #endif
 280 char * strerror(int n);
 281 #endif
 282
 283 #define BOOST_USER_CONFIG <config.h>
 284
 285 #if !defined(ENABLE_ASSERTIONS)
 286 #  define BOOST_DISABLE_ASSERTS 1
 287 #endif
 288 #define BOOST_ENABLE_ASSERT_HANDLER 1
 289
 290 #define BOOST_DISABLE_THREADS 1
 291 #define BOOST_NO_WREGEX 1
 292 #define BOOST_NO_WSTRING 1
 293
 294 #ifdef __CYGWIN__
 295 #  define _DEFAULT_SOURCE
 296 #  define NOMINMAX
 297 #  define BOOST_POSIX 1
 298 #  define BOOST_POSIX_API 1
 299 #  define BOOST_POSIX_PATH 1
 300 #endif
 301
 302 #ifdef __sparc__
 303 #  ifndef __BIG_ENDIAN__
 304 #    define __BIG_ENDIAN__ 1
 305 #  endif
 306 #endif
 307
 308 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 309 #  define USE_WCHAR_T
 310 #endif
 311
 312 #endif
 313 ])
 314
 315 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 316 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 317 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 318
 319 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 320         "${lyx_abs_top_srcdir}", [Top source directory])
 321 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 322         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 323 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 324         "${lyx_abs_installed_datadir}",[Hard system support directory])
 325 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 326         "${version_suffix}",[Program version suffix])
 327
 328 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 329 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 330 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 331 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 332 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 333 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 334 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 335 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 336
 337 AC_CONFIG_FILES([Makefile \
 338       lyx.1:lyx.1in \
 339       3rdparty/Makefile \
 340       3rdparty/boost/Makefile \
 341       3rdparty/dtl/Makefile \
 342       3rdparty/hunspell/Makefile \
 343       3rdparty/mythes/Makefile \
 344       3rdparty/nod/Makefile \
 345       3rdparty/libiconv/Makefile \
 346       $ICONV_ICONV_H_IN \
 347       3rdparty/zlib/Makefile \
 348       autotests/Makefile \
 349       config/Makefile \
 350       development/Makefile \
 351       development/MacOSX/Makefile \
 352       development/MacOSX/Info.plist \
 353       development/MacOSX/lyxrc.dist \
 354       development/MacOSX/spotlight/Makefile \
 355       development/cygwin/Makefile \
 356       development/cygwin/lyxrc.dist \
 357       development/lyx.spec \
 358       lib/lyx.desktop-temp:lib/lyx.desktop.in
 359       lib/Makefile \
 360       lib/doc/Makefile \
 361       lib/lyx2lyx/lyx2lyx_version.py \
 362       lib/lyx2lyx/Makefile \
 363       m4/Makefile \
 364       po/Makefile.in \
 365       sourcedoc/Doxyfile \
 366       sourcedoc/Makefile \
 367       src/client/Makefile \
 368       src/client/lyxclient.1:src/client/lyxclient.1in \
 369       src/Makefile \
 370       src/tex2lyx/Makefile \
 371       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 372       src/convert/Makefile \
 373       src/support/Makefile \
 374       src/frontends/Makefile \
 375       src/frontends/qt/Makefile
 376 ])
 377
 378
 379 AC_OUTPUT
 380
 381 # show version information
 382 echo
 383 printf "$VERSION_INFO"
 384 echo
 385
 386 # Display a final warning if there has been a LYX_WARNING
 387 LYX_CHECK_WARNINGS
 388
 389 cat <<EOF
 390 Configuration of LyX was successful.
 391 Type 'make' to compile the program,
 392 and then 'make install' to install it.
 393 EOF