configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.5.0svn,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AC_CONFIG_HEADERS([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 # First check the version
  11 LYX_CHECK_VERSION
  12 LYX_VERSION_SUFFIX
  13 # Check how the files should be packaged
  14 AC_CANONICAL_TARGET
  15 LYX_USE_PACKAGING
  16 # We need to define these variables here and the no-define option of
  17 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  18 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  19
  20 dnl default maintainer mode to true for development versions
  21 if test "${enable_maintainer_mode+set}" != set; then
  22   enable_maintainer_mode=$lyx_devel_version
  23 fi
  24 AM_MAINTAINER_MODE
  25
  26 save_PACKAGE=$PACKAGE
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
  28 PACKAGE=$save_PACKAGE
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38
  39 AC_PROG_AWK
  40 test "$AWK" = gawk && AWK="gawk --posix"
  41
  42 #AC_PROG_RANLIB
  43 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  44 if test "x$KPSEWHICH" = xkpsewhich ; then
  45     AC_DEFINE(HAVE_KPSEWHICH, 1,
  46     [Define this if you have the kpsewhich program working on your system.])
  47 fi
  48 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  49
  50 # Check for installed python
  51 AM_PATH_PYTHON(2.3,, :)
  52
  53 # Work around a problem in automake 1.4: when invoking install-strip,
  54 # INSTALL_PROGRAM is changed to 'install -s', and since
  55 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  56 # which returns an error condition when stripping fails.
  57 INSTALL_SCRIPT='${INSTALL}'
  58
  59 ### we will also need a C compiler to compile GNU gettext
  60 AC_PROG_CC
  61
  62 ### check for special systems
  63 AC_ISC_POSIX
  64 AC_AIX
  65
  66 ### check which frontend we want to use
  67 LYX_USE_FRONTENDS
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG(C++)
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_GLOBAL_CSTD
  78 LYX_STD_COUNT
  79 dnl we disable rtti for now
  80 dnl LYX_CXX_RTTI
  81 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  82 LYX_CXX_STL_MODERN_STREAMS
  83
  84 ### and now some special lyx flags.
  85 AC_ARG_ENABLE(assertions,
  86   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  87   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  88         enable_assertions=yes;
  89     else
  90         enable_assertions=no;
  91     fi;])
  92 if test "x$enable_assertions" = xyes ; then
  93    lyx_flags="assertions $lyx_flags"
  94    AC_DEFINE(ENABLE_ASSERTIONS,1,
  95     [Define if you want assertions to be enabled in the code])
  96 fi
  97
  98 ### Library Files
  99 dnl by testing these we check if it is ok to have
 100 dnl -lc and -lm as args to the compiler
 101 AC_CHECK_LIB(m, sin)
 102 AC_CHECK_LIB(c, fopen)
 103
 104 ### Add extra directories to check for libraries.
 105 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 107 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 108
 109 ### Add extra directories to check for include files.
 110 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 111 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 112 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 113
 114 ### Add both includes and libraries
 115 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 116 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 117 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 118   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 119
 120 ### These are needed in windows
 121 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 122 AC_SUBST(LIBSHLWAPI)
 123 AC_CHECK_LIB(gdi32, main)
 124
 125 AC_ARG_WITH(aiksaurus,
 126   [  --without-aiksaurus     do not use the Aiksaurus library],
 127   [lyx_use_aiksaurus=$withval])
 128 if test x$lyx_use_aiksaurus != xno; then
 129 AC_CHECK_LIB(Aiksaurus, main,
 130         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 131          AIKSAURUS_LIBS="-lAiksaurus"
 132          lyx_flags="aiksaurus $lyx_flags"
 133         ])
 134 AC_CHECK_HEADER(Aiksaurus.h,[
 135   ac_cv_header_aiksaurus_h=yes
 136   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 137 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 138   ac_cv_header_aiksaurus_h=yes
 139   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 140 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 141 fi
 142 AC_SUBST(AIKSAURUS_LIBS)
 143
 144 LYX_USE_INCLUDED_BOOST
 145
 146 ### Setup libtool
 147 dnl Dirty trick ahead: disable libtool checking for a fortran compiler
 148 dnl see http://permalink.gmane.org/gmane.comp.gnu.libtool.general/6699
 149 dnl Note that this will reportedly not be needed with libtool 2.0
 150 m4_undefine([AC_PROG_F77])
 151 m4_defun([AC_PROG_F77],[])
 152 AC_DISABLE_SHARED
 153 AC_LIBTOOL_WIN32_DLL
 154 #AM_PROG_LIBTOOL
 155 LYX_PROG_LIBTOOL
 156
 157 ### Check for X libraries
 158 AC_PATH_XTRA
 159 case $have_x in
 160   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 161        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 162   no) LYX_ERROR(dnl
 163 [Cannot find X window libraries and/or headers. Check your installation.
 164   If you use a Linux system, check that you have installed
 165   the development tools.]);;
 166   disable) ;;
 167 esac
 168
 169 ### check which frontend we want to use
 170
 171 dnl The code below is not in a macro, because this would cause big
 172 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 173 for frontend in $FRONTENDS ; do
 174   case "$frontend" in
 175     gtk)
 176           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
 177           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 178           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 179           RPM_FRONTEND="gtk"
 180           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 181           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 182           FRONTEND_INFO="${FRONTEND_INFO}\
 183   GTK Frontend:\n\
 184     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 185     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 186           ;;
 187
 188     qt3)
 189           QT_DO_IT_ALL
 190           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt3\$(EXEEXT)"
 191           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt3"
 192           RPM_FRONTEND="qt3"
 193           FRONTEND_INFO="${FRONTEND_INFO}\
 194   Qt Frontend:\n\
 195       Qt version:\t\t${QT_VERSION}\n"
 196 dnl qt build will fail without moc or uic
 197           if test -z "$MOC"; then
 198             LYX_ERROR([moc binary not found !])
 199           fi
 200           if test -z "$UIC"; then
 201             LYX_ERROR([uic binary not found !])
 202           fi
 203           if test -z "$QT_LIB"; then
 204             LYX_ERROR([qt library not found !])
 205           fi
 206       ;;
 207     qt4)
 208           QT4_DO_IT_ALL
 209           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
 210           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
 211           RPM_FRONTEND="qt4"
 212           FRONTEND_INFO="${FRONTEND_INFO}\
 213   Qt 4 Frontend:\n\
 214       Qt 4 version:\t\t${QT4_VERSION}\n"
 215 dnl qt 4 build will fail without moc or uic
 216           if test -z "$MOC4"; then
 217             LYX_ERROR([moc 4 binary not found !])
 218           fi
 219           if test -z "$UIC4"; then
 220             LYX_ERROR([uic 4 binary not found !])
 221           fi
 222           if test -z "$QT4_LIB"; then
 223             LYX_ERROR([qt 4 library not found !])
 224           fi
 225       ;;
 226     *)
 227           LYX_ERROR(Unknown frontend '$frontend');;
 228   esac
 229 done
 230
 231 # fix the value of the prefixes.
 232 test "x$prefix" = xNONE && prefix=$default_prefix
 233 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 234 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 235   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 236    causes problems with the Makefiles. The installation will be done in
 237    directory \"`pwd`/installprefix\" instead. Please move its contents to
 238    the right place after installation.])
 239   prefix=`pwd`/installprefix
 240 fi
 241
 242 ### We need iconv for unicode support
 243 AM_ICONV
 244 if test "$am_cv_func_iconv" = no; then
 245   LYX_ERROR([Cannot find required library iconv])
 246 fi
 247
 248 ### Setup GNU gettext
 249 dnl GNU gettext is written in C
 250 AC_LANG_PUSH(C)
 251 AM_GNU_GETTEXT
 252 AC_LANG_POP(C)
 253
 254 # some standard header files
 255 AC_HEADER_DIRENT
 256 AC_HEADER_MAJOR
 257 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 258
 259 # some standard structures
 260 AC_HEADER_STAT
 261 AC_HEADER_TIME
 262
 263 # some standard types
 264 AC_TYPE_MODE_T
 265 AC_TYPE_OFF_T
 266 AC_TYPE_PID_T
 267 AC_TYPE_SIGNAL
 268 AC_TYPE_SIZE_T
 269 AC_TYPE_UID_T
 270
 271 AC_CHECK_FUNCS(strerror)
 272 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 273 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 274
 275 # Check the form of mkdir()
 276 AC_FUNC_MKDIR
 277
 278 # check for compression support
 279 AC_CHECK_HEADERS(zlib.h,
 280  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 281  [LYX_LIB_ERROR(zlib.h,zlib)])
 282
 283 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 284 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 285 dnl We aim to remove this eventually, since we should test as much as
 286 dnl possible with the compiler which will use the functions (JMarc)
 287 AC_LANG_PUSH(C)
 288 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 289 AC_LANG_POP(C)
 290
 291 LYX_CHECK_SPELL_ENGINES
 292
 293 lyx_client_subdir=true
 294 AC_LANG_PUSH(C)
 295 dnl LIBS already contains some X extra libs that may interfere.
 296 save_LIBS="$LIBS"
 297 LIBS=
 298 AC_CHECK_FUNCS(fcntl,
 299   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 300    AC_SEARCH_LIBS([socket], [socket], [],
 301      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 302                 [], [-lnsl])])],
 303   [lyx_client_subdir=false])
 304 AC_SUBST(SOCKET_LIBS,$LIBS)
 305 LIBS="$save_LIBS"
 306 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 307 AC_LANG_POP(C)
 308
 309 AC_FUNC_SELECT_ARGTYPES
 310
 311 ### Some information on what just happened
 312 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 313 real_pkgdatadir=`eval "echo \`eval \"echo ${pkgdatadir}\"\`"`
 314 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 315 VERSION_INFO="Configuration\n\
 316   Host type:                      ${host}\n\
 317   Special build flags:            ${lyx_flags}\n\
 318   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 319   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 320   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 321   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 322   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 323   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 324   Linker flags:                   ${AM_LDFLAGS}\n\
 325   Linker user flags:              ${LDFLAGS}\n\
 326 ${FRONTEND_INFO}\
 327   Packaging:                      ${lyx_use_packaging}\n\
 328   LyX binary dir:                 ${real_bindir}\n\
 329   LyX files dir:                  ${real_pkgdatadir}\n"
 330
 331 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 332 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 333 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_pkgdatadir})
 334
 335 AC_SUBST(VERSION_INFO)
 336 AC_SUBST(RPM_FRONTEND)
 337 AC_SUBST(AM_CPPFLAGS)
 338 AC_SUBST(AM_CXXFLAGS)
 339 AC_SUBST(AM_CFLAGS)
 340 AC_SUBST(AM_LDFLAGS)
 341 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 342 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 343 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 344
 345 ## Some config.h stuff
 346
 347 AH_TOP([
 348 /* -*- C++ -*- */
 349 /*
 350  * \file config.h
 351  * This file is part of LyX, the document processor.
 352  * Licence details can be found in the file COPYING.
 353  *
 354  * This is the compilation configuration file for LyX.
 355  * It was generated by autoconfs configure.
 356  * You might want to change some of the defaults if something goes wrong
 357  * during the compilation.
 358  */
 359
 360 #ifndef _CONFIG_H
 361 #define _CONFIG_H
 362 ])
 363
 364 AH_BOTTOM([
 365 /************************************************************
 366  ** You should not need to change anything beyond this point */
 367
 368 #ifndef HAVE_STRERROR
 369 #if defined(__cplusplus)
 370 extern "C"
 371 #endif
 372 char * strerror(int n);
 373 #endif
 374
 375 #ifdef HAVE_MKSTEMP
 376 #ifndef HAVE_DECL_MKSTEMP
 377 #if defined(__cplusplus)
 378 extern "C"
 379 #endif
 380 int mkstemp(char*);
 381 #endif
 382 #endif
 383
 384 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 385 #  define USE_BOOST_FORMAT 1
 386 #else
 387 #  define USE_BOOST_FORMAT 0
 388 #endif
 389
 390 #define BOOST_USER_CONFIG <config.h>
 391
 392 #if !defined(ENABLE_ASSERTIONS)
 393 #  define BOOST_DISABLE_ASSERTS 1
 394 #endif
 395 #define BOOST_ENABLE_ASSERT_HANDLER 1
 396
 397 #define BOOST_DISABLE_THREADS 1
 398 #define BOOST_NO_WREGEX 1
 399 #define BOOST_NO_WSTRING 1
 400
 401 #ifdef __CYGWIN__
 402 #  define BOOST_POSIX 1
 403 #endif
 404
 405 #if defined(HAVE_NEWAPIS_H)
 406 #  define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 407 #endif
 408
 409 #endif
 410 ])
 411
 412 ### Finish the work.
 413 AC_CONFIG_FILES([Makefile  m4/Makefile \
 414        boost/Makefile \
 415        boost/libs/Makefile \
 416        boost/libs/filesystem/Makefile \
 417        boost/libs/filesystem/src/Makefile \
 418        boost/libs/iostreams/Makefile \
 419        boost/libs/iostreams/src/Makefile \
 420        boost/libs/regex/Makefile \
 421        boost/libs/regex/src/Makefile \
 422        boost/libs/signals/Makefile \
 423        boost/libs/signals/src/Makefile \
 424        config/Makefile \
 425        development/Makefile \
 426        development/lyx.spec \
 427        lib/Makefile \
 428        lib/doc/Makefile \
 429        lib/lyx2lyx/lyx2lyx_version.py \
 430        lib/lyx2lyx/Makefile \
 431        intl/Makefile \
 432        po/Makefile.in \
 433        sourcedoc/Doxyfile \
 434        sourcedoc/Makefile \
 435        src/client/Makefile \
 436        src/Makefile \
 437        src/version.C-tmp:src/version.C.in \
 438        src/tex2lyx/Makefile \
 439        src/mathed/Makefile \
 440        src/graphics/Makefile \
 441        src/insets/Makefile \
 442        src/support/Makefile \
 443        src/support/tests/Makefile \
 444        src/frontends/Makefile \
 445        src/frontends/controllers/Makefile \
 446        src/frontends/controllers/tests/Makefile \
 447        src/frontends/gtk/Makefile \
 448        src/frontends/gtk/gimages/Makefile \
 449        src/frontends/gtk/glade/Makefile \
 450        src/frontends/qt3/Makefile \
 451        src/frontends/qt3/moc/Makefile \
 452        src/frontends/qt3/ui/Makefile \
 453        src/frontends/qt3/ui/moc/Makefile \
 454        src/frontends/qt4/Makefile \
 455        src/frontends/qt4/ui/Makefile \
 456 ])
 457
 458 AC_OUTPUT
 459 # show version information
 460 echo
 461 printf "$VERSION_INFO"
 462 echo
 463
 464 # Display a final warning if there has been a LYX_ERROR
 465 LYX_CHECK_ERRORS