configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AM_MAINTAINER_MODE
  15 AC_CANONICAL_TARGET
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### check which frontend we want to use
  59 LYX_USE_FRONTENDS
  60
  61 ### Check for a C++ compiler
  62 LYX_PROG_CXX
  63 ### Some checks on what the C++ compiler can(not) do
  64 AC_LANG(C++)
  65 dnl we do not need that currently (and probably all our supported
  66 dnl compiler allow that)
  67 dnl LYX_CXX_PARTIAL
  68 LYX_CXX_EXPLICIT
  69 LYX_CXX_CHEADERS
  70 LYX_CXX_GLOBAL_CSTD
  71 LYX_STD_COUNT
  72 dnl we disable rtti for now
  73 dnl LYX_CXX_RTTI
  74 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  75 LYX_CXX_STL_MODERN_STREAMS
  76
  77 ###
  78 AC_ARG_WITH(included-string,
  79     AC_HELP_STRING([--with-included-string],[use std::string through namespace lyx]),
  80        [lyx_cv_with_included_string=$withval
  81         AC_MSG_RESULT([$with_included_string])],
  82        [AC_CACHE_CHECK([],lyx_cv_with_included_string,[lyx_cv_with_included_string=no])])
  83 if test x$lyx_cv_with_included_string = xyes ; then
  84     AC_DEFINE(USE_INCLUDED_STRING, 1,
  85         [Define to use std::string through namespace lyx.])
  86     lyx_flags="$lyx_flags included-string"
  87 fi
  88
  89
  90 ### and now some special lyx flags.
  91 AC_ARG_ENABLE(assertions,
  92   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  93   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  94         enable_assertions=yes;
  95     else
  96         enable_assertions=no;
  97     fi;])
  98 if test "x$enable_assertions" = xyes ; then
  99    lyx_flags="$lyx_flags assertions"
 100    AC_DEFINE(ENABLE_ASSERTIONS,1,
 101     [Define if you want assertions to be enabled in the code])
 102 fi
 103
 104 ### Library Files
 105 dnl by testing these we check if it is ok to have
 106 dnl -lc and -lm as args to the compiler
 107 AC_CHECK_LIB(m, sin)
 108 AC_CHECK_LIB(c, fopen)
 109
 110 ### Add extra directories to check for libraries.
 111 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 112 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 113 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 114
 115 ### Add extra directories to check for include files.
 116 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 117 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 118 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 119
 120 ### Add both includes and libraries
 121 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 122 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 123 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 124   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 125
 126 AC_ARG_WITH(aiksaurus,
 127   [  --without-aiksaurus     do not use the Aiksaurus library],
 128   [lyx_use_aiksaurus=$withval])
 129 if test x$lyx_use_aiksaurus != xno; then
 130 AC_CHECK_LIB(Aiksaurus, main,
 131         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 132          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 133         ],,"-lbz2")
 134 AC_CHECK_HEADER(Aiksaurus.h,[
 135   ac_cv_header_aiksaurus_h=yes
 136   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 137 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 138   ac_cv_header_aiksaurus_h=yes
 139   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 140 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 141 fi
 142 AC_SUBST(AIKSAURUS_LIBS)
 143
 144 LYX_USE_INCLUDED_BOOST
 145
 146 ### Setup libtool
 147 AC_DISABLE_SHARED
 148 AC_LIBTOOL_WIN32_DLL
 149 #AM_PROG_LIBTOOL
 150 LYX_PROG_LIBTOOL
 151
 152 ### Check if we want spell libraries, prefer new aspell
 153 CHECK_WITH_ASPELL
 154 if test "$USING_ASPELL" != "yes"; then
 155         CHECK_WITH_PSPELL
 156 fi
 157
 158 ### Check for some Cygwin-specific details.
 159 CHECK_WITH_CYGWIN
 160
 161 ### Check for X libraries
 162 AC_PATH_XTRA
 163 case $have_x in
 164   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 165        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 166   no) LYX_ERROR(dnl
 167 [Cannot find X window libraries and/or headers. Check your installation.
 168   If you use a Linux system, check that you have installed
 169   the development tools.]);;
 170   disable) ;;
 171 esac
 172
 173 ### check which frontend we want to use
 174
 175 dnl The code below is not in a macro, because this would cause big
 176 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 177 for frontend in $FRONTENDS ; do
 178   case "$frontend" in
 179     xforms)
 180           XFORMS_DO_IT_ALL
 181           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 182           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 183           RPM_FRONTEND="xforms"
 184           RPM_FRONTEND_DEPS='libforms >= 1.0'
 185           FRONTEND_INFO="${FRONTEND_INFO}\
 186   XForms Frontend:\n\
 187       libXpm version:\t\t${XPM_VERSION}\n\
 188       libforms version:\t\t${XFORMS_VERSION}\n"
 189           ;;
 190   dnl   gnome)
 191   dnl     XFORMS_DO_IT_ALL
 192   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 193   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 194   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 195
 196   dnl     FRONTEND="xforms gnome"
 197   dnl     FRONTEND_GUILIB="gnome/*.lo"
 198   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 199   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 200   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 201   dnl   ;;
 202     gtk)
 203           XFORMS_DO_IT_ALL
 204           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.0 libglademm-2.0)
 205           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 206           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms gtk"
 207           RPM_FRONTEND="gtk"
 208           RPM_FRONTEND_DEPS='gtkmm >= 2.2.0'
 209           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.0`
 210           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.0`
 211           FRONTEND_INFO="${FRONTEND_INFO}\
 212   GTK Frontend:\n\
 213     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 214     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 215           ;;
 216
 217     qt)
 218           QT_DO_IT_ALL
 219           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 220           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 221           RPM_FRONTEND="qt"
 222           RPM_FRONTEND_DEPS='qt >= 2.2.1'
 223           FRONTEND_INFO="${FRONTEND_INFO}\
 224   Qt Frontend:\n\
 225       Qt version:\t\t${QT_VERSION}\n"
 226       ;;
 227     *)
 228           LYX_ERROR(Unknown frontend '$frontend');;
 229   esac
 230 done
 231
 232 ### Setup GNU gettext
 233 dnl GNU gettext is written in C
 234 AC_LANG_PUSH(C)
 235 # Some tests that may be useful for gettext
 236 AC_C_CONST
 237 AC_C_INLINE
 238 # Do the real setup now
 239 AM_GNU_GETTEXT
 240 # a hack for those who try to change LyX, but do not have gettext installed
 241 case  "${XGETTEXT}" in
 242  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 243 esac
 244
 245 AC_SUBST(LINGUAS)
 246
 247 AC_LANG_POP(C)
 248
 249 # some standard header files
 250 AC_HEADER_DIRENT
 251 AC_HEADER_MAJOR
 252 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 253
 254 # some standard structures
 255 AC_HEADER_STAT
 256 AC_HEADER_TIME
 257
 258 # some standard types
 259 AC_TYPE_MODE_T
 260 AC_TYPE_OFF_T
 261 AC_TYPE_PID_T
 262 AC_TYPE_SIGNAL
 263 AC_TYPE_SIZE_T
 264 AC_TYPE_UID_T
 265
 266 AC_CHECK_FUNCS(snprintf vsnprintf strerror)
 267 LYX_CHECK_DECL(snprintf, stdio.h)
 268 LYX_CHECK_DECL(vsnprintf, stdio.h)
 269 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 270 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 271
 272 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 273     case "${enableval}" in
 274         yes) use_compression=true ;;
 275         no) use_compression=false ;;
 276         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 277     esac
 278 ],[use_compression=true])
 279 if test $use_compression=true ; then
 280         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 281         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 282         if test $use_compression = true ; then
 283                 AC_DEFINE(USE_COMRESSION, 1, [Define as 1 if you want to supprot compressed files.])
 284                 lyx_flags="$lyx_flags compression"
 285         fi
 286 fi
 287 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 288 AC_MSG_CHECKING([whether to support compressed files])
 289 AC_MSG_RESULT($use_compression)
 290
 291
 292 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 293 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 294 dnl We aim to remove this eventually, since we should test as much as
 295 dnl possible with the compiler which will use the functions (JMarc)
 296 AC_LANG_PUSH(C)
 297 AC_CHECK_FUNCS(memmove memset strchr mkfifo mkstemp mktemp)
 298 AC_LANG_POP(C)
 299
 300 AC_FUNC_SELECT_ARGTYPES
 301
 302 ### Some information on what just happened
 303 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 304 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 305 VERSION_INFO="Configuration\n\
 306   Host type:                      ${host}\n\
 307   Special build flags:           ${lyx_flags}\n\
 308   C   Compiler:                   ${CC}\n\
 309   C   Compiler flags:             ${CFLAGS}\n\
 310   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 311   C++ Compiler flags:             ${CXXFLAGS}\n\
 312   Linker flags:                   ${LDFLAGS}\n\
 313 ${FRONTEND_INFO}\
 314   LyX binary dir:                 ${real_bindir}\n\
 315   LyX files dir:                  ${real_datadir}\n"
 316
 317
 318 AC_SUBST(VERSION_INFO)
 319 AC_SUBST(RPM_FRONTEND)
 320 AC_SUBST(RPM_FRONTEND_DEPS)
 321
 322 ## Some config.h stuff
 323
 324 AH_TOP([
 325 /* -*- C++ -*- */
 326 /*
 327  * \file config.h
 328  * This file is part of LyX, the document processor.
 329  * Licence details can be found in the file COPYING.
 330  *
 331  * This is the compilation configuration file for LyX.
 332  * It was generated by autoconfs configure.
 333  * You might want to change some of the defaults if something goes wrong
 334  * during the compilation.
 335  */
 336
 337 #ifndef _CONFIG_H
 338 #define _CONFIG_H
 339 ])
 340
 341 AH_BOTTOM([
 342 /************************************************************
 343  ** You should not need to change anything beyond this point */
 344
 345 #ifndef HAVE_STRCHR
 346 # define strchr(a,b)    index(a,b)
 347 #endif
 348
 349 #ifndef HAVE_MEMMOVE
 350 # define memmove(a,b,c) bcopy(b,a,c)
 351 #endif
 352
 353 #ifndef HAVE_STRERROR
 354 #if defined(__cplusplus)
 355 extern "C"
 356 #endif
 357 char * strerror(int n);
 358 #endif
 359
 360 #ifdef BROKEN_HEADERS
 361 #include "broken_headers.h"
 362 #endif
 363
 364 #ifdef HAVE_MKSTEMP
 365 #ifndef HAVE_DECL_MKSTEMP
 366 #if defined(__cplusplus)
 367 extern "C"
 368 #endif
 369 int mkstemp(char*);
 370 #endif
 371 #endif
 372
 373 #ifdef __EMX__
 374 #include "support/os2_defines.h"
 375 #endif
 376
 377 #if defined(__CYGWIN__) || defined(__CYGWIN32__)
 378 #include "support/nt_defines.h"
 379 #endif
 380
 381 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 382 #define USE_BOOST_FORMAT 1
 383 #else
 384 #define USE_BOOST_FORMAT 0
 385 #endif
 386
 387 #if defined(ENABLE_ASSERTIONS)
 388 #define BOOST_ENABLE_ASSERT_HANDLER 1
 389 #else
 390 #define BOOST_DISABLE_ASSERTS 1
 391 #endif
 392
 393 #define BOOST_DISABLE_THREADS 1
 394 #define BOOST_NO_WREGEX 1
 395 #define BOOST_NO_WSTRING 1
 396
 397 #endif
 398 ])
 399
 400 ### Finish the work.
 401 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 402 AC_CONFIG_FILES([Makefile \
 403        boost/Makefile \
 404        boost/libs/Makefile \
 405        boost/libs/regex/Makefile \
 406        boost/libs/regex/src/Makefile \
 407        boost/libs/signals/Makefile \
 408        boost/libs/signals/src/Makefile \
 409        config/Makefile \
 410        development/Makefile \
 411        development/lyx.spec \
 412        lib/Makefile \
 413        intl/Makefile \
 414        po/Makefile.in \
 415        sourcedoc/Doxyfile \
 416        sourcedoc/Makefile \
 417        src/Makefile \
 418        src/version.C-tmp:src/version.C.in \
 419        src/tex2lyx/Makefile \
 420        src/mathed/Makefile \
 421        src/graphics/Makefile \
 422        src/insets/Makefile \
 423        src/support/Makefile \
 424        src/frontends/Makefile \
 425        src/frontends/controllers/Makefile \
 426        src/frontends/xforms/Makefile \
 427        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 428        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 429        src/frontends/xforms/forms/Makefile \
 430        src/frontends/gtk/Makefile \
 431        src/frontends/gtk/glade/Makefile \
 432        src/frontends/qt2/Makefile \
 433        src/frontends/qt2/moc/Makefile \
 434        src/frontends/qt2/ui/Makefile \
 435        src/frontends/qt2/ui/moc/Makefile \
 436        src/frontends/gnome/Makefile \
 437 ])
 438
 439 AC_OUTPUT
 440 # show version information
 441 echo
 442 printf "$VERSION_INFO"
 443 echo
 444
 445 # Display a final warning if there has been a LYX_ERROR
 446 LYX_CHECK_ERRORS