configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2014-04-14"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8] LYX_OBJECTS_LAYOUT)
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  37 PACKAGE=$save_PACKAGE
  38
  39 # Allow to build some parts of the code as one big chunk
  40 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  41 AC_ARG_ENABLE(monolithic-build,
  42   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  43                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  44   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  45    test "$enable_monolithic_build" = no && enable_monolithic_build=
  46    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  47    for i in $enable_monolithic_build ; do
  48        eval "enable_monolithic_$i=yes"
  49    done
  50    IFS="$ac_save_ifs"],
  51   [enable_monolithic_build=])
  52
  53 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  54 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  55 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  56 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  60
  61 ### Set the execute permissions of the various scripts correctly
  62 for file in config/install-sh ; do
  63   chmod 755 ${srcdir}/${file}
  64 done
  65
  66 AM_PATH_PYTHON(2.7.0,, :)
  67 AC_PROG_RANLIB
  68
  69 ### Check for a C++ compiler
  70 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  71 dnl if it is not set. We do not use autoconf defaults.
  72 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  73 if ! test "$lyx_has_CXXFLAGS" = yes; then
  74   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  75   CXXFLAGS=" "
  76 fi
  77 LYX_PROG_CXX
  78 if ! test "$lyx_has_CXXFLAGS" = yes; then
  79   unset CXXFLAGS
  80 fi
  81 AC_LANG(C++)
  82
  83 ### Objective-C compiler
  84 AC_PROG_OBJC
  85 _AM_DEPENDENCIES([OBJC])
  86
  87 ### Add extra directories to check for libraries.
  88 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  89 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  90 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  91
  92 ### Add extra directories to check for include files.
  93 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  94 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  95 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  96
  97 ### Add both includes and libraries
  98 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  99 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 100   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 101   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 102 ])
 103
 104 ### These are needed in windows
 105 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 106 AC_SUBST(LIBSHLWAPI)
 107 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 108 AC_SUBST(LIBPSAPI)
 109 AC_CHECK_LIB(gdi32, main)
 110
 111 LYX_USE_INCLUDED_BOOST
 112 LYX_USE_INCLUDED_MYTHES
 113
 114 ### we need to know the byte order for unicode conversions
 115 AC_C_BIGENDIAN
 116
 117 # Nice to have when an assertion triggers
 118 LYX_CHECK_CALLSTACK_PRINTING
 119
 120 # Needed for our char_type
 121 AC_CHECK_SIZEOF(wchar_t)
 122
 123 ### We need iconv for unicode support (Qt4 frontend requires it too)
 124 AM_ICONV
 125 if test "$am_cv_func_iconv" = no; then
 126   AC_MSG_ERROR([cannot find required library iconv.])
 127 else
 128   LIBS="$LIBS $LIBICONV"
 129 fi
 130
 131 ### check for compression support
 132 AC_CHECK_HEADERS(zlib.h,
 133  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 134  [LYX_LIB_ERROR(zlib.h,zlib)])
 135
 136 ### check for file magic support (currently optional)
 137 AC_CHECK_HEADERS(magic.h,
 138  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 139   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 140    is correctly installed on your system.
 141    Falling back to builtin file format detection.]))],
 142  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 143    is correctly installed on your system.
 144    Falling back to builtin file format detection.])])
 145
 146 ### setup the qt frontend.
 147 dnl The code below is not in a macro, because this would cause big
 148 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 149 QT_DO_IT_ALL([4.5.0])
 150 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 151 FRONTEND_INFO="${FRONTEND_INFO}\
 152   Qt Frontend:\n\
 153       Qt version:\t   ${QTLIB_VERSION}\n"
 154
 155 # fix the value of the prefixes.
 156 test "x$prefix" = xNONE && prefix=$default_prefix
 157 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 158 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 159   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 160    causes problems with the Makefiles. The installation will be done in
 161    directory \"`pwd`/installprefix\" instead. Please move its contents to
 162    the right place after installation.])
 163   prefix=`pwd`/installprefix
 164 fi
 165
 166 ### Setup po directory
 167 AM_PO_SUBDIRS
 168 AM_NLS
 169 if test $USE_NLS = "yes" ; then
 170   AC_DEFINE(ENABLE_NLS, 1,
 171     [Define to 1 if translation of program messages to the user's native language
 172    is requested.])dnl'
 173 fi
 174
 175 # some standard header files
 176 AC_HEADER_MAJOR
 177 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 178
 179 # some standard types
 180 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 181 AC_TYPE_OFF_T
 182 AC_TYPE_PID_T
 183 AC_TYPE_SIZE_T
 184 AC_TYPE_UID_T
 185 # Taken from gettext
 186 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 187    [AC_TRY_COMPILE([#include <stddef.h>
 188       wchar_t foo = (wchar_t)'\0';], ,
 189       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 190 if test $gt_cv_c_wchar_t = yes; then
 191   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 192 fi
 193
 194 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 195
 196 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 197 # Check the form of mkdir()
 198 AC_FUNC_MKDIR
 199 AC_FUNC_SELECT_ARGTYPES
 200
 201 LYX_CHECK_SPELL_ENGINES
 202
 203 lyx_client_subdir=true
 204 dnl AC_LANG_PUSH(C)
 205 dnl LIBS already contains some X extra libs that may interfere.
 206 save_LIBS="$LIBS"
 207 LIBS=
 208 AC_CHECK_FUNCS(fcntl,
 209   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 210    AC_SEARCH_LIBS([socket], [socket], [],
 211      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 212                 [], [-lnsl])])],
 213   [lyx_client_subdir=false])
 214 AC_SUBST(SOCKET_LIBS,$LIBS)
 215 LIBS="$save_LIBS"
 216 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 217 dnl AC_LANG_POP(C)
 218
 219 lyx_win_res=false;
 220 case ${host} in
 221     *mingw*|*cygwin*) lyx_win_res=true;;
 222 esac
 223 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 224 LYX_SET_VERSION_INFO
 225
 226
 227 ### Some information on what just happened
 228 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 229 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 230 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 231 VERSION_INFO="Configuration\n\
 232   Host type:               ${host}\n\
 233   Special build flags:     ${lyx_flags}\n\
 234   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 235   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 236   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 237   Linker flags:            ${AM_LDFLAGS}\n\
 238   Linker user flags:       ${LDFLAGS}\n\
 239 ${FRONTEND_INFO}\
 240   Packaging:               ${lyx_use_packaging}\n\
 241   LyX binary dir:          ${real_bindir}\n\
 242   LyX files dir:           ${real_pkgdatadir}\n"
 243
 244 AC_SUBST(VERSION_INFO)
 245 AC_SUBST(AM_CPPFLAGS)
 246 AC_SUBST(AM_CXXFLAGS)
 247 AC_SUBST(AM_LDFLAGS)
 248 AC_SUBST(real_pkgdatadir)
 249
 250 ## Some config.h stuff
 251
 252 AH_TOP([
 253 /* -*- C++ -*- */
 254 /*
 255  * \file config.h
 256  * This file is part of LyX, the document processor.
 257  * Licence details can be found in the file COPYING.
 258  *
 259  * This is the compilation configuration file for LyX.
 260  * It was generated by autoconfs configure.
 261  * You might want to change some of the defaults if something goes wrong
 262  * during the compilation.
 263  */
 264
 265 #ifndef _CONFIG_H
 266 #define _CONFIG_H
 267 ])
 268
 269 AH_BOTTOM([
 270 /************************************************************
 271  ** You should not need to change anything beyond this point */
 272
 273 #ifndef HAVE_STRERROR
 274 #if defined(__cplusplus)
 275 extern "C"
 276 #endif
 277 char * strerror(int n);
 278 #endif
 279
 280 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 281 #  define USE_BOOST_FORMAT 1
 282 #else
 283 #  define USE_BOOST_FORMAT 0
 284 #endif
 285
 286 #define BOOST_USER_CONFIG <config.h>
 287
 288 #if !defined(ENABLE_ASSERTIONS)
 289 #  define BOOST_DISABLE_ASSERTS 1
 290 #endif
 291 #define BOOST_ENABLE_ASSERT_HANDLER 1
 292
 293 #define BOOST_DISABLE_THREADS 1
 294 #define BOOST_NO_WREGEX 1
 295 #define BOOST_NO_WSTRING 1
 296 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 297
 298 #ifdef __CYGWIN__
 299 #  define NOMINMAX
 300 #  define BOOST_POSIX 1
 301 #  define BOOST_POSIX_API 1
 302 #  define BOOST_POSIX_PATH 1
 303 #endif
 304
 305 #ifdef __sparc__
 306 #  ifndef __BIG_ENDIAN__
 307 #    define __BIG_ENDIAN__ 1
 308 #  endif
 309 #endif
 310
 311 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 312 #  define USE_WCHAR_T
 313 #endif
 314
 315 #endif
 316 ])
 317
 318 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 319 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 320 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 321
 322 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 323         "${lyx_abs_top_srcdir}", [Top source directory])
 324 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 325         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 326 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 327         "${lyx_abs_installed_datadir}",[Hard system support directory])
 328 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 329         "${version_suffix}",[Program version suffix])
 330
 331 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 332 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 333 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 334 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 335 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 336 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 337 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 338 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 339
 340 AC_CONFIG_FILES([Makefile \
 341       lyx.1:lyx.1in \
 342       boost/Makefile \
 343       config/Makefile \
 344       development/Makefile \
 345       development/MacOSX/Makefile \
 346       development/MacOSX/Info.plist \
 347       development/MacOSX/lyxrc.dist \
 348       development/MacOSX/spotlight/Makefile \
 349       development/cygwin/Makefile \
 350       development/cygwin/lyxrc.dist \
 351       development/lyx.spec \
 352       lib/lyx.desktop-temp:lib/lyx.desktop.in
 353       lib/Makefile \
 354       lib/doc/Makefile \
 355       lib/lyx2lyx/lyx2lyx_version.py \
 356       lib/lyx2lyx/Makefile \
 357       m4/Makefile \
 358       po/Makefile.in \
 359       sourcedoc/Doxyfile \
 360       sourcedoc/Makefile \
 361       src/client/Makefile \
 362       src/client/lyxclient.1:src/client/lyxclient.1in \
 363       src/Makefile \
 364       src/tex2lyx/Makefile \
 365       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 366       src/support/Makefile \
 367       src/frontends/Makefile \
 368       src/frontends/qt4/Makefile
 369 ])
 370
 371
 372 AC_OUTPUT
 373
 374 # show version information
 375 echo
 376 printf "$VERSION_INFO"
 377 echo
 378
 379 # Display a final warning if there has been a LYX_WARNING
 380 LYX_CHECK_WARNINGS
 381
 382 cat <<EOF
 383 Configuration of LyX was successful.
 384 Type 'make' to compile the program,
 385 and then 'make install' to install it.
 386 EOF