configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT([LyX],[2.4.0dev],[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2018-02-24"])
   7 AC_PREREQ([2.65])
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29 AM_SILENT_RULES([yes])
  30 # Automake is pulling the historical V7 format. This tar format supports
  31 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  32 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  33 save_PACKAGE=$PACKAGE
  34 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.14 tar-ustar subdir-objects])
  35 PACKAGE=$save_PACKAGE
  36
  37 ### Set the execute permissions of the various scripts correctly
  38 for file in config/install-sh ; do
  39   chmod 755 ${srcdir}/${file}
  40 done
  41
  42 # Find a suitable python interpreter
  43 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  44 # do the usual python setup stuff
  45 AM_PATH_PYTHON
  46
  47 # Tools for creating libraries (note that we do not use libtool)
  48 AM_PROG_AR
  49 AC_PROG_RANLIB
  50 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  51 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  52 AC_SUBST([ARFLAGS], [cr])
  53
  54 ### Check for a C++ compiler
  55 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  56 dnl if it is not set. We do not use autoconf defaults.
  57 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  58 if ! test "$lyx_has_CXXFLAGS" = yes; then
  59   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  60   CXXFLAGS=" "
  61 fi
  62 LYX_PROG_CXX
  63 if ! test "$lyx_has_CXXFLAGS" = yes; then
  64   unset CXXFLAGS
  65 fi
  66 AC_LANG(C++)
  67
  68 ### Objective-C compiler
  69 AC_PROG_OBJC
  70 _AM_DEPENDENCIES([OBJC])
  71
  72 ### Add extra directories to check for libraries.
  73 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  74 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  75 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  76
  77 ### Add extra directories to check for include files.
  78 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  79 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  80 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  81
  82 ### Add both includes and libraries
  83 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  84 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  85   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  86   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
  87 ])
  88
  89 ### These are needed in windows
  90 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  91 AC_SUBST(LIBSHLWAPI)
  92 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  93 AC_SUBST(LIBPSAPI)
  94 AC_CHECK_LIB(gdi32, main)
  95 AC_CHECK_LIB(ole32, main)
  96
  97 LYX_USE_INCLUDED_BOOST
  98
  99 ### we need to know the byte order for unicode conversions
 100 AC_C_BIGENDIAN
 101
 102 # Nice to have when an assertion triggers
 103 LYX_CHECK_CALLSTACK_PRINTING
 104
 105 # C++14 only
 106 LYX_CHECK_DEF(make_unique, memory, [using std::make_unique;])
 107
 108 # Needed for our char_type
 109 AC_CHECK_SIZEOF(wchar_t)
 110
 111 # Taken from gettext, needed for libiconv
 112 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 113    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
 114       wchar_t foo = (wchar_t)'\0';]], [[]])],[gt_cv_c_wchar_t=yes],[gt_cv_c_wchar_t=no])])
 115 if test $gt_cv_c_wchar_t = yes; then
 116   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 117   HAVE_WCHAR_T=1
 118 else
 119   HAVE_WCHAR_T=0
 120 fi
 121 AC_SUBST([HAVE_WCHAR_T])
 122
 123 # Needed for Mingw-w64
 124 AC_TYPE_LONG_LONG_INT
 125
 126 ### We need iconv for unicode support (Qt4 frontend requires it too)
 127 LYX_USE_INCLUDED_ICONV
 128
 129 ### check for compression support
 130 LYX_USE_INCLUDED_ZLIB
 131
 132 ### check for file magic support (currently optional)
 133 AC_CHECK_HEADERS(magic.h,
 134  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 135   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 136    is correctly installed on your system.
 137    Falling back to builtin file format detection.]))],
 138  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 139    is correctly installed on your system.
 140    Falling back to builtin file format detection.])])
 141
 142 ### setup the qt frontend.
 143 dnl The code below is not in a macro, because this would cause big
 144 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 145 QT_DO_IT_ALL([4.5.0])
 146 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 147 FRONTEND_INFO="${FRONTEND_INFO}\
 148   Qt Frontend:\n\
 149       Qt version:\t   ${QTLIB_VERSION}\n"
 150
 151 # fix the value of the prefixes.
 152 test "x$prefix" = xNONE && prefix=$default_prefix
 153 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 154 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 155   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 156    causes problems with the Makefiles. The installation will be done in
 157    directory \"`pwd`/installprefix\" instead. Please move its contents to
 158    the right place after installation.])
 159   prefix=`pwd`/installprefix
 160 fi
 161
 162 ### Setup po directory
 163 AM_NLS
 164 if test $USE_NLS = "yes" ; then
 165   AC_DEFINE(ENABLE_NLS, 1,
 166     [Define to 1 if translation of program messages to the user's native language
 167    is requested.])dnl'
 168 fi
 169 AM_PO_SUBDIRS
 170
 171 # some standard header files
 172 AC_HEADER_MAJOR
 173 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 174
 175 # some standard types
 176 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 177 AC_TYPE_OFF_T
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_TYPE_UID_T
 181
 182 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 183
 184 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 185 # Check the form of mkdir()
 186 AC_FUNC_MKDIR
 187 AC_FUNC_SELECT_ARGTYPES
 188
 189 LYX_CHECK_SPELL_ENGINES
 190 LYX_USE_INCLUDED_MYTHES
 191
 192 lyx_client_subdir=true
 193 dnl LIBS already contains some X extra libs that may interfere.
 194 save_LIBS="$LIBS"
 195 LIBS=
 196 AC_CHECK_FUNCS(fcntl,
 197   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 198    AC_SEARCH_LIBS([socket], [socket network], [],
 199      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 200                 [], [-lnsl])])],
 201   [lyx_client_subdir=false])
 202 AC_SUBST(SOCKET_LIBS,$LIBS)
 203 LIBS="$save_LIBS"
 204 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 205
 206 lyx_win_res=false;
 207 case ${host} in
 208     *mingw*|*cygwin*) lyx_win_res=true;;
 209     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 210 esac
 211 if test "x$lyx_win_res" = "xtrue"; then
 212     AC_CHECK_TOOL(RC, windres,)
 213     if test -z "$RC"; then
 214       AC_MSG_ERROR([Could not find a resource compiler])
 215     fi
 216 fi
 217 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 218 LYX_SET_VERSION_INFO
 219
 220
 221 ### Some information on what just happened
 222 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 223 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 224 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 225 test -z "${lyx_included_libs}" && lyx_included_libs="(none)"
 226 VERSION_INFO="Configuration\n\
 227   Host type:               ${host}\n\
 228   Special build flags:     ${lyx_flags}\n\
 229   Bundled libraries:       ${lyx_included_libs}\n\
 230   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 231   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 232   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 233   Linker flags:            ${AM_LDFLAGS}\n\
 234   Linker user flags:       ${LDFLAGS}\n\
 235 ${FRONTEND_INFO}\
 236   Packaging:               ${lyx_use_packaging}\n\
 237   LyX binary dir:          ${real_bindir}\n\
 238   LyX files dir:           ${real_pkgdatadir}\n"
 239
 240 AC_SUBST(VERSION_INFO)
 241 AC_SUBST(AM_CPPFLAGS)
 242 AC_SUBST(AM_CXXFLAGS)
 243 AC_SUBST(AM_LDFLAGS)
 244 AC_SUBST(real_pkgdatadir)
 245
 246 ## Some config.h stuff
 247
 248 AH_TOP([
 249 /* -*- C++ -*- */
 250 /*
 251  * \file config.h
 252  * This file is part of LyX, the document processor.
 253  * Licence details can be found in the file COPYING.
 254  *
 255  * This is the compilation configuration file for LyX.
 256  * It was generated by autoconfs configure.
 257  * You might want to change some of the defaults if something goes wrong
 258  * during the compilation.
 259  */
 260
 261 #ifndef _CONFIG_H
 262 #define _CONFIG_H
 263 ])
 264
 265 AH_BOTTOM([
 266 /************************************************************
 267  ** You should not need to change anything beyond this point */
 268
 269 #ifndef HAVE_STRERROR
 270 #if defined(__cplusplus)
 271 extern "C"
 272 #endif
 273 char * strerror(int n);
 274 #endif
 275
 276 #define BOOST_USER_CONFIG <config.h>
 277
 278 #if !defined(ENABLE_ASSERTIONS)
 279 #  define BOOST_DISABLE_ASSERTS 1
 280 #endif
 281 #define BOOST_ENABLE_ASSERT_HANDLER 1
 282
 283 #define BOOST_DISABLE_THREADS 1
 284 #define BOOST_NO_WREGEX 1
 285 #define BOOST_NO_WSTRING 1
 286
 287 #ifdef __CYGWIN__
 288 #  define _DEFAULT_SOURCE
 289 #  define NOMINMAX
 290 #  define BOOST_POSIX 1
 291 #  define BOOST_POSIX_API 1
 292 #  define BOOST_POSIX_PATH 1
 293 #endif
 294
 295 #ifdef __sparc__
 296 #  ifndef __BIG_ENDIAN__
 297 #    define __BIG_ENDIAN__ 1
 298 #  endif
 299 #endif
 300
 301 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 302 #  define USE_WCHAR_T
 303 #endif
 304
 305 #endif
 306 ])
 307
 308 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 309 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 310 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 311
 312 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 313         "${lyx_abs_top_srcdir}", [Top source directory])
 314 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 315         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 316 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 317         "${lyx_abs_installed_datadir}",[Hard system support directory])
 318 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 319         "${version_suffix}",[Program version suffix])
 320
 321 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 322 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 323 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 324 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 325 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 326 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 327 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 328 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 329
 330 AC_CONFIG_FILES([Makefile \
 331       lyx.1:lyx.1in \
 332       3rdparty/Makefile \
 333       3rdparty/boost/Makefile \
 334       3rdparty/hunspell/Makefile \
 335       3rdparty/mythes/Makefile \
 336       3rdparty/libiconv/Makefile \
 337       $ICONV_ICONV_H_IN \
 338       3rdparty/zlib/Makefile \
 339       autotests/Makefile \
 340       config/Makefile \
 341       development/Makefile \
 342       development/MacOSX/Makefile \
 343       development/MacOSX/Info.plist \
 344       development/MacOSX/lyxrc.dist \
 345       development/MacOSX/spotlight/Makefile \
 346       development/cygwin/Makefile \
 347       development/cygwin/lyxrc.dist \
 348       development/lyx.spec \
 349       lib/lyx.desktop-temp:lib/lyx.desktop.in
 350       lib/Makefile \
 351       lib/doc/Makefile \
 352       lib/lyx2lyx/lyx2lyx_version.py \
 353       lib/lyx2lyx/Makefile \
 354       m4/Makefile \
 355       po/Makefile.in \
 356       sourcedoc/Doxyfile \
 357       sourcedoc/Makefile \
 358       src/client/Makefile \
 359       src/client/lyxclient.1:src/client/lyxclient.1in \
 360       src/Makefile \
 361       src/tex2lyx/Makefile \
 362       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 363       src/convert/Makefile \
 364       src/support/Makefile \
 365       src/frontends/Makefile \
 366       src/frontends/qt4/Makefile
 367 ])
 368
 369
 370 AC_OUTPUT
 371
 372 # show version information
 373 echo
 374 printf "$VERSION_INFO"
 375 echo
 376
 377 # Display a final warning if there has been a LYX_WARNING
 378 LYX_CHECK_WARNINGS
 379
 380 cat <<EOF
 381 Configuration of LyX was successful.
 382 Type 'make' to compile the program,
 383 and then 'make install' to install it.
 384 EOF