configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 ### Set the execute permissions of the various scripts correctly
  26 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  27   chmod 755 ${srcdir}/${file}
  28 done
  29
  30 ### Check for programs
  31 AC_PROG_MAKE_SET
  32 AC_PROG_INSTALL
  33
  34 AC_PROG_AWK
  35 test "$AWK" = gawk && AWK="gawk --posix"
  36
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Check for installed python
  46 AM_PATH_PYTHON(1.5.2,, :)
  47
  48 # Work around a problem in automake 1.4: when invoking install-strip,
  49 # INSTALL_PROGRAM is changed to 'install -s', and since
  50 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  51 # which returns an error condition when stripping fails.
  52 INSTALL_SCRIPT='${INSTALL}'
  53
  54 ### we will also need a C compiler to compile GNU gettext
  55 AC_PROG_CC
  56
  57 ### check for special systems
  58 AC_ISC_POSIX
  59 AC_AIX
  60
  61 ### check which frontend we want to use
  62 LYX_USE_FRONTENDS
  63
  64 ### Check for a C++ compiler
  65 LYX_PROG_CXX
  66 ### Some checks on what the C++ compiler can(not) do
  67 AC_LANG(C++)
  68 dnl we do not need that currently (and probably all our supported
  69 dnl compiler allow that)
  70 dnl LYX_CXX_PARTIAL
  71 LYX_CXX_EXPLICIT
  72 LYX_CXX_GLOBAL_CSTD
  73 LYX_STD_COUNT
  74 dnl we disable rtti for now
  75 dnl LYX_CXX_RTTI
  76 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  77 LYX_CXX_STL_MODERN_STREAMS
  78
  79 ### and now some special lyx flags.
  80 AC_ARG_ENABLE(assertions,
  81   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  82   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  83         enable_assertions=yes;
  84     else
  85         enable_assertions=no;
  86     fi;])
  87 if test "x$enable_assertions" = xyes ; then
  88    lyx_flags="assertions $lyx_flags"
  89    AC_DEFINE(ENABLE_ASSERTIONS,1,
  90     [Define if you want assertions to be enabled in the code])
  91 fi
  92
  93 ### Library Files
  94 dnl by testing these we check if it is ok to have
  95 dnl -lc and -lm as args to the compiler
  96 AC_CHECK_LIB(m, sin)
  97 AC_CHECK_LIB(c, fopen)
  98
  99 ### Add extra directories to check for libraries.
 100 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 101 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 102 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 103
 104 ### Add extra directories to check for include files.
 105 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 107 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 108
 109 ### Add both includes and libraries
 110 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 111 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 112 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 113   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 114
 115 AC_ARG_WITH(aiksaurus,
 116   [  --without-aiksaurus     do not use the Aiksaurus library],
 117   [lyx_use_aiksaurus=$withval])
 118 if test x$lyx_use_aiksaurus != xno; then
 119 AC_CHECK_LIB(Aiksaurus, main,
 120         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 121          AIKSAURUS_LIBS="-lAiksaurus"
 122          lyx_flags="aiksaurus $lyx_flags"
 123         ])
 124 AC_CHECK_HEADER(Aiksaurus.h,[
 125   ac_cv_header_aiksaurus_h=yes
 126   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 127 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 128   ac_cv_header_aiksaurus_h=yes
 129   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 130 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 131 fi
 132 AC_SUBST(AIKSAURUS_LIBS)
 133
 134 LYX_USE_INCLUDED_BOOST
 135
 136 ### Setup libtool
 137 AC_DISABLE_SHARED
 138 AC_LIBTOOL_WIN32_DLL
 139 #AM_PROG_LIBTOOL
 140 LYX_PROG_LIBTOOL
 141
 142 ### Check for some Cygwin-specific details.
 143 CHECK_WITH_CYGWIN
 144
 145 ### Check for X libraries
 146 AC_PATH_XTRA
 147 case $have_x in
 148   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 149        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 150   no) LYX_ERROR(dnl
 151 [Cannot find X window libraries and/or headers. Check your installation.
 152   If you use a Linux system, check that you have installed
 153   the development tools.]);;
 154   disable) ;;
 155 esac
 156
 157 ### check which frontend we want to use
 158
 159 dnl if the gtk frontend has been specified, then xforms is needed too
 160 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 161   FRONTENDS="xforms $FRONTENDS"
 162   noxformsbin=yes
 163 fi
 164
 165 dnl The code below is not in a macro, because this would cause big
 166 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 167 for frontend in $FRONTENDS ; do
 168   case "$frontend" in
 169     xforms)
 170           XFORMS_DO_IT_ALL
 171           if test -z "$noxformsbin" ; then
 172             FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 173           fi
 174           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 175           RPM_FRONTEND="xforms"
 176           FRONTEND_INFO="${FRONTEND_INFO}\
 177   XForms Frontend:\n\
 178       libXpm version:\t\t${XPM_VERSION}\n\
 179       libforms version:\t\t${XFORMS_VERSION}\n"
 180           ;;
 181   dnl   gnome)
 182   dnl     XFORMS_DO_IT_ALL
 183   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 184   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 185   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 186
 187   dnl     FRONTEND="xforms gnome"
 188   dnl     FRONTEND_GUILIB="gnome/*.lo"
 189   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 190   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 191   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 192   dnl   ;;
 193     gtk)
 194           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 195           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 196           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 197           RPM_FRONTEND="gtk"
 198           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 199           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 200           FRONTEND_INFO="${FRONTEND_INFO}\
 201   GTK Frontend:\n\
 202     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 203     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 204           ;;
 205
 206     qt)
 207           QT_DO_IT_ALL
 208           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 209           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 210           RPM_FRONTEND="qt"
 211           FRONTEND_INFO="${FRONTEND_INFO}\
 212   Qt Frontend:\n\
 213       Qt version:\t\t${QT_VERSION}\n"
 214 dnl qt build will fail without moc or uic
 215           if test -z "$MOC"; then
 216             LYX_ERROR([moc binary not found !])
 217           fi
 218           if test -z "$UIC"; then
 219             LYX_ERROR([uic binary not found !])
 220           fi
 221       ;;
 222     *)
 223           LYX_ERROR(Unknown frontend '$frontend');;
 224   esac
 225 done
 226
 227 ### Check how the files should be packaged
 228 LYX_USE_PACKAGING
 229 # fix the value of the prefixes.
 230 test "x$prefix" = xNONE && prefix=$default_prefix
 231 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 232 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 233   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 234    causes problems with the Makefiles. The installation will be done in
 235    directory \"`pwd`/installprefix\" instead. Please move its contents to
 236    the right place after installation.])
 237   prefix=`pwd`/installprefix
 238 fi
 239
 240 ### Setup GNU gettext
 241 dnl GNU gettext is written in C
 242 AC_LANG_PUSH(C)
 243 AM_GNU_GETTEXT
 244 AC_LANG_POP(C)
 245
 246 # some standard header files
 247 AC_HEADER_DIRENT
 248 AC_HEADER_MAJOR
 249 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h)
 250
 251 # some standard structures
 252 AC_HEADER_STAT
 253 AC_HEADER_TIME
 254
 255 # some standard types
 256 AC_TYPE_MODE_T
 257 AC_TYPE_OFF_T
 258 AC_TYPE_PID_T
 259 AC_TYPE_SIGNAL
 260 AC_TYPE_SIZE_T
 261 AC_TYPE_UID_T
 262
 263 AC_CHECK_FUNCS(strerror)
 264 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 265 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 266
 267 # Check the form of mkdir()
 268 AC_FUNC_MKDIR
 269
 270 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 271     case "${enableval}" in
 272         yes) use_compression=true ;;
 273         no) use_compression=false ;;
 274         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 275     esac
 276 ],[use_compression=true])
 277 if test $use_compression=true ; then
 278         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 279         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 280         if test $use_compression = true ; then
 281                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 282                 lyx_flags="compression $lyx_flags"
 283         fi
 284 fi
 285 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 286 AC_MSG_CHECKING([whether to support compressed files])
 287 AC_MSG_RESULT($use_compression)
 288
 289
 290 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 291 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 292 dnl We aim to remove this eventually, since we should test as much as
 293 dnl possible with the compiler which will use the functions (JMarc)
 294 AC_LANG_PUSH(C)
 295 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 296 AC_LANG_POP(C)
 297
 298 LYX_CHECK_SPELL_ENGINES
 299
 300 lyx_client_subdir=true
 301 AC_LANG_PUSH(C)
 302 AC_CHECK_FUNCS(fcntl,, [lyx_client_subdir=false])
 303 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 304 AC_LANG_POP(C)
 305
 306
 307 AC_FUNC_SELECT_ARGTYPES
 308
 309 ### Some information on what just happened
 310 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 311 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 312 VERSION_INFO="Configuration\n\
 313   Host type:                      ${host}\n\
 314   Special build flags:            ${lyx_flags}\n\
 315   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 316   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 317   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 318   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 319   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 320   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 321   Linker flags:                   ${AM_LDFLAGS}\n\
 322   Linker user flags:              ${LDFLAGS}\n\
 323 ${FRONTEND_INFO}\
 324   Packaging:                      ${lyx_use_packaging}\n\
 325   LyX binary dir:                 ${real_bindir}\n\
 326   LyX files dir:                  ${real_datadir}\n"
 327
 328
 329 AC_SUBST(VERSION_INFO)
 330 AC_SUBST(RPM_FRONTEND)
 331 AC_SUBST(AM_CPPFLAGS)
 332 AC_SUBST(AM_CXXFLAGS)
 333 AC_SUBST(AM_CFLAGS)
 334 AC_SUBST(AM_LDFLAGS)
 335
 336 ## Some config.h stuff
 337
 338 AH_TOP([
 339 /* -*- C++ -*- */
 340 /*
 341  * \file config.h
 342  * This file is part of LyX, the document processor.
 343  * Licence details can be found in the file COPYING.
 344  *
 345  * This is the compilation configuration file for LyX.
 346  * It was generated by autoconfs configure.
 347  * You might want to change some of the defaults if something goes wrong
 348  * during the compilation.
 349  */
 350
 351 #ifndef _CONFIG_H
 352 #define _CONFIG_H
 353 ])
 354
 355 AH_BOTTOM([
 356 /************************************************************
 357  ** You should not need to change anything beyond this point */
 358
 359 #ifndef HAVE_STRERROR
 360 #if defined(__cplusplus)
 361 extern "C"
 362 #endif
 363 char * strerror(int n);
 364 #endif
 365
 366 #ifdef HAVE_MKSTEMP
 367 #ifndef HAVE_DECL_MKSTEMP
 368 #if defined(__cplusplus)
 369 extern "C"
 370 #endif
 371 int mkstemp(char*);
 372 #endif
 373 #endif
 374
 375 #ifdef __EMX__
 376 #include "support/os2_defines.h"
 377 #endif
 378
 379 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 380 #define USE_BOOST_FORMAT 1
 381 #else
 382 #define USE_BOOST_FORMAT 0
 383 #endif
 384
 385 #define BOOST_USER_CONFIG <config.h>
 386
 387 #if defined(ENABLE_ASSERTIONS)
 388 #define BOOST_ENABLE_ASSERT_HANDLER 1
 389 #else
 390 #define BOOST_DISABLE_ASSERTS 1
 391 #endif
 392
 393 #define BOOST_DISABLE_THREADS 1
 394 #define BOOST_NO_WREGEX 1
 395 #define BOOST_NO_WSTRING 1
 396
 397 #ifdef __CYGWIN__
 398 #define BOOST_POSIX 1
 399 #endif
 400
 401 #endif
 402 ])
 403
 404 ### Finish the work.
 405 AC_CONFIG_SUBDIRS(lib)
 406 AC_CONFIG_FILES([Makefile  m4/Makefile \
 407        boost/Makefile \
 408        boost/libs/Makefile \
 409        boost/libs/filesystem/Makefile \
 410        boost/libs/filesystem/src/Makefile \
 411        boost/libs/regex/Makefile \
 412        boost/libs/regex/src/Makefile \
 413        boost/libs/signals/Makefile \
 414        boost/libs/signals/src/Makefile \
 415        config/Makefile \
 416        development/Makefile \
 417        development/lyx.spec \
 418        lib/Makefile \
 419        lib/doc/Makefile \
 420        lib/lyx2lyx/Makefile \
 421        intl/Makefile \
 422        po/Makefile.in \
 423        sourcedoc/Doxyfile \
 424        sourcedoc/Makefile \
 425        src/client/Makefile \
 426        src/Makefile \
 427        src/version.C-tmp:src/version.C.in \
 428        src/tex2lyx/Makefile \
 429        src/mathed/Makefile \
 430        src/graphics/Makefile \
 431        src/insets/Makefile \
 432        src/support/Makefile \
 433        src/support/tests/Makefile \
 434        src/frontends/Makefile \
 435        src/frontends/controllers/Makefile \
 436        src/frontends/xforms/Makefile \
 437        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 438        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 439        src/frontends/xforms/forms/Makefile \
 440        src/frontends/gtk/Makefile \
 441        src/frontends/gtk/gimages/Makefile \
 442        src/frontends/gtk/glade/Makefile \
 443        src/frontends/qt2/Makefile \
 444        src/frontends/qt2/moc/Makefile \
 445        src/frontends/qt2/ui/Makefile \
 446        src/frontends/qt2/ui/moc/Makefile \
 447 ])
 448
 449 AC_OUTPUT
 450 # show version information
 451 echo
 452 printf "$VERSION_INFO"
 453 echo
 454
 455 # Display a final warning if there has been a LYX_ERROR
 456 LYX_CHECK_ERRORS