configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 ### Set the execute permissions of the various scripts correctly
  26 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  27   chmod 755 ${srcdir}/${file}
  28 done
  29
  30 ### Check for programs
  31 AC_PROG_MAKE_SET
  32 AC_PROG_INSTALL
  33
  34 AC_SUBST(AWK,[gawk])
  35
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  43
  44 # Check for installed python
  45 AM_PATH_PYTHON(1.5.2,, :)
  46
  47 # Work around a problem in automake 1.4: when invoking install-strip,
  48 # INSTALL_PROGRAM is changed to 'install -s', and since
  49 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  50 # which returns an error condition when stripping fails.
  51 INSTALL_SCRIPT='${INSTALL}'
  52
  53 ### we will also need a C compiler to compile GNU gettext
  54 AC_PROG_CC
  55
  56 ### check for special systems
  57 AC_ISC_POSIX
  58 AC_AIX
  59
  60 ### check which frontend we want to use
  61 LYX_USE_FRONTENDS
  62
  63 ### Check for a C++ compiler
  64 LYX_PROG_CXX
  65 ### Some checks on what the C++ compiler can(not) do
  66 AC_LANG(C++)
  67 dnl we do not need that currently (and probably all our supported
  68 dnl compiler allow that)
  69 dnl LYX_CXX_PARTIAL
  70 LYX_CXX_EXPLICIT
  71 LYX_CXX_GLOBAL_CSTD
  72 LYX_STD_COUNT
  73 dnl we disable rtti for now
  74 dnl LYX_CXX_RTTI
  75 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  76 LYX_CXX_STL_MODERN_STREAMS
  77
  78 ### and now some special lyx flags.
  79 AC_ARG_ENABLE(assertions,
  80   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  81   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  82         enable_assertions=yes;
  83     else
  84         enable_assertions=no;
  85     fi;])
  86 if test "x$enable_assertions" = xyes ; then
  87    lyx_flags="assertions $lyx_flags"
  88    AC_DEFINE(ENABLE_ASSERTIONS,1,
  89     [Define if you want assertions to be enabled in the code])
  90 fi
  91
  92 ### Library Files
  93 dnl by testing these we check if it is ok to have
  94 dnl -lc and -lm as args to the compiler
  95 AC_CHECK_LIB(m, sin)
  96 AC_CHECK_LIB(c, fopen)
  97
  98 ### Add extra directories to check for libraries.
  99 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 100 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 101 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 102
 103 ### Add extra directories to check for include files.
 104 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 105 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 106 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 107
 108 ### Add both includes and libraries
 109 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 110 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 111 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 112   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 113
 114 AC_ARG_WITH(aiksaurus,
 115   [  --without-aiksaurus     do not use the Aiksaurus library],
 116   [lyx_use_aiksaurus=$withval])
 117 if test x$lyx_use_aiksaurus != xno; then
 118 AC_CHECK_LIB(Aiksaurus, main,
 119         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 120          AIKSAURUS_LIBS="-lAiksaurus"
 121          lyx_flags="aiksaurus $lyx_flags"
 122         ])
 123 AC_CHECK_HEADER(Aiksaurus.h,[
 124   ac_cv_header_aiksaurus_h=yes
 125   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 126 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 127   ac_cv_header_aiksaurus_h=yes
 128   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 129 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 130 fi
 131 AC_SUBST(AIKSAURUS_LIBS)
 132
 133 LYX_USE_INCLUDED_BOOST
 134
 135 ### Setup libtool
 136 AC_DISABLE_SHARED
 137 AC_LIBTOOL_WIN32_DLL
 138 #AM_PROG_LIBTOOL
 139 LYX_PROG_LIBTOOL
 140
 141 ### Check for some Cygwin-specific details.
 142 CHECK_WITH_CYGWIN
 143
 144 ### Check for X libraries
 145 AC_PATH_XTRA
 146 case $have_x in
 147   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 148        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 149   no) LYX_ERROR(dnl
 150 [Cannot find X window libraries and/or headers. Check your installation.
 151   If you use a Linux system, check that you have installed
 152   the development tools.]);;
 153   disable) ;;
 154 esac
 155
 156 ### check which frontend we want to use
 157
 158 dnl if the gtk frontend has been specified, then xforms is needed too
 159 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 160   FRONTENDS="xforms $FRONTENDS"
 161   noxformsbin=yes
 162 fi
 163
 164 dnl The code below is not in a macro, because this would cause big
 165 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 166 for frontend in $FRONTENDS ; do
 167   case "$frontend" in
 168     xforms)
 169           XFORMS_DO_IT_ALL
 170           if test -z "$noxformsbin" ; then
 171             FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 172           fi
 173           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 174           RPM_FRONTEND="xforms"
 175           FRONTEND_INFO="${FRONTEND_INFO}\
 176   XForms Frontend:\n\
 177       libXpm version:\t\t${XPM_VERSION}\n\
 178       libforms version:\t\t${XFORMS_VERSION}\n"
 179           ;;
 180   dnl   gnome)
 181   dnl     XFORMS_DO_IT_ALL
 182   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 183   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 184   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 185
 186   dnl     FRONTEND="xforms gnome"
 187   dnl     FRONTEND_GUILIB="gnome/*.lo"
 188   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 189   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 190   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 191   dnl   ;;
 192     gtk)
 193           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 194           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 195           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 196           RPM_FRONTEND="gtk"
 197           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 198           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 199           FRONTEND_INFO="${FRONTEND_INFO}\
 200   GTK Frontend:\n\
 201     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 202     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 203           ;;
 204
 205     qt)
 206           QT_DO_IT_ALL
 207           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 208           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 209           RPM_FRONTEND="qt"
 210           FRONTEND_INFO="${FRONTEND_INFO}\
 211   Qt Frontend:\n\
 212       Qt version:\t\t${QT_VERSION}\n"
 213 dnl qt build will fail without moc or uic
 214           if test -z "$MOC"; then
 215             LYX_ERROR([moc binary not found !])
 216           fi
 217           if test -z "$UIC"; then
 218             LYX_ERROR([uic binary not found !])
 219           fi
 220       ;;
 221     *)
 222           LYX_ERROR(Unknown frontend '$frontend');;
 223   esac
 224 done
 225
 226 ### Check how the files should be packaged
 227 LYX_USE_PACKAGING
 228 # fix the value of the prefixes.
 229 test "x$prefix" = xNONE && prefix=$default_prefix
 230 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 231 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 232   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 233    causes problems with the Makefiles. The installation will be done in
 234    directory \"`pwd`/installprefix\" instead. Please move its contents to
 235    the right place after installation.])
 236   prefix=`pwd`/installprefix
 237 fi
 238
 239 ### Setup GNU gettext
 240 dnl GNU gettext is written in C
 241 AC_LANG_PUSH(C)
 242 AM_GNU_GETTEXT
 243 AC_LANG_POP(C)
 244
 245 # some standard header files
 246 AC_HEADER_DIRENT
 247 AC_HEADER_MAJOR
 248 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h)
 249
 250 # some standard structures
 251 AC_HEADER_STAT
 252 AC_HEADER_TIME
 253
 254 # some standard types
 255 AC_TYPE_MODE_T
 256 AC_TYPE_OFF_T
 257 AC_TYPE_PID_T
 258 AC_TYPE_SIGNAL
 259 AC_TYPE_SIZE_T
 260 AC_TYPE_UID_T
 261
 262 AC_CHECK_FUNCS(strerror)
 263 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 264 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 265
 266 # Check the form of mkdir()
 267 AC_FUNC_MKDIR
 268
 269 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 270     case "${enableval}" in
 271         yes) use_compression=true ;;
 272         no) use_compression=false ;;
 273         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 274     esac
 275 ],[use_compression=true])
 276 if test $use_compression=true ; then
 277         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 278         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 279         if test $use_compression = true ; then
 280                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 281                 lyx_flags="compression $lyx_flags"
 282         fi
 283 fi
 284 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 285 AC_MSG_CHECKING([whether to support compressed files])
 286 AC_MSG_RESULT($use_compression)
 287
 288
 289 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 290 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 291 dnl We aim to remove this eventually, since we should test as much as
 292 dnl possible with the compiler which will use the functions (JMarc)
 293 AC_LANG_PUSH(C)
 294 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 295 AC_LANG_POP(C)
 296
 297 LYX_CHECK_SPELL_ENGINES
 298
 299 lyx_client_subdir=true
 300 AC_LANG_PUSH(C)
 301 AC_CHECK_FUNCS(fcntl,, [lyx_client_subdir=false])
 302 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 303 AC_LANG_POP(C)
 304
 305
 306 AC_FUNC_SELECT_ARGTYPES
 307
 308 ### Some information on what just happened
 309 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 310 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 311 VERSION_INFO="Configuration\n\
 312   Host type:                      ${host}\n\
 313   Special build flags:            ${lyx_flags}\n\
 314   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 315   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 316   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 317   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 318   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 319   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 320   Linker flags:                   ${AM_LDFLAGS}\n\
 321   Linker user flags:              ${LDFLAGS}\n\
 322 ${FRONTEND_INFO}\
 323   Packaging:                      ${lyx_use_packaging}\n\
 324   LyX binary dir:                 ${real_bindir}\n\
 325   LyX files dir:                  ${real_datadir}\n"
 326
 327
 328 AC_SUBST(VERSION_INFO)
 329 AC_SUBST(RPM_FRONTEND)
 330 AC_SUBST(AM_CPPFLAGS)
 331 AC_SUBST(AM_CXXFLAGS)
 332 AC_SUBST(AM_CFLAGS)
 333 AC_SUBST(AM_LDFLAGS)
 334
 335 ## Some config.h stuff
 336
 337 AH_TOP([
 338 /* -*- C++ -*- */
 339 /*
 340  * \file config.h
 341  * This file is part of LyX, the document processor.
 342  * Licence details can be found in the file COPYING.
 343  *
 344  * This is the compilation configuration file for LyX.
 345  * It was generated by autoconfs configure.
 346  * You might want to change some of the defaults if something goes wrong
 347  * during the compilation.
 348  */
 349
 350 #ifndef _CONFIG_H
 351 #define _CONFIG_H
 352 ])
 353
 354 AH_BOTTOM([
 355 /************************************************************
 356  ** You should not need to change anything beyond this point */
 357
 358 #ifndef HAVE_STRERROR
 359 #if defined(__cplusplus)
 360 extern "C"
 361 #endif
 362 char * strerror(int n);
 363 #endif
 364
 365 #ifdef HAVE_MKSTEMP
 366 #ifndef HAVE_DECL_MKSTEMP
 367 #if defined(__cplusplus)
 368 extern "C"
 369 #endif
 370 int mkstemp(char*);
 371 #endif
 372 #endif
 373
 374 #ifdef __EMX__
 375 #include "support/os2_defines.h"
 376 #endif
 377
 378 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 379 #define USE_BOOST_FORMAT 1
 380 #else
 381 #define USE_BOOST_FORMAT 0
 382 #endif
 383
 384 #define BOOST_USER_CONFIG <config.h>
 385
 386 #if defined(ENABLE_ASSERTIONS)
 387 #define BOOST_ENABLE_ASSERT_HANDLER 1
 388 #else
 389 #define BOOST_DISABLE_ASSERTS 1
 390 #endif
 391
 392 #define BOOST_DISABLE_THREADS 1
 393 #define BOOST_NO_WREGEX 1
 394 #define BOOST_NO_WSTRING 1
 395
 396 #ifdef __CYGWIN__
 397 #define BOOST_POSIX 1
 398 #endif
 399
 400 #endif
 401 ])
 402
 403 ### Finish the work.
 404 AC_CONFIG_SUBDIRS(lib)
 405 AC_CONFIG_FILES([Makefile  m4/Makefile \
 406        boost/Makefile \
 407        boost/libs/Makefile \
 408        boost/libs/filesystem/Makefile \
 409        boost/libs/filesystem/src/Makefile \
 410        boost/libs/regex/Makefile \
 411        boost/libs/regex/src/Makefile \
 412        boost/libs/signals/Makefile \
 413        boost/libs/signals/src/Makefile \
 414        config/Makefile \
 415        development/Makefile \
 416        development/lyx.spec \
 417        lib/Makefile \
 418        lib/doc/Makefile \
 419        lib/lyx2lyx/Makefile \
 420        intl/Makefile \
 421        po/Makefile.in \
 422        sourcedoc/Doxyfile \
 423        sourcedoc/Makefile \
 424        src/client/Makefile \
 425        src/Makefile \
 426        src/version.C-tmp:src/version.C.in \
 427        src/tex2lyx/Makefile \
 428        src/mathed/Makefile \
 429        src/graphics/Makefile \
 430        src/insets/Makefile \
 431        src/support/Makefile \
 432        src/support/tests/Makefile \
 433        src/frontends/Makefile \
 434        src/frontends/controllers/Makefile \
 435        src/frontends/xforms/Makefile \
 436        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 437        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 438        src/frontends/xforms/forms/Makefile \
 439        src/frontends/gtk/Makefile \
 440        src/frontends/gtk/gimages/Makefile \
 441        src/frontends/gtk/glade/Makefile \
 442        src/frontends/qt2/Makefile \
 443        src/frontends/qt2/moc/Makefile \
 444        src/frontends/qt2/ui/Makefile \
 445        src/frontends/qt2/ui/moc/Makefile \
 446 ])
 447
 448 AC_OUTPUT
 449 # show version information
 450 echo
 451 printf "$VERSION_INFO"
 452 echo
 453
 454 # Display a final warning if there has been a LYX_ERROR
 455 LYX_CHECK_ERRORS