configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.4.0pre4,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AC_CONFIG_HEADERS([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 # First check the version
  11 LYX_CHECK_VERSION
  12 AC_CANONICAL_TARGET
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
  21
  22 # Check how the files should be packaged
  23 LYX_USE_PACKAGING
  24 LYX_VERSION_SUFFIX
  25 # We need to define these variables here and the no-define option of
  26 # AM_INIT_AUTOMAKE above because LYX_VERSION_SUFFIX alters $PACKAGE.
  27 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37
  38 AC_PROG_AWK
  39 test "$AWK" = gawk && AWK="gawk --posix"
  40
  41 #AC_PROG_RANLIB
  42 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  43 if test "x$KPSEWHICH" = xkpsewhich ; then
  44     AC_DEFINE(HAVE_KPSEWHICH, 1,
  45     [Define this if you have the kpsewhich program working on your system.])
  46 fi
  47 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  48
  49 # Check for installed python
  50 AM_PATH_PYTHON(1.5.2,, :)
  51
  52 # Work around a problem in automake 1.4: when invoking install-strip,
  53 # INSTALL_PROGRAM is changed to 'install -s', and since
  54 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  55 # which returns an error condition when stripping fails.
  56 INSTALL_SCRIPT='${INSTALL}'
  57
  58 ### we will also need a C compiler to compile GNU gettext
  59 AC_PROG_CC
  60
  61 ### check for special systems
  62 AC_ISC_POSIX
  63 AC_AIX
  64
  65 ### check which frontend we want to use
  66 LYX_USE_FRONTENDS
  67
  68 ### Check for a C++ compiler
  69 LYX_PROG_CXX
  70 ### Some checks on what the C++ compiler can(not) do
  71 AC_LANG(C++)
  72 dnl we do not need that currently (and probably all our supported
  73 dnl compiler allow that)
  74 dnl LYX_CXX_PARTIAL
  75 LYX_CXX_EXPLICIT
  76 LYX_CXX_GLOBAL_CSTD
  77 LYX_STD_COUNT
  78 dnl we disable rtti for now
  79 dnl LYX_CXX_RTTI
  80 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  81 LYX_CXX_STL_MODERN_STREAMS
  82
  83 ### and now some special lyx flags.
  84 AC_ARG_ENABLE(assertions,
  85   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  86   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  87         enable_assertions=yes;
  88     else
  89         enable_assertions=no;
  90     fi;])
  91 if test "x$enable_assertions" = xyes ; then
  92    lyx_flags="assertions $lyx_flags"
  93    AC_DEFINE(ENABLE_ASSERTIONS,1,
  94     [Define if you want assertions to be enabled in the code])
  95 fi
  96
  97 ### Library Files
  98 dnl by testing these we check if it is ok to have
  99 dnl -lc and -lm as args to the compiler
 100 AC_CHECK_LIB(m, sin)
 101 AC_CHECK_LIB(c, fopen)
 102
 103 ### Add extra directories to check for libraries.
 104 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 105 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 106 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 107
 108 ### Add extra directories to check for include files.
 109 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 110 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 111 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 112
 113 ### Add both includes and libraries
 114 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 115 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 116 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 117   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 118
 119 AC_ARG_WITH(aiksaurus,
 120   [  --without-aiksaurus     do not use the Aiksaurus library],
 121   [lyx_use_aiksaurus=$withval])
 122 if test x$lyx_use_aiksaurus != xno; then
 123 AC_CHECK_LIB(Aiksaurus, main,
 124         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 125          AIKSAURUS_LIBS="-lAiksaurus"
 126          lyx_flags="aiksaurus $lyx_flags"
 127         ])
 128 AC_CHECK_HEADER(Aiksaurus.h,[
 129   ac_cv_header_aiksaurus_h=yes
 130   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 131 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 132   ac_cv_header_aiksaurus_h=yes
 133   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 134 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 135 fi
 136 AC_SUBST(AIKSAURUS_LIBS)
 137
 138 LYX_USE_INCLUDED_BOOST
 139
 140 ### Setup libtool
 141 AC_DISABLE_SHARED
 142 AC_LIBTOOL_WIN32_DLL
 143 #AM_PROG_LIBTOOL
 144 LYX_PROG_LIBTOOL
 145
 146 ### Check for some Cygwin-specific details.
 147 CHECK_WITH_CYGWIN
 148
 149 ### Check for X libraries
 150 AC_PATH_XTRA
 151 case $have_x in
 152   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 153        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 154   no) LYX_ERROR(dnl
 155 [Cannot find X window libraries and/or headers. Check your installation.
 156   If you use a Linux system, check that you have installed
 157   the development tools.]);;
 158   disable) ;;
 159 esac
 160
 161 ### check which frontend we want to use
 162
 163 dnl The code below is not in a macro, because this would cause big
 164 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 165 for frontend in $FRONTENDS ; do
 166   case "$frontend" in
 167     xforms)
 168           XFORMS_DO_IT_ALL
 169           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 170           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 171           RPM_FRONTEND="xforms"
 172           FRONTEND_INFO="${FRONTEND_INFO}\
 173   XForms Frontend:\n\
 174       libXpm version:\t\t${XPM_VERSION}\n\
 175       libforms version:\t\t${XFORMS_VERSION}\n"
 176           ;;
 177     gtk)
 178           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
 179           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 180           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 181           RPM_FRONTEND="gtk"
 182           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 183           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 184           FRONTEND_INFO="${FRONTEND_INFO}\
 185   GTK Frontend:\n\
 186     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 187     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 188           ;;
 189
 190     qt)
 191           QT_DO_IT_ALL
 192           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 193           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 194           RPM_FRONTEND="qt"
 195           FRONTEND_INFO="${FRONTEND_INFO}\
 196   Qt Frontend:\n\
 197       Qt version:\t\t${QT_VERSION}\n"
 198 dnl qt build will fail without moc or uic
 199           if test -z "$MOC"; then
 200             LYX_ERROR([moc binary not found !])
 201           fi
 202           if test -z "$UIC"; then
 203             LYX_ERROR([uic binary not found !])
 204           fi
 205           if test -z "$QT_LIB"; then
 206             LYX_ERROR([qt library not found !])
 207           fi
 208       ;;
 209     *)
 210           LYX_ERROR(Unknown frontend '$frontend');;
 211   esac
 212 done
 213
 214 # fix the value of the prefixes.
 215 test "x$prefix" = xNONE && prefix=$default_prefix
 216 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 217 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 218   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 219    causes problems with the Makefiles. The installation will be done in
 220    directory \"`pwd`/installprefix\" instead. Please move its contents to
 221    the right place after installation.])
 222   prefix=`pwd`/installprefix
 223 fi
 224
 225 ### Setup GNU gettext
 226 dnl GNU gettext is written in C
 227 AC_LANG_PUSH(C)
 228 AM_GNU_GETTEXT
 229 AC_LANG_POP(C)
 230
 231 # some standard header files
 232 AC_HEADER_DIRENT
 233 AC_HEADER_MAJOR
 234 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 235
 236 # some standard structures
 237 AC_HEADER_STAT
 238 AC_HEADER_TIME
 239
 240 # some standard types
 241 AC_TYPE_MODE_T
 242 AC_TYPE_OFF_T
 243 AC_TYPE_PID_T
 244 AC_TYPE_SIGNAL
 245 AC_TYPE_SIZE_T
 246 AC_TYPE_UID_T
 247
 248 AC_CHECK_FUNCS(strerror)
 249 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 250 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 251
 252 # Check the form of mkdir()
 253 AC_FUNC_MKDIR
 254
 255 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 256     case "${enableval}" in
 257         yes) use_compression=true ;;
 258         no) use_compression=false ;;
 259         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 260     esac
 261 ],[use_compression=true])
 262 if test $use_compression=true ; then
 263         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 264         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 265         if test $use_compression = true ; then
 266                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 267                 lyx_flags="compression $lyx_flags"
 268         fi
 269 fi
 270 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 271 AC_MSG_CHECKING([whether to support compressed files])
 272 AC_MSG_RESULT($use_compression)
 273
 274
 275 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 276 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 277 dnl We aim to remove this eventually, since we should test as much as
 278 dnl possible with the compiler which will use the functions (JMarc)
 279 AC_LANG_PUSH(C)
 280 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 281 AC_LANG_POP(C)
 282
 283 LYX_CHECK_SPELL_ENGINES
 284
 285 lyx_client_subdir=true
 286 AC_LANG_PUSH(C)
 287 dnl LIBS already contains some X extra libs that may interfere.
 288 save_LIBS="$LIBS"
 289 LIBS=
 290 AC_CHECK_FUNCS(fcntl,
 291   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 292    AC_SEARCH_LIBS([socket], [socket], [],
 293      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 294                 [], [-lnsl])])],
 295   [lyx_client_subdir=false])
 296 AC_SUBST(SOCKET_LIBS,$LIBS)
 297 LIBS="$save_LIBS"
 298 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 299 AC_LANG_POP(C)
 300
 301 AC_FUNC_SELECT_ARGTYPES
 302
 303 ### Some information on what just happened
 304 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 305 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 306 VERSION_INFO="Configuration\n\
 307   Host type:                      ${host}\n\
 308   Special build flags:            ${lyx_flags}\n\
 309   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 310   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 311   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 312   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 313   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 314   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 315   Linker flags:                   ${AM_LDFLAGS}\n\
 316   Linker user flags:              ${LDFLAGS}\n\
 317 ${FRONTEND_INFO}\
 318   Packaging:                      ${lyx_use_packaging}\n\
 319   LyX binary dir:                 ${real_bindir}\n\
 320   LyX files dir:                  ${real_datadir}\n"
 321
 322 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 323 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 324 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 325 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_datadir})
 326
 327 AC_SUBST(VERSION_INFO)
 328 AC_SUBST(RPM_FRONTEND)
 329 AC_SUBST(AM_CPPFLAGS)
 330 AC_SUBST(AM_CXXFLAGS)
 331 AC_SUBST(AM_CFLAGS)
 332 AC_SUBST(AM_LDFLAGS)
 333 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 334 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 335 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 336
 337 ## Some config.h stuff
 338
 339 AH_TOP([
 340 /* -*- C++ -*- */
 341 /*
 342  * \file config.h
 343  * This file is part of LyX, the document processor.
 344  * Licence details can be found in the file COPYING.
 345  *
 346  * This is the compilation configuration file for LyX.
 347  * It was generated by autoconfs configure.
 348  * You might want to change some of the defaults if something goes wrong
 349  * during the compilation.
 350  */
 351
 352 #ifndef _CONFIG_H
 353 #define _CONFIG_H
 354 ])
 355
 356 AH_BOTTOM([
 357 /************************************************************
 358  ** You should not need to change anything beyond this point */
 359
 360 #ifndef HAVE_STRERROR
 361 #if defined(__cplusplus)
 362 extern "C"
 363 #endif
 364 char * strerror(int n);
 365 #endif
 366
 367 #ifdef HAVE_MKSTEMP
 368 #ifndef HAVE_DECL_MKSTEMP
 369 #if defined(__cplusplus)
 370 extern "C"
 371 #endif
 372 int mkstemp(char*);
 373 #endif
 374 #endif
 375
 376 #ifdef __EMX__
 377 #include "support/os2_defines.h"
 378 #endif
 379
 380 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 381 #define USE_BOOST_FORMAT 1
 382 #else
 383 #define USE_BOOST_FORMAT 0
 384 #endif
 385
 386 #define BOOST_USER_CONFIG <config.h>
 387
 388 #if defined(ENABLE_ASSERTIONS)
 389 #define BOOST_ENABLE_ASSERT_HANDLER 1
 390 #else
 391 #define BOOST_DISABLE_ASSERTS 1
 392 #endif
 393
 394 #define BOOST_DISABLE_THREADS 1
 395 #define BOOST_NO_WREGEX 1
 396 #define BOOST_NO_WSTRING 1
 397
 398 #ifdef __CYGWIN__
 399 #define BOOST_POSIX 1
 400 #endif
 401
 402 #if defined(HAVE_NEWAPIS_H)
 403 #define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 404 #endif
 405
 406 #endif
 407 ])
 408
 409 ### Finish the work.
 410 AC_CONFIG_SUBDIRS(lib)
 411 AC_CONFIG_FILES([Makefile  m4/Makefile \
 412        boost/Makefile \
 413        boost/libs/Makefile \
 414        boost/libs/filesystem/Makefile \
 415        boost/libs/filesystem/src/Makefile \
 416        boost/libs/regex/Makefile \
 417        boost/libs/regex/src/Makefile \
 418        boost/libs/signals/Makefile \
 419        boost/libs/signals/src/Makefile \
 420        config/Makefile \
 421        development/Makefile \
 422        development/lyx.spec \
 423        lib/Makefile \
 424        lib/doc/Makefile \
 425        lib/lyx2lyx/Makefile \
 426        intl/Makefile \
 427        po/Makefile.in \
 428        sourcedoc/Doxyfile \
 429        sourcedoc/Makefile \
 430        src/client/Makefile \
 431        src/Makefile \
 432        src/version.C-tmp:src/version.C.in \
 433        src/tex2lyx/Makefile \
 434        src/mathed/Makefile \
 435        src/graphics/Makefile \
 436        src/insets/Makefile \
 437        src/support/Makefile \
 438        src/support/tests/Makefile \
 439        src/frontends/Makefile \
 440        src/frontends/controllers/Makefile \
 441        src/frontends/xforms/Makefile \
 442        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 443        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 444        src/frontends/xforms/forms/Makefile \
 445        src/frontends/gtk/Makefile \
 446        src/frontends/gtk/gimages/Makefile \
 447        src/frontends/gtk/glade/Makefile \
 448        src/frontends/qt2/Makefile \
 449        src/frontends/qt2/moc/Makefile \
 450        src/frontends/qt2/ui/Makefile \
 451        src/frontends/qt2/ui/moc/Makefile \
 452 ])
 453
 454 AC_OUTPUT
 455 # show version information
 456 echo
 457 printf "$VERSION_INFO"
 458 echo
 459
 460 # Display a final warning if there has been a LYX_ERROR
 461 LYX_CHECK_ERRORS