configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 # first the version
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13 AC_CANONICAL_TARGET
  14 # Check how the files should be packaged
  15 LYX_USE_PACKAGING
  16 LYX_VERSION_SUFFIX
  17
  18 dnl default maintainer mode to true for development versions
  19 if test "${enable_maintainer_mode+set}" != set; then
  20   enable_maintainer_mode=$lyx_devel_version
  21 fi
  22 AM_MAINTAINER_MODE
  23
  24 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  25
  26 ### Set the execute permissions of the various scripts correctly
  27 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  28   chmod 755 ${srcdir}/${file}
  29 done
  30
  31 ### Check for programs
  32 AC_PROG_MAKE_SET
  33 AC_PROG_INSTALL
  34
  35 AC_PROG_AWK
  36 test "$AWK" = gawk && AWK="gawk --posix"
  37
  38 #AC_PROG_RANLIB
  39 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  40 if test "x$KPSEWHICH" = xkpsewhich ; then
  41     AC_DEFINE(HAVE_KPSEWHICH, 1,
  42     [Define this if you have the kpsewhich program working on your system.])
  43 fi
  44 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  45
  46 # Check for installed python
  47 AM_PATH_PYTHON(1.5.2,, :)
  48
  49 # Work around a problem in automake 1.4: when invoking install-strip,
  50 # INSTALL_PROGRAM is changed to 'install -s', and since
  51 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  52 # which returns an error condition when stripping fails.
  53 INSTALL_SCRIPT='${INSTALL}'
  54
  55 ### we will also need a C compiler to compile GNU gettext
  56 AC_PROG_CC
  57
  58 ### check for special systems
  59 AC_ISC_POSIX
  60 AC_AIX
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTENDS
  64
  65 ### Check for a C++ compiler
  66 LYX_PROG_CXX
  67 ### Some checks on what the C++ compiler can(not) do
  68 AC_LANG(C++)
  69 dnl we do not need that currently (and probably all our supported
  70 dnl compiler allow that)
  71 dnl LYX_CXX_PARTIAL
  72 LYX_CXX_EXPLICIT
  73 LYX_CXX_GLOBAL_CSTD
  74 LYX_STD_COUNT
  75 dnl we disable rtti for now
  76 dnl LYX_CXX_RTTI
  77 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  78 LYX_CXX_STL_MODERN_STREAMS
  79
  80 ### and now some special lyx flags.
  81 AC_ARG_ENABLE(assertions,
  82   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  83   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  84         enable_assertions=yes;
  85     else
  86         enable_assertions=no;
  87     fi;])
  88 if test "x$enable_assertions" = xyes ; then
  89    lyx_flags="assertions $lyx_flags"
  90    AC_DEFINE(ENABLE_ASSERTIONS,1,
  91     [Define if you want assertions to be enabled in the code])
  92 fi
  93
  94 ### Library Files
  95 dnl by testing these we check if it is ok to have
  96 dnl -lc and -lm as args to the compiler
  97 AC_CHECK_LIB(m, sin)
  98 AC_CHECK_LIB(c, fopen)
  99
 100 ### Add extra directories to check for libraries.
 101 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 103 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 104
 105 ### Add extra directories to check for include files.
 106 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 107 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 108 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 109
 110 ### Add both includes and libraries
 111 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 112 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 113 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 114   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 115
 116 AC_ARG_WITH(aiksaurus,
 117   [  --without-aiksaurus     do not use the Aiksaurus library],
 118   [lyx_use_aiksaurus=$withval])
 119 if test x$lyx_use_aiksaurus != xno; then
 120 AC_CHECK_LIB(Aiksaurus, main,
 121         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 122          AIKSAURUS_LIBS="-lAiksaurus"
 123          lyx_flags="aiksaurus $lyx_flags"
 124         ])
 125 AC_CHECK_HEADER(Aiksaurus.h,[
 126   ac_cv_header_aiksaurus_h=yes
 127   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 128 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 129   ac_cv_header_aiksaurus_h=yes
 130   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 131 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 132 fi
 133 AC_SUBST(AIKSAURUS_LIBS)
 134
 135 LYX_USE_INCLUDED_BOOST
 136
 137 ### Setup libtool
 138 AC_DISABLE_SHARED
 139 AC_LIBTOOL_WIN32_DLL
 140 #AM_PROG_LIBTOOL
 141 LYX_PROG_LIBTOOL
 142
 143 ### Check for some Cygwin-specific details.
 144 CHECK_WITH_CYGWIN
 145
 146 ### Check for X libraries
 147 AC_PATH_XTRA
 148 case $have_x in
 149   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 150        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 151   no) LYX_ERROR(dnl
 152 [Cannot find X window libraries and/or headers. Check your installation.
 153   If you use a Linux system, check that you have installed
 154   the development tools.]);;
 155   disable) ;;
 156 esac
 157
 158 ### check which frontend we want to use
 159
 160 dnl if the gtk frontend has been specified, then xforms is needed too
 161 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 162   FRONTENDS="xforms $FRONTENDS"
 163   noxformsbin=yes
 164 fi
 165
 166 dnl The code below is not in a macro, because this would cause big
 167 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 168 for frontend in $FRONTENDS ; do
 169   case "$frontend" in
 170     xforms)
 171           XFORMS_DO_IT_ALL
 172           if test -z "$noxformsbin" ; then
 173             FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 174           fi
 175           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 176           RPM_FRONTEND="xforms"
 177           FRONTEND_INFO="${FRONTEND_INFO}\
 178   XForms Frontend:\n\
 179       libXpm version:\t\t${XPM_VERSION}\n\
 180       libforms version:\t\t${XFORMS_VERSION}\n"
 181           ;;
 182     gtk)
 183           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4 xft)
 184           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 185           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 186           RPM_FRONTEND="gtk"
 187           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 188           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 189           FRONTEND_INFO="${FRONTEND_INFO}\
 190   GTK Frontend:\n\
 191     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 192     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 193           ;;
 194
 195     qt)
 196           QT_DO_IT_ALL
 197           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 198           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 199           RPM_FRONTEND="qt"
 200           FRONTEND_INFO="${FRONTEND_INFO}\
 201   Qt Frontend:\n\
 202       Qt version:\t\t${QT_VERSION}\n"
 203 dnl qt build will fail without moc or uic
 204           if test -z "$MOC"; then
 205             LYX_ERROR([moc binary not found !])
 206           fi
 207           if test -z "$UIC"; then
 208             LYX_ERROR([uic binary not found !])
 209           fi
 210           if test -z "$QT_LIB"; then
 211             LYX_ERROR([qt library not found !])
 212           fi
 213       ;;
 214     *)
 215           LYX_ERROR(Unknown frontend '$frontend');;
 216   esac
 217 done
 218
 219 # fix the value of the prefixes.
 220 test "x$prefix" = xNONE && prefix=$default_prefix
 221 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 222 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 223   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 224    causes problems with the Makefiles. The installation will be done in
 225    directory \"`pwd`/installprefix\" instead. Please move its contents to
 226    the right place after installation.])
 227   prefix=`pwd`/installprefix
 228 fi
 229
 230 ### Setup GNU gettext
 231 dnl GNU gettext is written in C
 232 AC_LANG_PUSH(C)
 233 AM_GNU_GETTEXT
 234 AC_LANG_POP(C)
 235
 236 # some standard header files
 237 AC_HEADER_DIRENT
 238 AC_HEADER_MAJOR
 239 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 240
 241 # some standard structures
 242 AC_HEADER_STAT
 243 AC_HEADER_TIME
 244
 245 # some standard types
 246 AC_TYPE_MODE_T
 247 AC_TYPE_OFF_T
 248 AC_TYPE_PID_T
 249 AC_TYPE_SIGNAL
 250 AC_TYPE_SIZE_T
 251 AC_TYPE_UID_T
 252
 253 AC_CHECK_FUNCS(strerror)
 254 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 255 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 256
 257 # Check the form of mkdir()
 258 AC_FUNC_MKDIR
 259
 260 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 261     case "${enableval}" in
 262         yes) use_compression=true ;;
 263         no) use_compression=false ;;
 264         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 265     esac
 266 ],[use_compression=true])
 267 if test $use_compression=true ; then
 268         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 269         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 270         if test $use_compression = true ; then
 271                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 272                 lyx_flags="compression $lyx_flags"
 273         fi
 274 fi
 275 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 276 AC_MSG_CHECKING([whether to support compressed files])
 277 AC_MSG_RESULT($use_compression)
 278
 279
 280 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 281 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 282 dnl We aim to remove this eventually, since we should test as much as
 283 dnl possible with the compiler which will use the functions (JMarc)
 284 AC_LANG_PUSH(C)
 285 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 286 AC_LANG_POP(C)
 287
 288 LYX_CHECK_SPELL_ENGINES
 289
 290 lyx_client_subdir=true
 291 AC_LANG_PUSH(C)
 292 dnl LIBS already contains some X extra libs that may interfere.
 293 save_LIBS="$LIBS"
 294 LIBS=
 295 AC_CHECK_FUNCS(fcntl,
 296   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 297    AC_SEARCH_LIBS([socket], [socket], [],
 298      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 299                 [], [-lnsl])])],
 300   [lyx_client_subdir=false])
 301 AC_SUBST(SOCKET_LIBS,$LIBS)
 302 LIBS="$save_LIBS"
 303 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 304 AC_LANG_POP(C)
 305
 306 AC_FUNC_SELECT_ARGTYPES
 307
 308 ### Some information on what just happened
 309 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 310 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 311 VERSION_INFO="Configuration\n\
 312   Host type:                      ${host}\n\
 313   Special build flags:            ${lyx_flags}\n\
 314   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 315   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 316   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 317   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 318   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 319   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 320   Linker flags:                   ${AM_LDFLAGS}\n\
 321   Linker user flags:              ${LDFLAGS}\n\
 322 ${FRONTEND_INFO}\
 323   Packaging:                      ${lyx_use_packaging}\n\
 324   LyX binary dir:                 ${real_bindir}\n\
 325   LyX files dir:                  ${real_datadir}\n"
 326
 327 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 328 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 329 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 330 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_datadir})
 331
 332 AC_SUBST(VERSION_INFO)
 333 AC_SUBST(RPM_FRONTEND)
 334 AC_SUBST(AM_CPPFLAGS)
 335 AC_SUBST(AM_CXXFLAGS)
 336 AC_SUBST(AM_CFLAGS)
 337 AC_SUBST(AM_LDFLAGS)
 338 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 339 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 340 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 341
 342 ## Some config.h stuff
 343
 344 AH_TOP([
 345 /* -*- C++ -*- */
 346 /*
 347  * \file config.h
 348  * This file is part of LyX, the document processor.
 349  * Licence details can be found in the file COPYING.
 350  *
 351  * This is the compilation configuration file for LyX.
 352  * It was generated by autoconfs configure.
 353  * You might want to change some of the defaults if something goes wrong
 354  * during the compilation.
 355  */
 356
 357 #ifndef _CONFIG_H
 358 #define _CONFIG_H
 359 ])
 360
 361 AH_BOTTOM([
 362 /************************************************************
 363  ** You should not need to change anything beyond this point */
 364
 365 #ifndef HAVE_STRERROR
 366 #if defined(__cplusplus)
 367 extern "C"
 368 #endif
 369 char * strerror(int n);
 370 #endif
 371
 372 #ifdef HAVE_MKSTEMP
 373 #ifndef HAVE_DECL_MKSTEMP
 374 #if defined(__cplusplus)
 375 extern "C"
 376 #endif
 377 int mkstemp(char*);
 378 #endif
 379 #endif
 380
 381 #ifdef __EMX__
 382 #include "support/os2_defines.h"
 383 #endif
 384
 385 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 386 #define USE_BOOST_FORMAT 1
 387 #else
 388 #define USE_BOOST_FORMAT 0
 389 #endif
 390
 391 #define BOOST_USER_CONFIG <config.h>
 392
 393 #if defined(ENABLE_ASSERTIONS)
 394 #define BOOST_ENABLE_ASSERT_HANDLER 1
 395 #else
 396 #define BOOST_DISABLE_ASSERTS 1
 397 #endif
 398
 399 #define BOOST_DISABLE_THREADS 1
 400 #define BOOST_NO_WREGEX 1
 401 #define BOOST_NO_WSTRING 1
 402
 403 #ifdef __CYGWIN__
 404 #define BOOST_POSIX 1
 405 #endif
 406
 407 #if defined(HAVE_NEWAPIS_H)
 408 #define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 409 #endif
 410
 411 #endif
 412 ])
 413
 414 ### Finish the work.
 415 AC_CONFIG_SUBDIRS(lib)
 416 AC_CONFIG_FILES([Makefile  m4/Makefile \
 417        boost/Makefile \
 418        boost/libs/Makefile \
 419        boost/libs/filesystem/Makefile \
 420        boost/libs/filesystem/src/Makefile \
 421        boost/libs/regex/Makefile \
 422        boost/libs/regex/src/Makefile \
 423        boost/libs/signals/Makefile \
 424        boost/libs/signals/src/Makefile \
 425        config/Makefile \
 426        development/Makefile \
 427        development/lyx.spec \
 428        lib/Makefile \
 429        lib/doc/Makefile \
 430        lib/lyx2lyx/Makefile \
 431        intl/Makefile \
 432        po/Makefile.in \
 433        sourcedoc/Doxyfile \
 434        sourcedoc/Makefile \
 435        src/client/Makefile \
 436        src/Makefile \
 437        src/version.C-tmp:src/version.C.in \
 438        src/tex2lyx/Makefile \
 439        src/mathed/Makefile \
 440        src/graphics/Makefile \
 441        src/insets/Makefile \
 442        src/support/Makefile \
 443        src/support/tests/Makefile \
 444        src/frontends/Makefile \
 445        src/frontends/controllers/Makefile \
 446        src/frontends/xforms/Makefile \
 447        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 448        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 449        src/frontends/xforms/forms/Makefile \
 450        src/frontends/gtk/Makefile \
 451        src/frontends/gtk/gimages/Makefile \
 452        src/frontends/gtk/glade/Makefile \
 453        src/frontends/qt2/Makefile \
 454        src/frontends/qt2/moc/Makefile \
 455        src/frontends/qt2/ui/Makefile \
 456        src/frontends/qt2/ui/moc/Makefile \
 457 ])
 458
 459 AC_OUTPUT
 460 # show version information
 461 echo
 462 printf "$VERSION_INFO"
 463 echo
 464
 465 # Display a final warning if there has been a LYX_ERROR
 466 LYX_CHECK_ERRORS