configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.1.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 # Use ISO format only. The frontend needs to parse this
   5 AC_SUBST(LYX_DATE, ["2011-04-29"])
   6 AC_PREREQ(2.52)
   7 AC_CONFIG_SRCDIR(src/main.cpp)
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AC_CONFIG_AUX_DIR(config)
  11
  12 # First check the version
  13 LYX_CHECK_VERSION
  14 LYX_VERSION_SUFFIX
  15 # Check how the files should be packaged
  16 AC_CANONICAL_TARGET
  17 LYX_USE_PACKAGING
  18 # We need to define these variables here and the no-define option of
  19 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  20 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  21
  22 dnl Default maintainer mode to true for development versions
  23 if test "${enable_maintainer_mode+set}" != set; then
  24   enable_maintainer_mode=$lyx_devel_version
  25 fi
  26 AM_MAINTAINER_MODE
  27
  28 save_PACKAGE=$PACKAGE
  29 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8])
  30 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  31 PACKAGE=$save_PACKAGE
  32
  33 # Allow to build some parts of the code as one big chunk
  34 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt4])
  35 AC_ARG_ENABLE(monolithic-build,
  36   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  37                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  38   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  39    test "$enable_monolithic_build" = no && enable_monolithic_build=
  40    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  41    for i in $enable_monolithic_build ; do
  42        eval "enable_monolithic_$i=yes"
  43    done
  44    IFS="$ac_save_ifs"],
  45   [enable_monolithic_build=])
  46
  47 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  48 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  49 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  50 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  51 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  52 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  53 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT4, test "x$enable_monolithic_frontend_qt4" = "xyes")
  54
  55 ### Set the execute permissions of the various scripts correctly
  56 for file in config/install-sh ; do
  57   chmod 755 ${srcdir}/${file}
  58 done
  59
  60 # Check for installed python
  61 AM_PATH_PYTHON(2.4.0,, :)
  62
  63 ### we need to know the byte order for unicode conversions
  64 AC_C_BIGENDIAN
  65
  66 ### check which frontend we want to use
  67 LYX_USE_FRONTENDS
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71
  72 ### Objective-C compiler
  73 AC_PROG_OBJC
  74 _AM_DEPENDENCIES([OBJC])
  75
  76 ### Add extra directories to check for libraries.
  77 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  78 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  79 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  80
  81 ### Add extra directories to check for include files.
  82 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  83 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  84 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  85
  86 ### Add both includes and libraries
  87 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  88 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  89 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  90   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  91
  92 ### These are needed in windows
  93 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  94 AC_SUBST(LIBSHLWAPI)
  95 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  96 AC_SUBST(LIBPSAPI)
  97 AC_CHECK_LIB(gdi32, main)
  98
  99 LYX_USE_INCLUDED_BOOST
 100 LYX_USE_INCLUDED_MYTHES
 101
 102 # Needed for our char_type
 103 AC_CHECK_SIZEOF(wchar_t)
 104
 105 ### We need iconv for unicode support (Qt4 frontend requires it too)
 106 AM_ICONV
 107 if test "$am_cv_func_iconv" = no; then
 108   LYX_ERROR([Cannot find required library iconv])
 109 else
 110   LIBS="$LIBS $LIBICONV"
 111 fi
 112
 113 ### check for compression support
 114 AC_CHECK_HEADERS(zlib.h,
 115  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 116  [LYX_LIB_ERROR(zlib.h,zlib)])
 117
 118 ### check for file magic support (currently optional)
 119 AC_CHECK_HEADERS(magic.h,
 120  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 121   LYX_WARNING([Cannot find limagic. Please check that the libmagic library
 122    is correctly installed on your system.
 123    Falling back to builtin file format detection.]))],
 124  [LYX_WARNING([Cannot find magic.h. Please check that the libmagic library
 125    is correctly installed on your system.
 126    Falling back to builtin file format detection.])])
 127
 128
 129 ### check which frontend we want to use
 130
 131 dnl The code below is not in a macro, because this would cause big
 132 dnl problems with the AC_REQUIRE contained in QT4_DO_IT_ALL.
 133 for frontend in $FRONTENDS ; do
 134   case "$frontend" in
 135     qt4)
 136           QT4_DO_IT_ALL
 137           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
 138           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
 139           RPM_FRONTEND="qt4"
 140           FRONTEND_INFO="${FRONTEND_INFO}\
 141   Qt 4 Frontend:\n\
 142       Qt 4 version:\t\t${QT4_VERSION}\n"
 143 dnl qt 4 build will fail without moc, uic, or bc
 144           if test -z "$MOC4"; then
 145             LYX_ERROR([moc 4 binary not found !])
 146           fi
 147           if test -z "$UIC4"; then
 148             LYX_ERROR([uic 4 binary not found !])
 149           fi
 150           if test -z "$QT4_LIB"; then
 151             LYX_ERROR([qt 4 library not found !])
 152           fi
 153           if test "$bc_found" = "no"; then
 154             LYX_ERROR([bc binary not found !])
 155           fi
 156       ;;
 157     *)
 158           LYX_ERROR(Unknown frontend '$frontend');;
 159   esac
 160 done
 161
 162 # fix the value of the prefixes.
 163 test "x$prefix" = xNONE && prefix=$default_prefix
 164 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 165 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 166   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 167    causes problems with the Makefiles. The installation will be done in
 168    directory \"`pwd`/installprefix\" instead. Please move its contents to
 169    the right place after installation.])
 170   prefix=`pwd`/installprefix
 171 fi
 172
 173 ### Setup GNU gettext
 174 dnl GNU gettext is written in C
 175 AC_LANG_PUSH(C)
 176 dnl Dirty trick ahead: disable macro AC_GNU_SOURCE because it triggers a bug with autoconf 2.62.
 177 dnl this can be removed if gettext is been updated to avoid that.
 178 m4_undefine([AC_GNU_SOURCE])
 179 m4_defun([AC_GNU_SOURCE],[])
 180 AM_GNU_GETTEXT([no-libtool])
 181 AM_GNU_GETTEXT_VERSION([0.16.1])
 182 AC_LANG_POP(C)
 183
 184 # some standard header files
 185 AC_HEADER_MAJOR
 186 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 187
 188 # some standard structures
 189 AC_HEADER_STAT
 190 AC_HEADER_TIME
 191
 192 # some standard types
 193 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 194 AC_TYPE_OFF_T
 195 AC_TYPE_PID_T
 196 AC_TYPE_SIGNAL
 197 AC_TYPE_SIZE_T
 198 AC_TYPE_UID_T
 199
 200 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 201
 202 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lstat mkfifo open _open pclose _pclose popen _popen readlink strerror unsetenv)
 203 # Check the form of mkdir()
 204 AC_FUNC_MKDIR
 205 AC_FUNC_SELECT_ARGTYPES
 206
 207 LYX_CHECK_SPELL_ENGINES
 208
 209 lyx_client_subdir=true
 210 AC_LANG_PUSH(C)
 211 dnl LIBS already contains some X extra libs that may interfere.
 212 save_LIBS="$LIBS"
 213 LIBS=
 214 AC_CHECK_FUNCS(fcntl,
 215   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 216    AC_SEARCH_LIBS([socket], [socket], [],
 217      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 218                 [], [-lnsl])])],
 219   [lyx_client_subdir=false])
 220 AC_SUBST(SOCKET_LIBS,$LIBS)
 221 LIBS="$save_LIBS"
 222 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 223 AC_LANG_POP(C)
 224
 225 lyx_win_res=false;
 226 case ${host} in
 227     *mingw*|*cygwin*) lyx_win_res=true;;
 228 esac
 229 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 230 LYX_SET_VERSION_INFO
 231
 232
 233 ### Some information on what just happened
 234 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 235 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 236 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 237 VERSION_INFO="Configuration\n\
 238   Host type:                    ${host}\n\
 239   Special build flags:         ${lyx_flags}\n\
 240   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 241   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 242   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 243   Linker flags:                 ${AM_LDFLAGS}\n\
 244   Linker user flags:            ${LDFLAGS}\n\
 245 ${FRONTEND_INFO}\
 246   Packaging:                    ${lyx_use_packaging}\n\
 247   LyX binary dir:               ${real_bindir}\n\
 248   LyX files dir:                ${real_pkgdatadir}\n"
 249
 250 AC_SUBST(VERSION_INFO)
 251 AC_SUBST(RPM_FRONTEND)
 252 AC_SUBST(AM_CPPFLAGS)
 253 AC_SUBST(AM_CXXFLAGS)
 254 AC_SUBST(AM_CFLAGS)
 255 AC_SUBST(AM_LDFLAGS)
 256 AC_SUBST(real_pkgdatadir)
 257
 258 ## Some config.h stuff
 259
 260 AH_TOP([
 261 /* -*- C++ -*- */
 262 /*
 263  * \file config.h
 264  * This file is part of LyX, the document processor.
 265  * Licence details can be found in the file COPYING.
 266  *
 267  * This is the compilation configuration file for LyX.
 268  * It was generated by autoconfs configure.
 269  * You might want to change some of the defaults if something goes wrong
 270  * during the compilation.
 271  */
 272
 273 #ifndef _CONFIG_H
 274 #define _CONFIG_H
 275 ])
 276
 277 AH_BOTTOM([
 278 /************************************************************
 279  ** You should not need to change anything beyond this point */
 280
 281 #ifndef HAVE_STRERROR
 282 #if defined(__cplusplus)
 283 extern "C"
 284 #endif
 285 char * strerror(int n);
 286 #endif
 287
 288 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 289 #  define USE_BOOST_FORMAT 1
 290 #else
 291 #  define USE_BOOST_FORMAT 0
 292 #endif
 293
 294 #define BOOST_USER_CONFIG <config.h>
 295
 296 #if !defined(ENABLE_ASSERTIONS)
 297 #  define BOOST_DISABLE_ASSERTS 1
 298 #endif
 299 #define BOOST_ENABLE_ASSERT_HANDLER 1
 300
 301 #define BOOST_DISABLE_THREADS 1
 302 #define BOOST_NO_WREGEX 1
 303 #define BOOST_NO_WSTRING 1
 304
 305 // TR1 regex not supported in GCC <= 4.5
 306 #ifndef LYX_USE_TR1
 307 #  if __GNUC__ == 4
 308 #    define LYX_USE_TR1
 309 #  endif
 310 #endif
 311
 312 #ifdef __CYGWIN__
 313 #  define NOMINMAX
 314 #  define BOOST_POSIX 1
 315 #  define BOOST_POSIX_API 1
 316 #  define BOOST_POSIX_PATH 1
 317 #endif
 318
 319 /*
 320  * the FreeBSD libc uses UCS4, but libstdc++ has no proper wchar_t
 321  * support compiled in:
 322  * http://gcc.gnu.org/onlinedocs/libstdc++/faq/index.html#3_9
 323  * And we are not interested at all what libc
 324  * does: What we need is a 32bit wide wchar_t, and a libstdc++ that
 325  * has the needed wchar_t support and uses UCS4. Whether it
 326  * implements this with the help of libc, or whether it has own code
 327  * does not matter for us, because we do not use libc directly (Georg)
 328 */
 329 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4 && !defined(__FreeBSD__) && !defined(__FreeBSD_kernel__)
 330 #  define USE_WCHAR_T
 331 #endif
 332
 333 #endif
 334 ])
 335
 336 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 337 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 338 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 339
 340 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 341         "${lyx_abs_top_srcdir}", [Top source directory])
 342 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 343         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 344 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 345         "${lyx_abs_installed_datadir}",[Hard system support directory])
 346 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 347         "${version_suffix}",[Program version suffix])
 348
 349 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 350 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 351 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 352 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 353 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 354 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 355 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 356 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 357
 358 AC_CONFIG_FILES([Makefile \
 359       lyx.1:lyx.1in \
 360       boost/Makefile \
 361       config/Makefile \
 362       development/Makefile \
 363       development/MacOSX/Makefile \
 364       development/MacOSX/Info.plist \
 365       development/MacOSX/lyxrc.dist \
 366       development/MacOSX/spotlight/Makefile \
 367       development/cygwin/Makefile \
 368       development/cygwin/lyxrc.dist \
 369       development/lyx.spec \
 370       intl/Makefile \
 371       lib/lyx.desktop-temp:lib/lyx.desktop.in
 372       lib/Makefile \
 373       lib/doc/Makefile \
 374       lib/lyx2lyx/lyx2lyx_version.py \
 375       lib/lyx2lyx/Makefile \
 376       m4/Makefile \
 377       po/Makefile.in \
 378       sourcedoc/Doxyfile \
 379       sourcedoc/Makefile \
 380       src/client/Makefile \
 381       src/client/lyxclient.1:src/client/lyxclient.1in \
 382       src/Makefile \
 383       src/tex2lyx/Makefile \
 384       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 385       src/support/Makefile \
 386       src/frontends/Makefile \
 387       src/frontends/qt4/Makefile
 388 ])
 389
 390
 391 AC_OUTPUT
 392
 393 # show version information
 394 echo
 395 printf "$VERSION_INFO"
 396 echo
 397
 398 # Display a final warning if there has been a LYX_ERROR
 399 LYX_CHECK_ERRORS