configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 ### Set the execute permissions of the various scripts correctly
  26 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  27   chmod 755 ${srcdir}/${file}
  28 done
  29
  30 ### Check for programs
  31 AC_PROG_MAKE_SET
  32 AC_PROG_INSTALL
  33 #AC_PROG_RANLIB
  34 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  35 if test "x$KPSEWHICH" = xkpsewhich ; then
  36     AC_DEFINE(HAVE_KPSEWHICH, 1,
  37     [Define this if you have the kpsewhich program working on your system.])
  38 fi
  39 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  40
  41 # Work around a problem in automake 1.4: when invoking install-strip,
  42 # INSTALL_PROGRAM is changed to 'install -s', and since
  43 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  44 # which returns an error condition when stripping fails.
  45 INSTALL_SCRIPT='${INSTALL}'
  46
  47 ### we will also need a C compiler to compile GNU gettext
  48 AC_PROG_CC
  49
  50 ### check for special systems
  51 AC_ISC_POSIX
  52 AC_AIX
  53
  54 ### check which frontend we want to use
  55 LYX_USE_FRONTENDS
  56
  57 ### Check for a C++ compiler
  58 LYX_PROG_CXX
  59 ### Some checks on what the C++ compiler can(not) do
  60 AC_LANG(C++)
  61 dnl we do not need that currently (and probably all our supported
  62 dnl compiler allow that)
  63 dnl LYX_CXX_PARTIAL
  64 LYX_CXX_EXPLICIT
  65 LYX_CXX_GLOBAL_CSTD
  66 LYX_STD_COUNT
  67 dnl we disable rtti for now
  68 dnl LYX_CXX_RTTI
  69 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  70 LYX_CXX_STL_MODERN_STREAMS
  71
  72 ### and now some special lyx flags.
  73 AC_ARG_ENABLE(assertions,
  74   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  75   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  76         enable_assertions=yes;
  77     else
  78         enable_assertions=no;
  79     fi;])
  80 if test "x$enable_assertions" = xyes ; then
  81    lyx_flags="$lyx_flags assertions"
  82    AC_DEFINE(ENABLE_ASSERTIONS,1,
  83     [Define if you want assertions to be enabled in the code])
  84 fi
  85
  86 ### Library Files
  87 dnl by testing these we check if it is ok to have
  88 dnl -lc and -lm as args to the compiler
  89 AC_CHECK_LIB(m, sin)
  90 AC_CHECK_LIB(c, fopen)
  91
  92 ### Add extra directories to check for libraries.
  93 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  94 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  95 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  96
  97 ### Add extra directories to check for include files.
  98 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  99 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 100 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 101
 102 ### Add both includes and libraries
 103 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 104 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 105 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 106   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 107
 108 AC_ARG_WITH(aiksaurus,
 109   [  --without-aiksaurus     do not use the Aiksaurus library],
 110   [lyx_use_aiksaurus=$withval])
 111 if test x$lyx_use_aiksaurus != xno; then
 112 AC_CHECK_LIB(Aiksaurus, main,
 113         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 114          AIKSAURUS_LIBS="-lAiksaurus"
 115          lyx_flags="$lyx_flags aiksaurus"
 116         ])
 117 AC_CHECK_HEADER(Aiksaurus.h,[
 118   ac_cv_header_aiksaurus_h=yes
 119   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 120 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 121   ac_cv_header_aiksaurus_h=yes
 122   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 123 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 124 fi
 125 AC_SUBST(AIKSAURUS_LIBS)
 126
 127 LYX_USE_INCLUDED_BOOST
 128
 129 ### Setup libtool
 130 AC_DISABLE_SHARED
 131 AC_LIBTOOL_WIN32_DLL
 132 #AM_PROG_LIBTOOL
 133 LYX_PROG_LIBTOOL
 134
 135 ### Check for some Cygwin-specific details.
 136 CHECK_WITH_CYGWIN
 137
 138 ### Check for X libraries
 139 AC_PATH_XTRA
 140 case $have_x in
 141   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 142        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 143   no) LYX_ERROR(dnl
 144 [Cannot find X window libraries and/or headers. Check your installation.
 145   If you use a Linux system, check that you have installed
 146   the development tools.]);;
 147   disable) ;;
 148 esac
 149
 150 ### check which frontend we want to use
 151
 152 dnl if the gtk frontend has been specified, then xforms is needed too
 153 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 154   FRONTENDS="xforms $FRONTENDS"
 155 fi
 156
 157 dnl The code below is not in a macro, because this would cause big
 158 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 159 for frontend in $FRONTENDS ; do
 160   case "$frontend" in
 161     xforms)
 162           XFORMS_DO_IT_ALL
 163           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 164           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 165           RPM_FRONTEND="xforms"
 166           FRONTEND_INFO="${FRONTEND_INFO}\
 167   XForms Frontend:\n\
 168       libXpm version:\t\t${XPM_VERSION}\n\
 169       libforms version:\t\t${XFORMS_VERSION}\n"
 170           ;;
 171   dnl   gnome)
 172   dnl     XFORMS_DO_IT_ALL
 173   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 174   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 175   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 176
 177   dnl     FRONTEND="xforms gnome"
 178   dnl     FRONTEND_GUILIB="gnome/*.lo"
 179   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 180   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 181   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 182   dnl   ;;
 183     gtk)
 184           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 185           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 186           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 187           RPM_FRONTEND="gtk"
 188           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 189           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 190           FRONTEND_INFO="${FRONTEND_INFO}\
 191   GTK Frontend:\n\
 192     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 193     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 194           ;;
 195
 196     qt)
 197           QT_DO_IT_ALL
 198           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 199           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 200           RPM_FRONTEND="qt"
 201           FRONTEND_INFO="${FRONTEND_INFO}\
 202   Qt Frontend:\n\
 203       Qt version:\t\t${QT_VERSION}\n"
 204 dnl qt build will fail without moc or uic
 205           if test -z "$MOC"; then
 206             LYX_ERROR([moc binary not found !])
 207           fi
 208           if test -z "$UIC"; then
 209             LYX_ERROR([uic binary not found !])
 210           fi
 211       ;;
 212     *)
 213           LYX_ERROR(Unknown frontend '$frontend');;
 214   esac
 215 done
 216
 217 ### Check how the files should be packaged
 218 LYX_USE_PACKAGING
 219 # fix the value of the prefixes.
 220 test "x$prefix" = xNONE && prefix=$default_prefix
 221 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 222 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 223   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 224    causes problems with the Makefiles. The installation will be done in
 225    directory \"`pwd`/installprefix\" instead. Please move its contents to
 226    the right place after installation.])
 227   prefix=`pwd`/installprefix
 228 fi
 229
 230 ### Setup GNU gettext
 231 dnl GNU gettext is written in C
 232 AC_LANG_PUSH(C)
 233 AM_GNU_GETTEXT
 234 AC_LANG_POP(C)
 235
 236 # some standard header files
 237 AC_HEADER_DIRENT
 238 AC_HEADER_MAJOR
 239 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 240
 241 # some standard structures
 242 AC_HEADER_STAT
 243 AC_HEADER_TIME
 244
 245 # some standard types
 246 AC_TYPE_MODE_T
 247 AC_TYPE_OFF_T
 248 AC_TYPE_PID_T
 249 AC_TYPE_SIGNAL
 250 AC_TYPE_SIZE_T
 251 AC_TYPE_UID_T
 252
 253 AC_CHECK_FUNCS(strerror)
 254 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 255 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 256
 257 # Check the form of mkdir()
 258 AC_FUNC_MKDIR
 259
 260 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 261     case "${enableval}" in
 262         yes) use_compression=true ;;
 263         no) use_compression=false ;;
 264         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 265     esac
 266 ],[use_compression=true])
 267 if test $use_compression=true ; then
 268         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 269         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 270         if test $use_compression = true ; then
 271                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 272                 lyx_flags="$lyx_flags compression"
 273         fi
 274 fi
 275 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 276 AC_MSG_CHECKING([whether to support compressed files])
 277 AC_MSG_RESULT($use_compression)
 278
 279
 280 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 281 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 282 dnl We aim to remove this eventually, since we should test as much as
 283 dnl possible with the compiler which will use the functions (JMarc)
 284 AC_LANG_PUSH(C)
 285 AC_CHECK_FUNCS(mkfifo mkstemp mktemp lstat readlink)
 286 AC_LANG_POP(C)
 287
 288 LYX_CHECK_SPELL_ENGINES
 289
 290 lyx_client_subdir=true
 291 AC_LANG_PUSH(C)
 292 AC_CHECK_FUNCS(fcntl,, [lyx_client_subdir=false])
 293 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 294 AC_LANG_POP(C)
 295
 296
 297 AC_FUNC_SELECT_ARGTYPES
 298
 299 ### Some information on what just happened
 300 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 301 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 302 VERSION_INFO="Configuration\n\
 303   Host type:                      ${host}\n\
 304   Special build flags:           ${lyx_flags}\n\
 305   C   Compiler:                   ${CC}\n\
 306   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 307   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 308   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 309   Linker flags:                   ${LDFLAGS}\n\
 310 ${FRONTEND_INFO}\
 311   Packaging:                      ${lyx_use_packaging}\n\
 312   LyX binary dir:                 ${real_bindir}\n\
 313   LyX files dir:                  ${real_datadir}\n"
 314
 315
 316 AC_SUBST(VERSION_INFO)
 317 AC_SUBST(RPM_FRONTEND)
 318
 319 ## Some config.h stuff
 320
 321 AH_TOP([
 322 /* -*- C++ -*- */
 323 /*
 324  * \file config.h
 325  * This file is part of LyX, the document processor.
 326  * Licence details can be found in the file COPYING.
 327  *
 328  * This is the compilation configuration file for LyX.
 329  * It was generated by autoconfs configure.
 330  * You might want to change some of the defaults if something goes wrong
 331  * during the compilation.
 332  */
 333
 334 #ifndef _CONFIG_H
 335 #define _CONFIG_H
 336 ])
 337
 338 AH_BOTTOM([
 339 /************************************************************
 340  ** You should not need to change anything beyond this point */
 341
 342 #ifndef HAVE_STRERROR
 343 #if defined(__cplusplus)
 344 extern "C"
 345 #endif
 346 char * strerror(int n);
 347 #endif
 348
 349 #ifdef HAVE_MKSTEMP
 350 #ifndef HAVE_DECL_MKSTEMP
 351 #if defined(__cplusplus)
 352 extern "C"
 353 #endif
 354 int mkstemp(char*);
 355 #endif
 356 #endif
 357
 358 #ifdef __EMX__
 359 #include "support/os2_defines.h"
 360 #endif
 361
 362 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 363 #define USE_BOOST_FORMAT 1
 364 #else
 365 #define USE_BOOST_FORMAT 0
 366 #endif
 367
 368 #define BOOST_USER_CONFIG <config.h>
 369
 370 #if defined(ENABLE_ASSERTIONS)
 371 #define BOOST_ENABLE_ASSERT_HANDLER 1
 372 #else
 373 #define BOOST_DISABLE_ASSERTS 1
 374 #endif
 375
 376 #define BOOST_DISABLE_THREADS 1
 377 #define BOOST_NO_WREGEX 1
 378 #define BOOST_NO_WSTRING 1
 379
 380 #ifdef __CYGWIN__
 381 #define BOOST_POSIX 1
 382 #endif
 383
 384 #endif
 385 ])
 386
 387 ### Finish the work.
 388 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 389 AC_CONFIG_FILES([Makefile  m4/Makefile \
 390        boost/Makefile \
 391        boost/libs/Makefile \
 392        boost/libs/filesystem/Makefile \
 393        boost/libs/filesystem/src/Makefile \
 394        boost/libs/regex/Makefile \
 395        boost/libs/regex/src/Makefile \
 396        boost/libs/signals/Makefile \
 397        boost/libs/signals/src/Makefile \
 398        config/Makefile \
 399        development/Makefile \
 400        development/lyx.spec \
 401        lib/Makefile \
 402        lib/doc/Makefile \
 403        intl/Makefile \
 404        po/Makefile.in \
 405        sourcedoc/Doxyfile \
 406        sourcedoc/Makefile \
 407        src/client/Makefile \
 408        src/Makefile \
 409        src/version.C-tmp:src/version.C.in \
 410        src/tex2lyx/Makefile \
 411        src/mathed/Makefile \
 412        src/graphics/Makefile \
 413        src/insets/Makefile \
 414        src/support/Makefile \
 415        src/support/tests/Makefile \
 416        src/frontends/Makefile \
 417        src/frontends/controllers/Makefile \
 418        src/frontends/xforms/Makefile \
 419        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 420        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 421        src/frontends/xforms/forms/Makefile \
 422        src/frontends/gtk/Makefile \
 423        src/frontends/gtk/gimages/Makefile \
 424        src/frontends/gtk/glade/Makefile \
 425        src/frontends/qt2/Makefile \
 426        src/frontends/qt2/moc/Makefile \
 427        src/frontends/qt2/ui/Makefile \
 428        src/frontends/qt2/ui/moc/Makefile \
 429 ])
 430
 431 AC_OUTPUT
 432 # show version information
 433 echo
 434 printf "$VERSION_INFO"
 435 echo
 436
 437 # Display a final warning if there has been a LYX_ERROR
 438 LYX_CHECK_ERRORS