configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.3.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2016-04-16"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 # Automake is pulling the historical V7 format. This tar format supports
  36 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  37 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  39 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  40 PACKAGE=$save_PACKAGE
  41
  42 # Allow to build some parts of the code as one big chunk
  43 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  44 AC_ARG_ENABLE(monolithic-build,
  45   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  46                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  47   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  48    test "$enable_monolithic_build" = no && enable_monolithic_build=
  49    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  50    for i in $enable_monolithic_build ; do
  51        eval "enable_monolithic_$i=yes"
  52    done
  53    IFS="$ac_save_ifs"],
  54   [enable_monolithic_build=])
  55
  56 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  63
  64 ### Set the execute permissions of the various scripts correctly
  65 for file in config/install-sh ; do
  66   chmod 755 ${srcdir}/${file}
  67 done
  68
  69 # Find a suitable python interpreter
  70 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  71 # do the usual python setup stuff
  72 AM_PATH_PYTHON
  73
  74 # Tools for creating libraries (note that we do not use libtool)
  75 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  76 AC_PROG_RANLIB
  77
  78 ### Check for a C++ compiler
  79 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  80 dnl if it is not set. We do not use autoconf defaults.
  81 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  82 if ! test "$lyx_has_CXXFLAGS" = yes; then
  83   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  84   CXXFLAGS=" "
  85 fi
  86 LYX_PROG_CXX
  87 if ! test "$lyx_has_CXXFLAGS" = yes; then
  88   unset CXXFLAGS
  89 fi
  90 AC_LANG(C++)
  91
  92 ### Objective-C compiler
  93 AC_PROG_OBJC
  94 _AM_DEPENDENCIES([OBJC])
  95
  96 ### Add extra directories to check for libraries.
  97 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  98 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  99 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 100
 101 ### Add extra directories to check for include files.
 102 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 104 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 105
 106 ### Add both includes and libraries
 107 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 108 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 109   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 110   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 111 ])
 112
 113 ### These are needed in windows
 114 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 115 AC_SUBST(LIBSHLWAPI)
 116 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 117 AC_SUBST(LIBPSAPI)
 118 AC_CHECK_LIB(gdi32, main)
 119 AC_CHECK_LIB(ole32, main)
 120
 121 LYX_USE_INCLUDED_BOOST
 122 LYX_USE_INCLUDED_MYTHES
 123
 124 ### we need to know the byte order for unicode conversions
 125 AC_C_BIGENDIAN
 126
 127 # Nice to have when an assertion triggers
 128 LYX_CHECK_CALLSTACK_PRINTING
 129
 130 # Needed for our char_type
 131 AC_CHECK_SIZEOF(wchar_t)
 132
 133 # Taken from gettext, needed for libiconv
 134 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 135    [AC_TRY_COMPILE([#include <stddef.h>
 136       wchar_t foo = (wchar_t)'\0';], ,
 137       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 138 if test $gt_cv_c_wchar_t = yes; then
 139   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 140   HAVE_WCHAR_T=1
 141 else
 142   HAVE_WCHAR_T=0
 143 fi
 144 AC_SUBST([HAVE_WCHAR_T])
 145
 146 # Needed for Mingw-w64
 147 AC_TYPE_LONG_LONG_INT
 148 if test "$ac_cv_type_long_long_int" = yes; then
 149   AC_CHECK_SIZEOF(long)
 150   AC_CHECK_SIZEOF(long long)
 151 fi
 152
 153 ### We need iconv for unicode support (Qt4 frontend requires it too)
 154 LYX_USE_INCLUDED_ICONV
 155
 156 ### check for compression support
 157 LYX_USE_INCLUDED_ZLIB
 158
 159 ### check for file magic support (currently optional)
 160 AC_CHECK_HEADERS(magic.h,
 161  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 162   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 163    is correctly installed on your system.
 164    Falling back to builtin file format detection.]))],
 165  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 166    is correctly installed on your system.
 167    Falling back to builtin file format detection.])])
 168
 169 ### setup the qt frontend.
 170 dnl The code below is not in a macro, because this would cause big
 171 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 172 QT_DO_IT_ALL([4.5.0])
 173 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 174 FRONTEND_INFO="${FRONTEND_INFO}\
 175   Qt Frontend:\n\
 176       Qt version:\t   ${QTLIB_VERSION}\n"
 177
 178 # fix the value of the prefixes.
 179 test "x$prefix" = xNONE && prefix=$default_prefix
 180 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 181 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 182   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 183    causes problems with the Makefiles. The installation will be done in
 184    directory \"`pwd`/installprefix\" instead. Please move its contents to
 185    the right place after installation.])
 186   prefix=`pwd`/installprefix
 187 fi
 188
 189 ### Setup po directory
 190 AM_NLS
 191 if test $USE_NLS = "yes" ; then
 192   AC_DEFINE(ENABLE_NLS, 1,
 193     [Define to 1 if translation of program messages to the user's native language
 194    is requested.])dnl'
 195 fi
 196 AM_PO_SUBDIRS
 197
 198 # some standard header files
 199 AC_HEADER_MAJOR
 200 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 201
 202 # some standard types
 203 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 204 AC_TYPE_OFF_T
 205 AC_TYPE_PID_T
 206 AC_TYPE_SIZE_T
 207 AC_TYPE_UID_T
 208
 209 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 210
 211 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 212 # Check the form of mkdir()
 213 AC_FUNC_MKDIR
 214 AC_FUNC_SELECT_ARGTYPES
 215
 216 LYX_CHECK_SPELL_ENGINES
 217
 218 lyx_client_subdir=true
 219 dnl AC_LANG_PUSH(C)
 220 dnl LIBS already contains some X extra libs that may interfere.
 221 save_LIBS="$LIBS"
 222 LIBS=
 223 AC_CHECK_FUNCS(fcntl,
 224   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 225    AC_SEARCH_LIBS([socket], [socket network], [],
 226      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 227                 [], [-lnsl])])],
 228   [lyx_client_subdir=false])
 229 AC_SUBST(SOCKET_LIBS,$LIBS)
 230 LIBS="$save_LIBS"
 231 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 232 dnl AC_LANG_POP(C)
 233
 234 lyx_win_res=false;
 235 case ${host} in
 236     *mingw*|*cygwin*) lyx_win_res=true;;
 237 esac
 238 if test "x$lyx_win_res" = "xtrue"; then
 239     AC_CHECK_TOOL(RC, windres,)
 240     if test -z "$RC"; then
 241       AC_ERROR([Could not find a resource compiler])
 242     fi
 243 fi
 244 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 245 LYX_SET_VERSION_INFO
 246
 247
 248 ### Some information on what just happened
 249 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 250 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 251 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 252 VERSION_INFO="Configuration\n\
 253   Host type:               ${host}\n\
 254   Special build flags:     ${lyx_flags}\n\
 255   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 256   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 257   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 258   Linker flags:            ${AM_LDFLAGS}\n\
 259   Linker user flags:       ${LDFLAGS}\n\
 260 ${FRONTEND_INFO}\
 261   Packaging:               ${lyx_use_packaging}\n\
 262   LyX binary dir:          ${real_bindir}\n\
 263   LyX files dir:           ${real_pkgdatadir}\n"
 264
 265 AC_SUBST(VERSION_INFO)
 266 AC_SUBST(AM_CPPFLAGS)
 267 AC_SUBST(AM_CXXFLAGS)
 268 AC_SUBST(AM_LDFLAGS)
 269 AC_SUBST(real_pkgdatadir)
 270
 271 ## Some config.h stuff
 272
 273 AH_TOP([
 274 /* -*- C++ -*- */
 275 /*
 276  * \file config.h
 277  * This file is part of LyX, the document processor.
 278  * Licence details can be found in the file COPYING.
 279  *
 280  * This is the compilation configuration file for LyX.
 281  * It was generated by autoconfs configure.
 282  * You might want to change some of the defaults if something goes wrong
 283  * during the compilation.
 284  */
 285
 286 #ifndef _CONFIG_H
 287 #define _CONFIG_H
 288 ])
 289
 290 AH_BOTTOM([
 291 /************************************************************
 292  ** You should not need to change anything beyond this point */
 293
 294 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 295 #define LYX_USE_CXX11
 296 #endif
 297
 298 #ifndef HAVE_STRERROR
 299 #if defined(__cplusplus)
 300 extern "C"
 301 #endif
 302 char * strerror(int n);
 303 #endif
 304
 305 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 306 #  define USE_BOOST_FORMAT 1
 307 #else
 308 #  define USE_BOOST_FORMAT 0
 309 #endif
 310
 311 #define BOOST_USER_CONFIG <config.h>
 312
 313 #if !defined(ENABLE_ASSERTIONS)
 314 #  define BOOST_DISABLE_ASSERTS 1
 315 #endif
 316 #define BOOST_ENABLE_ASSERT_HANDLER 1
 317
 318 #define BOOST_DISABLE_THREADS 1
 319 #define BOOST_NO_WREGEX 1
 320 #define BOOST_NO_WSTRING 1
 321 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 322
 323 #ifdef __CYGWIN__
 324 #  define NOMINMAX
 325 #  define BOOST_POSIX 1
 326 #  define BOOST_POSIX_API 1
 327 #  define BOOST_POSIX_PATH 1
 328 #endif
 329
 330 #ifdef __sparc__
 331 #  ifndef __BIG_ENDIAN__
 332 #    define __BIG_ENDIAN__ 1
 333 #  endif
 334 #endif
 335
 336 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 337 #  define USE_WCHAR_T
 338 #endif
 339
 340 #ifdef HAVE_LONG_LONG_INT
 341 #if SIZEOF_LONG_LONG > SIZEOF_LONG
 342 #define LYX_USE_LONG_LONG
 343 #endif
 344 #endif
 345
 346 #endif
 347 ])
 348
 349 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 350 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 351 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 352
 353 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 354         "${lyx_abs_top_srcdir}", [Top source directory])
 355 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 356         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 357 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 358         "${lyx_abs_installed_datadir}",[Hard system support directory])
 359 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 360         "${version_suffix}",[Program version suffix])
 361
 362 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 363 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 364 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 365 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 366 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 367 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 368 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 369 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 370
 371 AC_CONFIG_FILES([Makefile \
 372       lyx.1:lyx.1in \
 373       3rdparty/Makefile \
 374       3rdparty/boost/Makefile \
 375       3rdparty/hunspell/Makefile \
 376       3rdparty/libiconv/Makefile \
 377       $ICONV_ICONV_H_IN \
 378       3rdparty/zlib/Makefile \
 379       autotests/Makefile \
 380       config/Makefile \
 381       development/Makefile \
 382       development/MacOSX/Makefile \
 383       development/MacOSX/Info.plist \
 384       development/MacOSX/lyxrc.dist \
 385       development/MacOSX/spotlight/Makefile \
 386       development/cygwin/Makefile \
 387       development/cygwin/lyxrc.dist \
 388       development/lyx.spec \
 389       lib/lyx.desktop-temp:lib/lyx.desktop.in
 390       lib/Makefile \
 391       lib/doc/Makefile \
 392       lib/lyx2lyx/lyx2lyx_version.py \
 393       lib/lyx2lyx/Makefile \
 394       m4/Makefile \
 395       po/Makefile.in \
 396       sourcedoc/Doxyfile \
 397       sourcedoc/Makefile \
 398       src/client/Makefile \
 399       src/client/lyxclient.1:src/client/lyxclient.1in \
 400       src/Makefile \
 401       src/tex2lyx/Makefile \
 402       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 403       src/support/Makefile \
 404       src/frontends/Makefile \
 405       src/frontends/qt4/Makefile
 406 ])
 407
 408
 409 AC_OUTPUT
 410
 411 # show version information
 412 echo
 413 printf "$VERSION_INFO"
 414 echo
 415
 416 # Display a final warning if there has been a LYX_WARNING
 417 LYX_CHECK_WARNINGS
 418
 419 cat <<EOF
 420 Configuration of LyX was successful.
 421 Type 'make' to compile the program,
 422 and then 'make install' to install it.
 423 EOF