configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.4.0cvs,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AC_CONFIG_HEADERS([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 # First check the version
  11 LYX_CHECK_VERSION
  12 AC_CANONICAL_TARGET
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19
  20 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
  21
  22 # Check how the files should be packaged
  23 LYX_USE_PACKAGING
  24 LYX_VERSION_SUFFIX
  25 # We need to define these variables here and the no-define option of
  26 # AM_INIT_AUTOMAKE above because LYX_VERSION_SUFFIX alters $PACKAGE.
  27 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37
  38 AC_PROG_AWK
  39 test "$AWK" = gawk && AWK="gawk --posix"
  40
  41 #AC_PROG_RANLIB
  42 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  43 if test "x$KPSEWHICH" = xkpsewhich ; then
  44     AC_DEFINE(HAVE_KPSEWHICH, 1,
  45     [Define this if you have the kpsewhich program working on your system.])
  46 fi
  47 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  48
  49 # Check for installed python
  50 AM_PATH_PYTHON(1.5.2,, :)
  51
  52 # Work around a problem in automake 1.4: when invoking install-strip,
  53 # INSTALL_PROGRAM is changed to 'install -s', and since
  54 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  55 # which returns an error condition when stripping fails.
  56 INSTALL_SCRIPT='${INSTALL}'
  57
  58 ### we will also need a C compiler to compile GNU gettext
  59 AC_PROG_CC
  60
  61 ### check for special systems
  62 AC_ISC_POSIX
  63 AC_AIX
  64
  65 ### check which frontend we want to use
  66 LYX_USE_FRONTENDS
  67
  68 ### Check for a C++ compiler
  69 LYX_PROG_CXX
  70 ### Some checks on what the C++ compiler can(not) do
  71 AC_LANG(C++)
  72 dnl we do not need that currently (and probably all our supported
  73 dnl compiler allow that)
  74 dnl LYX_CXX_PARTIAL
  75 LYX_CXX_EXPLICIT
  76 LYX_CXX_GLOBAL_CSTD
  77 LYX_STD_COUNT
  78 dnl we disable rtti for now
  79 dnl LYX_CXX_RTTI
  80 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  81 LYX_CXX_STL_MODERN_STREAMS
  82
  83 ### and now some special lyx flags.
  84 AC_ARG_ENABLE(assertions,
  85   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  86   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  87         enable_assertions=yes;
  88     else
  89         enable_assertions=no;
  90     fi;])
  91 if test "x$enable_assertions" = xyes ; then
  92    lyx_flags="assertions $lyx_flags"
  93    AC_DEFINE(ENABLE_ASSERTIONS,1,
  94     [Define if you want assertions to be enabled in the code])
  95 fi
  96
  97 ### Library Files
  98 dnl by testing these we check if it is ok to have
  99 dnl -lc and -lm as args to the compiler
 100 AC_CHECK_LIB(m, sin)
 101 AC_CHECK_LIB(c, fopen)
 102
 103 ### Add extra directories to check for libraries.
 104 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 105 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 106 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 107
 108 ### Add extra directories to check for include files.
 109 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 110 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 111 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 112
 113 ### Add both includes and libraries
 114 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 115 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 116 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 117   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 118
 119 AC_ARG_WITH(aiksaurus,
 120   [  --without-aiksaurus     do not use the Aiksaurus library],
 121   [lyx_use_aiksaurus=$withval])
 122 if test x$lyx_use_aiksaurus != xno; then
 123 AC_CHECK_LIB(Aiksaurus, main,
 124         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 125          AIKSAURUS_LIBS="-lAiksaurus"
 126          lyx_flags="aiksaurus $lyx_flags"
 127         ])
 128 AC_CHECK_HEADER(Aiksaurus.h,[
 129   ac_cv_header_aiksaurus_h=yes
 130   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 131 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 132   ac_cv_header_aiksaurus_h=yes
 133   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 134 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 135 fi
 136 AC_SUBST(AIKSAURUS_LIBS)
 137
 138 LYX_USE_INCLUDED_BOOST
 139
 140 ### Setup libtool
 141 AC_DISABLE_SHARED
 142 AC_LIBTOOL_WIN32_DLL
 143 #AM_PROG_LIBTOOL
 144 LYX_PROG_LIBTOOL
 145
 146 ### Check for some Cygwin-specific details.
 147 CHECK_WITH_CYGWIN
 148
 149 ### Check for X libraries
 150 AC_PATH_XTRA
 151 case $have_x in
 152   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 153        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 154   no) LYX_ERROR(dnl
 155 [Cannot find X window libraries and/or headers. Check your installation.
 156   If you use a Linux system, check that you have installed
 157   the development tools.]);;
 158   disable) ;;
 159 esac
 160
 161 ### check which frontend we want to use
 162
 163 dnl if the gtk frontend has been specified, then xforms is needed too
 164 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 165   FRONTENDS="xforms $FRONTENDS"
 166   noxformsbin=yes
 167 fi
 168
 169 dnl The code below is not in a macro, because this would cause big
 170 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 171 for frontend in $FRONTENDS ; do
 172   case "$frontend" in
 173     xforms)
 174           XFORMS_DO_IT_ALL
 175           if test -z "$noxformsbin" ; then
 176             FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 177           fi
 178           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 179           RPM_FRONTEND="xforms"
 180           FRONTEND_INFO="${FRONTEND_INFO}\
 181   XForms Frontend:\n\
 182       libXpm version:\t\t${XPM_VERSION}\n\
 183       libforms version:\t\t${XFORMS_VERSION}\n"
 184           ;;
 185     gtk)
 186           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
 187           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 188           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 189           RPM_FRONTEND="gtk"
 190           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 191           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 192           FRONTEND_INFO="${FRONTEND_INFO}\
 193   GTK Frontend:\n\
 194     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 195     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 196           ;;
 197
 198     qt)
 199           QT_DO_IT_ALL
 200           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 201           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 202           RPM_FRONTEND="qt"
 203           FRONTEND_INFO="${FRONTEND_INFO}\
 204   Qt Frontend:\n\
 205       Qt version:\t\t${QT_VERSION}\n"
 206 dnl qt build will fail without moc or uic
 207           if test -z "$MOC"; then
 208             LYX_ERROR([moc binary not found !])
 209           fi
 210           if test -z "$UIC"; then
 211             LYX_ERROR([uic binary not found !])
 212           fi
 213           if test -z "$QT_LIB"; then
 214             LYX_ERROR([qt library not found !])
 215           fi
 216       ;;
 217     *)
 218           LYX_ERROR(Unknown frontend '$frontend');;
 219   esac
 220 done
 221
 222 # fix the value of the prefixes.
 223 test "x$prefix" = xNONE && prefix=$default_prefix
 224 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 225 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 226   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 227    causes problems with the Makefiles. The installation will be done in
 228    directory \"`pwd`/installprefix\" instead. Please move its contents to
 229    the right place after installation.])
 230   prefix=`pwd`/installprefix
 231 fi
 232
 233 ### Setup GNU gettext
 234 dnl GNU gettext is written in C
 235 AC_LANG_PUSH(C)
 236 AM_GNU_GETTEXT
 237 AC_LANG_POP(C)
 238
 239 # some standard header files
 240 AC_HEADER_DIRENT
 241 AC_HEADER_MAJOR
 242 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 243
 244 # some standard structures
 245 AC_HEADER_STAT
 246 AC_HEADER_TIME
 247
 248 # some standard types
 249 AC_TYPE_MODE_T
 250 AC_TYPE_OFF_T
 251 AC_TYPE_PID_T
 252 AC_TYPE_SIGNAL
 253 AC_TYPE_SIZE_T
 254 AC_TYPE_UID_T
 255
 256 AC_CHECK_FUNCS(strerror)
 257 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 258 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 259
 260 # Check the form of mkdir()
 261 AC_FUNC_MKDIR
 262
 263 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 264     case "${enableval}" in
 265         yes) use_compression=true ;;
 266         no) use_compression=false ;;
 267         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 268     esac
 269 ],[use_compression=true])
 270 if test $use_compression=true ; then
 271         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 272         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 273         if test $use_compression = true ; then
 274                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 275                 lyx_flags="compression $lyx_flags"
 276         fi
 277 fi
 278 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 279 AC_MSG_CHECKING([whether to support compressed files])
 280 AC_MSG_RESULT($use_compression)
 281
 282
 283 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 284 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 285 dnl We aim to remove this eventually, since we should test as much as
 286 dnl possible with the compiler which will use the functions (JMarc)
 287 AC_LANG_PUSH(C)
 288 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 289 AC_LANG_POP(C)
 290
 291 LYX_CHECK_SPELL_ENGINES
 292
 293 lyx_client_subdir=true
 294 AC_LANG_PUSH(C)
 295 dnl LIBS already contains some X extra libs that may interfere.
 296 save_LIBS="$LIBS"
 297 LIBS=
 298 AC_CHECK_FUNCS(fcntl,
 299   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 300    AC_SEARCH_LIBS([socket], [socket], [],
 301      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 302                 [], [-lnsl])])],
 303   [lyx_client_subdir=false])
 304 AC_SUBST(SOCKET_LIBS,$LIBS)
 305 LIBS="$save_LIBS"
 306 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 307 AC_LANG_POP(C)
 308
 309 AC_FUNC_SELECT_ARGTYPES
 310
 311 ### Some information on what just happened
 312 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 313 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 314 VERSION_INFO="Configuration\n\
 315   Host type:                      ${host}\n\
 316   Special build flags:            ${lyx_flags}\n\
 317   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 318   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 319   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 320   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 321   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 322   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 323   Linker flags:                   ${AM_LDFLAGS}\n\
 324   Linker user flags:              ${LDFLAGS}\n\
 325 ${FRONTEND_INFO}\
 326   Packaging:                      ${lyx_use_packaging}\n\
 327   LyX binary dir:                 ${real_bindir}\n\
 328   LyX files dir:                  ${real_datadir}\n"
 329
 330 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 331 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 332 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 333 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_datadir})
 334
 335 AC_SUBST(VERSION_INFO)
 336 AC_SUBST(RPM_FRONTEND)
 337 AC_SUBST(AM_CPPFLAGS)
 338 AC_SUBST(AM_CXXFLAGS)
 339 AC_SUBST(AM_CFLAGS)
 340 AC_SUBST(AM_LDFLAGS)
 341 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 342 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 343 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 344
 345 ## Some config.h stuff
 346
 347 AH_TOP([
 348 /* -*- C++ -*- */
 349 /*
 350  * \file config.h
 351  * This file is part of LyX, the document processor.
 352  * Licence details can be found in the file COPYING.
 353  *
 354  * This is the compilation configuration file for LyX.
 355  * It was generated by autoconfs configure.
 356  * You might want to change some of the defaults if something goes wrong
 357  * during the compilation.
 358  */
 359
 360 #ifndef _CONFIG_H
 361 #define _CONFIG_H
 362 ])
 363
 364 AH_BOTTOM([
 365 /************************************************************
 366  ** You should not need to change anything beyond this point */
 367
 368 #ifndef HAVE_STRERROR
 369 #if defined(__cplusplus)
 370 extern "C"
 371 #endif
 372 char * strerror(int n);
 373 #endif
 374
 375 #ifdef HAVE_MKSTEMP
 376 #ifndef HAVE_DECL_MKSTEMP
 377 #if defined(__cplusplus)
 378 extern "C"
 379 #endif
 380 int mkstemp(char*);
 381 #endif
 382 #endif
 383
 384 #ifdef __EMX__
 385 #include "support/os2_defines.h"
 386 #endif
 387
 388 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 389 #define USE_BOOST_FORMAT 1
 390 #else
 391 #define USE_BOOST_FORMAT 0
 392 #endif
 393
 394 #define BOOST_USER_CONFIG <config.h>
 395
 396 #if defined(ENABLE_ASSERTIONS)
 397 #define BOOST_ENABLE_ASSERT_HANDLER 1
 398 #else
 399 #define BOOST_DISABLE_ASSERTS 1
 400 #endif
 401
 402 #define BOOST_DISABLE_THREADS 1
 403 #define BOOST_NO_WREGEX 1
 404 #define BOOST_NO_WSTRING 1
 405
 406 #ifdef __CYGWIN__
 407 #define BOOST_POSIX 1
 408 #endif
 409
 410 #if defined(HAVE_NEWAPIS_H)
 411 #define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 412 #endif
 413
 414 #endif
 415 ])
 416
 417 ### Finish the work.
 418 AC_CONFIG_SUBDIRS(lib)
 419 AC_CONFIG_FILES([Makefile  m4/Makefile \
 420        boost/Makefile \
 421        boost/libs/Makefile \
 422        boost/libs/filesystem/Makefile \
 423        boost/libs/filesystem/src/Makefile \
 424        boost/libs/regex/Makefile \
 425        boost/libs/regex/src/Makefile \
 426        boost/libs/signals/Makefile \
 427        boost/libs/signals/src/Makefile \
 428        config/Makefile \
 429        development/Makefile \
 430        development/lyx.spec \
 431        lib/Makefile \
 432        lib/doc/Makefile \
 433        lib/lyx2lyx/Makefile \
 434        intl/Makefile \
 435        po/Makefile.in \
 436        sourcedoc/Doxyfile \
 437        sourcedoc/Makefile \
 438        src/client/Makefile \
 439        src/Makefile \
 440        src/version.C-tmp:src/version.C.in \
 441        src/tex2lyx/Makefile \
 442        src/mathed/Makefile \
 443        src/graphics/Makefile \
 444        src/insets/Makefile \
 445        src/support/Makefile \
 446        src/support/tests/Makefile \
 447        src/frontends/Makefile \
 448        src/frontends/controllers/Makefile \
 449        src/frontends/xforms/Makefile \
 450        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 451        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 452        src/frontends/xforms/forms/Makefile \
 453        src/frontends/gtk/Makefile \
 454        src/frontends/gtk/gimages/Makefile \
 455        src/frontends/gtk/glade/Makefile \
 456        src/frontends/qt2/Makefile \
 457        src/frontends/qt2/moc/Makefile \
 458        src/frontends/qt2/ui/Makefile \
 459        src/frontends/qt2/ui/moc/Makefile \
 460 ])
 461
 462 AC_OUTPUT
 463 # show version information
 464 echo
 465 printf "$VERSION_INFO"
 466 echo
 467
 468 # Display a final warning if there has been a LYX_ERROR
 469 LYX_CHECK_ERRORS