configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AM_MAINTAINER_MODE
  15 AC_CANONICAL_TARGET
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### check which frontend we want to use
  59 LYX_USE_FRONTENDS
  60
  61 ### Check for a C++ compiler
  62 LYX_PROG_CXX
  63 ### Some checks on what the C++ compiler can(not) do
  64 AC_LANG(C++)
  65 dnl we do not need that currently (and probably all our supported
  66 dnl compiler allow that)
  67 dnl LYX_CXX_PARTIAL
  68 LYX_CXX_EXPLICIT
  69 LYX_CXX_CHEADERS
  70 LYX_CXX_GLOBAL_CSTD
  71 LYX_STD_COUNT
  72 dnl we disable rtti for now
  73 dnl LYX_CXX_RTTI
  74 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  75 LYX_CXX_STL_MODERN_STREAMS
  76
  77 ### and now some special lyx flags.
  78 AC_ARG_ENABLE(assertions,
  79   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  80   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  81         enable_assertions=yes;
  82     else
  83         enable_assertions=no;
  84     fi;])
  85 if test "x$enable_assertions" = xyes ; then
  86    lyx_flags="$lyx_flags assertions"
  87    AC_DEFINE(ENABLE_ASSERTIONS,1,
  88     [Define if you want assertions to be enabled in the code])
  89 fi
  90
  91 ### Library Files
  92 dnl by testing these we check if it is ok to have
  93 dnl -lc and -lm as args to the compiler
  94 AC_CHECK_LIB(m, sin)
  95 AC_CHECK_LIB(c, fopen)
  96
  97 ### Add extra directories to check for libraries.
  98 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  99 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 100 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 101
 102 ### Add extra directories to check for include files.
 103 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 104 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 105 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 106
 107 ### Add both includes and libraries
 108 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 109 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 110 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 111   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 112
 113 AC_ARG_WITH(aiksaurus,
 114   [  --without-aiksaurus     do not use the Aiksaurus library],
 115   [lyx_use_aiksaurus=$withval])
 116 if test x$lyx_use_aiksaurus != xno; then
 117 AC_CHECK_LIB(Aiksaurus, main,
 118         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 119          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 120         ],,"-lbz2")
 121 AC_CHECK_HEADER(Aiksaurus.h,[
 122   ac_cv_header_aiksaurus_h=yes
 123   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 124 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 125   ac_cv_header_aiksaurus_h=yes
 126   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 127 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 128 fi
 129 AC_SUBST(AIKSAURUS_LIBS)
 130
 131 LYX_USE_INCLUDED_BOOST
 132
 133 ### Setup libtool
 134 AC_DISABLE_SHARED
 135 AC_LIBTOOL_WIN32_DLL
 136 #AM_PROG_LIBTOOL
 137 LYX_PROG_LIBTOOL
 138
 139 ### Check if we want spell libraries, prefer new aspell
 140 CHECK_WITH_ASPELL
 141 if test "$USING_ASPELL" != "yes"; then
 142         CHECK_WITH_PSPELL
 143 fi
 144
 145 ### Check for some Cygwin-specific details.
 146 CHECK_WITH_CYGWIN
 147
 148 ### Check for X libraries
 149 AC_PATH_XTRA
 150 case $have_x in
 151   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 152        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 153   no) LYX_ERROR(dnl
 154 [Cannot find X window libraries and/or headers. Check your installation.
 155   If you use a Linux system, check that you have installed
 156   the development tools.]);;
 157   disable) ;;
 158 esac
 159
 160 ### check which frontend we want to use
 161
 162 dnl The code below is not in a macro, because this would cause big
 163 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 164 for frontend in $FRONTENDS ; do
 165   case "$frontend" in
 166     xforms)
 167           XFORMS_DO_IT_ALL
 168           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 169           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 170           RPM_FRONTEND="xforms"
 171           RPM_FRONTEND_DEPS='libforms >= 1.0'
 172           FRONTEND_INFO="${FRONTEND_INFO}\
 173   XForms Frontend:\n\
 174       libXpm version:\t\t${XPM_VERSION}\n\
 175       libforms version:\t\t${XFORMS_VERSION}\n"
 176           ;;
 177   dnl   gnome)
 178   dnl     XFORMS_DO_IT_ALL
 179   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 180   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 181   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 182
 183   dnl     FRONTEND="xforms gnome"
 184   dnl     FRONTEND_GUILIB="gnome/*.lo"
 185   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 186   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 187   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 188   dnl   ;;
 189     gtk)
 190           XFORMS_DO_IT_ALL
 191           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.0 libglademm-2.0)
 192           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 193           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms gtk"
 194           RPM_FRONTEND="gtk"
 195           RPM_FRONTEND_DEPS='gtkmm >= 2.2.0'
 196           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.0`
 197           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.0`
 198           FRONTEND_INFO="${FRONTEND_INFO}\
 199   GTK Frontend:\n\
 200     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 201     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 202           ;;
 203
 204     qt)
 205           QT_DO_IT_ALL
 206           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 207           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 208           RPM_FRONTEND="qt"
 209           RPM_FRONTEND_DEPS='qt >= 2.2.1'
 210           FRONTEND_INFO="${FRONTEND_INFO}\
 211   Qt Frontend:\n\
 212       Qt version:\t\t${QT_VERSION}\n"
 213       ;;
 214     *)
 215           LYX_ERROR(Unknown frontend '$frontend');;
 216   esac
 217 done
 218
 219 ### Setup GNU gettext
 220 dnl GNU gettext is written in C
 221 AC_LANG_PUSH(C)
 222 # Some tests that may be useful for gettext
 223 AC_C_CONST
 224 AC_C_INLINE
 225 # Do the real setup now
 226 AM_GNU_GETTEXT
 227 # a hack for those who try to change LyX, but do not have gettext installed
 228 case  "${XGETTEXT}" in
 229  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 230 esac
 231
 232 AC_SUBST(LINGUAS)
 233
 234 AC_LANG_POP(C)
 235
 236 # some standard header files
 237 AC_HEADER_DIRENT
 238 AC_HEADER_MAJOR
 239 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 240
 241 # some standard structures
 242 AC_HEADER_STAT
 243 AC_HEADER_TIME
 244
 245 # some standard types
 246 AC_TYPE_MODE_T
 247 AC_TYPE_OFF_T
 248 AC_TYPE_PID_T
 249 AC_TYPE_SIGNAL
 250 AC_TYPE_SIZE_T
 251 AC_TYPE_UID_T
 252
 253 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 254 LYX_CHECK_DECL(snprintf, stdio.h)
 255 LYX_CHECK_DECL(vsnprintf, stdio.h)
 256 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 257 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 258
 259 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 260     case "${enableval}" in
 261         yes) use_compression=true ;;
 262         no) use_compression=false ;;
 263         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 264     esac
 265 ],[use_compression=true])
 266 if test $use_compression=true ; then
 267         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 268         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 269         if test $use_compression = true ; then
 270                 AC_DEFINE(USE_COMRESSION, 1, [Define as 1 if you want to support compressed files.])
 271                 lyx_flags="$lyx_flags compression"
 272         fi
 273 fi
 274 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 275 AC_MSG_CHECKING([whether to support compressed files])
 276 AC_MSG_RESULT($use_compression)
 277
 278
 279 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 280 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 281 dnl We aim to remove this eventually, since we should test as much as
 282 dnl possible with the compiler which will use the functions (JMarc)
 283 AC_LANG_PUSH(C)
 284 AC_CHECK_FUNCS(memmove memset strchr mkfifo mkstemp mktemp)
 285 AC_LANG_POP(C)
 286
 287 AC_FUNC_SELECT_ARGTYPES
 288
 289 ### Some information on what just happened
 290 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 291 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 292 VERSION_INFO="Configuration\n\
 293   Host type:                      ${host}\n\
 294   Special build flags:           ${lyx_flags}\n\
 295   C   Compiler:                   ${CC}\n\
 296   C   Compiler flags:             ${CFLAGS}\n\
 297   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 298   C++ Compiler flags:             ${CXXFLAGS}\n\
 299   Linker flags:                   ${LDFLAGS}\n\
 300 ${FRONTEND_INFO}\
 301   LyX binary dir:                 ${real_bindir}\n\
 302   LyX files dir:                  ${real_datadir}\n"
 303
 304
 305 AC_SUBST(VERSION_INFO)
 306 AC_SUBST(RPM_FRONTEND)
 307 AC_SUBST(RPM_FRONTEND_DEPS)
 308
 309 ## Some config.h stuff
 310
 311 AH_TOP([
 312 /* -*- C++ -*- */
 313 /*
 314  * \file config.h
 315  * This file is part of LyX, the document processor.
 316  * Licence details can be found in the file COPYING.
 317  *
 318  * This is the compilation configuration file for LyX.
 319  * It was generated by autoconfs configure.
 320  * You might want to change some of the defaults if something goes wrong
 321  * during the compilation.
 322  */
 323
 324 #ifndef _CONFIG_H
 325 #define _CONFIG_H
 326 ])
 327
 328 AH_BOTTOM([
 329 /************************************************************
 330  ** You should not need to change anything beyond this point */
 331
 332 #ifndef HAVE_STRCHR
 333 # define strchr(a,b)    index(a,b)
 334 #endif
 335
 336 #ifndef HAVE_MEMMOVE
 337 # define memmove(a,b,c) bcopy(b,a,c)
 338 #endif
 339
 340 #ifndef HAVE_STRERROR
 341 #if defined(__cplusplus)
 342 extern "C"
 343 #endif
 344 char * strerror(int n);
 345 #endif
 346
 347 #ifdef BROKEN_HEADERS
 348 #include "broken_headers.h"
 349 #endif
 350
 351 #ifdef HAVE_MKSTEMP
 352 #ifndef HAVE_DECL_MKSTEMP
 353 #if defined(__cplusplus)
 354 extern "C"
 355 #endif
 356 int mkstemp(char*);
 357 #endif
 358 #endif
 359
 360 #ifdef __EMX__
 361 #include "support/os2_defines.h"
 362 #endif
 363
 364 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 365 #define USE_BOOST_FORMAT 1
 366 #else
 367 #define USE_BOOST_FORMAT 0
 368 #endif
 369
 370 #define BOOST_USER_CONFIG <config.h>
 371
 372 #if defined(ENABLE_ASSERTIONS)
 373 #define BOOST_ENABLE_ASSERT_HANDLER 1
 374 #else
 375 #define BOOST_DISABLE_ASSERTS 1
 376 #endif
 377
 378 #define BOOST_DISABLE_THREADS 1
 379 #define BOOST_NO_WREGEX 1
 380 #define BOOST_NO_WSTRING 1
 381
 382 #endif
 383 ])
 384
 385 ### Finish the work.
 386 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 387 AC_CONFIG_FILES([Makefile  m4/Makefile \
 388        boost/Makefile \
 389        boost/libs/Makefile \
 390        boost/libs/filesystem/Makefile \
 391        boost/libs/filesystem/src/Makefile \
 392        boost/libs/regex/Makefile \
 393        boost/libs/regex/src/Makefile \
 394        boost/libs/signals/Makefile \
 395        boost/libs/signals/src/Makefile \
 396        config/Makefile \
 397        development/Makefile \
 398        development/lyx.spec \
 399        lib/Makefile \
 400        lib/doc/Makefile \
 401        intl/Makefile \
 402        po/Makefile.in \
 403        sourcedoc/Doxyfile \
 404        sourcedoc/Makefile \
 405        src/Makefile \
 406        src/version.C-tmp:src/version.C.in \
 407        src/tex2lyx/Makefile \
 408        src/mathed/Makefile \
 409        src/graphics/Makefile \
 410        src/insets/Makefile \
 411        src/support/Makefile \
 412        src/frontends/Makefile \
 413        src/frontends/controllers/Makefile \
 414        src/frontends/xforms/Makefile \
 415        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 416        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 417        src/frontends/xforms/forms/Makefile \
 418        src/frontends/gtk/Makefile \
 419        src/frontends/gtk/gimages/Makefile \
 420        src/frontends/gtk/glade/Makefile \
 421        src/frontends/qt2/Makefile \
 422        src/frontends/qt2/moc/Makefile \
 423        src/frontends/qt2/ui/Makefile \
 424        src/frontends/qt2/ui/moc/Makefile \
 425        src/frontends/gnome/Makefile \
 426 ])
 427
 428 AC_OUTPUT
 429 # show version information
 430 echo
 431 printf "$VERSION_INFO"
 432 echo
 433
 434 # Display a final warning if there has been a LYX_ERROR
 435 LYX_CHECK_ERRORS