configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.4dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5
   6 # Use ISO format only. The frontend needs to parse this
   7 AC_SUBST(LYX_DATE, ["2017-05-15"])
   8 AC_PREREQ(2.60)
   9 AC_CONFIG_SRCDIR(src/main.cpp)
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 # First check the version
  15 LYX_CHECK_VERSION
  16 LYX_VERSION_SUFFIX
  17 LYX_CHECK_QT5
  18 # Check how the files should be packaged
  19 AC_CANONICAL_TARGET
  20 LYX_USE_PACKAGING
  21 # We need to define these variables here and the no-define option of
  22 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  23 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  24
  25 dnl Default maintainer mode to true for development versions
  26 if test "${enable_maintainer_mode+set}" != set; then
  27   enable_maintainer_mode=$lyx_devel_version
  28 fi
  29 AM_MAINTAINER_MODE
  30
  31 save_PACKAGE=$PACKAGE
  32 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  33 dnl which are the versions where subdir-objects can beused.
  34 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  35 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  36 # Automake is pulling the historical V7 format. This tar format supports
  37 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  38 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  39 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  40 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  41 PACKAGE=$save_PACKAGE
  42
  43 # Allow to build some parts of the code as one big chunk
  44 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  45 AC_ARG_ENABLE(monolithic-build,
  46   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  47                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  48   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  49    test "$enable_monolithic_build" = no && enable_monolithic_build=
  50    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  51    for i in $enable_monolithic_build ; do
  52        eval "enable_monolithic_$i=yes"
  53    done
  54    IFS="$ac_save_ifs"],
  55   [enable_monolithic_build=])
  56
  57 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  63 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  64
  65 ### Set the execute permissions of the various scripts correctly
  66 for file in config/install-sh ; do
  67   chmod 755 ${srcdir}/${file}
  68 done
  69
  70 # Find a suitable python interpreter
  71 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  72 # do the usual python setup stuff
  73 AM_PATH_PYTHON
  74
  75 # Tools for creating libraries (note that we do not use libtool)
  76 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  77 AC_PROG_RANLIB
  78 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  79 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  80 AC_SUBST([ARFLAGS], [cr])
  81
  82 ### Check for a C++ compiler
  83 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  84 dnl if it is not set. We do not use autoconf defaults.
  85 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  86 if ! test "$lyx_has_CXXFLAGS" = yes; then
  87   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  88   CXXFLAGS=" "
  89 fi
  90 LYX_PROG_CXX
  91 if ! test "$lyx_has_CXXFLAGS" = yes; then
  92   unset CXXFLAGS
  93 fi
  94 AC_LANG(C++)
  95
  96 ### Objective-C compiler
  97 AC_PROG_OBJC
  98 _AM_DEPENDENCIES([OBJC])
  99
 100 ### Add extra directories to check for libraries.
 101 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 103 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 104
 105 ### Add extra directories to check for include files.
 106 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 107 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 108 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 109
 110 ### Add both includes and libraries
 111 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 112 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 113   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 114   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 115 ])
 116
 117 ### These are needed in windows
 118 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 119 AC_SUBST(LIBSHLWAPI)
 120 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 121 AC_SUBST(LIBPSAPI)
 122 AC_CHECK_LIB(gdi32, main)
 123
 124 LYX_USE_INCLUDED_BOOST
 125 LYX_USE_INCLUDED_MYTHES
 126
 127 ### we need to know the byte order for unicode conversions
 128 AC_C_BIGENDIAN
 129
 130 # Nice to have when an assertion triggers
 131 LYX_CHECK_CALLSTACK_PRINTING
 132
 133 # Needed for our char_type
 134 AC_CHECK_SIZEOF(wchar_t)
 135
 136 ### We need iconv for unicode support (Qt4 frontend requires it too)
 137 AM_ICONV
 138 if test "$am_cv_func_iconv" = no; then
 139   AC_MSG_ERROR([cannot find required library iconv.])
 140 else
 141   LIBS="$LIBS $LIBICONV"
 142 fi
 143
 144 ### check for compression support
 145 AC_CHECK_HEADERS(zlib.h,
 146  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 147  [LYX_LIB_ERROR(zlib.h,zlib)])
 148
 149 ### check for file magic support (currently optional)
 150 AC_CHECK_HEADERS(magic.h,
 151  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 152   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 153    is correctly installed on your system.
 154    Falling back to builtin file format detection.]))],
 155  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 156    is correctly installed on your system.
 157    Falling back to builtin file format detection.])])
 158
 159 ### setup the qt frontend.
 160 dnl The code below is not in a macro, because this would cause big
 161 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 162 QT_DO_IT_ALL([4.5.0])
 163 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 164 FRONTEND_INFO="${FRONTEND_INFO}\
 165   Qt Frontend:\n\
 166       Qt version:\t   ${QTLIB_VERSION}\n"
 167
 168 # fix the value of the prefixes.
 169 test "x$prefix" = xNONE && prefix=$default_prefix
 170 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 171 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 172   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 173    causes problems with the Makefiles. The installation will be done in
 174    directory \"`pwd`/installprefix\" instead. Please move its contents to
 175    the right place after installation.])
 176   prefix=`pwd`/installprefix
 177 fi
 178
 179 ### Setup po directory
 180 AM_NLS
 181 if test $USE_NLS = "yes" ; then
 182   AC_DEFINE(ENABLE_NLS, 1,
 183     [Define to 1 if translation of program messages to the user's native language
 184    is requested.])dnl'
 185 fi
 186 AM_PO_SUBDIRS
 187
 188 # some standard header files
 189 AC_HEADER_MAJOR
 190 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 191
 192 # some standard types
 193 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 194 AC_TYPE_OFF_T
 195 AC_TYPE_PID_T
 196 AC_TYPE_SIZE_T
 197 AC_TYPE_UID_T
 198 # Taken from gettext
 199 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 200    [AC_TRY_COMPILE([#include <stddef.h>
 201       wchar_t foo = (wchar_t)'\0';], ,
 202       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 203 if test $gt_cv_c_wchar_t = yes; then
 204   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 205 fi
 206
 207 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 208
 209 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 210 # Check the form of mkdir()
 211 AC_FUNC_MKDIR
 212 AC_FUNC_SELECT_ARGTYPES
 213
 214 LYX_CHECK_SPELL_ENGINES
 215
 216 lyx_client_subdir=true
 217 dnl AC_LANG_PUSH(C)
 218 dnl LIBS already contains some X extra libs that may interfere.
 219 save_LIBS="$LIBS"
 220 LIBS=
 221 AC_CHECK_FUNCS(fcntl,
 222   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 223    AC_SEARCH_LIBS([socket], [socket network], [],
 224      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 225                 [], [-lnsl])])],
 226   [lyx_client_subdir=false])
 227 AC_SUBST(SOCKET_LIBS,$LIBS)
 228 LIBS="$save_LIBS"
 229 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 230 dnl AC_LANG_POP(C)
 231
 232 lyx_win_res=false;
 233 case ${host} in
 234     *mingw*|*cygwin*) lyx_win_res=true;;
 235     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 236 esac
 237 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 238 LYX_SET_VERSION_INFO
 239
 240
 241 ### Some information on what just happened
 242 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 243 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 244 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 245 VERSION_INFO="Configuration\n\
 246   Host type:               ${host}\n\
 247   Special build flags:     ${lyx_flags}\n\
 248   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 249   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 250   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 251   Linker flags:            ${AM_LDFLAGS}\n\
 252   Linker user flags:       ${LDFLAGS}\n\
 253 ${FRONTEND_INFO}\
 254   Packaging:               ${lyx_use_packaging}\n\
 255   LyX binary dir:          ${real_bindir}\n\
 256   LyX files dir:           ${real_pkgdatadir}\n"
 257
 258 AC_SUBST(VERSION_INFO)
 259 AC_SUBST(AM_CPPFLAGS)
 260 AC_SUBST(AM_CXXFLAGS)
 261 AC_SUBST(AM_LDFLAGS)
 262 AC_SUBST(real_pkgdatadir)
 263
 264 ## Some config.h stuff
 265
 266 AH_TOP([
 267 /* -*- C++ -*- */
 268 /*
 269  * \file config.h
 270  * This file is part of LyX, the document processor.
 271  * Licence details can be found in the file COPYING.
 272  *
 273  * This is the compilation configuration file for LyX.
 274  * It was generated by autoconfs configure.
 275  * You might want to change some of the defaults if something goes wrong
 276  * during the compilation.
 277  */
 278
 279 #ifndef _CONFIG_H
 280 #define _CONFIG_H
 281 ])
 282
 283 AH_BOTTOM([
 284 /************************************************************
 285  ** You should not need to change anything beyond this point */
 286
 287 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 288 #define LYX_USE_CXX11
 289 #endif
 290
 291 #ifndef HAVE_STRERROR
 292 #if defined(__cplusplus)
 293 extern "C"
 294 #endif
 295 char * strerror(int n);
 296 #endif
 297
 298 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 299 #  define USE_BOOST_FORMAT 1
 300 #else
 301 #  define USE_BOOST_FORMAT 0
 302 #endif
 303
 304 #define BOOST_USER_CONFIG <config.h>
 305
 306 #if !defined(ENABLE_ASSERTIONS)
 307 #  define BOOST_DISABLE_ASSERTS 1
 308 #endif
 309 #define BOOST_ENABLE_ASSERT_HANDLER 1
 310
 311 #define BOOST_DISABLE_THREADS 1
 312 #define BOOST_NO_WREGEX 1
 313 #define BOOST_NO_WSTRING 1
 314 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 315
 316 #ifdef __CYGWIN__
 317 #  define NOMINMAX
 318 #  define BOOST_POSIX 1
 319 #  define BOOST_POSIX_API 1
 320 #  define BOOST_POSIX_PATH 1
 321 #endif
 322
 323 #ifdef __sparc__
 324 #  ifndef __BIG_ENDIAN__
 325 #    define __BIG_ENDIAN__ 1
 326 #  endif
 327 #endif
 328
 329 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 330 #  define USE_WCHAR_T
 331 #endif
 332
 333 #endif
 334 ])
 335
 336 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 337 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 338 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 339
 340 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 341         "${lyx_abs_top_srcdir}", [Top source directory])
 342 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 343         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 344 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 345         "${lyx_abs_installed_datadir}",[Hard system support directory])
 346 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 347         "${version_suffix}",[Program version suffix])
 348
 349 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 350 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 351 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 352 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 353 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 354 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 355 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 356 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 357
 358 AC_CONFIG_FILES([Makefile \
 359       lyx.1:lyx.1in \
 360       3rdparty/Makefile \
 361       3rdparty/boost/Makefile \
 362       3rdparty/hunspell/Makefile \
 363       3rdparty/libiconv/Makefile \
 364       3rdparty/zlib/Makefile \
 365       autotests/Makefile \
 366       config/Makefile \
 367       development/Makefile \
 368       development/MacOSX/Makefile \
 369       development/MacOSX/Info.plist \
 370       development/MacOSX/lyxrc.dist \
 371       development/MacOSX/spotlight/Makefile \
 372       development/cygwin/Makefile \
 373       development/cygwin/lyxrc.dist \
 374       development/lyx.spec \
 375       lib/lyx.desktop-temp:lib/lyx.desktop.in
 376       lib/Makefile \
 377       lib/doc/Makefile \
 378       lib/lyx2lyx/lyx2lyx_version.py \
 379       lib/lyx2lyx/Makefile \
 380       m4/Makefile \
 381       po/Makefile.in \
 382       sourcedoc/Doxyfile \
 383       sourcedoc/Makefile \
 384       src/client/Makefile \
 385       src/client/lyxclient.1:src/client/lyxclient.1in \
 386       src/Makefile \
 387       src/tex2lyx/Makefile \
 388       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 389       src/support/Makefile \
 390       src/frontends/Makefile \
 391       src/frontends/qt4/Makefile
 392 ])
 393
 394
 395 AC_OUTPUT
 396
 397 # show version information
 398 echo
 399 printf "$VERSION_INFO"
 400 echo
 401
 402 # Display a final warning if there has been a LYX_WARNING
 403 LYX_CHECK_WARNINGS
 404
 405 cat <<EOF
 406 Configuration of LyX was successful.
 407 Type 'make' to compile the program,
 408 and then 'make install' to install it.
 409 EOF