configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2014-04-14"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 # Check how the files should be packaged
  17 AC_CANONICAL_TARGET
  18 LYX_USE_PACKAGING
  19 # We need to define these variables here and the no-define option of
  20 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  22
  23 dnl Default maintainer mode to true for development versions
  24 if test "${enable_maintainer_mode+set}" != set; then
  25   enable_maintainer_mode=$lyx_devel_version
  26 fi
  27 AM_MAINTAINER_MODE
  28
  29 save_PACKAGE=$PACKAGE
  30 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  31 dnl which are the versions where subdir-objects can beused.
  32 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  33 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  34 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8] LYX_OBJECTS_LAYOUT)
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36 PACKAGE=$save_PACKAGE
  37
  38 # Allow to build some parts of the code as one big chunk
  39 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  40 AC_ARG_ENABLE(monolithic-build,
  41   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  42                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  43   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  44    test "$enable_monolithic_build" = no && enable_monolithic_build=
  45    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  46    for i in $enable_monolithic_build ; do
  47        eval "enable_monolithic_$i=yes"
  48    done
  49    IFS="$ac_save_ifs"],
  50   [enable_monolithic_build=])
  51
  52 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  53 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  54 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  55 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  56 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  59
  60 ### Set the execute permissions of the various scripts correctly
  61 for file in config/install-sh ; do
  62   chmod 755 ${srcdir}/${file}
  63 done
  64
  65 AM_PATH_PYTHON(2.4.0,, :)
  66 AC_PROG_RANLIB
  67
  68 ### Check for a C++ compiler
  69 LYX_PROG_CXX
  70 AC_LANG(C++)
  71
  72 ### Objective-C compiler
  73 AC_PROG_OBJC
  74 _AM_DEPENDENCIES([OBJC])
  75
  76 ### Add extra directories to check for libraries.
  77 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  78 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  79 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  80
  81 ### Add extra directories to check for include files.
  82 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  83 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  84 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  85
  86 ### Add both includes and libraries
  87 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  88 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  89 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  90   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  91
  92 ### These are needed in windows
  93 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  94 AC_SUBST(LIBSHLWAPI)
  95 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  96 AC_SUBST(LIBPSAPI)
  97 AC_CHECK_LIB(gdi32, main)
  98
  99 LYX_USE_INCLUDED_BOOST
 100 LYX_USE_INCLUDED_MYTHES
 101
 102 ### we need to know the byte order for unicode conversions
 103 AC_C_BIGENDIAN
 104
 105 # Nice to have when an assertion triggers
 106 LYX_CHECK_CALLSTACK_PRINTING
 107
 108 # Needed for our char_type
 109 AC_CHECK_SIZEOF(wchar_t)
 110
 111 ### We need iconv for unicode support (Qt4 frontend requires it too)
 112 AM_ICONV
 113 if test "$am_cv_func_iconv" = no; then
 114   AC_MSG_ERROR([cannot find required library iconv.])
 115 else
 116   LIBS="$LIBS $LIBICONV"
 117 fi
 118
 119 ### check for compression support
 120 AC_CHECK_HEADERS(zlib.h,
 121  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 122  [LYX_LIB_ERROR(zlib.h,zlib)])
 123
 124 ### check for file magic support (currently optional)
 125 AC_CHECK_HEADERS(magic.h,
 126  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 127   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 128    is correctly installed on your system.
 129    Falling back to builtin file format detection.]))],
 130  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 131    is correctly installed on your system.
 132    Falling back to builtin file format detection.])])
 133
 134 ### setup the qt frontend.
 135 dnl The code below is not in a macro, because this would cause big
 136 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 137 QT_DO_IT_ALL([4.5.0])
 138 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 139 FRONTEND_INFO="${FRONTEND_INFO}\
 140   Qt Frontend:\n\
 141       Qt version:\t\t${QTLIB_VERSION}\n"
 142
 143 # fix the value of the prefixes.
 144 test "x$prefix" = xNONE && prefix=$default_prefix
 145 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 146 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 147   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 148    causes problems with the Makefiles. The installation will be done in
 149    directory \"`pwd`/installprefix\" instead. Please move its contents to
 150    the right place after installation.])
 151   prefix=`pwd`/installprefix
 152 fi
 153
 154 ### Setup po directory
 155 AM_PO_SUBDIRS
 156 AM_NLS
 157 if test $USE_NLS = "yes" ; then
 158   AC_DEFINE(ENABLE_NLS, 1,
 159     [Define to 1 if translation of program messages to the user's native language
 160    is requested.])dnl'
 161 fi
 162
 163 # some standard header files
 164 AC_HEADER_MAJOR
 165 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 166
 167 # some standard types
 168 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 169 AC_TYPE_OFF_T
 170 AC_TYPE_PID_T
 171 AC_TYPE_SIZE_T
 172 AC_TYPE_UID_T
 173 # Taken from gettext
 174 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 175    [AC_TRY_COMPILE([#include <stddef.h>
 176       wchar_t foo = (wchar_t)'\0';], ,
 177       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 178 if test $gt_cv_c_wchar_t = yes; then
 179   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 180 fi
 181
 182 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 183
 184 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 185 # Check the form of mkdir()
 186 AC_FUNC_MKDIR
 187 AC_FUNC_SELECT_ARGTYPES
 188
 189 LYX_CHECK_SPELL_ENGINES
 190
 191 lyx_client_subdir=true
 192 dnl AC_LANG_PUSH(C)
 193 dnl LIBS already contains some X extra libs that may interfere.
 194 save_LIBS="$LIBS"
 195 LIBS=
 196 AC_CHECK_FUNCS(fcntl,
 197   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 198    AC_SEARCH_LIBS([socket], [socket], [],
 199      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 200                 [], [-lnsl])])],
 201   [lyx_client_subdir=false])
 202 AC_SUBST(SOCKET_LIBS,$LIBS)
 203 LIBS="$save_LIBS"
 204 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 205 dnl AC_LANG_POP(C)
 206
 207 lyx_win_res=false;
 208 case ${host} in
 209     *mingw*|*cygwin*) lyx_win_res=true;;
 210 esac
 211 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 212 LYX_SET_VERSION_INFO
 213
 214
 215 ### Some information on what just happened
 216 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 217 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 218 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 219 VERSION_INFO="Configuration\n\
 220   Host type:                    ${host}\n\
 221   Special build flags:         ${lyx_flags}\n\
 222   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 223   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 224   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 225   Linker flags:                 ${AM_LDFLAGS}\n\
 226   Linker user flags:            ${LDFLAGS}\n\
 227 ${FRONTEND_INFO}\
 228   Packaging:                    ${lyx_use_packaging}\n\
 229   LyX binary dir:               ${real_bindir}\n\
 230   LyX files dir:                ${real_pkgdatadir}\n"
 231
 232 AC_SUBST(VERSION_INFO)
 233 AC_SUBST(AM_CPPFLAGS)
 234 AC_SUBST(AM_CXXFLAGS)
 235 AC_SUBST(AM_CFLAGS)
 236 AC_SUBST(AM_LDFLAGS)
 237 AC_SUBST(real_pkgdatadir)
 238
 239 ## Some config.h stuff
 240
 241 AH_TOP([
 242 /* -*- C++ -*- */
 243 /*
 244  * \file config.h
 245  * This file is part of LyX, the document processor.
 246  * Licence details can be found in the file COPYING.
 247  *
 248  * This is the compilation configuration file for LyX.
 249  * It was generated by autoconfs configure.
 250  * You might want to change some of the defaults if something goes wrong
 251  * during the compilation.
 252  */
 253
 254 #ifndef _CONFIG_H
 255 #define _CONFIG_H
 256 ])
 257
 258 AH_BOTTOM([
 259 /************************************************************
 260  ** You should not need to change anything beyond this point */
 261
 262 #ifndef HAVE_STRERROR
 263 #if defined(__cplusplus)
 264 extern "C"
 265 #endif
 266 char * strerror(int n);
 267 #endif
 268
 269 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 270 #  define USE_BOOST_FORMAT 1
 271 #else
 272 #  define USE_BOOST_FORMAT 0
 273 #endif
 274
 275 #define BOOST_USER_CONFIG <config.h>
 276
 277 #if !defined(ENABLE_ASSERTIONS)
 278 #  define BOOST_DISABLE_ASSERTS 1
 279 #endif
 280 #define BOOST_ENABLE_ASSERT_HANDLER 1
 281
 282 #define BOOST_DISABLE_THREADS 1
 283 #define BOOST_NO_WREGEX 1
 284 #define BOOST_NO_WSTRING 1
 285 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 286
 287 // <regex> in gcc is unusable in versions less than 4.9.0
 288 // see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=53631
 289 // clang defines __GNUC__ but how do the versions match?
 290 #ifndef LYX_USE_STD_REGEX
 291 #  if (__GNUC__ == 4 && __GNUC_MINOR__ >= 9) || __GNUC__ > 4 || defined(USE_LLVM_LIBCPP)
 292 #    define LYX_USE_STD_REGEX
 293 #  endif
 294 #endif
 295
 296 #ifdef __CYGWIN__
 297 #  define NOMINMAX
 298 #  define BOOST_POSIX 1
 299 #  define BOOST_POSIX_API 1
 300 #  define BOOST_POSIX_PATH 1
 301 #endif
 302
 303 #ifdef __sparc__
 304 #  ifndef __BIG_ENDIAN__
 305 #    define __BIG_ENDIAN__ 1
 306 #  endif
 307 #endif
 308
 309 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 310 #  define USE_WCHAR_T
 311 #endif
 312
 313 #endif
 314 ])
 315
 316 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 317 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 318 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 319
 320 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 321         "${lyx_abs_top_srcdir}", [Top source directory])
 322 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 323         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 324 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 325         "${lyx_abs_installed_datadir}",[Hard system support directory])
 326 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 327         "${version_suffix}",[Program version suffix])
 328
 329 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 330 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 331 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 332 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 333 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 334 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 335 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 336 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 337
 338 AC_CONFIG_FILES([Makefile \
 339       lyx.1:lyx.1in \
 340       boost/Makefile \
 341       config/Makefile \
 342       development/Makefile \
 343       development/MacOSX/Makefile \
 344       development/MacOSX/Info.plist \
 345       development/MacOSX/lyxrc.dist \
 346       development/MacOSX/spotlight/Makefile \
 347       development/cygwin/Makefile \
 348       development/cygwin/lyxrc.dist \
 349       development/lyx.spec \
 350       lib/lyx.desktop-temp:lib/lyx.desktop.in
 351       lib/Makefile \
 352       lib/doc/Makefile \
 353       lib/lyx2lyx/lyx2lyx_version.py \
 354       lib/lyx2lyx/Makefile \
 355       m4/Makefile \
 356       po/Makefile.in \
 357       sourcedoc/Doxyfile \
 358       sourcedoc/Makefile \
 359       src/client/Makefile \
 360       src/client/lyxclient.1:src/client/lyxclient.1in \
 361       src/Makefile \
 362       src/tex2lyx/Makefile \
 363       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 364       src/support/Makefile \
 365       src/frontends/Makefile \
 366       src/frontends/qt4/Makefile
 367 ])
 368
 369
 370 AC_OUTPUT
 371
 372 # show version information
 373 echo
 374 printf "$VERSION_INFO"
 375 echo
 376
 377 # Display a final warning if there has been a LYX_WARNING
 378 LYX_CHECK_WARNINGS
 379
 380 cat <<EOF
 381 Configuration of LyX was successful.
 382 Type 'make' to compile the program,
 383 and then 'make install' to install it.
 384 EOF