configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 ### Set the execute permissions of the various scripts correctly
  26 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  27   chmod 755 ${srcdir}/${file}
  28 done
  29
  30 ### Check for programs
  31 AC_PROG_MAKE_SET
  32 AC_PROG_INSTALL
  33 #AC_PROG_RANLIB
  34 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  35 if test "x$KPSEWHICH" = xkpsewhich ; then
  36     AC_DEFINE(HAVE_KPSEWHICH, 1,
  37     [Define this if you have the kpsewhich program working on your system.])
  38 fi
  39 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  40
  41 # Work around a problem in automake 1.4: when invoking install-strip,
  42 # INSTALL_PROGRAM is changed to 'install -s', and since
  43 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  44 # which returns an error condition when stripping fails.
  45 INSTALL_SCRIPT='${INSTALL}'
  46
  47 ### we will also need a C compiler to compile GNU gettext
  48 AC_PROG_CC
  49
  50 ### check for special systems
  51 AC_ISC_POSIX
  52 AC_AIX
  53
  54 ### check which frontend we want to use
  55 LYX_USE_FRONTENDS
  56
  57 ### Check for a C++ compiler
  58 LYX_PROG_CXX
  59 ### Some checks on what the C++ compiler can(not) do
  60 AC_LANG(C++)
  61 dnl we do not need that currently (and probably all our supported
  62 dnl compiler allow that)
  63 dnl LYX_CXX_PARTIAL
  64 LYX_CXX_EXPLICIT
  65 LYX_CXX_GLOBAL_CSTD
  66 LYX_STD_COUNT
  67 dnl we disable rtti for now
  68 dnl LYX_CXX_RTTI
  69 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  70 LYX_CXX_STL_MODERN_STREAMS
  71
  72 ### and now some special lyx flags.
  73 AC_ARG_ENABLE(assertions,
  74   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  75   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  76         enable_assertions=yes;
  77     else
  78         enable_assertions=no;
  79     fi;])
  80 if test "x$enable_assertions" = xyes ; then
  81    lyx_flags="assertions $lyx_flags"
  82    AC_DEFINE(ENABLE_ASSERTIONS,1,
  83     [Define if you want assertions to be enabled in the code])
  84 fi
  85
  86 ### Library Files
  87 dnl by testing these we check if it is ok to have
  88 dnl -lc and -lm as args to the compiler
  89 AC_CHECK_LIB(m, sin)
  90 AC_CHECK_LIB(c, fopen)
  91
  92 ### Add extra directories to check for libraries.
  93 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  94 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  95 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  96
  97 ### Add extra directories to check for include files.
  98 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  99 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 100 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 101
 102 ### Add both includes and libraries
 103 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 104 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 105 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 106   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 107
 108 AC_ARG_WITH(aiksaurus,
 109   [  --without-aiksaurus     do not use the Aiksaurus library],
 110   [lyx_use_aiksaurus=$withval])
 111 if test x$lyx_use_aiksaurus != xno; then
 112 AC_CHECK_LIB(Aiksaurus, main,
 113         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 114          AIKSAURUS_LIBS="-lAiksaurus"
 115          lyx_flags="aiksaurus $lyx_flags"
 116         ])
 117 AC_CHECK_HEADER(Aiksaurus.h,[
 118   ac_cv_header_aiksaurus_h=yes
 119   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 120 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 121   ac_cv_header_aiksaurus_h=yes
 122   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 123 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 124 fi
 125 AC_SUBST(AIKSAURUS_LIBS)
 126
 127 LYX_USE_INCLUDED_BOOST
 128
 129 ### Setup libtool
 130 AC_DISABLE_SHARED
 131 AC_LIBTOOL_WIN32_DLL
 132 #AM_PROG_LIBTOOL
 133 LYX_PROG_LIBTOOL
 134
 135 ### Check for some Cygwin-specific details.
 136 CHECK_WITH_CYGWIN
 137
 138 ### Check for X libraries
 139 AC_PATH_XTRA
 140 case $have_x in
 141   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 142        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 143   no) LYX_ERROR(dnl
 144 [Cannot find X window libraries and/or headers. Check your installation.
 145   If you use a Linux system, check that you have installed
 146   the development tools.]);;
 147   disable) ;;
 148 esac
 149
 150 ### check which frontend we want to use
 151
 152 dnl if the gtk frontend has been specified, then xforms is needed too
 153 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 154   FRONTENDS="xforms $FRONTENDS"
 155   noxformsbin=yes
 156 fi
 157
 158 dnl The code below is not in a macro, because this would cause big
 159 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 160 for frontend in $FRONTENDS ; do
 161   case "$frontend" in
 162     xforms)
 163           XFORMS_DO_IT_ALL
 164           if test -z "$noxformsbin" ; then
 165             FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 166           fi
 167           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 168           RPM_FRONTEND="xforms"
 169           FRONTEND_INFO="${FRONTEND_INFO}\
 170   XForms Frontend:\n\
 171       libXpm version:\t\t${XPM_VERSION}\n\
 172       libforms version:\t\t${XFORMS_VERSION}\n"
 173           ;;
 174   dnl   gnome)
 175   dnl     XFORMS_DO_IT_ALL
 176   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 177   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 178   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 179
 180   dnl     FRONTEND="xforms gnome"
 181   dnl     FRONTEND_GUILIB="gnome/*.lo"
 182   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 183   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 184   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 185   dnl   ;;
 186     gtk)
 187           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 188           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 189           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 190           RPM_FRONTEND="gtk"
 191           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 192           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 193           FRONTEND_INFO="${FRONTEND_INFO}\
 194   GTK Frontend:\n\
 195     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 196     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 197           ;;
 198
 199     qt)
 200           QT_DO_IT_ALL
 201           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 202           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 203           RPM_FRONTEND="qt"
 204           FRONTEND_INFO="${FRONTEND_INFO}\
 205   Qt Frontend:\n\
 206       Qt version:\t\t${QT_VERSION}\n"
 207 dnl qt build will fail without moc or uic
 208           if test -z "$MOC"; then
 209             LYX_ERROR([moc binary not found !])
 210           fi
 211           if test -z "$UIC"; then
 212             LYX_ERROR([uic binary not found !])
 213           fi
 214       ;;
 215     *)
 216           LYX_ERROR(Unknown frontend '$frontend');;
 217   esac
 218 done
 219
 220 ### Check how the files should be packaged
 221 LYX_USE_PACKAGING
 222 # fix the value of the prefixes.
 223 test "x$prefix" = xNONE && prefix=$default_prefix
 224 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 225 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 226   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 227    causes problems with the Makefiles. The installation will be done in
 228    directory \"`pwd`/installprefix\" instead. Please move its contents to
 229    the right place after installation.])
 230   prefix=`pwd`/installprefix
 231 fi
 232
 233 ### Setup GNU gettext
 234 dnl GNU gettext is written in C
 235 AC_LANG_PUSH(C)
 236 AM_GNU_GETTEXT
 237 AC_LANG_POP(C)
 238
 239 # some standard header files
 240 AC_HEADER_DIRENT
 241 AC_HEADER_MAJOR
 242 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h)
 243
 244 # some standard structures
 245 AC_HEADER_STAT
 246 AC_HEADER_TIME
 247
 248 # some standard types
 249 AC_TYPE_MODE_T
 250 AC_TYPE_OFF_T
 251 AC_TYPE_PID_T
 252 AC_TYPE_SIGNAL
 253 AC_TYPE_SIZE_T
 254 AC_TYPE_UID_T
 255
 256 AC_CHECK_FUNCS(strerror)
 257 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 258 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 259
 260 # Check the form of mkdir()
 261 AC_FUNC_MKDIR
 262
 263 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 264     case "${enableval}" in
 265         yes) use_compression=true ;;
 266         no) use_compression=false ;;
 267         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 268     esac
 269 ],[use_compression=true])
 270 if test $use_compression=true ; then
 271         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 272         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 273         if test $use_compression = true ; then
 274                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 275                 lyx_flags="compression $lyx_flags"
 276         fi
 277 fi
 278 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 279 AC_MSG_CHECKING([whether to support compressed files])
 280 AC_MSG_RESULT($use_compression)
 281
 282
 283 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 284 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 285 dnl We aim to remove this eventually, since we should test as much as
 286 dnl possible with the compiler which will use the functions (JMarc)
 287 AC_LANG_PUSH(C)
 288 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 289 AC_LANG_POP(C)
 290
 291 LYX_CHECK_SPELL_ENGINES
 292
 293 lyx_client_subdir=true
 294 AC_LANG_PUSH(C)
 295 AC_CHECK_FUNCS(fcntl,, [lyx_client_subdir=false])
 296 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 297 AC_LANG_POP(C)
 298
 299
 300 AC_FUNC_SELECT_ARGTYPES
 301
 302 ### Some information on what just happened
 303 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 304 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 305 VERSION_INFO="Configuration\n\
 306   Host type:                      ${host}\n\
 307   Special build flags:            ${lyx_flags}\n\
 308   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 309   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 310   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 311   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 312   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 313   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 314   Linker flags:                   ${AM_LDFLAGS}\n\
 315   Linker user flags:              ${LDFLAGS}\n\
 316 ${FRONTEND_INFO}\
 317   Packaging:                      ${lyx_use_packaging}\n\
 318   LyX binary dir:                 ${real_bindir}\n\
 319   LyX files dir:                  ${real_datadir}\n"
 320
 321
 322 AC_SUBST(VERSION_INFO)
 323 AC_SUBST(RPM_FRONTEND)
 324 AC_SUBST(AM_CPPFLAGS)
 325 AC_SUBST(AM_CXXFLAGS)
 326 AC_SUBST(AM_CFLAGS)
 327 AC_SUBST(AM_LDFLAGS)
 328
 329 ## Some config.h stuff
 330
 331 AH_TOP([
 332 /* -*- C++ -*- */
 333 /*
 334  * \file config.h
 335  * This file is part of LyX, the document processor.
 336  * Licence details can be found in the file COPYING.
 337  *
 338  * This is the compilation configuration file for LyX.
 339  * It was generated by autoconfs configure.
 340  * You might want to change some of the defaults if something goes wrong
 341  * during the compilation.
 342  */
 343
 344 #ifndef _CONFIG_H
 345 #define _CONFIG_H
 346 ])
 347
 348 AH_BOTTOM([
 349 /************************************************************
 350  ** You should not need to change anything beyond this point */
 351
 352 #ifndef HAVE_STRERROR
 353 #if defined(__cplusplus)
 354 extern "C"
 355 #endif
 356 char * strerror(int n);
 357 #endif
 358
 359 #ifdef HAVE_MKSTEMP
 360 #ifndef HAVE_DECL_MKSTEMP
 361 #if defined(__cplusplus)
 362 extern "C"
 363 #endif
 364 int mkstemp(char*);
 365 #endif
 366 #endif
 367
 368 #ifdef __EMX__
 369 #include "support/os2_defines.h"
 370 #endif
 371
 372 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 373 #define USE_BOOST_FORMAT 1
 374 #else
 375 #define USE_BOOST_FORMAT 0
 376 #endif
 377
 378 #define BOOST_USER_CONFIG <config.h>
 379
 380 #if defined(ENABLE_ASSERTIONS)
 381 #define BOOST_ENABLE_ASSERT_HANDLER 1
 382 #else
 383 #define BOOST_DISABLE_ASSERTS 1
 384 #endif
 385
 386 #define BOOST_DISABLE_THREADS 1
 387 #define BOOST_NO_WREGEX 1
 388 #define BOOST_NO_WSTRING 1
 389
 390 #ifdef __CYGWIN__
 391 #define BOOST_POSIX 1
 392 #endif
 393
 394 #endif
 395 ])
 396
 397 ### Finish the work.
 398 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 399 AC_CONFIG_FILES([Makefile  m4/Makefile \
 400        boost/Makefile \
 401        boost/libs/Makefile \
 402        boost/libs/filesystem/Makefile \
 403        boost/libs/filesystem/src/Makefile \
 404        boost/libs/regex/Makefile \
 405        boost/libs/regex/src/Makefile \
 406        boost/libs/signals/Makefile \
 407        boost/libs/signals/src/Makefile \
 408        config/Makefile \
 409        development/Makefile \
 410        development/lyx.spec \
 411        lib/Makefile \
 412        lib/doc/Makefile \
 413        intl/Makefile \
 414        po/Makefile.in \
 415        sourcedoc/Doxyfile \
 416        sourcedoc/Makefile \
 417        src/client/Makefile \
 418        src/Makefile \
 419        src/version.C-tmp:src/version.C.in \
 420        src/tex2lyx/Makefile \
 421        src/mathed/Makefile \
 422        src/graphics/Makefile \
 423        src/insets/Makefile \
 424        src/support/Makefile \
 425        src/support/tests/Makefile \
 426        src/frontends/Makefile \
 427        src/frontends/controllers/Makefile \
 428        src/frontends/xforms/Makefile \
 429        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 430        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 431        src/frontends/xforms/forms/Makefile \
 432        src/frontends/gtk/Makefile \
 433        src/frontends/gtk/gimages/Makefile \
 434        src/frontends/gtk/glade/Makefile \
 435        src/frontends/qt2/Makefile \
 436        src/frontends/qt2/moc/Makefile \
 437        src/frontends/qt2/ui/Makefile \
 438        src/frontends/qt2/ui/moc/Makefile \
 439 ])
 440
 441 AC_OUTPUT
 442 # show version information
 443 echo
 444 printf "$VERSION_INFO"
 445 echo
 446
 447 # Display a final warning if there has been a LYX_ERROR
 448 LYX_CHECK_ERRORS