configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.5.0svn,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AC_CONFIG_HEADERS([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 # First check the version
  11 LYX_CHECK_VERSION
  12 LYX_VERSION_SUFFIX
  13 # Check how the files should be packaged
  14 AC_CANONICAL_TARGET
  15 LYX_USE_PACKAGING
  16 # We need to define these variables here and the no-define option of
  17 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  18 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  19
  20 dnl default maintainer mode to true for development versions
  21 if test "${enable_maintainer_mode+set}" != set; then
  22   enable_maintainer_mode=$lyx_devel_version
  23 fi
  24 AM_MAINTAINER_MODE
  25
  26 save_PACKAGE=$PACKAGE
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
  28 PACKAGE=$save_PACKAGE
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38
  39 AC_PROG_AWK
  40 test "$AWK" = gawk && AWK="gawk --posix"
  41
  42 #AC_PROG_RANLIB
  43 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  44 if test "x$KPSEWHICH" = xkpsewhich ; then
  45     AC_DEFINE(HAVE_KPSEWHICH, 1,
  46     [Define this if you have the kpsewhich program working on your system.])
  47 fi
  48 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  49
  50 # Check for installed python
  51 AM_PATH_PYTHON(1.5.2,, :)
  52
  53 # Work around a problem in automake 1.4: when invoking install-strip,
  54 # INSTALL_PROGRAM is changed to 'install -s', and since
  55 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  56 # which returns an error condition when stripping fails.
  57 INSTALL_SCRIPT='${INSTALL}'
  58
  59 ### we will also need a C compiler to compile GNU gettext
  60 AC_PROG_CC
  61
  62 ### check for special systems
  63 AC_ISC_POSIX
  64 AC_AIX
  65
  66 ### check which frontend we want to use
  67 LYX_USE_FRONTENDS
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG(C++)
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_GLOBAL_CSTD
  78 LYX_STD_COUNT
  79 dnl we disable rtti for now
  80 dnl LYX_CXX_RTTI
  81 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  82 LYX_CXX_STL_MODERN_STREAMS
  83
  84 ### and now some special lyx flags.
  85 AC_ARG_ENABLE(assertions,
  86   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  87   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  88         enable_assertions=yes;
  89     else
  90         enable_assertions=no;
  91     fi;])
  92 if test "x$enable_assertions" = xyes ; then
  93    lyx_flags="assertions $lyx_flags"
  94    AC_DEFINE(ENABLE_ASSERTIONS,1,
  95     [Define if you want assertions to be enabled in the code])
  96 fi
  97
  98 ### Library Files
  99 dnl by testing these we check if it is ok to have
 100 dnl -lc and -lm as args to the compiler
 101 AC_CHECK_LIB(m, sin)
 102 AC_CHECK_LIB(c, fopen)
 103
 104 ### Add extra directories to check for libraries.
 105 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 107 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 108
 109 ### Add extra directories to check for include files.
 110 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 111 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 112 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 113
 114 ### Add both includes and libraries
 115 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 116 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 117 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 118   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 119
 120 ### These are needed in windows
 121 AC_CHECK_LIB(shlwapi, main)
 122 AC_CHECK_LIB(gdi32, main)
 123
 124 AC_ARG_WITH(aiksaurus,
 125   [  --without-aiksaurus     do not use the Aiksaurus library],
 126   [lyx_use_aiksaurus=$withval])
 127 if test x$lyx_use_aiksaurus != xno; then
 128 AC_CHECK_LIB(Aiksaurus, main,
 129         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 130          AIKSAURUS_LIBS="-lAiksaurus"
 131          lyx_flags="aiksaurus $lyx_flags"
 132         ])
 133 AC_CHECK_HEADER(Aiksaurus.h,[
 134   ac_cv_header_aiksaurus_h=yes
 135   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 136 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 137   ac_cv_header_aiksaurus_h=yes
 138   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 139 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 140 fi
 141 AC_SUBST(AIKSAURUS_LIBS)
 142
 143 LYX_USE_INCLUDED_BOOST
 144
 145 ### Setup libtool
 146 AC_DISABLE_SHARED
 147 AC_LIBTOOL_WIN32_DLL
 148 #AM_PROG_LIBTOOL
 149 LYX_PROG_LIBTOOL
 150
 151 ### Check for X libraries
 152 AC_PATH_XTRA
 153 case $have_x in
 154   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 155        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 156   no) LYX_ERROR(dnl
 157 [Cannot find X window libraries and/or headers. Check your installation.
 158   If you use a Linux system, check that you have installed
 159   the development tools.]);;
 160   disable) ;;
 161 esac
 162
 163 ### check which frontend we want to use
 164
 165 dnl The code below is not in a macro, because this would cause big
 166 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 167 for frontend in $FRONTENDS ; do
 168   case "$frontend" in
 169     xforms)
 170           XFORMS_DO_IT_ALL
 171           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 172           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 173           RPM_FRONTEND="xforms"
 174           FRONTEND_INFO="${FRONTEND_INFO}\
 175   XForms Frontend:\n\
 176       libXpm version:\t\t${XPM_VERSION}\n\
 177       libforms version:\t\t${XFORMS_VERSION}\n"
 178           ;;
 179     gtk)
 180           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
 181           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 182           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 183           RPM_FRONTEND="gtk"
 184           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 185           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 186           FRONTEND_INFO="${FRONTEND_INFO}\
 187   GTK Frontend:\n\
 188     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 189     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 190           ;;
 191
 192     qt)
 193           QT_DO_IT_ALL
 194           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 195           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt3"
 196           RPM_FRONTEND="qt"
 197           FRONTEND_INFO="${FRONTEND_INFO}\
 198   Qt Frontend:\n\
 199       Qt version:\t\t${QT_VERSION}\n"
 200 dnl qt build will fail without moc or uic
 201           if test -z "$MOC"; then
 202             LYX_ERROR([moc binary not found !])
 203           fi
 204           if test -z "$UIC"; then
 205             LYX_ERROR([uic binary not found !])
 206           fi
 207           if test -z "$QT_LIB"; then
 208             LYX_ERROR([qt library not found !])
 209           fi
 210       ;;
 211     qt4)
 212           QT4_DO_IT_ALL
 213           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
 214           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
 215           RPM_FRONTEND="qt4"
 216           FRONTEND_INFO="${FRONTEND_INFO}\
 217   Qt 4 Frontend:\n\
 218       Qt 4 version:\t\t${QT4_VERSION}\n"
 219 dnl qt 4 build will fail without moc or uic
 220           if test -z "$MOC4"; then
 221             LYX_ERROR([moc 4 binary not found !])
 222           fi
 223           if test -z "$UIC4"; then
 224             LYX_ERROR([uic 4 binary not found !])
 225           fi
 226           if test -z "$QT4_LIB"; then
 227             LYX_ERROR([qt 4 library not found !])
 228           fi
 229       ;;
 230     *)
 231           LYX_ERROR(Unknown frontend '$frontend');;
 232   esac
 233 done
 234
 235 # fix the value of the prefixes.
 236 test "x$prefix" = xNONE && prefix=$default_prefix
 237 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 238 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 239   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 240    causes problems with the Makefiles. The installation will be done in
 241    directory \"`pwd`/installprefix\" instead. Please move its contents to
 242    the right place after installation.])
 243   prefix=`pwd`/installprefix
 244 fi
 245
 246 ### Setup GNU gettext
 247 dnl GNU gettext is written in C
 248 AC_LANG_PUSH(C)
 249 AM_GNU_GETTEXT
 250 AC_LANG_POP(C)
 251
 252 # some standard header files
 253 AC_HEADER_DIRENT
 254 AC_HEADER_MAJOR
 255 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 256
 257 # some standard structures
 258 AC_HEADER_STAT
 259 AC_HEADER_TIME
 260
 261 # some standard types
 262 AC_TYPE_MODE_T
 263 AC_TYPE_OFF_T
 264 AC_TYPE_PID_T
 265 AC_TYPE_SIGNAL
 266 AC_TYPE_SIZE_T
 267 AC_TYPE_UID_T
 268
 269 AC_CHECK_FUNCS(strerror)
 270 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 271 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 272
 273 # Check the form of mkdir()
 274 AC_FUNC_MKDIR
 275
 276 # check for compression support
 277 AC_CHECK_HEADERS(zlib.h,
 278  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_ERROR([zlib not found!]))],
 279  [LYX_ERROR([zlib.h not found!])])
 280
 281 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 282 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 283 dnl We aim to remove this eventually, since we should test as much as
 284 dnl possible with the compiler which will use the functions (JMarc)
 285 AC_LANG_PUSH(C)
 286 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 287 AC_LANG_POP(C)
 288
 289 LYX_CHECK_SPELL_ENGINES
 290
 291 lyx_client_subdir=true
 292 AC_LANG_PUSH(C)
 293 dnl LIBS already contains some X extra libs that may interfere.
 294 save_LIBS="$LIBS"
 295 LIBS=
 296 AC_CHECK_FUNCS(fcntl,
 297   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 298    AC_SEARCH_LIBS([socket], [socket], [],
 299      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 300                 [], [-lnsl])])],
 301   [lyx_client_subdir=false])
 302 AC_SUBST(SOCKET_LIBS,$LIBS)
 303 LIBS="$save_LIBS"
 304 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 305 AC_LANG_POP(C)
 306
 307 AC_FUNC_SELECT_ARGTYPES
 308
 309 ### Some information on what just happened
 310 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 311 real_pkgdatadir=`eval "echo \`eval \"echo ${pkgdatadir}\"\`"`
 312 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 313 VERSION_INFO="Configuration\n\
 314   Host type:                      ${host}\n\
 315   Special build flags:            ${lyx_flags}\n\
 316   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 317   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 318   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 319   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 320   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 321   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 322   Linker flags:                   ${AM_LDFLAGS}\n\
 323   Linker user flags:              ${LDFLAGS}\n\
 324 ${FRONTEND_INFO}\
 325   Packaging:                      ${lyx_use_packaging}\n\
 326   LyX binary dir:                 ${real_bindir}\n\
 327   LyX files dir:                  ${real_pkgdatadir}\n"
 328
 329 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 330 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 331 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_pkgdatadir})
 332
 333 AC_SUBST(VERSION_INFO)
 334 AC_SUBST(RPM_FRONTEND)
 335 AC_SUBST(AM_CPPFLAGS)
 336 AC_SUBST(AM_CXXFLAGS)
 337 AC_SUBST(AM_CFLAGS)
 338 AC_SUBST(AM_LDFLAGS)
 339 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 340 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 341 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 342
 343 ## Some config.h stuff
 344
 345 AH_TOP([
 346 /* -*- C++ -*- */
 347 /*
 348  * \file config.h
 349  * This file is part of LyX, the document processor.
 350  * Licence details can be found in the file COPYING.
 351  *
 352  * This is the compilation configuration file for LyX.
 353  * It was generated by autoconfs configure.
 354  * You might want to change some of the defaults if something goes wrong
 355  * during the compilation.
 356  */
 357
 358 #ifndef _CONFIG_H
 359 #define _CONFIG_H
 360 ])
 361
 362 AH_BOTTOM([
 363 /************************************************************
 364  ** You should not need to change anything beyond this point */
 365
 366 #ifndef HAVE_STRERROR
 367 #if defined(__cplusplus)
 368 extern "C"
 369 #endif
 370 char * strerror(int n);
 371 #endif
 372
 373 #ifdef HAVE_MKSTEMP
 374 #ifndef HAVE_DECL_MKSTEMP
 375 #if defined(__cplusplus)
 376 extern "C"
 377 #endif
 378 int mkstemp(char*);
 379 #endif
 380 #endif
 381
 382 #ifdef __EMX__
 383 #  include "support/os2_defines.h"
 384 #endif
 385
 386 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 387 #  define USE_BOOST_FORMAT 1
 388 #else
 389 #  define USE_BOOST_FORMAT 0
 390 #endif
 391
 392 #define BOOST_USER_CONFIG <config.h>
 393
 394 #if !defined(ENABLE_ASSERTIONS)
 395 #  define BOOST_DISABLE_ASSERTS 1
 396 #endif
 397 #define BOOST_ENABLE_ASSERT_HANDLER 1
 398
 399 #define BOOST_DISABLE_THREADS 1
 400 #define BOOST_NO_WREGEX 1
 401 #define BOOST_NO_WSTRING 1
 402
 403 #ifdef __CYGWIN__
 404 #  define BOOST_POSIX 1
 405 #endif
 406
 407 #if defined(HAVE_NEWAPIS_H)
 408 #  define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 409 #endif
 410
 411 #endif
 412 ])
 413
 414 ### Finish the work.
 415 AC_CONFIG_FILES([Makefile  m4/Makefile \
 416        boost/Makefile \
 417        boost/libs/Makefile \
 418        boost/libs/filesystem/Makefile \
 419        boost/libs/filesystem/src/Makefile \
 420        boost/libs/iostreams/Makefile \
 421        boost/libs/iostreams/src/Makefile \
 422        boost/libs/regex/Makefile \
 423        boost/libs/regex/src/Makefile \
 424        boost/libs/signals/Makefile \
 425        boost/libs/signals/src/Makefile \
 426        config/Makefile \
 427        development/Makefile \
 428        development/lyx.spec \
 429        lib/Makefile \
 430        lib/doc/Makefile \
 431        lib/lyx2lyx/lyx2lyx_version.py \
 432        lib/lyx2lyx/Makefile \
 433        intl/Makefile \
 434        po/Makefile.in \
 435        sourcedoc/Doxyfile \
 436        sourcedoc/Makefile \
 437        src/client/Makefile \
 438        src/Makefile \
 439        src/version.C-tmp:src/version.C.in \
 440        src/tex2lyx/Makefile \
 441        src/mathed/Makefile \
 442        src/graphics/Makefile \
 443        src/insets/Makefile \
 444        src/support/Makefile \
 445        src/support/tests/Makefile \
 446        src/frontends/Makefile \
 447        src/frontends/controllers/Makefile \
 448        src/frontends/controllers/tests/Makefile \
 449        src/frontends/xforms/Makefile \
 450        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 451        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 452        src/frontends/xforms/forms/Makefile \
 453        src/frontends/gtk/Makefile \
 454        src/frontends/gtk/gimages/Makefile \
 455        src/frontends/gtk/glade/Makefile \
 456        src/frontends/qt3/Makefile \
 457        src/frontends/qt3/moc/Makefile \
 458        src/frontends/qt3/ui/Makefile \
 459        src/frontends/qt3/ui/moc/Makefile \
 460        src/frontends/qt4/Makefile \
 461        src/frontends/qt4/moc/Makefile \
 462        src/frontends/qt4/ui/Makefile \
 463 ])
 464
 465 AC_OUTPUT
 466 # show version information
 467 echo
 468 printf "$VERSION_INFO"
 469 echo
 470
 471 # Display a final warning if there has been a LYX_ERROR
 472 LYX_CHECK_ERRORS