configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AM_MAINTAINER_MODE
  15 AC_CANONICAL_TARGET
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### check which frontend we want to use
  59 LYX_USE_FRONTENDS
  60
  61 ### Check for a C++ compiler
  62 LYX_PROG_CXX
  63 ### Some checks on what the C++ compiler can(not) do
  64 AC_LANG(C++)
  65 dnl we do not need that currently (and probably all our supported
  66 dnl compiler allow that)
  67 dnl LYX_CXX_PARTIAL
  68 LYX_CXX_EXPLICIT
  69 LYX_CXX_STL_STRING
  70 LYX_CXX_GOOD_STD_STRING
  71 LYX_CXX_CHEADERS
  72 LYX_CXX_GLOBAL_CSTD
  73 LYX_STD_COUNT
  74 dnl we disable rtti for now
  75 dnl LYX_CXX_RTTI
  76 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  77 LYX_CXX_STL_MODERN_STREAMS
  78
  79 ### and now some special lyx flags.
  80 AC_ARG_ENABLE(assertions,
  81   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  82   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  83         enable_assertions=yes;
  84     else
  85         enable_assertions=no;
  86     fi;])
  87 if test "x$enable_assertions" = xyes ; then
  88    lyx_flags="$lyx_flags assertions"
  89    AC_DEFINE(ENABLE_ASSERTIONS,1,
  90     [Define if you want assertions to be enabled in the code])
  91 fi
  92
  93 ### Library Files
  94 dnl by testing these we check if it is ok to have
  95 dnl -lc and -lm as args to the compiler
  96 AC_CHECK_LIB(m, sin)
  97 AC_CHECK_LIB(c, fopen)
  98
  99 ### Add extra directories to check for libraries.
 100 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 101 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 102 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 103
 104 ### Add extra directories to check for include files.
 105 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 107 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 108
 109 ### Add both includes and libraries
 110 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 111 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 112 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 113   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 114
 115 AC_ARG_WITH(aiksaurus,
 116   [  --without-aiksaurus     do not use the Aiksaurus library],
 117   [lyx_use_aiksaurus=$withval])
 118 if test x$lyx_use_aiksaurus != xno; then
 119 AC_CHECK_LIB(Aiksaurus, main,
 120         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 121          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 122         ],,"-lbz2")
 123 AC_CHECK_HEADER(Aiksaurus.h,[
 124   ac_cv_header_aiksaurus_h=yes
 125   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 126 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 127   ac_cv_header_aiksaurus_h=yes
 128   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 129 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 130 fi
 131 AC_SUBST(AIKSAURUS_LIBS)
 132
 133 LYX_USE_INCLUDED_BOOST
 134
 135 ### Setup libtool
 136 AC_DISABLE_SHARED
 137 AC_LIBTOOL_WIN32_DLL
 138 #AM_PROG_LIBTOOL
 139 LYX_PROG_LIBTOOL
 140
 141 ### Check if we want spell libraries, prefer new aspell
 142 CHECK_WITH_ASPELL
 143 if test "$USING_ASPELL" != "yes"; then
 144         CHECK_WITH_PSPELL
 145 fi
 146
 147 ### Check for some Cygwin-specific details.
 148 CHECK_WITH_CYGWIN
 149
 150 ### Check for X libraries
 151 AC_PATH_XTRA
 152 case $have_x in
 153   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 154        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 155   no) LYX_ERROR(dnl
 156 [Cannot find X window libraries and/or headers. Check your installation.
 157   If you use a Linux system, check that you have installed
 158   the development tools.]);;
 159   disable) ;;
 160 esac
 161
 162 ### check which frontend we want to use
 163
 164 dnl The code below is not in a macro, because this would cause big
 165 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 166 for frontend in $FRONTENDS ; do
 167   case "$frontend" in
 168     xforms)
 169           XFORMS_DO_IT_ALL
 170           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 171           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 172           RPM_FRONTEND="xforms"
 173           RPM_FRONTEND_DEPS='libforms >= 1.0'
 174           FRONTEND_INFO="${FRONTEND_INFO}\
 175   XForms Frontend:\n\
 176       libXpm version:               ${XPM_VERSION}\n\
 177       libforms version:             ${XFORMS_VERSION}\n"
 178           ;;
 179   dnl   gnome)
 180   dnl     XFORMS_DO_IT_ALL
 181   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 182   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 183   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 184
 185   dnl     FRONTEND="xforms gnome"
 186   dnl     FRONTEND_GUILIB="gnome/*.lo"
 187   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 188   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 189   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 190   dnl   ;;
 191     gtk)
 192           XFORMS_DO_IT_ALL
 193           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.0 libglademm-2.0)
 194           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 195           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms gtk"
 196           RPM_FRONTEND="gtk"
 197           RPM_FRONTEND_DEPS='gtkmm >= 2.2.0'
 198           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.0`
 199           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.0`
 200           FRONTEND_INFO="    libgtkmm version:             ${GTKMM_VERSION}\n\
 201     libglademm version:           ${LIBGLADEMM_VERSION}\n"
 202           ;;
 203
 204     qt)
 205           QT_DO_IT_ALL
 206           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 207           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 208           RPM_FRONTEND="qt"
 209           RPM_FRONTEND_DEPS='qt >= 2.2.1'
 210           FRONTEND_INFO="${FRONTEND_INFO}\
 211   Qt Frontend:\n\
 212       Qt version:                   ${QT_VERSION}\n"
 213       ;;
 214     *)
 215           LYX_ERROR(Unknown frontend '$frontend');;
 216   esac
 217 done
 218
 219 ### Setup GNU gettext
 220 dnl GNU gettext is written in C
 221 AC_LANG_PUSH(C)
 222 # Some tests that may be useful for gettext
 223 AC_C_CONST
 224 AC_C_INLINE
 225 # Do the real setup now
 226 AM_GNU_GETTEXT
 227 # a hack for those who try to change LyX, but do not have gettext installed
 228 case  "${XGETTEXT}" in
 229  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 230 esac
 231
 232 AC_SUBST(LINGUAS)
 233
 234 AC_LANG_POP(C)
 235
 236 # some standard header files
 237 AC_HEADER_DIRENT
 238 AC_HEADER_MAJOR
 239 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 240
 241 # some standard structures
 242 AC_HEADER_STAT
 243 AC_HEADER_TIME
 244
 245 # some standard types
 246 AC_TYPE_MODE_T
 247 AC_TYPE_OFF_T
 248 AC_TYPE_PID_T
 249 AC_TYPE_SIGNAL
 250 AC_TYPE_SIZE_T
 251 AC_TYPE_UID_T
 252
 253 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 254 LYX_CHECK_DECL(snprintf, stdio.h)
 255 LYX_CHECK_DECL(vsnprintf, stdio.h)
 256 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 257 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 258
 259 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 260     case "${enableval}" in
 261         yes) use_compression=true ;;
 262         no) use_compression=false ;;
 263         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 264     esac
 265 ],[use_compression=true])
 266 if test $use_compression=true ; then
 267         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 268         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 269         if test $use_compression = true ; then
 270                 AC_DEFINE(USE_COMRESSION, 1, [Define as 1 if you want to supprot compressed files.])
 271                 lyx_flags="$lyx_flags compression"
 272         fi
 273 fi
 274 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 275 AC_MSG_CHECKING([whether to support compressed files])
 276 AC_MSG_RESULT($use_compression)
 277
 278
 279 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 280 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 281 dnl We aim to remove this eventually, since we should test as much as
 282 dnl possible with the compiler which will use the functions (JMarc)
 283 AC_LANG_PUSH(C)
 284 AC_CHECK_FUNCS(memmove memset strchr mkfifo mkstemp mktemp)
 285 AC_LANG_POP(C)
 286
 287 AC_FUNC_SELECT_ARGTYPES
 288
 289 ### Some information on what just happened
 290 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 291 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 292 VERSION_INFO="Configuration\n\
 293   Host type:                      ${host}\n\
 294   Special build flags:           ${lyx_flags}\n\
 295   C   Compiler:                   ${CC}\n\
 296   C   Compiler flags:             ${CFLAGS}\n\
 297   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 298   C++ Compiler flags:             ${CXXFLAGS}\n\
 299   Linker flags:                   ${LDFLAGS}\n\
 300 ${FRONTEND_INFO}\
 301   LyX binary dir:                 ${real_bindir}\n\
 302   LyX files dir:                  ${real_datadir}\n"
 303
 304
 305 AC_SUBST(VERSION_INFO)
 306 AC_SUBST(RPM_FRONTEND)
 307 AC_SUBST(RPM_FRONTEND_DEPS)
 308
 309 ## Some config.h stuff
 310
 311 AH_TOP([
 312 /* -*- C++ -*- */
 313 /*
 314  * \file config.h
 315  * This file is part of LyX, the document processor.
 316  * Licence details can be found in the file COPYING.
 317  *
 318  * This is the compilation configuration file for LyX.
 319  * It was generated by autoconfs configure.
 320  * You might want to change some of the defaults if something goes wrong
 321  * during the compilation.
 322  */
 323
 324 #ifndef _CONFIG_H
 325 #define _CONFIG_H
 326 ])
 327
 328 AH_BOTTOM([
 329 /************************************************************
 330  ** You should not need to change anything beyond this point */
 331
 332 #ifndef HAVE_STRCHR
 333 # define strchr(a,b)    index(a,b)
 334 #endif
 335
 336 #ifndef HAVE_MEMMOVE
 337 # define memmove(a,b,c) bcopy(b,a,c)
 338 #endif
 339
 340 #ifndef HAVE_STRERROR
 341 #if defined(__cplusplus)
 342 extern "C"
 343 #endif
 344 char * strerror(int n);
 345 #endif
 346
 347 #ifdef BROKEN_HEADERS
 348 #include "broken_headers.h"
 349 #endif
 350
 351 #ifdef HAVE_MKSTEMP
 352 #ifndef HAVE_DECL_MKSTEMP
 353 #if defined(__cplusplus)
 354 extern "C"
 355 #endif
 356 int mkstemp(char*);
 357 #endif
 358 #endif
 359
 360 #ifdef __EMX__
 361 #include "support/os2_defines.h"
 362 #endif
 363
 364 #if defined(__CYGWIN__) || defined(__CYGWIN32__)
 365 #include "support/nt_defines.h"
 366 #endif
 367
 368 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 369 #define USE_BOOST_FORMAT 1
 370 #else
 371 #define USE_BOOST_FORMAT 0
 372 #endif
 373
 374 #define BOOST_DISABLE_THREADS 1
 375 #define BOOST_NO_WREGEX 1
 376 #define BOOST_NO_WSTRING 1
 377
 378 #endif
 379 ])
 380
 381 ### Finish the work.
 382 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 383 AC_CONFIG_FILES([Makefile \
 384        boost/Makefile \
 385        boost/libs/Makefile \
 386        boost/libs/regex/Makefile \
 387        boost/libs/regex/src/Makefile \
 388        boost/libs/signals/Makefile \
 389        boost/libs/signals/src/Makefile \
 390        config/Makefile \
 391        development/Makefile \
 392        development/lyx.spec \
 393        lib/Makefile \
 394        intl/Makefile \
 395        po/Makefile.in \
 396        sourcedoc/Doxyfile \
 397        sourcedoc/Makefile \
 398        src/Makefile \
 399        src/version.C-tmp:src/version.C.in \
 400        src/tex2lyx/Makefile \
 401        src/mathed/Makefile \
 402        src/graphics/Makefile \
 403        src/insets/Makefile \
 404        src/support/Makefile \
 405        src/frontends/Makefile \
 406        src/frontends/controllers/Makefile \
 407        src/frontends/xforms/Makefile \
 408        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 409        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 410        src/frontends/xforms/forms/Makefile \
 411        src/frontends/gtk/Makefile \
 412        src/frontends/gtk/glade/Makefile \
 413        src/frontends/qt2/Makefile \
 414        src/frontends/qt2/moc/Makefile \
 415        src/frontends/qt2/ui/Makefile \
 416        src/frontends/qt2/ui/moc/Makefile \
 417        src/frontends/gnome/Makefile \
 418 ])
 419
 420 AC_OUTPUT
 421 # show version information
 422 echo
 423 printf "$VERSION_INFO"
 424 echo
 425
 426 # Display a final warning if there has been a LYX_ERROR
 427 LYX_CHECK_ERRORS