configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.6.0svn,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_SUBST(LYX_DATE, ["Wed, Jun 27, 2007"])
   5 AC_PREREQ(2.52)
   6 AC_CONFIG_SRCDIR(src/main.cpp)
   7 AC_CONFIG_HEADERS([src/config.h])
   8
   9 AC_CONFIG_AUX_DIR(config)
  10
  11 # First check the version
  12 LYX_CHECK_VERSION
  13 LYX_VERSION_SUFFIX
  14 # Check how the files should be packaged
  15 AC_CANONICAL_TARGET
  16 LYX_USE_PACKAGING
  17 # We need to define these variables here and the no-define option of
  18 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  19 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  20
  21 dnl default maintainer mode to true for development versions
  22 if test "${enable_maintainer_mode+set}" != set; then
  23   enable_maintainer_mode=$lyx_devel_version
  24 fi
  25 AM_MAINTAINER_MODE
  26
  27 save_PACKAGE=$PACKAGE
  28 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.5])
  29 PACKAGE=$save_PACKAGE
  30
  31 ### Set the execute permissions of the various scripts correctly
  32 for file in config/install-sh config/mkinstalldirs ; do
  33   chmod 755 ${srcdir}/${file}
  34 done
  35
  36 ### Check for programs
  37 AC_PROG_MAKE_SET
  38 AC_PROG_INSTALL
  39
  40 AC_PROG_AWK
  41 test "$AWK" = gawk && AWK="gawk --posix"
  42
  43 #AC_PROG_RANLIB
  44 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  45 if test "x$KPSEWHICH" = xkpsewhich ; then
  46     AC_DEFINE(HAVE_KPSEWHICH, 1,
  47     [Define this if you have the kpsewhich program working on your system.])
  48 fi
  49 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  50
  51 # Check for installed python
  52 AM_PATH_PYTHON(2.3,, :)
  53
  54 # Work around a problem in automake 1.4: when invoking install-strip,
  55 # INSTALL_PROGRAM is changed to 'install -s', and since
  56 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  57 # which returns an error condition when stripping fails.
  58 INSTALL_SCRIPT='${INSTALL}'
  59
  60 ### we will also need a C compiler to compile GNU gettext
  61 AC_PROG_CC
  62
  63 ### check for special systems
  64 AC_ISC_POSIX
  65 AC_AIX
  66
  67 ### we need to know the byte order for unicode conversions
  68 AC_C_BIGENDIAN
  69
  70 ### check which frontend we want to use
  71 LYX_USE_FRONTENDS
  72
  73 ### Check for a C++ compiler
  74 LYX_PROG_CXX
  75 ### Some checks on what the C++ compiler can(not) do
  76 AC_LANG(C++)
  77 dnl we do not need that currently (and probably all our supported
  78 dnl compiler allow that)
  79 dnl LYX_CXX_PARTIAL
  80 dnl LYX_CXX_EXPLICIT
  81 LYX_CXX_GLOBAL_CSTD
  82 dnl LYX_STD_COUNT
  83 dnl we disable rtti for now
  84 dnl LYX_CXX_RTTI
  85 dnl AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  86 dnl LYX_CXX_STL_MODERN_STREAMS
  87
  88 ### and now some special lyx flags.
  89 AC_ARG_ENABLE(assertions,
  90   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  91   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  92         enable_assertions=yes;
  93     else
  94         enable_assertions=no;
  95     fi;])
  96 if test "x$enable_assertions" = xyes ; then
  97    lyx_flags="assertions $lyx_flags"
  98    AC_DEFINE(ENABLE_ASSERTIONS,1,
  99     [Define if you want assertions to be enabled in the code])
 100 fi
 101
 102 ### Library Files
 103 dnl AC_CHECK_LIB(m, sin)
 104
 105 ### Add extra directories to check for libraries.
 106 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 107 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 108 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 109
 110 ### Add extra directories to check for include files.
 111 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 112 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 113 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 114
 115 ### Add both includes and libraries
 116 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 117 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 118 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 119   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 120
 121 ### These are needed in windows
 122 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 123 AC_SUBST(LIBSHLWAPI)
 124 AC_CHECK_LIB(gdi32, main)
 125
 126 AC_ARG_WITH(aiksaurus,
 127   [  --without-aiksaurus     do not use the Aiksaurus library],
 128   [lyx_use_aiksaurus=$withval])
 129 if test x$lyx_use_aiksaurus != xno; then
 130 AC_CHECK_LIB(Aiksaurus, main,
 131         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 132          AIKSAURUS_LIBS="-lAiksaurus"
 133          lyx_flags="aiksaurus $lyx_flags"
 134         ])
 135 AC_CHECK_HEADER(Aiksaurus.h,[
 136   ac_cv_header_aiksaurus_h=yes
 137   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 138 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 139   ac_cv_header_aiksaurus_h=yes
 140   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 141 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 142 fi
 143 AC_SUBST(AIKSAURUS_LIBS)
 144
 145 LYX_USE_INCLUDED_BOOST
 146
 147 # Needed for our char_type
 148 AC_CHECK_SIZEOF(wchar_t)
 149
 150 ### Setup libtool
 151 dnl Dirty trick ahead: disable libtool checking for a fortran compiler
 152 dnl see http://permalink.gmane.org/gmane.comp.gnu.libtool.general/6699
 153 dnl Note that this will reportedly not be needed with libtool 2.0
 154 m4_undefine([AC_PROG_F77])
 155 m4_defun([AC_PROG_F77],[])
 156 #AC_DISABLE_SHARED
 157 AC_DISABLE_STATIC
 158 AC_LIBTOOL_WIN32_DLL
 159 #AM_PROG_LIBTOOL
 160 LYX_PROG_LIBTOOL
 161
 162 ### We need iconv for unicode support (Qt4 frontend requires it too)
 163 AM_ICONV
 164 if test "$am_cv_func_iconv" = no; then
 165   LYX_ERROR([Cannot find required library iconv])
 166 else
 167   LIBS="$LIBS $LIBICONV"
 168 fi
 169
 170 ### check for compression support
 171 AC_CHECK_HEADERS(zlib.h,
 172  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 173  [LYX_LIB_ERROR(zlib.h,zlib)])
 174
 175
 176 ### Check for X libraries
 177 AC_PATH_XTRA
 178 case $have_x in
 179   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 180        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 181   no) LYX_ERROR(dnl
 182 [Cannot find X window libraries and/or headers. Check your installation.
 183   If you use a Linux system, check that you have installed
 184   the development tools.]);;
 185   disable) ;;
 186 esac
 187
 188 ### check which frontend we want to use
 189
 190 dnl The code below is not in a macro, because this would cause big
 191 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 192 for frontend in $FRONTENDS ; do
 193   case "$frontend" in
 194     qt4)
 195           QT4_DO_IT_ALL
 196           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
 197           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
 198           RPM_FRONTEND="qt4"
 199           FRONTEND_INFO="${FRONTEND_INFO}\
 200   Qt 4 Frontend:\n\
 201       Qt 4 version:\t\t${QT4_VERSION}\n"
 202 dnl qt 4 build will fail without moc or uic
 203           if test -z "$MOC4"; then
 204             LYX_ERROR([moc 4 binary not found !])
 205           fi
 206           if test -z "$UIC4"; then
 207             LYX_ERROR([uic 4 binary not found !])
 208           fi
 209           if test -z "$QT4_LIB"; then
 210             LYX_ERROR([qt 4 library not found !])
 211           fi
 212       ;;
 213     *)
 214           LYX_ERROR(Unknown frontend '$frontend');;
 215   esac
 216 done
 217
 218 # fix the value of the prefixes.
 219 test "x$prefix" = xNONE && prefix=$default_prefix
 220 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 221 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 222   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 223    causes problems with the Makefiles. The installation will be done in
 224    directory \"`pwd`/installprefix\" instead. Please move its contents to
 225    the right place after installation.])
 226   prefix=`pwd`/installprefix
 227 fi
 228
 229 ### Setup GNU gettext
 230 dnl GNU gettext is written in C
 231 AC_LANG_PUSH(C)
 232 AM_GNU_GETTEXT
 233 AC_LANG_POP(C)
 234
 235 # some standard header files
 236 AC_HEADER_DIRENT
 237 AC_HEADER_MAJOR
 238 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h io.h process.h NewAPIs.h)
 239
 240 # some standard structures
 241 AC_HEADER_STAT
 242 AC_HEADER_TIME
 243
 244 # some standard types
 245 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 246 AC_TYPE_OFF_T
 247 AC_TYPE_PID_T
 248 AC_TYPE_SIGNAL
 249 AC_TYPE_SIZE_T
 250 AC_TYPE_UID_T
 251
 252 AC_CHECK_FUNCS(strerror)
 253 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 254 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 255
 256 # Check the form of mkdir()
 257 AC_FUNC_MKDIR
 258
 259 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 260 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 261 dnl We aim to remove this eventually, since we should test as much as
 262 dnl possible with the compiler which will use the functions (JMarc)
 263 AC_LANG_PUSH(C)
 264 AC_CHECK_FUNCS(chmod close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 265 AC_LANG_POP(C)
 266
 267 LYX_CHECK_SPELL_ENGINES
 268
 269 lyx_client_subdir=true
 270 AC_LANG_PUSH(C)
 271 dnl LIBS already contains some X extra libs that may interfere.
 272 save_LIBS="$LIBS"
 273 LIBS=
 274 AC_CHECK_FUNCS(fcntl,
 275   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 276    AC_SEARCH_LIBS([socket], [socket], [],
 277      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 278                 [], [-lnsl])])],
 279   [lyx_client_subdir=false])
 280 AC_SUBST(SOCKET_LIBS,$LIBS)
 281 LIBS="$save_LIBS"
 282 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 283 AC_LANG_POP(C)
 284
 285 AC_FUNC_SELECT_ARGTYPES
 286
 287 ### Some information on what just happened
 288 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 289 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 290 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 291 VERSION_INFO="Configuration\n\
 292   Host type:                      ${host}\n\
 293   Special build flags:            ${lyx_flags}\n\
 294   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 295   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 296   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 297   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 298   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 299   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 300   Linker flags:                   ${AM_LDFLAGS}\n\
 301   Linker user flags:              ${LDFLAGS}\n\
 302 ${FRONTEND_INFO}\
 303   Packaging:                      ${lyx_use_packaging}\n\
 304   LyX binary dir:                 ${real_bindir}\n\
 305   LyX files dir:                  ${real_pkgdatadir}\n"
 306
 307 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 308 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 309 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_pkgdatadir})
 310
 311 AC_SUBST(VERSION_INFO)
 312 AC_SUBST(RPM_FRONTEND)
 313 AC_SUBST(AM_CPPFLAGS)
 314 AC_SUBST(AM_CXXFLAGS)
 315 AC_SUBST(AM_CFLAGS)
 316 AC_SUBST(AM_LDFLAGS)
 317 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 318 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 319 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 320
 321 ## Some config.h stuff
 322
 323 AH_TOP([
 324 /* -*- C++ -*- */
 325 /*
 326  * \file config.h
 327  * This file is part of LyX, the document processor.
 328  * Licence details can be found in the file COPYING.
 329  *
 330  * This is the compilation configuration file for LyX.
 331  * It was generated by autoconfs configure.
 332  * You might want to change some of the defaults if something goes wrong
 333  * during the compilation.
 334  */
 335
 336 #ifndef _CONFIG_H
 337 #define _CONFIG_H
 338 ])
 339
 340 AH_BOTTOM([
 341 /************************************************************
 342  ** You should not need to change anything beyond this point */
 343
 344 #ifndef HAVE_STRERROR
 345 #if defined(__cplusplus)
 346 extern "C"
 347 #endif
 348 char * strerror(int n);
 349 #endif
 350
 351 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 352 #  define USE_BOOST_FORMAT 1
 353 #else
 354 #  define USE_BOOST_FORMAT 0
 355 #endif
 356
 357 #define BOOST_USER_CONFIG <config.h>
 358
 359 #if !defined(ENABLE_ASSERTIONS)
 360 #  define BOOST_DISABLE_ASSERTS 1
 361 #endif
 362 #define BOOST_ENABLE_ASSERT_HANDLER 1
 363
 364 #define BOOST_DISABLE_THREADS 1
 365 #define BOOST_NO_WREGEX 1
 366 #define BOOST_NO_WSTRING 1
 367
 368 #ifdef __CYGWIN__
 369 #  define BOOST_POSIX 1
 370 #  define BOOST_POSIX_API 1
 371 #  define BOOST_POSIX_PATH 1
 372 #endif
 373
 374 #if defined(HAVE_NEWAPIS_H)
 375 #  define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 376 #endif
 377
 378 /*
 379  * the FreeBSD libc uses UCS4, but libstdc++ has no proper wchar_t
 380  * support compiled in:
 381  * http://gcc.gnu.org/onlinedocs/libstdc++/faq/index.html#3_9
 382  * And we are not interested at all what libc
 383  * does: What we need is a 32bit wide wchar_t, and a libstdc++ that
 384  * has the needed wchar_t support and uses UCS4. Whether it
 385  * implements this with the help of libc, or whether it has own code
 386  * does not matter for us, because we don't use libc directly (Georg)
 387 */
 388 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4 && !defined(__FreeBSD__) && !defined(__FreeBSD_kernel__)
 389 #  define USE_WCHAR_T
 390 #endif
 391
 392 #endif
 393 ])
 394
 395 ### Finish the work.
 396 AC_CONFIG_FILES([Makefile
 397        boost/Makefile \
 398        config/Makefile \
 399        development/Makefile \
 400        development/MacOSX/Makefile \
 401        development/MacOSX/Info.plist \
 402        development/MacOSX/lyxrc.dist \
 403        development/MacOSX/spotlight/Makefile \
 404        development/lyx.spec \
 405        intl/Makefile \
 406        lib/Makefile \
 407        lib/doc/Makefile \
 408        lib/lyx2lyx/lyx2lyx_version.py \
 409        lib/lyx2lyx/Makefile \
 410        m4/Makefile \
 411        po/Makefile.in \
 412        sourcedoc/Doxyfile \
 413        sourcedoc/Makefile \
 414        src/client/Makefile \
 415        src/Makefile \
 416        src/version.cpp-tmp:src/version.cpp.in \
 417        src/tex2lyx/Makefile \
 418        src/support/Makefile \
 419        src/frontends/Makefile \
 420        src/frontends/controllers/Makefile \
 421        src/frontends/qt4/Makefile \
 422 ])
 423
 424 AC_OUTPUT
 425 # show version information
 426 echo
 427 printf "$VERSION_INFO"
 428 echo
 429
 430 # Display a final warning if there has been a LYX_ERROR
 431 LYX_CHECK_ERRORS