configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.1.0svn,[lyx-devel@lists.lyx.org],[lyx])
   4 # Use ISO format only. The frontend needs to parse this
   5 AC_SUBST(LYX_DATE, ["2011-04-29"])
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.cpp)
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AC_CONFIG_AUX_DIR(config)
  11
  12 # First check the version
  13 LYX_CHECK_VERSION
  14 LYX_VERSION_SUFFIX
  15 # Check how the files should be packaged
  16 AC_CANONICAL_TARGET
  17 LYX_USE_PACKAGING
  18 # We need to define these variables here and the no-define option of
  19 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  20 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  21
  22 dnl Default maintainer mode to true for development versions
  23 if test "${enable_maintainer_mode+set}" != set; then
  24   enable_maintainer_mode=$lyx_devel_version
  25 fi
  26 AM_MAINTAINER_MODE
  27
  28 save_PACKAGE=$PACKAGE
  29 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8])
  30 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  31 PACKAGE=$save_PACKAGE
  32
  33 # Allow to build some parts of the code as one big chunk
  34 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt4])
  35 AC_ARG_ENABLE(monolithic-build,
  36   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  37                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  38   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  39    test "$enable_monolithic_build" = no && enable_monolithic_build=
  40    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  41    for i in $enable_monolithic_build ; do
  42        eval "enable_monolithic_$i=yes"
  43    done
  44    IFS="$ac_save_ifs"],
  45   [enable_monolithic_build=])
  46
  47 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  48 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  49 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  50 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  51 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  52 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  53 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT4, test "x$enable_monolithic_frontend_qt4" = "xyes")
  54
  55 ### Set the execute permissions of the various scripts correctly
  56 for file in config/install-sh ; do
  57   chmod 755 ${srcdir}/${file}
  58 done
  59
  60 # Check for installed python
  61 AM_PATH_PYTHON(2.3.4,, :)
  62
  63 ### we need to know the byte order for unicode conversions
  64 AC_C_BIGENDIAN
  65
  66 ### check which frontend we want to use
  67 LYX_USE_FRONTENDS
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71
  72 ### Objective-C compiler
  73 AC_PROG_OBJC
  74 _AM_DEPENDENCIES([OBJC])
  75
  76 ### Add extra directories to check for libraries.
  77 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  78 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  79 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  80
  81 ### Add extra directories to check for include files.
  82 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  83 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  84 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  85
  86 ### Add both includes and libraries
  87 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  88 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  89 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  90   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  91
  92 ### These are needed in windows
  93 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  94 AC_SUBST(LIBSHLWAPI)
  95 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  96 AC_SUBST(LIBPSAPI)
  97 AC_CHECK_LIB(gdi32, main)
  98
  99 LYX_USE_INCLUDED_BOOST
 100 LYX_USE_INCLUDED_MYTHES
 101
 102 # Needed for our char_type
 103 AC_CHECK_SIZEOF(wchar_t)
 104
 105 ### We need iconv for unicode support (Qt4 frontend requires it too)
 106 AM_ICONV
 107 if test "$am_cv_func_iconv" = no; then
 108   LYX_ERROR([Cannot find required library iconv])
 109 else
 110   LIBS="$LIBS $LIBICONV"
 111 fi
 112
 113 ### check for compression support
 114 AC_CHECK_HEADERS(zlib.h,
 115  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 116  [LYX_LIB_ERROR(zlib.h,zlib)])
 117
 118
 119 ### check which frontend we want to use
 120
 121 dnl The code below is not in a macro, because this would cause big
 122 dnl problems with the AC_REQUIRE contained in QT4_DO_IT_ALL.
 123 for frontend in $FRONTENDS ; do
 124   case "$frontend" in
 125     qt4)
 126           QT4_DO_IT_ALL
 127           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
 128           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
 129           RPM_FRONTEND="qt4"
 130           FRONTEND_INFO="${FRONTEND_INFO}\
 131   Qt 4 Frontend:\n\
 132       Qt 4 version:\t\t${QT4_VERSION}\n"
 133 dnl qt 4 build will fail without moc or uic
 134           if test -z "$MOC4"; then
 135             LYX_ERROR([moc 4 binary not found !])
 136           fi
 137           if test -z "$UIC4"; then
 138             LYX_ERROR([uic 4 binary not found !])
 139           fi
 140           if test -z "$QT4_LIB"; then
 141             LYX_ERROR([qt 4 library not found !])
 142           fi
 143       ;;
 144     *)
 145           LYX_ERROR(Unknown frontend '$frontend');;
 146   esac
 147 done
 148
 149 # fix the value of the prefixes.
 150 test "x$prefix" = xNONE && prefix=$default_prefix
 151 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 152 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 153   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 154    causes problems with the Makefiles. The installation will be done in
 155    directory \"`pwd`/installprefix\" instead. Please move its contents to
 156    the right place after installation.])
 157   prefix=`pwd`/installprefix
 158 fi
 159
 160 ### Setup GNU gettext
 161 dnl GNU gettext is written in C
 162 AC_LANG_PUSH(C)
 163 dnl Dirty trick ahead: disable macro AC_GNU_SOURCE because it triggers a bug with autoconf 2.62.
 164 dnl this can be removed if gettext is been updated to avoid that.
 165 m4_undefine([AC_GNU_SOURCE])
 166 m4_defun([AC_GNU_SOURCE],[])
 167 AM_GNU_GETTEXT([no-libtool])
 168 AM_GNU_GETTEXT_VERSION([0.16.1])
 169 AC_LANG_POP(C)
 170
 171 # some standard header files
 172 AC_HEADER_MAJOR
 173 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 174
 175 # some standard structures
 176 AC_HEADER_STAT
 177 AC_HEADER_TIME
 178
 179 # some standard types
 180 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 181 AC_TYPE_OFF_T
 182 AC_TYPE_PID_T
 183 AC_TYPE_SIGNAL
 184 AC_TYPE_SIZE_T
 185 AC_TYPE_UID_T
 186
 187 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 188
 189 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lstat mkfifo open _open pclose _pclose popen _popen readlink strerror)
 190 # Check the form of mkdir()
 191 AC_FUNC_MKDIR
 192 AC_FUNC_SELECT_ARGTYPES
 193
 194 LYX_CHECK_SPELL_ENGINES
 195
 196 lyx_client_subdir=true
 197 AC_LANG_PUSH(C)
 198 dnl LIBS already contains some X extra libs that may interfere.
 199 save_LIBS="$LIBS"
 200 LIBS=
 201 AC_CHECK_FUNCS(fcntl,
 202   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 203    AC_SEARCH_LIBS([socket], [socket], [],
 204      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 205                 [], [-lnsl])])],
 206   [lyx_client_subdir=false])
 207 AC_SUBST(SOCKET_LIBS,$LIBS)
 208 LIBS="$save_LIBS"
 209 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 210 AC_LANG_POP(C)
 211
 212 lyx_win_res=false;
 213 case ${host} in
 214     *mingw*|*cygwin*) lyx_win_res=true;;
 215 esac
 216 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 217 LYX_SET_VERSION_INFO
 218
 219
 220 ### Some information on what just happened
 221 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 222 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 223 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 224 VERSION_INFO="Configuration\n\
 225   Host type:                    ${host}\n\
 226   Special build flags:         ${lyx_flags}\n\
 227   C   Compiler:                 ${CC} ${CC_VERSION}\n\
 228   C   Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 229   C   Compiler flags:           ${CPPFLAGS} ${CFLAGS}\n\
 230   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 231   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 232   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 233   Linker flags:                 ${AM_LDFLAGS}\n\
 234   Linker user flags:            ${LDFLAGS}\n\
 235 ${FRONTEND_INFO}\
 236   Packaging:                    ${lyx_use_packaging}\n\
 237   LyX binary dir:               ${real_bindir}\n\
 238   LyX files dir:                ${real_pkgdatadir}\n"
 239
 240 AC_SUBST(VERSION_INFO)
 241 AC_SUBST(RPM_FRONTEND)
 242 AC_SUBST(AM_CPPFLAGS)
 243 AC_SUBST(AM_CXXFLAGS)
 244 AC_SUBST(AM_CFLAGS)
 245 AC_SUBST(AM_LDFLAGS)
 246 AC_SUBST(real_pkgdatadir)
 247
 248 ## Some config.h stuff
 249
 250 AH_TOP([
 251 /* -*- C++ -*- */
 252 /*
 253  * \file config.h
 254  * This file is part of LyX, the document processor.
 255  * Licence details can be found in the file COPYING.
 256  *
 257  * This is the compilation configuration file for LyX.
 258  * It was generated by autoconfs configure.
 259  * You might want to change some of the defaults if something goes wrong
 260  * during the compilation.
 261  */
 262
 263 #ifndef _CONFIG_H
 264 #define _CONFIG_H
 265 ])
 266
 267 AH_BOTTOM([
 268 /************************************************************
 269  ** You should not need to change anything beyond this point */
 270
 271 #ifndef HAVE_STRERROR
 272 #if defined(__cplusplus)
 273 extern "C"
 274 #endif
 275 char * strerror(int n);
 276 #endif
 277
 278 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 279 #  define USE_BOOST_FORMAT 1
 280 #else
 281 #  define USE_BOOST_FORMAT 0
 282 #endif
 283
 284 #define BOOST_USER_CONFIG <config.h>
 285
 286 #if !defined(ENABLE_ASSERTIONS)
 287 #  define BOOST_DISABLE_ASSERTS 1
 288 #endif
 289 #define BOOST_ENABLE_ASSERT_HANDLER 1
 290
 291 #define BOOST_DISABLE_THREADS 1
 292 #define BOOST_NO_WREGEX 1
 293 #define BOOST_NO_WSTRING 1
 294
 295 // TR1 regex not supported in GCC <= 4.5
 296 #ifndef LYX_USE_TR1
 297 #  if __GNUC__ == 4
 298 #    define LYX_USE_TR1
 299 #  endif
 300 #endif
 301
 302 #ifdef __CYGWIN__
 303 #  define NOMINMAX
 304 #  define BOOST_POSIX 1
 305 #  define BOOST_POSIX_API 1
 306 #  define BOOST_POSIX_PATH 1
 307 #endif
 308
 309 /*
 310  * the FreeBSD libc uses UCS4, but libstdc++ has no proper wchar_t
 311  * support compiled in:
 312  * http://gcc.gnu.org/onlinedocs/libstdc++/faq/index.html#3_9
 313  * And we are not interested at all what libc
 314  * does: What we need is a 32bit wide wchar_t, and a libstdc++ that
 315  * has the needed wchar_t support and uses UCS4. Whether it
 316  * implements this with the help of libc, or whether it has own code
 317  * does not matter for us, because we do not use libc directly (Georg)
 318 */
 319 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4 && !defined(__FreeBSD__) && !defined(__FreeBSD_kernel__)
 320 #  define USE_WCHAR_T
 321 #endif
 322
 323 #endif
 324 ])
 325
 326 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 327 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 328 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 329
 330 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 331         "${lyx_abs_top_srcdir}", [Top source directory])
 332 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 333         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 334 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 335         "${lyx_abs_installed_datadir}",[Hard system support directory])
 336 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 337         "${version_suffix}",[Program version suffix])
 338
 339 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 340 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 341 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 342 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 343 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 344 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 345 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 346 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 347
 348 AC_CONFIG_FILES([Makefile \
 349       lyx.1:lyx.1in \
 350       boost/Makefile \
 351       config/Makefile \
 352       development/Makefile \
 353       development/MacOSX/Makefile \
 354       development/MacOSX/Info.plist \
 355       development/MacOSX/lyxrc.dist \
 356       development/MacOSX/spotlight/Makefile \
 357       development/cygwin/Makefile \
 358       development/cygwin/lyxrc.dist \
 359       development/lyx.spec \
 360       intl/Makefile \
 361       lib/Makefile \
 362       lib/doc/Makefile \
 363       lib/lyx2lyx/lyx2lyx_version.py \
 364       lib/lyx2lyx/Makefile \
 365       m4/Makefile \
 366       po/Makefile.in \
 367       sourcedoc/Doxyfile \
 368       sourcedoc/Makefile \
 369       src/client/Makefile \
 370       src/client/lyxclient.1:src/client/lyxclient.1in \
 371       src/Makefile \
 372       src/tex2lyx/Makefile \
 373       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 374       src/support/Makefile \
 375       src/frontends/Makefile \
 376       src/frontends/qt4/Makefile
 377 ])
 378
 379
 380 AC_OUTPUT
 381
 382 # show version information
 383 echo
 384 printf "$VERSION_INFO"
 385 echo
 386
 387 # Display a final warning if there has been a LYX_ERROR
 388 LYX_CHECK_ERRORS