configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 # The list of languages known to LyX
  26 # This is needed by GNU gettext
  27 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  28
  29 # fix the value of the prefixes.
  30 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  31 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  32
  33 ### Set the execute permissions of the various scripts correctly
  34 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  35   chmod 755 ${srcdir}/${file}
  36 done
  37
  38 ### Check for programs
  39 AC_PROG_MAKE_SET
  40 AC_PROG_INSTALL
  41 #AC_PROG_RANLIB
  42 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  43 if test "x$KPSEWHICH" = xkpsewhich ; then
  44     AC_DEFINE(HAVE_KPSEWHICH, 1,
  45     [Define this if you have the kpsewhich program working on your system.])
  46 fi
  47 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  48
  49 # Work around a problem in automake 1.4: when invoking install-strip,
  50 # INSTALL_PROGRAM is changed to 'install -s', and since
  51 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  52 # which returns an error condition when stripping fails.
  53 INSTALL_SCRIPT='${INSTALL}'
  54
  55 ### we will also need a C compiler to compile GNU gettext
  56 AC_PROG_CC
  57
  58 ### check for special systems
  59 AC_ISC_POSIX
  60 AC_AIX
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTENDS
  64
  65 ### Check for a C++ compiler
  66 LYX_PROG_CXX
  67 ### Some checks on what the C++ compiler can(not) do
  68 AC_LANG(C++)
  69 dnl we do not need that currently (and probably all our supported
  70 dnl compiler allow that)
  71 dnl LYX_CXX_PARTIAL
  72 LYX_CXX_EXPLICIT
  73 LYX_CXX_CHEADERS
  74 LYX_CXX_GLOBAL_CSTD
  75 LYX_STD_COUNT
  76 dnl we disable rtti for now
  77 dnl LYX_CXX_RTTI
  78 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  79 LYX_CXX_STL_MODERN_STREAMS
  80
  81 ### and now some special lyx flags.
  82 AC_ARG_ENABLE(assertions,
  83   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  84   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  85         enable_assertions=yes;
  86     else
  87         enable_assertions=no;
  88     fi;])
  89 if test "x$enable_assertions" = xyes ; then
  90    lyx_flags="$lyx_flags assertions"
  91    AC_DEFINE(ENABLE_ASSERTIONS,1,
  92     [Define if you want assertions to be enabled in the code])
  93 fi
  94
  95 ### Library Files
  96 dnl by testing these we check if it is ok to have
  97 dnl -lc and -lm as args to the compiler
  98 AC_CHECK_LIB(m, sin)
  99 AC_CHECK_LIB(c, fopen)
 100
 101 ### Add extra directories to check for libraries.
 102 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 104 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 105
 106 ### Add extra directories to check for include files.
 107 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 108 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 109 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 110
 111 ### Add both includes and libraries
 112 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 113 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 114 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 115   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 116
 117 AC_ARG_WITH(aiksaurus,
 118   [  --without-aiksaurus     do not use the Aiksaurus library],
 119   [lyx_use_aiksaurus=$withval])
 120 if test x$lyx_use_aiksaurus != xno; then
 121 AC_CHECK_LIB(Aiksaurus, main,
 122         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 123          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 124         ],,"-lbz2")
 125 AC_CHECK_HEADER(Aiksaurus.h,[
 126   ac_cv_header_aiksaurus_h=yes
 127   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 128 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 129   ac_cv_header_aiksaurus_h=yes
 130   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 131 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 132 fi
 133 AC_SUBST(AIKSAURUS_LIBS)
 134
 135 LYX_USE_INCLUDED_BOOST
 136
 137 ### Setup libtool
 138 AC_DISABLE_SHARED
 139 AC_LIBTOOL_WIN32_DLL
 140 #AM_PROG_LIBTOOL
 141 LYX_PROG_LIBTOOL
 142
 143 ### Check if we want spell libraries, prefer new aspell
 144 CHECK_WITH_ASPELL
 145 if test "$USING_ASPELL" != "yes"; then
 146         CHECK_WITH_PSPELL
 147 fi
 148
 149 ### Check for some Cygwin-specific details.
 150 CHECK_WITH_CYGWIN
 151
 152 ### Check for X libraries
 153 AC_PATH_XTRA
 154 case $have_x in
 155   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 156        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 157   no) LYX_ERROR(dnl
 158 [Cannot find X window libraries and/or headers. Check your installation.
 159   If you use a Linux system, check that you have installed
 160   the development tools.]);;
 161   disable) ;;
 162 esac
 163
 164 ### check which frontend we want to use
 165
 166 dnl if the gtk frontend has been specified, then xforms is needed too
 167 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 168   FRONTENDS="$FRONTENDS xforms"
 169 fi
 170
 171 dnl The code below is not in a macro, because this would cause big
 172 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 173 for frontend in $FRONTENDS ; do
 174   case "$frontend" in
 175     xforms)
 176           XFORMS_DO_IT_ALL
 177           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 178           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 179           RPM_FRONTEND="xforms"
 180           FRONTEND_INFO="${FRONTEND_INFO}\
 181   XForms Frontend:\n\
 182       libXpm version:\t\t${XPM_VERSION}\n\
 183       libforms version:\t\t${XFORMS_VERSION}\n"
 184           ;;
 185   dnl   gnome)
 186   dnl     XFORMS_DO_IT_ALL
 187   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 188   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 189   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 190
 191   dnl     FRONTEND="xforms gnome"
 192   dnl     FRONTEND_GUILIB="gnome/*.lo"
 193   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 194   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 195   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 196   dnl   ;;
 197     gtk)
 198           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 199           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 200           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 201           RPM_FRONTEND="gtk"
 202           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 203           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 204           FRONTEND_INFO="${FRONTEND_INFO}\
 205   GTK Frontend:\n\
 206     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 207     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 208           ;;
 209
 210     qt)
 211           QT_DO_IT_ALL
 212           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 213           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 214           RPM_FRONTEND="qt"
 215           FRONTEND_INFO="${FRONTEND_INFO}\
 216   Qt Frontend:\n\
 217       Qt version:\t\t${QT_VERSION}\n"
 218 dnl qt build will fail without moc or uic
 219           if test -z "$MOC"; then
 220             LYX_ERROR([moc binary not found !])
 221           fi
 222           if test -z "$UIC"; then
 223             LYX_ERROR([uic binary not found !])
 224           fi
 225       ;;
 226     *)
 227           LYX_ERROR(Unknown frontend '$frontend');;
 228   esac
 229 done
 230
 231 ### Setup GNU gettext
 232 dnl GNU gettext is written in C
 233 AC_LANG_PUSH(C)
 234 # Some tests that may be useful for gettext
 235 AC_C_CONST
 236 AC_C_INLINE
 237 # Do the real setup now
 238 AM_GNU_GETTEXT
 239 # a hack for those who try to change LyX, but do not have gettext installed
 240 case  "${XGETTEXT}" in
 241  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 242 esac
 243
 244 AC_SUBST(LINGUAS)
 245
 246 AC_LANG_POP(C)
 247
 248 # some standard header files
 249 AC_HEADER_DIRENT
 250 AC_HEADER_MAJOR
 251 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 252
 253 # some standard structures
 254 AC_HEADER_STAT
 255 AC_HEADER_TIME
 256
 257 # some standard types
 258 AC_TYPE_MODE_T
 259 AC_TYPE_OFF_T
 260 AC_TYPE_PID_T
 261 AC_TYPE_SIGNAL
 262 AC_TYPE_SIZE_T
 263 AC_TYPE_UID_T
 264
 265 AC_CHECK_FUNCS(strerror)
 266 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 267 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 268
 269 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 270     case "${enableval}" in
 271         yes) use_compression=true ;;
 272         no) use_compression=false ;;
 273         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 274     esac
 275 ],[use_compression=true])
 276 if test $use_compression=true ; then
 277         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 278         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 279         if test $use_compression = true ; then
 280                 AC_DEFINE(USE_COMRESSION, 1, [Define as 1 if you want to support compressed files.])
 281                 lyx_flags="$lyx_flags compression"
 282         fi
 283 fi
 284 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 285 AC_MSG_CHECKING([whether to support compressed files])
 286 AC_MSG_RESULT($use_compression)
 287
 288
 289 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 290 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 291 dnl We aim to remove this eventually, since we should test as much as
 292 dnl possible with the compiler which will use the functions (JMarc)
 293 AC_LANG_PUSH(C)
 294 AC_CHECK_FUNCS(mkfifo mkstemp mktemp)
 295 AC_LANG_POP(C)
 296
 297 AC_FUNC_SELECT_ARGTYPES
 298
 299 ### Some information on what just happened
 300 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 301 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 302 VERSION_INFO="Configuration\n\
 303   Host type:                      ${host}\n\
 304   Special build flags:           ${lyx_flags}\n\
 305   C   Compiler:                   ${CC}\n\
 306   C   Compiler flags:             ${CFLAGS}\n\
 307   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 308   C++ Compiler flags:             ${CXXFLAGS}\n\
 309   Linker flags:                   ${LDFLAGS}\n\
 310 ${FRONTEND_INFO}\
 311   LyX binary dir:                 ${real_bindir}\n\
 312   LyX files dir:                  ${real_datadir}\n"
 313
 314
 315 AC_SUBST(VERSION_INFO)
 316 AC_SUBST(RPM_FRONTEND)
 317
 318 ## Some config.h stuff
 319
 320 AH_TOP([
 321 /* -*- C++ -*- */
 322 /*
 323  * \file config.h
 324  * This file is part of LyX, the document processor.
 325  * Licence details can be found in the file COPYING.
 326  *
 327  * This is the compilation configuration file for LyX.
 328  * It was generated by autoconfs configure.
 329  * You might want to change some of the defaults if something goes wrong
 330  * during the compilation.
 331  */
 332
 333 #ifndef _CONFIG_H
 334 #define _CONFIG_H
 335 ])
 336
 337 AH_BOTTOM([
 338 /************************************************************
 339  ** You should not need to change anything beyond this point */
 340
 341 #ifndef HAVE_STRERROR
 342 #if defined(__cplusplus)
 343 extern "C"
 344 #endif
 345 char * strerror(int n);
 346 #endif
 347
 348 #ifdef HAVE_MKSTEMP
 349 #ifndef HAVE_DECL_MKSTEMP
 350 #if defined(__cplusplus)
 351 extern "C"
 352 #endif
 353 int mkstemp(char*);
 354 #endif
 355 #endif
 356
 357 #ifdef __EMX__
 358 #include "support/os2_defines.h"
 359 #endif
 360
 361 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 362 #define USE_BOOST_FORMAT 1
 363 #else
 364 #define USE_BOOST_FORMAT 0
 365 #endif
 366
 367 #define BOOST_USER_CONFIG <config.h>
 368
 369 #if defined(ENABLE_ASSERTIONS)
 370 #define BOOST_ENABLE_ASSERT_HANDLER 1
 371 #else
 372 #define BOOST_DISABLE_ASSERTS 1
 373 #endif
 374
 375 #define BOOST_DISABLE_THREADS 1
 376 #define BOOST_NO_WREGEX 1
 377 #define BOOST_NO_WSTRING 1
 378
 379 #endif
 380 ])
 381
 382 ### Finish the work.
 383 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 384 AC_CONFIG_FILES([Makefile  m4/Makefile \
 385        boost/Makefile \
 386        boost/libs/Makefile \
 387        boost/libs/filesystem/Makefile \
 388        boost/libs/filesystem/src/Makefile \
 389        boost/libs/regex/Makefile \
 390        boost/libs/regex/src/Makefile \
 391        boost/libs/signals/Makefile \
 392        boost/libs/signals/src/Makefile \
 393        config/Makefile \
 394        development/Makefile \
 395        development/lyx.spec \
 396        lib/Makefile \
 397        lib/doc/Makefile \
 398        intl/Makefile \
 399        po/Makefile.in \
 400        sourcedoc/Doxyfile \
 401        sourcedoc/Makefile \
 402        src/client/Makefile \
 403        src/Makefile \
 404        src/version.C-tmp:src/version.C.in \
 405        src/tex2lyx/Makefile \
 406        src/mathed/Makefile \
 407        src/graphics/Makefile \
 408        src/insets/Makefile \
 409        src/support/Makefile \
 410        src/frontends/Makefile \
 411        src/frontends/controllers/Makefile \
 412        src/frontends/xforms/Makefile \
 413        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 414        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 415        src/frontends/xforms/forms/Makefile \
 416        src/frontends/gtk/Makefile \
 417        src/frontends/gtk/gimages/Makefile \
 418        src/frontends/gtk/glade/Makefile \
 419        src/frontends/qt2/Makefile \
 420        src/frontends/qt2/moc/Makefile \
 421        src/frontends/qt2/ui/Makefile \
 422        src/frontends/qt2/ui/moc/Makefile \
 423        src/frontends/gnome/Makefile \
 424 ])
 425
 426 AC_OUTPUT
 427 # show version information
 428 echo
 429 printf "$VERSION_INFO"
 430 echo
 431
 432 # Display a final warning if there has been a LYX_ERROR
 433 LYX_CHECK_ERRORS