configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.1.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2011-04-29"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 # Check how the files should be packaged
  17 AC_CANONICAL_TARGET
  18 LYX_USE_PACKAGING
  19 # We need to define these variables here and the no-define option of
  20 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  22
  23 dnl Default maintainer mode to true for development versions
  24 if test "${enable_maintainer_mode+set}" != set; then
  25   enable_maintainer_mode=$lyx_devel_version
  26 fi
  27 AM_MAINTAINER_MODE
  28
  29 save_PACKAGE=$PACKAGE
  30 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8])
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32 PACKAGE=$save_PACKAGE
  33
  34 # Allow to build some parts of the code as one big chunk
  35 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt4])
  36 AC_ARG_ENABLE(monolithic-build,
  37   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  38                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  39   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  40    test "$enable_monolithic_build" = no && enable_monolithic_build=
  41    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  42    for i in $enable_monolithic_build ; do
  43        eval "enable_monolithic_$i=yes"
  44    done
  45    IFS="$ac_save_ifs"],
  46   [enable_monolithic_build=])
  47
  48 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  49 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  50 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  51 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  52 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  53 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  54 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT4, test "x$enable_monolithic_frontend_qt4" = "xyes")
  55
  56 ### Set the execute permissions of the various scripts correctly
  57 for file in config/install-sh ; do
  58   chmod 755 ${srcdir}/${file}
  59 done
  60
  61 # Check for installed python
  62 AM_PATH_PYTHON(2.4.0,, :)
  63
  64 ### we need to know the byte order for unicode conversions
  65 AC_C_BIGENDIAN
  66
  67 ### Check for a C++ compiler
  68 LYX_PROG_CXX
  69
  70 ### Objective-C compiler
  71 AC_PROG_OBJC
  72 _AM_DEPENDENCIES([OBJC])
  73
  74 ### Add extra directories to check for libraries.
  75 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  76 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  77 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  78
  79 ### Add extra directories to check for include files.
  80 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  81 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  82 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  83
  84 ### Add both includes and libraries
  85 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  86 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  87 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  88   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  89
  90 ### These are needed in windows
  91 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  92 AC_SUBST(LIBSHLWAPI)
  93 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  94 AC_SUBST(LIBPSAPI)
  95 AC_CHECK_LIB(gdi32, main)
  96
  97 LYX_USE_INCLUDED_BOOST
  98 LYX_USE_INCLUDED_MYTHES
  99
 100 # Needed for our char_type
 101 AC_CHECK_SIZEOF(wchar_t)
 102
 103 ### We need iconv for unicode support (Qt4 frontend requires it too)
 104 AM_ICONV
 105 if test "$am_cv_func_iconv" = no; then
 106   AC_MSG_ERROR([cannot find required library iconv.])
 107 else
 108   LIBS="$LIBS $LIBICONV"
 109 fi
 110
 111 ### check for compression support
 112 AC_CHECK_HEADERS(zlib.h,
 113  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 114  [LYX_LIB_ERROR(zlib.h,zlib)])
 115
 116 ### check for file magic support (currently optional)
 117 AC_CHECK_HEADERS(magic.h,
 118  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 119   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 120    is correctly installed on your system.
 121    Falling back to builtin file format detection.]))],
 122  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 123    is correctly installed on your system.
 124    Falling back to builtin file format detection.])])
 125
 126 ### setup the qt4 frontend.
 127 dnl The code below is not in a macro, because this would cause big
 128 dnl problems with the AC_REQUIRE contained in QT4_DO_IT_ALL.
 129 QT4_DO_IT_ALL([4.5.0])
 130 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 131 FRONTEND_INFO="${FRONTEND_INFO}\
 132   Qt 4 Frontend:\n\
 133       Qt 4 version:\t\t${QT4_VERSION}\n"
 134
 135 # fix the value of the prefixes.
 136 test "x$prefix" = xNONE && prefix=$default_prefix
 137 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 138 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 139   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 140    causes problems with the Makefiles. The installation will be done in
 141    directory \"`pwd`/installprefix\" instead. Please move its contents to
 142    the right place after installation.])
 143   prefix=`pwd`/installprefix
 144 fi
 145
 146 ### Setup GNU gettext
 147 dnl GNU gettext is written in C
 148 AC_LANG_PUSH(C)
 149 dnl Dirty trick ahead: disable macro AC_GNU_SOURCE because it triggers a bug with autoconf 2.62.
 150 dnl this can be removed if gettext is been updated to avoid that.
 151 m4_undefine([AC_GNU_SOURCE])
 152 m4_defun([AC_GNU_SOURCE],[])
 153 AM_GNU_GETTEXT([no-libtool])
 154 AM_GNU_GETTEXT_VERSION([0.16.1])
 155 AC_LANG_POP(C)
 156
 157 # some standard header files
 158 AC_HEADER_MAJOR
 159 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 160
 161 # some standard types
 162 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 163 AC_TYPE_OFF_T
 164 AC_TYPE_PID_T
 165 AC_TYPE_SIZE_T
 166 AC_TYPE_UID_T
 167
 168 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 169
 170 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lstat mkfifo open _open pclose _pclose popen _popen readlink strerror unsetenv)
 171 # Check the form of mkdir()
 172 AC_FUNC_MKDIR
 173 AC_FUNC_SELECT_ARGTYPES
 174
 175 LYX_CHECK_SPELL_ENGINES
 176
 177 lyx_client_subdir=true
 178 AC_LANG_PUSH(C)
 179 dnl LIBS already contains some X extra libs that may interfere.
 180 save_LIBS="$LIBS"
 181 LIBS=
 182 AC_CHECK_FUNCS(fcntl,
 183   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 184    AC_SEARCH_LIBS([socket], [socket], [],
 185      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 186                 [], [-lnsl])])],
 187   [lyx_client_subdir=false])
 188 AC_SUBST(SOCKET_LIBS,$LIBS)
 189 LIBS="$save_LIBS"
 190 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 191 AC_LANG_POP(C)
 192
 193 lyx_win_res=false;
 194 case ${host} in
 195     *mingw*|*cygwin*) lyx_win_res=true;;
 196 esac
 197 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 198 LYX_SET_VERSION_INFO
 199
 200
 201 ### Some information on what just happened
 202 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 203 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 204 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 205 VERSION_INFO="Configuration\n\
 206   Host type:                    ${host}\n\
 207   Special build flags:         ${lyx_flags}\n\
 208   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 209   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 210   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 211   Linker flags:                 ${AM_LDFLAGS}\n\
 212   Linker user flags:            ${LDFLAGS}\n\
 213 ${FRONTEND_INFO}\
 214   Packaging:                    ${lyx_use_packaging}\n\
 215   LyX binary dir:               ${real_bindir}\n\
 216   LyX files dir:                ${real_pkgdatadir}\n"
 217
 218 AC_SUBST(VERSION_INFO)
 219 AC_SUBST(AM_CPPFLAGS)
 220 AC_SUBST(AM_CXXFLAGS)
 221 AC_SUBST(AM_CFLAGS)
 222 AC_SUBST(AM_LDFLAGS)
 223 AC_SUBST(real_pkgdatadir)
 224
 225 ## Some config.h stuff
 226
 227 AH_TOP([
 228 /* -*- C++ -*- */
 229 /*
 230  * \file config.h
 231  * This file is part of LyX, the document processor.
 232  * Licence details can be found in the file COPYING.
 233  *
 234  * This is the compilation configuration file for LyX.
 235  * It was generated by autoconfs configure.
 236  * You might want to change some of the defaults if something goes wrong
 237  * during the compilation.
 238  */
 239
 240 #ifndef _CONFIG_H
 241 #define _CONFIG_H
 242 ])
 243
 244 AH_BOTTOM([
 245 /************************************************************
 246  ** You should not need to change anything beyond this point */
 247
 248 #ifndef HAVE_STRERROR
 249 #if defined(__cplusplus)
 250 extern "C"
 251 #endif
 252 char * strerror(int n);
 253 #endif
 254
 255 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 256 #  define USE_BOOST_FORMAT 1
 257 #else
 258 #  define USE_BOOST_FORMAT 0
 259 #endif
 260
 261 #define BOOST_USER_CONFIG <config.h>
 262
 263 #if !defined(ENABLE_ASSERTIONS)
 264 #  define BOOST_DISABLE_ASSERTS 1
 265 #endif
 266 #define BOOST_ENABLE_ASSERT_HANDLER 1
 267
 268 #define BOOST_DISABLE_THREADS 1
 269 #define BOOST_NO_WREGEX 1
 270 #define BOOST_NO_WSTRING 1
 271
 272 // TR1 regex not supported in GCC <= 4.5
 273 #ifndef LYX_USE_TR1
 274 #  if __GNUC__ == 4
 275 #    define LYX_USE_TR1
 276 #  endif
 277 #endif
 278
 279 #ifdef __CYGWIN__
 280 #  define NOMINMAX
 281 #  define BOOST_POSIX 1
 282 #  define BOOST_POSIX_API 1
 283 #  define BOOST_POSIX_PATH 1
 284 #endif
 285
 286 /*
 287  * the FreeBSD libc uses UCS4, but libstdc++ has no proper wchar_t
 288  * support compiled in:
 289  * http://gcc.gnu.org/onlinedocs/libstdc++/faq/index.html#3_9
 290  * And we are not interested at all what libc
 291  * does: What we need is a 32bit wide wchar_t, and a libstdc++ that
 292  * has the needed wchar_t support and uses UCS4. Whether it
 293  * implements this with the help of libc, or whether it has own code
 294  * does not matter for us, because we do not use libc directly (Georg)
 295 */
 296 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4 && !defined(__FreeBSD__) && !defined(__FreeBSD_kernel__)
 297 #  define USE_WCHAR_T
 298 #endif
 299
 300 #endif
 301 ])
 302
 303 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 304 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 305 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 306
 307 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 308         "${lyx_abs_top_srcdir}", [Top source directory])
 309 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 310         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 311 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 312         "${lyx_abs_installed_datadir}",[Hard system support directory])
 313 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 314         "${version_suffix}",[Program version suffix])
 315
 316 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 317 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 318 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 319 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 320 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 321 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 322 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 323 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 324
 325 AC_CONFIG_FILES([Makefile \
 326       lyx.1:lyx.1in \
 327       boost/Makefile \
 328       config/Makefile \
 329       development/Makefile \
 330       development/MacOSX/Makefile \
 331       development/MacOSX/Info.plist \
 332       development/MacOSX/lyxrc.dist \
 333       development/MacOSX/spotlight/Makefile \
 334       development/cygwin/Makefile \
 335       development/cygwin/lyxrc.dist \
 336       development/lyx.spec \
 337       intl/Makefile \
 338       lib/lyx.desktop-temp:lib/lyx.desktop.in
 339       lib/Makefile \
 340       lib/doc/Makefile \
 341       lib/lyx2lyx/lyx2lyx_version.py \
 342       lib/lyx2lyx/Makefile \
 343       m4/Makefile \
 344       po/Makefile.in \
 345       sourcedoc/Doxyfile \
 346       sourcedoc/Makefile \
 347       src/client/Makefile \
 348       src/client/lyxclient.1:src/client/lyxclient.1in \
 349       src/Makefile \
 350       src/tex2lyx/Makefile \
 351       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 352       src/support/Makefile \
 353       src/frontends/Makefile \
 354       src/frontends/qt4/Makefile
 355 ])
 356
 357
 358 AC_OUTPUT
 359
 360 # show version information
 361 echo
 362 printf "$VERSION_INFO"
 363 echo
 364
 365 # Display a final warning if there has been a LYX_WARNING
 366 LYX_CHECK_WARNINGS
 367
 368 cat <<EOF
 369 Configuration of LyX was successful.
 370 Type 'make' to compile the program,
 371 and then 'make install' to install it.
 372 EOF