]> git.lyx.org Git - lyx.git/blob - configure.ac
5bcbe727e643d1eae769c985a7af8fb5a958d104
[lyx.git] / configure.ac
1 dnl Process with autoconf to generate configure script   -*- sh -*-
2
3 AC_INIT(LyX,1.5.0svn,[lyx-devel@lists.lyx.org],[lyx])
4 AC_SUBST(LYX_DATE, ["Fri, Jul 13, 2006"])
5 AC_PREREQ(2.52)
6 AC_CONFIG_SRCDIR(src/main.C)
7 AC_CONFIG_HEADERS([src/config.h])
8
9 AC_CONFIG_AUX_DIR(config)
10
11 # First check the version
12 LYX_CHECK_VERSION
13 LYX_VERSION_SUFFIX
14 # Check how the files should be packaged
15 AC_CANONICAL_TARGET
16 LYX_USE_PACKAGING
17 # We need to define these variables here and the no-define option of
18 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
19 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
20
21 dnl default maintainer mode to true for development versions
22 if test "${enable_maintainer_mode+set}" != set; then
23   enable_maintainer_mode=$lyx_devel_version
24 fi
25 AM_MAINTAINER_MODE
26
27 save_PACKAGE=$PACKAGE
28 AM_INIT_AUTOMAKE([foreign dist-bzip2 tar-ustar no-define 1.9])
29 PACKAGE=$save_PACKAGE
30
31 ### Set the execute permissions of the various scripts correctly
32 for file in config/install-sh config/mkinstalldirs ; do
33   chmod 755 ${srcdir}/${file}
34 done
35
36 ### Check for programs
37 AC_PROG_MAKE_SET
38 AC_PROG_INSTALL
39
40 AC_PROG_AWK
41 test "$AWK" = gawk && AWK="gawk --posix"
42
43 #AC_PROG_RANLIB
44 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
45 if test "x$KPSEWHICH" = xkpsewhich ; then
46     AC_DEFINE(HAVE_KPSEWHICH, 1,
47     [Define this if you have the kpsewhich program working on your system.])
48 fi
49 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
50
51 # Check for installed python
52 AM_PATH_PYTHON(2.3,, :)
53
54 # Work around a problem in automake 1.4: when invoking install-strip,
55 # INSTALL_PROGRAM is changed to 'install -s', and since
56 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
57 # which returns an error condition when stripping fails.
58 INSTALL_SCRIPT='${INSTALL}'
59
60 ### we will also need a C compiler to compile GNU gettext
61 AC_PROG_CC
62
63 ### check for special systems
64 AC_ISC_POSIX
65 AC_AIX
66
67 ### we need to know the byte order for unicode conversions
68 AC_C_BIGENDIAN
69
70 ### check which frontend we want to use
71 LYX_USE_FRONTENDS
72
73 ### Check for a C++ compiler
74 LYX_PROG_CXX
75 ### Some checks on what the C++ compiler can(not) do
76 AC_LANG(C++)
77 dnl we do not need that currently (and probably all our supported
78 dnl compiler allow that)
79 dnl LYX_CXX_PARTIAL
80 LYX_CXX_EXPLICIT
81 LYX_CXX_GLOBAL_CSTD
82 LYX_STD_COUNT
83 dnl we disable rtti for now
84 dnl LYX_CXX_RTTI
85 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
86 LYX_CXX_STL_MODERN_STREAMS
87
88 ### and now some special lyx flags.
89 AC_ARG_ENABLE(assertions,
90   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
91   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
92         enable_assertions=yes;
93     else
94         enable_assertions=no;
95     fi;])
96 if test "x$enable_assertions" = xyes ; then
97    lyx_flags="assertions $lyx_flags"
98    AC_DEFINE(ENABLE_ASSERTIONS,1,
99     [Define if you want assertions to be enabled in the code])
100 fi
101
102 ### Library Files
103 dnl by testing these we check if it is ok to have
104 dnl -lc and -lm as args to the compiler
105 AC_CHECK_LIB(m, sin)
106 AC_CHECK_LIB(c, fopen)
107
108 ### Add extra directories to check for libraries.
109 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
110 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
111 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
112
113 ### Add extra directories to check for include files.
114 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
115 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
116 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
117
118 ### Add both includes and libraries
119 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
120 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
121 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
122   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
123
124 ### These are needed in windows
125 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
126 AC_SUBST(LIBSHLWAPI)
127 AC_CHECK_LIB(gdi32, main)
128
129 AC_ARG_WITH(aiksaurus,
130   [  --without-aiksaurus     do not use the Aiksaurus library],
131   [lyx_use_aiksaurus=$withval])
132 if test x$lyx_use_aiksaurus != xno; then
133 AC_CHECK_LIB(Aiksaurus, main,
134         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
135          AIKSAURUS_LIBS="-lAiksaurus"
136          lyx_flags="aiksaurus $lyx_flags"
137         ])
138 AC_CHECK_HEADER(Aiksaurus.h,[
139   ac_cv_header_aiksaurus_h=yes
140   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
141 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
142   ac_cv_header_aiksaurus_h=yes
143   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
144 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
145 fi
146 AC_SUBST(AIKSAURUS_LIBS)
147
148 LYX_USE_INCLUDED_BOOST
149
150 # Needed for our char_type
151 AC_CHECK_SIZEOF(wchar_t)
152
153 ### Setup libtool
154 dnl Dirty trick ahead: disable libtool checking for a fortran compiler
155 dnl see http://permalink.gmane.org/gmane.comp.gnu.libtool.general/6699
156 dnl Note that this will reportedly not be needed with libtool 2.0
157 m4_undefine([AC_PROG_F77])
158 m4_defun([AC_PROG_F77],[])
159 AC_DISABLE_SHARED
160 AC_LIBTOOL_WIN32_DLL
161 #AM_PROG_LIBTOOL
162 LYX_PROG_LIBTOOL
163
164 ### Check for X libraries
165 AC_PATH_XTRA
166 case $have_x in
167   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
168        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
169   no) LYX_ERROR(dnl
170 [Cannot find X window libraries and/or headers. Check your installation.
171   If you use a Linux system, check that you have installed
172   the development tools.]);;
173   disable) ;;
174 esac
175
176 ### check which frontend we want to use
177
178 dnl The code below is not in a macro, because this would cause big
179 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
180 for frontend in $FRONTENDS ; do
181   case "$frontend" in
182     gtk)
183           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
184           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
185           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
186           RPM_FRONTEND="gtk"
187           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
188           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
189           FRONTEND_INFO="${FRONTEND_INFO}\
190   GTK Frontend:\n\
191     libgtkmm version:\t\t${GTKMM_VERSION}\n\
192     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
193           ;;
194
195     qt3)
196           QT_DO_IT_ALL
197           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt3\$(EXEEXT)"
198           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt3"
199           RPM_FRONTEND="qt3"
200           FRONTEND_INFO="${FRONTEND_INFO}\
201   Qt Frontend:\n\
202       Qt version:\t\t${QT_VERSION}\n"
203 dnl qt build will fail without moc or uic
204           if test -z "$MOC"; then
205             LYX_ERROR([moc binary not found !])
206           fi
207           if test -z "$UIC"; then
208             LYX_ERROR([uic binary not found !])
209           fi
210           if test -z "$QT_LIB"; then
211             LYX_ERROR([qt library not found !])
212           fi
213       ;;
214     qt4)
215           QT4_DO_IT_ALL
216           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
217           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
218           RPM_FRONTEND="qt4"
219           FRONTEND_INFO="${FRONTEND_INFO}\
220   Qt 4 Frontend:\n\
221       Qt 4 version:\t\t${QT4_VERSION}\n"
222 dnl qt 4 build will fail without moc or uic
223           if test -z "$MOC4"; then
224             LYX_ERROR([moc 4 binary not found !])
225           fi
226           if test -z "$UIC4"; then
227             LYX_ERROR([uic 4 binary not found !])
228           fi
229           if test -z "$QT4_LIB"; then
230             LYX_ERROR([qt 4 library not found !])
231           fi
232       ;;
233     *)
234           LYX_ERROR(Unknown frontend '$frontend');;
235   esac
236 done
237
238 # fix the value of the prefixes.
239 test "x$prefix" = xNONE && prefix=$default_prefix
240 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
241 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
242   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
243    causes problems with the Makefiles. The installation will be done in
244    directory \"`pwd`/installprefix\" instead. Please move its contents to
245    the right place after installation.])
246   prefix=`pwd`/installprefix
247 fi
248
249 ### We need iconv for unicode support
250 AM_ICONV
251 if test "$am_cv_func_iconv" = no; then
252   LYX_ERROR([Cannot find required library iconv])
253 fi
254
255 ### Setup GNU gettext
256 dnl GNU gettext is written in C
257 AC_LANG_PUSH(C)
258 AM_GNU_GETTEXT
259 AC_LANG_POP(C)
260
261 # some standard header files
262 AC_HEADER_DIRENT
263 AC_HEADER_MAJOR
264 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
265
266 # some standard structures
267 AC_HEADER_STAT
268 AC_HEADER_TIME
269
270 # some standard types
271 AC_TYPE_MODE_T
272 AC_TYPE_OFF_T
273 AC_TYPE_PID_T
274 AC_TYPE_SIGNAL
275 AC_TYPE_SIZE_T
276 AC_TYPE_UID_T
277
278 AC_CHECK_FUNCS(strerror)
279 LYX_CHECK_DECL(istreambuf_iterator, iterator)
280 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
281
282 # Check the form of mkdir()
283 AC_FUNC_MKDIR
284
285 # check for compression support
286 AC_CHECK_HEADERS(zlib.h,
287  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
288  [LYX_LIB_ERROR(zlib.h,zlib)])
289
290 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
291 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
292 dnl We aim to remove this eventually, since we should test as much as
293 dnl possible with the compiler which will use the functions (JMarc)
294 AC_LANG_PUSH(C)
295 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
296 AC_LANG_POP(C)
297
298 LYX_CHECK_SPELL_ENGINES
299
300 lyx_client_subdir=true
301 AC_LANG_PUSH(C)
302 dnl LIBS already contains some X extra libs that may interfere.
303 save_LIBS="$LIBS"
304 LIBS=
305 AC_CHECK_FUNCS(fcntl,
306   [AC_SEARCH_LIBS([gethostbyname], [nsl])
307    AC_SEARCH_LIBS([socket], [socket], [],
308      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
309                 [], [-lnsl])])],
310   [lyx_client_subdir=false])
311 AC_SUBST(SOCKET_LIBS,$LIBS)
312 LIBS="$save_LIBS"
313 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
314 AC_LANG_POP(C)
315
316 AC_FUNC_SELECT_ARGTYPES
317
318 ### Some information on what just happened
319 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
320 real_pkgdatadir=`eval "echo \`eval \"echo ${pkgdatadir}\"\`"`
321 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
322 VERSION_INFO="Configuration\n\
323   Host type:                      ${host}\n\
324   Special build flags:            ${lyx_flags}\n\
325   C   Compiler:                   ${CC} ${CC_VERSION}\n\
326   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
327   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
328   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
329   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
330   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
331   Linker flags:                   ${AM_LDFLAGS}\n\
332   Linker user flags:              ${LDFLAGS}\n\
333 ${FRONTEND_INFO}\
334   Packaging:                      ${lyx_use_packaging}\n\
335   LyX binary dir:                 ${real_bindir}\n\
336   LyX files dir:                  ${real_pkgdatadir}\n"
337
338 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
339 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
340 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_pkgdatadir})
341
342 AC_SUBST(VERSION_INFO)
343 AC_SUBST(RPM_FRONTEND)
344 AC_SUBST(AM_CPPFLAGS)
345 AC_SUBST(AM_CXXFLAGS)
346 AC_SUBST(AM_CFLAGS)
347 AC_SUBST(AM_LDFLAGS)
348 AC_SUBST(LYX_ABS_TOP_SRCDIR)
349 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
350 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
351
352 ## Some config.h stuff
353
354 AH_TOP([
355 /* -*- C++ -*- */
356 /*
357  * \file config.h
358  * This file is part of LyX, the document processor.
359  * Licence details can be found in the file COPYING.
360  *
361  * This is the compilation configuration file for LyX.
362  * It was generated by autoconfs configure.
363  * You might want to change some of the defaults if something goes wrong
364  * during the compilation.
365  */
366
367 #ifndef _CONFIG_H
368 #define _CONFIG_H
369 ])
370
371 AH_BOTTOM([
372 /************************************************************
373  ** You should not need to change anything beyond this point */
374
375 #ifndef HAVE_STRERROR
376 #if defined(__cplusplus)
377 extern "C"
378 #endif
379 char * strerror(int n);
380 #endif
381
382 #ifdef HAVE_MKSTEMP
383 #ifndef HAVE_DECL_MKSTEMP
384 #if defined(__cplusplus)
385 extern "C"
386 #endif
387 int mkstemp(char*);
388 #endif
389 #endif
390
391 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM) && !defined(__CYGWIN__)
392 #  define USE_BOOST_FORMAT 1
393 #else
394 #  define USE_BOOST_FORMAT 0
395 #endif
396
397 #define BOOST_USER_CONFIG <config.h>
398
399 #if !defined(ENABLE_ASSERTIONS)
400 #  define BOOST_DISABLE_ASSERTS 1
401 #endif
402 #define BOOST_ENABLE_ASSERT_HANDLER 1
403
404 #define BOOST_DISABLE_THREADS 1
405 #define BOOST_NO_WREGEX 1
406 #define BOOST_NO_WSTRING 1
407
408 #ifdef __CYGWIN__
409 #  define BOOST_POSIX 1
410 #  define BOOST_POSIX_API 1
411 #  define BOOST_POSIX_PATH 1
412 #endif
413
414 #if defined(HAVE_NEWAPIS_H)
415 #  define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
416 #endif
417
418 #endif
419 ])
420
421 ### Finish the work.
422 AC_CONFIG_FILES([Makefile  m4/Makefile \
423        boost/Makefile \
424        boost/libs/Makefile \
425        boost/libs/filesystem/Makefile \
426        boost/libs/filesystem/src/Makefile \
427        boost/libs/iostreams/Makefile \
428        boost/libs/iostreams/src/Makefile \
429        boost/libs/regex/Makefile \
430        boost/libs/regex/src/Makefile \
431        boost/libs/signals/Makefile \
432        boost/libs/signals/src/Makefile \
433        config/Makefile \
434        development/Makefile \
435        development/lyx.spec \
436        lib/Makefile \
437        lib/doc/Makefile \
438        lib/lyx2lyx/lyx2lyx_version.py \
439        lib/lyx2lyx/Makefile \
440        intl/Makefile \
441        po/Makefile.in \
442        sourcedoc/Doxyfile \
443        sourcedoc/Makefile \
444        src/client/Makefile \
445        src/Makefile \
446        src/version.C-tmp:src/version.C.in \
447        src/tex2lyx/Makefile \
448        src/mathed/Makefile \
449        src/graphics/Makefile \
450        src/insets/Makefile \
451        src/support/Makefile \
452        src/support/tests/Makefile \
453        src/frontends/Makefile \
454        src/frontends/controllers/Makefile \
455        src/frontends/controllers/tests/Makefile \
456        src/frontends/gtk/Makefile \
457        src/frontends/gtk/gimages/Makefile \
458        src/frontends/gtk/glade/Makefile \
459        src/frontends/qt3/Makefile \
460        src/frontends/qt3/ui/Makefile \
461        src/frontends/qt3/ui/moc/Makefile \
462        src/frontends/qt4/Makefile \
463        src/frontends/qt4/ui/Makefile \
464 ])
465
466 AC_OUTPUT
467 # show version information
468 echo
469 printf "$VERSION_INFO"
470 echo
471
472 # Display a final warning if there has been a LYX_ERROR
473 LYX_CHECK_ERRORS