configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.4.0svn,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AC_CONFIG_HEADERS([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 # First check the version
  11 LYX_CHECK_VERSION
  12 LYX_VERSION_SUFFIX
  13 # Check how the files should be packaged
  14 AC_CANONICAL_TARGET
  15 LYX_USE_PACKAGING
  16 # We need to define these variables here and the no-define option of
  17 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  18 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  19
  20 dnl default maintainer mode to true for development versions
  21 if test "${enable_maintainer_mode+set}" != set; then
  22   enable_maintainer_mode=$lyx_devel_version
  23 fi
  24 AM_MAINTAINER_MODE
  25
  26 save_PACKAGE=$PACKAGE
  27 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
  28 PACKAGE=$save_PACKAGE
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38
  39 AC_PROG_AWK
  40 test "$AWK" = gawk && AWK="gawk --posix"
  41
  42 #AC_PROG_RANLIB
  43 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  44 if test "x$KPSEWHICH" = xkpsewhich ; then
  45     AC_DEFINE(HAVE_KPSEWHICH, 1,
  46     [Define this if you have the kpsewhich program working on your system.])
  47 fi
  48 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  49
  50 # Check for installed python
  51 AM_PATH_PYTHON(1.5.2,, :)
  52
  53 # Work around a problem in automake 1.4: when invoking install-strip,
  54 # INSTALL_PROGRAM is changed to 'install -s', and since
  55 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  56 # which returns an error condition when stripping fails.
  57 INSTALL_SCRIPT='${INSTALL}'
  58
  59 ### we will also need a C compiler to compile GNU gettext
  60 AC_PROG_CC
  61
  62 ### check for special systems
  63 AC_ISC_POSIX
  64 AC_AIX
  65
  66 ### check which frontend we want to use
  67 LYX_USE_FRONTENDS
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG(C++)
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_GLOBAL_CSTD
  78 LYX_STD_COUNT
  79 dnl we disable rtti for now
  80 dnl LYX_CXX_RTTI
  81 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  82 LYX_CXX_STL_MODERN_STREAMS
  83
  84 ### and now some special lyx flags.
  85 AC_ARG_ENABLE(assertions,
  86   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  87   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  88         enable_assertions=yes;
  89     else
  90         enable_assertions=no;
  91     fi;])
  92 if test "x$enable_assertions" = xyes ; then
  93    lyx_flags="assertions $lyx_flags"
  94    AC_DEFINE(ENABLE_ASSERTIONS,1,
  95     [Define if you want assertions to be enabled in the code])
  96 fi
  97
  98 ### Library Files
  99 dnl by testing these we check if it is ok to have
 100 dnl -lc and -lm as args to the compiler
 101 AC_CHECK_LIB(m, sin)
 102 AC_CHECK_LIB(c, fopen)
 103
 104 ### Add extra directories to check for libraries.
 105 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 107 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 108
 109 ### Add extra directories to check for include files.
 110 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 111 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 112 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 113
 114 ### Add both includes and libraries
 115 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 116 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 117 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 118   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 119
 120 AC_ARG_WITH(aiksaurus,
 121   [  --without-aiksaurus     do not use the Aiksaurus library],
 122   [lyx_use_aiksaurus=$withval])
 123 if test x$lyx_use_aiksaurus != xno; then
 124 AC_CHECK_LIB(Aiksaurus, main,
 125         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 126          AIKSAURUS_LIBS="-lAiksaurus"
 127          lyx_flags="aiksaurus $lyx_flags"
 128         ])
 129 AC_CHECK_HEADER(Aiksaurus.h,[
 130   ac_cv_header_aiksaurus_h=yes
 131   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 132 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 133   ac_cv_header_aiksaurus_h=yes
 134   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 135 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 136 fi
 137 AC_SUBST(AIKSAURUS_LIBS)
 138
 139 LYX_USE_INCLUDED_BOOST
 140
 141 ### Setup libtool
 142 AC_DISABLE_SHARED
 143 AC_LIBTOOL_WIN32_DLL
 144 #AM_PROG_LIBTOOL
 145 LYX_PROG_LIBTOOL
 146
 147 ### Check for some Cygwin-specific details.
 148 CHECK_WITH_CYGWIN
 149
 150 ### Check for X libraries
 151 AC_PATH_XTRA
 152 case $have_x in
 153   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 154        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 155   no) LYX_ERROR(dnl
 156 [Cannot find X window libraries and/or headers. Check your installation.
 157   If you use a Linux system, check that you have installed
 158   the development tools.]);;
 159   disable) ;;
 160 esac
 161
 162 ### check which frontend we want to use
 163
 164 dnl The code below is not in a macro, because this would cause big
 165 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 166 for frontend in $FRONTENDS ; do
 167   case "$frontend" in
 168     xforms)
 169           XFORMS_DO_IT_ALL
 170           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 171           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 172           RPM_FRONTEND="xforms"
 173           FRONTEND_INFO="${FRONTEND_INFO}\
 174   XForms Frontend:\n\
 175       libXpm version:\t\t${XPM_VERSION}\n\
 176       libforms version:\t\t${XFORMS_VERSION}\n"
 177           ;;
 178     gtk)
 179           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
 180           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 181           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 182           RPM_FRONTEND="gtk"
 183           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 184           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 185           FRONTEND_INFO="${FRONTEND_INFO}\
 186   GTK Frontend:\n\
 187     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 188     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 189           ;;
 190
 191     qt)
 192           QT_DO_IT_ALL
 193           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 194           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 195           RPM_FRONTEND="qt"
 196           FRONTEND_INFO="${FRONTEND_INFO}\
 197   Qt Frontend:\n\
 198       Qt version:\t\t${QT_VERSION}\n"
 199 dnl qt build will fail without moc or uic
 200           if test -z "$MOC"; then
 201             LYX_ERROR([moc binary not found !])
 202           fi
 203           if test -z "$UIC"; then
 204             LYX_ERROR([uic binary not found !])
 205           fi
 206           if test -z "$QT_LIB"; then
 207             LYX_ERROR([qt library not found !])
 208           fi
 209       ;;
 210     *)
 211           LYX_ERROR(Unknown frontend '$frontend');;
 212   esac
 213 done
 214
 215 # fix the value of the prefixes.
 216 test "x$prefix" = xNONE && prefix=$default_prefix
 217 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 218 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 219   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 220    causes problems with the Makefiles. The installation will be done in
 221    directory \"`pwd`/installprefix\" instead. Please move its contents to
 222    the right place after installation.])
 223   prefix=`pwd`/installprefix
 224 fi
 225
 226 ### Setup GNU gettext
 227 dnl GNU gettext is written in C
 228 AC_LANG_PUSH(C)
 229 AM_GNU_GETTEXT
 230 AC_LANG_POP(C)
 231
 232 # some standard header files
 233 AC_HEADER_DIRENT
 234 AC_HEADER_MAJOR
 235 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 236
 237 # some standard structures
 238 AC_HEADER_STAT
 239 AC_HEADER_TIME
 240
 241 # some standard types
 242 AC_TYPE_MODE_T
 243 AC_TYPE_OFF_T
 244 AC_TYPE_PID_T
 245 AC_TYPE_SIGNAL
 246 AC_TYPE_SIZE_T
 247 AC_TYPE_UID_T
 248
 249 AC_CHECK_FUNCS(strerror)
 250 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 251 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 252
 253 # Check the form of mkdir()
 254 AC_FUNC_MKDIR
 255
 256 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 257     case "${enableval}" in
 258         yes) use_compression=true ;;
 259         no) use_compression=false ;;
 260         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 261     esac
 262 ],[use_compression=true])
 263 if test $use_compression=true ; then
 264         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 265         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 266         if test $use_compression = true ; then
 267                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 268                 lyx_flags="compression $lyx_flags"
 269         fi
 270 fi
 271 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 272 AC_MSG_CHECKING([whether to support compressed files])
 273 AC_MSG_RESULT($use_compression)
 274
 275
 276 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 277 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 278 dnl We aim to remove this eventually, since we should test as much as
 279 dnl possible with the compiler which will use the functions (JMarc)
 280 AC_LANG_PUSH(C)
 281 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 282 AC_LANG_POP(C)
 283
 284 LYX_CHECK_SPELL_ENGINES
 285
 286 lyx_client_subdir=true
 287 AC_LANG_PUSH(C)
 288 dnl LIBS already contains some X extra libs that may interfere.
 289 save_LIBS="$LIBS"
 290 LIBS=
 291 AC_CHECK_FUNCS(fcntl,
 292   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 293    AC_SEARCH_LIBS([socket], [socket], [],
 294      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 295                 [], [-lnsl])])],
 296   [lyx_client_subdir=false])
 297 AC_SUBST(SOCKET_LIBS,$LIBS)
 298 LIBS="$save_LIBS"
 299 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 300 AC_LANG_POP(C)
 301
 302 AC_FUNC_SELECT_ARGTYPES
 303
 304 ### Some information on what just happened
 305 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 306 real_pkgdatadir=`eval "echo \`eval \"echo ${pkgdatadir}\"\`"`
 307 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 308 VERSION_INFO="Configuration\n\
 309   Host type:                      ${host}\n\
 310   Special build flags:            ${lyx_flags}\n\
 311   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 312   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 313   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 314   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 315   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 316   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 317   Linker flags:                   ${AM_LDFLAGS}\n\
 318   Linker user flags:              ${LDFLAGS}\n\
 319 ${FRONTEND_INFO}\
 320   Packaging:                      ${lyx_use_packaging}\n\
 321   LyX binary dir:                 ${real_bindir}\n\
 322   LyX files dir:                  ${real_pkgdatadir}\n"
 323
 324 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 325 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 326 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_pkgdatadir})
 327
 328 AC_SUBST(VERSION_INFO)
 329 AC_SUBST(RPM_FRONTEND)
 330 AC_SUBST(AM_CPPFLAGS)
 331 AC_SUBST(AM_CXXFLAGS)
 332 AC_SUBST(AM_CFLAGS)
 333 AC_SUBST(AM_LDFLAGS)
 334 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 335 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 336 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 337
 338 ## Some config.h stuff
 339
 340 AH_TOP([
 341 /* -*- C++ -*- */
 342 /*
 343  * \file config.h
 344  * This file is part of LyX, the document processor.
 345  * Licence details can be found in the file COPYING.
 346  *
 347  * This is the compilation configuration file for LyX.
 348  * It was generated by autoconfs configure.
 349  * You might want to change some of the defaults if something goes wrong
 350  * during the compilation.
 351  */
 352
 353 #ifndef _CONFIG_H
 354 #define _CONFIG_H
 355 ])
 356
 357 AH_BOTTOM([
 358 /************************************************************
 359  ** You should not need to change anything beyond this point */
 360
 361 #ifndef HAVE_STRERROR
 362 #if defined(__cplusplus)
 363 extern "C"
 364 #endif
 365 char * strerror(int n);
 366 #endif
 367
 368 #ifdef HAVE_MKSTEMP
 369 #ifndef HAVE_DECL_MKSTEMP
 370 #if defined(__cplusplus)
 371 extern "C"
 372 #endif
 373 int mkstemp(char*);
 374 #endif
 375 #endif
 376
 377 #ifdef __EMX__
 378 #include "support/os2_defines.h"
 379 #endif
 380
 381 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 382 #define USE_BOOST_FORMAT 1
 383 #else
 384 #define USE_BOOST_FORMAT 0
 385 #endif
 386
 387 #define BOOST_USER_CONFIG <config.h>
 388
 389 #if defined(ENABLE_ASSERTIONS)
 390 #define BOOST_ENABLE_ASSERT_HANDLER 1
 391 #else
 392 #define BOOST_DISABLE_ASSERTS 1
 393 #endif
 394
 395 #define BOOST_DISABLE_THREADS 1
 396 #define BOOST_NO_WREGEX 1
 397 #define BOOST_NO_WSTRING 1
 398
 399 #ifdef __CYGWIN__
 400 #define BOOST_POSIX 1
 401 #endif
 402
 403 #if defined(HAVE_NEWAPIS_H)
 404 #define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 405 #endif
 406
 407 #endif
 408 ])
 409
 410 ### Finish the work.
 411 AC_CONFIG_SUBDIRS(lib)
 412 AC_CONFIG_FILES([Makefile  m4/Makefile \
 413        boost/Makefile \
 414        boost/libs/Makefile \
 415        boost/libs/filesystem/Makefile \
 416        boost/libs/filesystem/src/Makefile \
 417        boost/libs/regex/Makefile \
 418        boost/libs/regex/src/Makefile \
 419        boost/libs/signals/Makefile \
 420        boost/libs/signals/src/Makefile \
 421        config/Makefile \
 422        development/Makefile \
 423        development/lyx.spec \
 424        lib/Makefile \
 425        lib/doc/Makefile \
 426        lib/lyx2lyx/Makefile \
 427        intl/Makefile \
 428        po/Makefile.in \
 429        sourcedoc/Doxyfile \
 430        sourcedoc/Makefile \
 431        src/client/Makefile \
 432        src/Makefile \
 433        src/version.C-tmp:src/version.C.in \
 434        src/tex2lyx/Makefile \
 435        src/mathed/Makefile \
 436        src/graphics/Makefile \
 437        src/insets/Makefile \
 438        src/support/Makefile \
 439        src/support/tests/Makefile \
 440        src/frontends/Makefile \
 441        src/frontends/controllers/Makefile \
 442        src/frontends/xforms/Makefile \
 443        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 444        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 445        src/frontends/xforms/forms/Makefile \
 446        src/frontends/gtk/Makefile \
 447        src/frontends/gtk/gimages/Makefile \
 448        src/frontends/gtk/glade/Makefile \
 449        src/frontends/qt2/Makefile \
 450        src/frontends/qt2/moc/Makefile \
 451        src/frontends/qt2/ui/Makefile \
 452        src/frontends/qt2/ui/moc/Makefile \
 453 ])
 454
 455 AC_OUTPUT
 456 # show version information
 457 echo
 458 printf "$VERSION_INFO"
 459 echo
 460
 461 # Display a final warning if there has been a LYX_ERROR
 462 LYX_CHECK_ERRORS