]> git.lyx.org Git - lyx.git/blob - configure.ac
b2803b007f92eeb32edfad2552646fa064668738
[lyx.git] / configure.ac
1 dnl Process with autoconf to generate configure script   -*- sh -*-
2
3 AC_INIT(LyX,1.5.0svn,[lyx-devel@lists.lyx.org],[lyx])
4 AC_SUBST(LYX_DATE, [Fri, Jul 13, 2006])
5 AC_PREREQ(2.52)
6 AC_CONFIG_SRCDIR(src/main.C)
7 AC_CONFIG_HEADERS([src/config.h])
8
9 AC_CONFIG_AUX_DIR(config)
10
11 # First check the version
12 LYX_CHECK_VERSION
13 LYX_VERSION_SUFFIX
14 # Check how the files should be packaged
15 AC_CANONICAL_TARGET
16 LYX_USE_PACKAGING
17 # We need to define these variables here and the no-define option of
18 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
19 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
20
21 dnl default maintainer mode to true for development versions
22 if test "${enable_maintainer_mode+set}" != set; then
23   enable_maintainer_mode=$lyx_devel_version
24 fi
25 AM_MAINTAINER_MODE
26
27 save_PACKAGE=$PACKAGE
28 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
29 PACKAGE=$save_PACKAGE
30
31 ### Set the execute permissions of the various scripts correctly
32 for file in config/install-sh config/mkinstalldirs ; do
33   chmod 755 ${srcdir}/${file}
34 done
35
36 ### Check for programs
37 AC_PROG_MAKE_SET
38 AC_PROG_INSTALL
39
40 AC_PROG_AWK
41 test "$AWK" = gawk && AWK="gawk --posix"
42
43 #AC_PROG_RANLIB
44 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
45 if test "x$KPSEWHICH" = xkpsewhich ; then
46     AC_DEFINE(HAVE_KPSEWHICH, 1,
47     [Define this if you have the kpsewhich program working on your system.])
48 fi
49 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
50
51 # Check for installed python
52 AM_PATH_PYTHON(2.3,, :)
53
54 # Work around a problem in automake 1.4: when invoking install-strip,
55 # INSTALL_PROGRAM is changed to 'install -s', and since
56 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
57 # which returns an error condition when stripping fails.
58 INSTALL_SCRIPT='${INSTALL}'
59
60 ### we will also need a C compiler to compile GNU gettext
61 AC_PROG_CC
62
63 ### check for special systems
64 AC_ISC_POSIX
65 AC_AIX
66
67 ### check which frontend we want to use
68 LYX_USE_FRONTENDS
69
70 ### Check for a C++ compiler
71 LYX_PROG_CXX
72 ### Some checks on what the C++ compiler can(not) do
73 AC_LANG(C++)
74 dnl we do not need that currently (and probably all our supported
75 dnl compiler allow that)
76 dnl LYX_CXX_PARTIAL
77 LYX_CXX_EXPLICIT
78 LYX_CXX_GLOBAL_CSTD
79 LYX_STD_COUNT
80 dnl we disable rtti for now
81 dnl LYX_CXX_RTTI
82 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
83 LYX_CXX_STL_MODERN_STREAMS
84
85 ### and now some special lyx flags.
86 AC_ARG_ENABLE(assertions,
87   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
88   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
89         enable_assertions=yes;
90     else
91         enable_assertions=no;
92     fi;])
93 if test "x$enable_assertions" = xyes ; then
94    lyx_flags="assertions $lyx_flags"
95    AC_DEFINE(ENABLE_ASSERTIONS,1,
96     [Define if you want assertions to be enabled in the code])
97 fi
98
99 ### Library Files
100 dnl by testing these we check if it is ok to have
101 dnl -lc and -lm as args to the compiler
102 AC_CHECK_LIB(m, sin)
103 AC_CHECK_LIB(c, fopen)
104
105 ### Add extra directories to check for libraries.
106 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
107 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
108 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
109
110 ### Add extra directories to check for include files.
111 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
112 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
113 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
114
115 ### Add both includes and libraries
116 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
117 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
118 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
119   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
120
121 ### These are needed in windows
122 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
123 AC_SUBST(LIBSHLWAPI)
124 AC_CHECK_LIB(gdi32, main)
125
126 AC_ARG_WITH(aiksaurus,
127   [  --without-aiksaurus     do not use the Aiksaurus library],
128   [lyx_use_aiksaurus=$withval])
129 if test x$lyx_use_aiksaurus != xno; then
130 AC_CHECK_LIB(Aiksaurus, main,
131         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
132          AIKSAURUS_LIBS="-lAiksaurus"
133          lyx_flags="aiksaurus $lyx_flags"
134         ])
135 AC_CHECK_HEADER(Aiksaurus.h,[
136   ac_cv_header_aiksaurus_h=yes
137   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
138 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
139   ac_cv_header_aiksaurus_h=yes
140   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
141 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
142 fi
143 AC_SUBST(AIKSAURUS_LIBS)
144
145 LYX_USE_INCLUDED_BOOST
146
147 ### Setup libtool
148 dnl Dirty trick ahead: disable libtool checking for a fortran compiler
149 dnl see http://permalink.gmane.org/gmane.comp.gnu.libtool.general/6699
150 dnl Note that this will reportedly not be needed with libtool 2.0
151 m4_undefine([AC_PROG_F77])
152 m4_defun([AC_PROG_F77],[])
153 AC_DISABLE_SHARED
154 AC_LIBTOOL_WIN32_DLL
155 #AM_PROG_LIBTOOL
156 LYX_PROG_LIBTOOL
157
158 ### Check for X libraries
159 AC_PATH_XTRA
160 case $have_x in
161   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
162        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
163   no) LYX_ERROR(dnl
164 [Cannot find X window libraries and/or headers. Check your installation.
165   If you use a Linux system, check that you have installed
166   the development tools.]);;
167   disable) ;;
168 esac
169
170 ### check which frontend we want to use
171
172 dnl The code below is not in a macro, because this would cause big
173 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
174 for frontend in $FRONTENDS ; do
175   case "$frontend" in
176     gtk)
177           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
178           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
179           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
180           RPM_FRONTEND="gtk"
181           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
182           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
183           FRONTEND_INFO="${FRONTEND_INFO}\
184   GTK Frontend:\n\
185     libgtkmm version:\t\t${GTKMM_VERSION}\n\
186     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
187           ;;
188
189     qt3)
190           QT_DO_IT_ALL
191           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt3\$(EXEEXT)"
192           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt3"
193           RPM_FRONTEND="qt3"
194           FRONTEND_INFO="${FRONTEND_INFO}\
195   Qt Frontend:\n\
196       Qt version:\t\t${QT_VERSION}\n"
197 dnl qt build will fail without moc or uic
198           if test -z "$MOC"; then
199             LYX_ERROR([moc binary not found !])
200           fi
201           if test -z "$UIC"; then
202             LYX_ERROR([uic binary not found !])
203           fi
204           if test -z "$QT_LIB"; then
205             LYX_ERROR([qt library not found !])
206           fi
207       ;;
208     qt4)
209           QT4_DO_IT_ALL
210           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
211           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
212           RPM_FRONTEND="qt4"
213           FRONTEND_INFO="${FRONTEND_INFO}\
214   Qt 4 Frontend:\n\
215       Qt 4 version:\t\t${QT4_VERSION}\n"
216 dnl qt 4 build will fail without moc or uic
217           if test -z "$MOC4"; then
218             LYX_ERROR([moc 4 binary not found !])
219           fi
220           if test -z "$UIC4"; then
221             LYX_ERROR([uic 4 binary not found !])
222           fi
223           if test -z "$QT4_LIB"; then
224             LYX_ERROR([qt 4 library not found !])
225           fi
226       ;;
227     *)
228           LYX_ERROR(Unknown frontend '$frontend');;
229   esac
230 done
231
232 # fix the value of the prefixes.
233 test "x$prefix" = xNONE && prefix=$default_prefix
234 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
235 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
236   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
237    causes problems with the Makefiles. The installation will be done in
238    directory \"`pwd`/installprefix\" instead. Please move its contents to
239    the right place after installation.])
240   prefix=`pwd`/installprefix
241 fi
242
243 ### We need iconv for unicode support
244 AM_ICONV
245 if test "$am_cv_func_iconv" = no; then
246   LYX_ERROR([Cannot find required library iconv])
247 fi
248
249 ### Setup GNU gettext
250 dnl GNU gettext is written in C
251 AC_LANG_PUSH(C)
252 AM_GNU_GETTEXT
253 AC_LANG_POP(C)
254
255 # some standard header files
256 AC_HEADER_DIRENT
257 AC_HEADER_MAJOR
258 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
259
260 # some standard structures
261 AC_HEADER_STAT
262 AC_HEADER_TIME
263
264 # some standard types
265 AC_TYPE_MODE_T
266 AC_TYPE_OFF_T
267 AC_TYPE_PID_T
268 AC_TYPE_SIGNAL
269 AC_TYPE_SIZE_T
270 AC_TYPE_UID_T
271
272 AC_CHECK_FUNCS(strerror)
273 LYX_CHECK_DECL(istreambuf_iterator, iterator)
274 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
275
276 # Check the form of mkdir()
277 AC_FUNC_MKDIR
278
279 # check for compression support
280 AC_CHECK_HEADERS(zlib.h,
281  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
282  [LYX_LIB_ERROR(zlib.h,zlib)])
283
284 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
285 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
286 dnl We aim to remove this eventually, since we should test as much as
287 dnl possible with the compiler which will use the functions (JMarc)
288 AC_LANG_PUSH(C)
289 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
290 AC_LANG_POP(C)
291
292 LYX_CHECK_SPELL_ENGINES
293
294 lyx_client_subdir=true
295 AC_LANG_PUSH(C)
296 dnl LIBS already contains some X extra libs that may interfere.
297 save_LIBS="$LIBS"
298 LIBS=
299 AC_CHECK_FUNCS(fcntl,
300   [AC_SEARCH_LIBS([gethostbyname], [nsl])
301    AC_SEARCH_LIBS([socket], [socket], [],
302      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
303                 [], [-lnsl])])],
304   [lyx_client_subdir=false])
305 AC_SUBST(SOCKET_LIBS,$LIBS)
306 LIBS="$save_LIBS"
307 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
308 AC_LANG_POP(C)
309
310 AC_FUNC_SELECT_ARGTYPES
311
312 ### Some information on what just happened
313 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
314 real_pkgdatadir=`eval "echo \`eval \"echo ${pkgdatadir}\"\`"`
315 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
316 VERSION_INFO="Configuration\n\
317   Host type:                      ${host}\n\
318   Special build flags:            ${lyx_flags}\n\
319   C   Compiler:                   ${CC} ${CC_VERSION}\n\
320   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
321   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
322   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
323   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
324   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
325   Linker flags:                   ${AM_LDFLAGS}\n\
326   Linker user flags:              ${LDFLAGS}\n\
327 ${FRONTEND_INFO}\
328   Packaging:                      ${lyx_use_packaging}\n\
329   LyX binary dir:                 ${real_bindir}\n\
330   LyX files dir:                  ${real_pkgdatadir}\n"
331
332 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
333 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
334 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_pkgdatadir})
335
336 AC_SUBST(VERSION_INFO)
337 AC_SUBST(RPM_FRONTEND)
338 AC_SUBST(AM_CPPFLAGS)
339 AC_SUBST(AM_CXXFLAGS)
340 AC_SUBST(AM_CFLAGS)
341 AC_SUBST(AM_LDFLAGS)
342 AC_SUBST(LYX_ABS_TOP_SRCDIR)
343 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
344 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
345
346 ## Some config.h stuff
347
348 AH_TOP([
349 /* -*- C++ -*- */
350 /*
351  * \file config.h
352  * This file is part of LyX, the document processor.
353  * Licence details can be found in the file COPYING.
354  *
355  * This is the compilation configuration file for LyX.
356  * It was generated by autoconfs configure.
357  * You might want to change some of the defaults if something goes wrong
358  * during the compilation.
359  */
360
361 #ifndef _CONFIG_H
362 #define _CONFIG_H
363 ])
364
365 AH_BOTTOM([
366 /************************************************************
367  ** You should not need to change anything beyond this point */
368
369 #ifndef HAVE_STRERROR
370 #if defined(__cplusplus)
371 extern "C"
372 #endif
373 char * strerror(int n);
374 #endif
375
376 #ifdef HAVE_MKSTEMP
377 #ifndef HAVE_DECL_MKSTEMP
378 #if defined(__cplusplus)
379 extern "C"
380 #endif
381 int mkstemp(char*);
382 #endif
383 #endif
384
385 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
386 #  define USE_BOOST_FORMAT 1
387 #else
388 #  define USE_BOOST_FORMAT 0
389 #endif
390
391 #define BOOST_USER_CONFIG <config.h>
392
393 #if !defined(ENABLE_ASSERTIONS)
394 #  define BOOST_DISABLE_ASSERTS 1
395 #endif
396 #define BOOST_ENABLE_ASSERT_HANDLER 1
397
398 #define BOOST_DISABLE_THREADS 1
399 #define BOOST_NO_WREGEX 1
400 #define BOOST_NO_WSTRING 1
401
402 #ifdef __CYGWIN__
403 #  define BOOST_POSIX 1
404 #endif
405
406 #if defined(HAVE_NEWAPIS_H)
407 #  define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
408 #endif
409
410 #endif
411 ])
412
413 ### Finish the work.
414 AC_CONFIG_FILES([Makefile  m4/Makefile \
415        boost/Makefile \
416        boost/libs/Makefile \
417        boost/libs/filesystem/Makefile \
418        boost/libs/filesystem/src/Makefile \
419        boost/libs/iostreams/Makefile \
420        boost/libs/iostreams/src/Makefile \
421        boost/libs/regex/Makefile \
422        boost/libs/regex/src/Makefile \
423        boost/libs/signals/Makefile \
424        boost/libs/signals/src/Makefile \
425        config/Makefile \
426        development/Makefile \
427        development/lyx.spec \
428        lib/Makefile \
429        lib/doc/Makefile \
430        lib/lyx2lyx/lyx2lyx_version.py \
431        lib/lyx2lyx/Makefile \
432        intl/Makefile \
433        po/Makefile.in \
434        sourcedoc/Doxyfile \
435        sourcedoc/Makefile \
436        src/client/Makefile \
437        src/Makefile \
438        src/version.C-tmp:src/version.C.in \
439        src/tex2lyx/Makefile \
440        src/mathed/Makefile \
441        src/graphics/Makefile \
442        src/insets/Makefile \
443        src/support/Makefile \
444        src/support/tests/Makefile \
445        src/frontends/Makefile \
446        src/frontends/controllers/Makefile \
447        src/frontends/controllers/tests/Makefile \
448        src/frontends/gtk/Makefile \
449        src/frontends/gtk/gimages/Makefile \
450        src/frontends/gtk/glade/Makefile \
451        src/frontends/qt3/Makefile \
452        src/frontends/qt3/moc/Makefile \
453        src/frontends/qt3/ui/Makefile \
454        src/frontends/qt3/ui/moc/Makefile \
455        src/frontends/qt4/Makefile \
456        src/frontends/qt4/ui/Makefile \
457 ])
458
459 AC_OUTPUT
460 # show version information
461 echo
462 printf "$VERSION_INFO"
463 echo
464
465 # Display a final warning if there has been a LYX_ERROR
466 LYX_CHECK_ERRORS