configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 # The list of languages known to LyX
  26 # This is needed by GNU gettext
  27 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl nn no pl pt ro ru sk sl sv tr wa"
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### check which frontend we want to use
  59 LYX_USE_FRONTENDS
  60
  61 ### Check for a C++ compiler
  62 LYX_PROG_CXX
  63 ### Some checks on what the C++ compiler can(not) do
  64 AC_LANG(C++)
  65 dnl we do not need that currently (and probably all our supported
  66 dnl compiler allow that)
  67 dnl LYX_CXX_PARTIAL
  68 LYX_CXX_EXPLICIT
  69 LYX_CXX_GLOBAL_CSTD
  70 LYX_STD_COUNT
  71 dnl we disable rtti for now
  72 dnl LYX_CXX_RTTI
  73 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  74 LYX_CXX_STL_MODERN_STREAMS
  75
  76 ### and now some special lyx flags.
  77 AC_ARG_ENABLE(assertions,
  78   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  79   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  80         enable_assertions=yes;
  81     else
  82         enable_assertions=no;
  83     fi;])
  84 if test "x$enable_assertions" = xyes ; then
  85    lyx_flags="$lyx_flags assertions"
  86    AC_DEFINE(ENABLE_ASSERTIONS,1,
  87     [Define if you want assertions to be enabled in the code])
  88 fi
  89
  90 ### Library Files
  91 dnl by testing these we check if it is ok to have
  92 dnl -lc and -lm as args to the compiler
  93 AC_CHECK_LIB(m, sin)
  94 AC_CHECK_LIB(c, fopen)
  95
  96 ### Add extra directories to check for libraries.
  97 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  98 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  99 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 100
 101 ### Add extra directories to check for include files.
 102 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 104 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 105
 106 ### Add both includes and libraries
 107 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 108 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 109 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 110   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 111
 112 AC_ARG_WITH(aiksaurus,
 113   [  --without-aiksaurus     do not use the Aiksaurus library],
 114   [lyx_use_aiksaurus=$withval])
 115 if test x$lyx_use_aiksaurus != xno; then
 116 AC_CHECK_LIB(Aiksaurus, main,
 117         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 118          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 119         ],,"-lbz2")
 120 AC_CHECK_HEADER(Aiksaurus.h,[
 121   ac_cv_header_aiksaurus_h=yes
 122   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 123 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 124   ac_cv_header_aiksaurus_h=yes
 125   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 126 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 127 fi
 128 AC_SUBST(AIKSAURUS_LIBS)
 129
 130 LYX_USE_INCLUDED_BOOST
 131
 132 ### Setup libtool
 133 AC_DISABLE_SHARED
 134 AC_LIBTOOL_WIN32_DLL
 135 #AM_PROG_LIBTOOL
 136 LYX_PROG_LIBTOOL
 137
 138 ### Check if we want spell libraries, prefer new aspell
 139 CHECK_WITH_ASPELL
 140 if test "$USING_ASPELL" != "yes"; then
 141         CHECK_WITH_PSPELL
 142 fi
 143
 144 ### Check for some Cygwin-specific details.
 145 CHECK_WITH_CYGWIN
 146
 147 ### Check for X libraries
 148 AC_PATH_XTRA
 149 case $have_x in
 150   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 151        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 152   no) LYX_ERROR(dnl
 153 [Cannot find X window libraries and/or headers. Check your installation.
 154   If you use a Linux system, check that you have installed
 155   the development tools.]);;
 156   disable) ;;
 157 esac
 158
 159 ### check which frontend we want to use
 160
 161 dnl if the gtk frontend has been specified, then xforms is needed too
 162 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 163   FRONTENDS="$FRONTENDS xforms"
 164 fi
 165
 166 dnl The code below is not in a macro, because this would cause big
 167 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 168 for frontend in $FRONTENDS ; do
 169   case "$frontend" in
 170     xforms)
 171           XFORMS_DO_IT_ALL
 172           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 173           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 174           RPM_FRONTEND="xforms"
 175           FRONTEND_INFO="${FRONTEND_INFO}\
 176   XForms Frontend:\n\
 177       libXpm version:\t\t${XPM_VERSION}\n\
 178       libforms version:\t\t${XFORMS_VERSION}\n"
 179           ;;
 180   dnl   gnome)
 181   dnl     XFORMS_DO_IT_ALL
 182   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 183   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 184   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 185
 186   dnl     FRONTEND="xforms gnome"
 187   dnl     FRONTEND_GUILIB="gnome/*.lo"
 188   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 189   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 190   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 191   dnl   ;;
 192     gtk)
 193           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 194           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 195           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 196           RPM_FRONTEND="gtk"
 197           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 198           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 199           FRONTEND_INFO="${FRONTEND_INFO}\
 200   GTK Frontend:\n\
 201     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 202     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 203           ;;
 204
 205     qt)
 206           QT_DO_IT_ALL
 207           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 208           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 209           RPM_FRONTEND="qt"
 210           FRONTEND_INFO="${FRONTEND_INFO}\
 211   Qt Frontend:\n\
 212       Qt version:\t\t${QT_VERSION}\n"
 213 dnl qt build will fail without moc or uic
 214           if test -z "$MOC"; then
 215             LYX_ERROR([moc binary not found !])
 216           fi
 217           if test -z "$UIC"; then
 218             LYX_ERROR([uic binary not found !])
 219           fi
 220       ;;
 221     *)
 222           LYX_ERROR(Unknown frontend '$frontend');;
 223   esac
 224 done
 225
 226 ### Check how the files should be packaged
 227 LYX_USE_PACKAGING
 228 # fix the value of the prefixes.
 229 test "x$prefix" = xNONE && prefix=$default_prefix
 230 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 231
 232 ### Setup GNU gettext
 233 dnl GNU gettext is written in C
 234 AC_LANG_PUSH(C)
 235 # Some tests that may be useful for gettext
 236 AC_C_CONST
 237 AC_C_INLINE
 238 # Do the real setup now
 239 AM_GNU_GETTEXT
 240 # a hack for those who try to change LyX, but do not have gettext installed
 241 case  "${XGETTEXT}" in
 242  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 243 esac
 244
 245 AC_SUBST(LINGUAS)
 246
 247 AC_LANG_POP(C)
 248
 249 # some standard header files
 250 AC_HEADER_DIRENT
 251 AC_HEADER_MAJOR
 252 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 253
 254 # some standard structures
 255 AC_HEADER_STAT
 256 AC_HEADER_TIME
 257
 258 # some standard types
 259 AC_TYPE_MODE_T
 260 AC_TYPE_OFF_T
 261 AC_TYPE_PID_T
 262 AC_TYPE_SIGNAL
 263 AC_TYPE_SIZE_T
 264 AC_TYPE_UID_T
 265
 266 AC_CHECK_FUNCS(strerror)
 267 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 268 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 269
 270 # Check the form of mkdir()
 271 AC_FUNC_MKDIR
 272
 273 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 274     case "${enableval}" in
 275         yes) use_compression=true ;;
 276         no) use_compression=false ;;
 277         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 278     esac
 279 ],[use_compression=true])
 280 if test $use_compression=true ; then
 281         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 282         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 283         if test $use_compression = true ; then
 284                 AC_DEFINE(USE_COMRESSION, 1, [Define as 1 if you want to support compressed files.])
 285                 lyx_flags="$lyx_flags compression"
 286         fi
 287 fi
 288 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 289 AC_MSG_CHECKING([whether to support compressed files])
 290 AC_MSG_RESULT($use_compression)
 291
 292
 293 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 294 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 295 dnl We aim to remove this eventually, since we should test as much as
 296 dnl possible with the compiler which will use the functions (JMarc)
 297 AC_LANG_PUSH(C)
 298 AC_CHECK_FUNCS(mkfifo mkstemp mktemp lstat readlink)
 299 AC_LANG_POP(C)
 300
 301 AC_FUNC_SELECT_ARGTYPES
 302
 303 ### Some information on what just happened
 304 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 305 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 306 VERSION_INFO="Configuration\n\
 307   Host type:                      ${host}\n\
 308   Special build flags:           ${lyx_flags}\n\
 309   C   Compiler:                   ${CC}\n\
 310   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 311   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 312   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 313   Linker flags:                   ${LDFLAGS}\n\
 314 ${FRONTEND_INFO}\
 315   Packaging:                      ${lyx_use_packaging}\n\
 316   LyX binary dir:                 ${real_bindir}\n\
 317   LyX files dir:                  ${real_datadir}\n"
 318
 319
 320 AC_SUBST(VERSION_INFO)
 321 AC_SUBST(RPM_FRONTEND)
 322
 323 ## Some config.h stuff
 324
 325 AH_TOP([
 326 /* -*- C++ -*- */
 327 /*
 328  * \file config.h
 329  * This file is part of LyX, the document processor.
 330  * Licence details can be found in the file COPYING.
 331  *
 332  * This is the compilation configuration file for LyX.
 333  * It was generated by autoconfs configure.
 334  * You might want to change some of the defaults if something goes wrong
 335  * during the compilation.
 336  */
 337
 338 #ifndef _CONFIG_H
 339 #define _CONFIG_H
 340 ])
 341
 342 AH_BOTTOM([
 343 /************************************************************
 344  ** You should not need to change anything beyond this point */
 345
 346 #ifndef HAVE_STRERROR
 347 #if defined(__cplusplus)
 348 extern "C"
 349 #endif
 350 char * strerror(int n);
 351 #endif
 352
 353 #ifdef HAVE_MKSTEMP
 354 #ifndef HAVE_DECL_MKSTEMP
 355 #if defined(__cplusplus)
 356 extern "C"
 357 #endif
 358 int mkstemp(char*);
 359 #endif
 360 #endif
 361
 362 #ifdef __EMX__
 363 #include "support/os2_defines.h"
 364 #endif
 365
 366 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 367 #define USE_BOOST_FORMAT 1
 368 #else
 369 #define USE_BOOST_FORMAT 0
 370 #endif
 371
 372 #define BOOST_USER_CONFIG <config.h>
 373
 374 #if defined(ENABLE_ASSERTIONS)
 375 #define BOOST_ENABLE_ASSERT_HANDLER 1
 376 #else
 377 #define BOOST_DISABLE_ASSERTS 1
 378 #endif
 379
 380 #define BOOST_DISABLE_THREADS 1
 381 #define BOOST_NO_WREGEX 1
 382 #define BOOST_NO_WSTRING 1
 383
 384 #endif
 385 ])
 386
 387 ### Finish the work.
 388 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 389 AC_CONFIG_FILES([Makefile  m4/Makefile \
 390        boost/Makefile \
 391        boost/libs/Makefile \
 392        boost/libs/filesystem/Makefile \
 393        boost/libs/filesystem/src/Makefile \
 394        boost/libs/regex/Makefile \
 395        boost/libs/regex/src/Makefile \
 396        boost/libs/signals/Makefile \
 397        boost/libs/signals/src/Makefile \
 398        config/Makefile \
 399        development/Makefile \
 400        development/lyx.spec \
 401        lib/Makefile \
 402        lib/doc/Makefile \
 403        intl/Makefile \
 404        po/Makefile.in \
 405        sourcedoc/Doxyfile \
 406        sourcedoc/Makefile \
 407        src/client/Makefile \
 408        src/Makefile \
 409        src/version.C-tmp:src/version.C.in \
 410        src/tex2lyx/Makefile \
 411        src/mathed/Makefile \
 412        src/graphics/Makefile \
 413        src/insets/Makefile \
 414        src/support/Makefile \
 415        src/frontends/Makefile \
 416        src/frontends/controllers/Makefile \
 417        src/frontends/xforms/Makefile \
 418        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 419        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 420        src/frontends/xforms/forms/Makefile \
 421        src/frontends/gtk/Makefile \
 422        src/frontends/gtk/gimages/Makefile \
 423        src/frontends/gtk/glade/Makefile \
 424        src/frontends/qt2/Makefile \
 425        src/frontends/qt2/moc/Makefile \
 426        src/frontends/qt2/ui/Makefile \
 427        src/frontends/qt2/ui/moc/Makefile \
 428        src/frontends/gnome/Makefile \
 429 ])
 430
 431 AC_OUTPUT
 432 # show version information
 433 echo
 434 printf "$VERSION_INFO"
 435 echo
 436
 437 # Display a final warning if there has been a LYX_ERROR
 438 LYX_CHECK_ERRORS