configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.1dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2016-05-23"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 # Automake is pulling the historical V7 format. This tar format supports
  36 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  37 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  39 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  40 PACKAGE=$save_PACKAGE
  41
  42 # Allow to build some parts of the code as one big chunk
  43 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  44 AC_ARG_ENABLE(monolithic-build,
  45   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  46                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  47   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  48    test "$enable_monolithic_build" = no && enable_monolithic_build=
  49    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  50    for i in $enable_monolithic_build ; do
  51        eval "enable_monolithic_$i=yes"
  52    done
  53    IFS="$ac_save_ifs"],
  54   [enable_monolithic_build=])
  55
  56 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  63
  64 ### Set the execute permissions of the various scripts correctly
  65 for file in config/install-sh ; do
  66   chmod 755 ${srcdir}/${file}
  67 done
  68
  69 # Find a suitable python interpreter
  70 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  71 # do the usual python setup stuff
  72 AM_PATH_PYTHON
  73
  74 # Tools for creating libraries (note that we do not use libtool)
  75 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  76 AC_PROG_RANLIB
  77
  78 ### Check for a C++ compiler
  79 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  80 dnl if it is not set. We do not use autoconf defaults.
  81 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  82 if ! test "$lyx_has_CXXFLAGS" = yes; then
  83   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  84   CXXFLAGS=" "
  85 fi
  86 LYX_PROG_CXX
  87 if ! test "$lyx_has_CXXFLAGS" = yes; then
  88   unset CXXFLAGS
  89 fi
  90 AC_LANG(C++)
  91
  92 ### Objective-C compiler
  93 AC_PROG_OBJC
  94 _AM_DEPENDENCIES([OBJC])
  95
  96 ### Add extra directories to check for libraries.
  97 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  98 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  99 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 100
 101 ### Add extra directories to check for include files.
 102 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 104 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 105
 106 ### Add both includes and libraries
 107 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 108 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 109   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 110   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 111 ])
 112
 113 ### These are needed in windows
 114 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 115 AC_SUBST(LIBSHLWAPI)
 116 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 117 AC_SUBST(LIBPSAPI)
 118 AC_CHECK_LIB(gdi32, main)
 119
 120 LYX_USE_INCLUDED_BOOST
 121 LYX_USE_INCLUDED_MYTHES
 122
 123 ### we need to know the byte order for unicode conversions
 124 AC_C_BIGENDIAN
 125
 126 # Nice to have when an assertion triggers
 127 LYX_CHECK_CALLSTACK_PRINTING
 128
 129 # Needed for our char_type
 130 AC_CHECK_SIZEOF(wchar_t)
 131
 132 ### We need iconv for unicode support (Qt4 frontend requires it too)
 133 AM_ICONV
 134 if test "$am_cv_func_iconv" = no; then
 135   AC_MSG_ERROR([cannot find required library iconv.])
 136 else
 137   LIBS="$LIBS $LIBICONV"
 138 fi
 139
 140 ### check for compression support
 141 AC_CHECK_HEADERS(zlib.h,
 142  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 143  [LYX_LIB_ERROR(zlib.h,zlib)])
 144
 145 ### check for file magic support (currently optional)
 146 AC_CHECK_HEADERS(magic.h,
 147  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 148   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 149    is correctly installed on your system.
 150    Falling back to builtin file format detection.]))],
 151  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 152    is correctly installed on your system.
 153    Falling back to builtin file format detection.])])
 154
 155 ### setup the qt frontend.
 156 dnl The code below is not in a macro, because this would cause big
 157 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 158 QT_DO_IT_ALL([4.5.0])
 159 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 160 FRONTEND_INFO="${FRONTEND_INFO}\
 161   Qt Frontend:\n\
 162       Qt version:\t   ${QTLIB_VERSION}\n"
 163
 164 # fix the value of the prefixes.
 165 test "x$prefix" = xNONE && prefix=$default_prefix
 166 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 167 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 168   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 169    causes problems with the Makefiles. The installation will be done in
 170    directory \"`pwd`/installprefix\" instead. Please move its contents to
 171    the right place after installation.])
 172   prefix=`pwd`/installprefix
 173 fi
 174
 175 ### Setup po directory
 176 AM_NLS
 177 if test $USE_NLS = "yes" ; then
 178   AC_DEFINE(ENABLE_NLS, 1,
 179     [Define to 1 if translation of program messages to the user's native language
 180    is requested.])dnl'
 181 fi
 182 AM_PO_SUBDIRS
 183
 184 # some standard header files
 185 AC_HEADER_MAJOR
 186 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 187
 188 # some standard types
 189 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 190 AC_TYPE_OFF_T
 191 AC_TYPE_PID_T
 192 AC_TYPE_SIZE_T
 193 AC_TYPE_UID_T
 194 # Taken from gettext
 195 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 196    [AC_TRY_COMPILE([#include <stddef.h>
 197       wchar_t foo = (wchar_t)'\0';], ,
 198       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 199 if test $gt_cv_c_wchar_t = yes; then
 200   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 201 fi
 202
 203 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 204
 205 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 206 # Check the form of mkdir()
 207 AC_FUNC_MKDIR
 208 AC_FUNC_SELECT_ARGTYPES
 209
 210 LYX_CHECK_SPELL_ENGINES
 211
 212 lyx_client_subdir=true
 213 dnl AC_LANG_PUSH(C)
 214 dnl LIBS already contains some X extra libs that may interfere.
 215 save_LIBS="$LIBS"
 216 LIBS=
 217 AC_CHECK_FUNCS(fcntl,
 218   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 219    AC_SEARCH_LIBS([socket], [socket network], [],
 220      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 221                 [], [-lnsl])])],
 222   [lyx_client_subdir=false])
 223 AC_SUBST(SOCKET_LIBS,$LIBS)
 224 LIBS="$save_LIBS"
 225 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 226 dnl AC_LANG_POP(C)
 227
 228 lyx_win_res=false;
 229 case ${host} in
 230     *mingw*|*cygwin*) lyx_win_res=true;;
 231     *freebsd*) AC_SEARCH_LIBS(backtrace_symbols, [execinfo])
 232 esac
 233 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 234 LYX_SET_VERSION_INFO
 235
 236
 237 ### Some information on what just happened
 238 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 239 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 240 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 241 VERSION_INFO="Configuration\n\
 242   Host type:               ${host}\n\
 243   Special build flags:     ${lyx_flags}\n\
 244   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 245   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 246   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 247   Linker flags:            ${AM_LDFLAGS}\n\
 248   Linker user flags:       ${LDFLAGS}\n\
 249 ${FRONTEND_INFO}\
 250   Packaging:               ${lyx_use_packaging}\n\
 251   LyX binary dir:          ${real_bindir}\n\
 252   LyX files dir:           ${real_pkgdatadir}\n"
 253
 254 AC_SUBST(VERSION_INFO)
 255 AC_SUBST(AM_CPPFLAGS)
 256 AC_SUBST(AM_CXXFLAGS)
 257 AC_SUBST(AM_LDFLAGS)
 258 AC_SUBST(real_pkgdatadir)
 259
 260 ## Some config.h stuff
 261
 262 AH_TOP([
 263 /* -*- C++ -*- */
 264 /*
 265  * \file config.h
 266  * This file is part of LyX, the document processor.
 267  * Licence details can be found in the file COPYING.
 268  *
 269  * This is the compilation configuration file for LyX.
 270  * It was generated by autoconfs configure.
 271  * You might want to change some of the defaults if something goes wrong
 272  * during the compilation.
 273  */
 274
 275 #ifndef _CONFIG_H
 276 #define _CONFIG_H
 277 ])
 278
 279 AH_BOTTOM([
 280 /************************************************************
 281  ** You should not need to change anything beyond this point */
 282
 283 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 284 #define LYX_USE_CXX11
 285 #endif
 286
 287 #ifndef HAVE_STRERROR
 288 #if defined(__cplusplus)
 289 extern "C"
 290 #endif
 291 char * strerror(int n);
 292 #endif
 293
 294 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 295 #  define USE_BOOST_FORMAT 1
 296 #else
 297 #  define USE_BOOST_FORMAT 0
 298 #endif
 299
 300 #define BOOST_USER_CONFIG <config.h>
 301
 302 #if !defined(ENABLE_ASSERTIONS)
 303 #  define BOOST_DISABLE_ASSERTS 1
 304 #endif
 305 #define BOOST_ENABLE_ASSERT_HANDLER 1
 306
 307 #define BOOST_DISABLE_THREADS 1
 308 #define BOOST_NO_WREGEX 1
 309 #define BOOST_NO_WSTRING 1
 310 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 311
 312 #ifdef __CYGWIN__
 313 #  define NOMINMAX
 314 #  define BOOST_POSIX 1
 315 #  define BOOST_POSIX_API 1
 316 #  define BOOST_POSIX_PATH 1
 317 #endif
 318
 319 #ifdef __sparc__
 320 #  ifndef __BIG_ENDIAN__
 321 #    define __BIG_ENDIAN__ 1
 322 #  endif
 323 #endif
 324
 325 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 326 #  define USE_WCHAR_T
 327 #endif
 328
 329 #endif
 330 ])
 331
 332 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 333 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 334 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 335
 336 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 337         "${lyx_abs_top_srcdir}", [Top source directory])
 338 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 339         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 340 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 341         "${lyx_abs_installed_datadir}",[Hard system support directory])
 342 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 343         "${version_suffix}",[Program version suffix])
 344
 345 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 346 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 347 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 348 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 349 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 350 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 351 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 352 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 353
 354 AC_CONFIG_FILES([Makefile \
 355       lyx.1:lyx.1in \
 356       3rdparty/Makefile \
 357       3rdparty/boost/Makefile \
 358       3rdparty/hunspell/Makefile \
 359       3rdparty/libiconv/Makefile \
 360       3rdparty/zlib/Makefile \
 361       autotests/Makefile \
 362       config/Makefile \
 363       development/Makefile \
 364       development/MacOSX/Makefile \
 365       development/MacOSX/Info.plist \
 366       development/MacOSX/lyxrc.dist \
 367       development/MacOSX/spotlight/Makefile \
 368       development/cygwin/Makefile \
 369       development/cygwin/lyxrc.dist \
 370       development/lyx.spec \
 371       lib/lyx.desktop-temp:lib/lyx.desktop.in
 372       lib/Makefile \
 373       lib/doc/Makefile \
 374       lib/lyx2lyx/lyx2lyx_version.py \
 375       lib/lyx2lyx/Makefile \
 376       m4/Makefile \
 377       po/Makefile.in \
 378       sourcedoc/Doxyfile \
 379       sourcedoc/Makefile \
 380       src/client/Makefile \
 381       src/client/lyxclient.1:src/client/lyxclient.1in \
 382       src/Makefile \
 383       src/tex2lyx/Makefile \
 384       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 385       src/support/Makefile \
 386       src/frontends/Makefile \
 387       src/frontends/qt4/Makefile
 388 ])
 389
 390
 391 AC_OUTPUT
 392
 393 # show version information
 394 echo
 395 printf "$VERSION_INFO"
 396 echo
 397
 398 # Display a final warning if there has been a LYX_WARNING
 399 LYX_CHECK_WARNINGS
 400
 401 cat <<EOF
 402 Configuration of LyX was successful.
 403 Type 'make' to compile the program,
 404 and then 'make install' to install it.
 405 EOF