configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 # first the version
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13 AC_CANONICAL_TARGET
  14 # Check how the files should be packaged
  15 LYX_USE_PACKAGING
  16 LYX_VERSION_SUFFIX
  17
  18 dnl default maintainer mode to true for development versions
  19 if test "${enable_maintainer_mode+set}" != set; then
  20   enable_maintainer_mode=$lyx_devel_version
  21 fi
  22 AM_MAINTAINER_MODE
  23
  24 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  25
  26 ### Set the execute permissions of the various scripts correctly
  27 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  28   chmod 755 ${srcdir}/${file}
  29 done
  30
  31 ### Check for programs
  32 AC_PROG_MAKE_SET
  33 AC_PROG_INSTALL
  34
  35 AC_PROG_AWK
  36 test "$AWK" = gawk && AWK="gawk --posix"
  37
  38 #AC_PROG_RANLIB
  39 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  40 if test "x$KPSEWHICH" = xkpsewhich ; then
  41     AC_DEFINE(HAVE_KPSEWHICH, 1,
  42     [Define this if you have the kpsewhich program working on your system.])
  43 fi
  44 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  45
  46 # Check for installed python
  47 AM_PATH_PYTHON(1.5.2,, :)
  48
  49 # Work around a problem in automake 1.4: when invoking install-strip,
  50 # INSTALL_PROGRAM is changed to 'install -s', and since
  51 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  52 # which returns an error condition when stripping fails.
  53 INSTALL_SCRIPT='${INSTALL}'
  54
  55 ### we will also need a C compiler to compile GNU gettext
  56 AC_PROG_CC
  57
  58 ### check for special systems
  59 AC_ISC_POSIX
  60 AC_AIX
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTENDS
  64
  65 ### Check for a C++ compiler
  66 LYX_PROG_CXX
  67 ### Some checks on what the C++ compiler can(not) do
  68 AC_LANG(C++)
  69 dnl we do not need that currently (and probably all our supported
  70 dnl compiler allow that)
  71 dnl LYX_CXX_PARTIAL
  72 LYX_CXX_EXPLICIT
  73 LYX_CXX_GLOBAL_CSTD
  74 LYX_STD_COUNT
  75 dnl we disable rtti for now
  76 dnl LYX_CXX_RTTI
  77 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  78 LYX_CXX_STL_MODERN_STREAMS
  79
  80 ### and now some special lyx flags.
  81 AC_ARG_ENABLE(assertions,
  82   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  83   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  84         enable_assertions=yes;
  85     else
  86         enable_assertions=no;
  87     fi;])
  88 if test "x$enable_assertions" = xyes ; then
  89    lyx_flags="assertions $lyx_flags"
  90    AC_DEFINE(ENABLE_ASSERTIONS,1,
  91     [Define if you want assertions to be enabled in the code])
  92 fi
  93
  94 ### Library Files
  95 dnl by testing these we check if it is ok to have
  96 dnl -lc and -lm as args to the compiler
  97 AC_CHECK_LIB(m, sin)
  98 AC_CHECK_LIB(c, fopen)
  99
 100 ### Add extra directories to check for libraries.
 101 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 103 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 104
 105 ### Add extra directories to check for include files.
 106 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 107 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 108 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 109
 110 ### Add both includes and libraries
 111 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 112 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 113 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 114   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 115
 116 AC_ARG_WITH(aiksaurus,
 117   [  --without-aiksaurus     do not use the Aiksaurus library],
 118   [lyx_use_aiksaurus=$withval])
 119 if test x$lyx_use_aiksaurus != xno; then
 120 AC_CHECK_LIB(Aiksaurus, main,
 121         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 122          AIKSAURUS_LIBS="-lAiksaurus"
 123          lyx_flags="aiksaurus $lyx_flags"
 124         ])
 125 AC_CHECK_HEADER(Aiksaurus.h,[
 126   ac_cv_header_aiksaurus_h=yes
 127   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 128 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 129   ac_cv_header_aiksaurus_h=yes
 130   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 131 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 132 fi
 133 AC_SUBST(AIKSAURUS_LIBS)
 134
 135 LYX_USE_INCLUDED_BOOST
 136
 137 ### Setup libtool
 138 AC_DISABLE_SHARED
 139 AC_LIBTOOL_WIN32_DLL
 140 #AM_PROG_LIBTOOL
 141 LYX_PROG_LIBTOOL
 142
 143 ### Check for some Cygwin-specific details.
 144 CHECK_WITH_CYGWIN
 145
 146 ### Check for X libraries
 147 AC_PATH_XTRA
 148 case $have_x in
 149   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 150        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 151   no) LYX_ERROR(dnl
 152 [Cannot find X window libraries and/or headers. Check your installation.
 153   If you use a Linux system, check that you have installed
 154   the development tools.]);;
 155   disable) ;;
 156 esac
 157
 158 ### check which frontend we want to use
 159
 160 dnl if the gtk frontend has been specified, then xforms is needed too
 161 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 162   FRONTENDS="xforms $FRONTENDS"
 163   noxformsbin=yes
 164 fi
 165
 166 dnl The code below is not in a macro, because this would cause big
 167 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 168 for frontend in $FRONTENDS ; do
 169   case "$frontend" in
 170     xforms)
 171           XFORMS_DO_IT_ALL
 172           if test -z "$noxformsbin" ; then
 173             FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 174           fi
 175           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 176           RPM_FRONTEND="xforms"
 177           FRONTEND_INFO="${FRONTEND_INFO}\
 178   XForms Frontend:\n\
 179       libXpm version:\t\t${XPM_VERSION}\n\
 180       libforms version:\t\t${XFORMS_VERSION}\n"
 181           ;;
 182   dnl   gnome)
 183   dnl     XFORMS_DO_IT_ALL
 184   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 185   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 186   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 187
 188   dnl     FRONTEND="xforms gnome"
 189   dnl     FRONTEND_GUILIB="gnome/*.lo"
 190   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 191   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 192   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 193   dnl   ;;
 194     gtk)
 195           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 196           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 197           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 198           RPM_FRONTEND="gtk"
 199           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 200           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 201           FRONTEND_INFO="${FRONTEND_INFO}\
 202   GTK Frontend:\n\
 203     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 204     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 205           ;;
 206
 207     qt)
 208           QT_DO_IT_ALL
 209           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 210           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 211           RPM_FRONTEND="qt"
 212           FRONTEND_INFO="${FRONTEND_INFO}\
 213   Qt Frontend:\n\
 214       Qt version:\t\t${QT_VERSION}\n"
 215 dnl qt build will fail without moc or uic
 216           if test -z "$MOC"; then
 217             LYX_ERROR([moc binary not found !])
 218           fi
 219           if test -z "$UIC"; then
 220             LYX_ERROR([uic binary not found !])
 221           fi
 222           if test -z "$QT_LIB"; then
 223             LYX_ERROR([qt library not found !])
 224           fi
 225       ;;
 226     *)
 227           LYX_ERROR(Unknown frontend '$frontend');;
 228   esac
 229 done
 230
 231 # fix the value of the prefixes.
 232 test "x$prefix" = xNONE && prefix=$default_prefix
 233 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 234 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 235   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 236    causes problems with the Makefiles. The installation will be done in
 237    directory \"`pwd`/installprefix\" instead. Please move its contents to
 238    the right place after installation.])
 239   prefix=`pwd`/installprefix
 240 fi
 241
 242 ### Setup GNU gettext
 243 dnl GNU gettext is written in C
 244 AC_LANG_PUSH(C)
 245 AM_GNU_GETTEXT
 246 AC_LANG_POP(C)
 247
 248 # some standard header files
 249 AC_HEADER_DIRENT
 250 AC_HEADER_MAJOR
 251 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h utime.h sys/utime.h io.h process.h NewAPIs.h)
 252
 253 # some standard structures
 254 AC_HEADER_STAT
 255 AC_HEADER_TIME
 256
 257 # some standard types
 258 AC_TYPE_MODE_T
 259 AC_TYPE_OFF_T
 260 AC_TYPE_PID_T
 261 AC_TYPE_SIGNAL
 262 AC_TYPE_SIZE_T
 263 AC_TYPE_UID_T
 264
 265 AC_CHECK_FUNCS(strerror)
 266 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 267 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 268
 269 # Check the form of mkdir()
 270 AC_FUNC_MKDIR
 271
 272 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 273     case "${enableval}" in
 274         yes) use_compression=true ;;
 275         no) use_compression=false ;;
 276         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 277     esac
 278 ],[use_compression=true])
 279 if test $use_compression=true ; then
 280         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 281         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 282         if test $use_compression = true ; then
 283                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 284                 lyx_flags="compression $lyx_flags"
 285         fi
 286 fi
 287 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 288 AC_MSG_CHECKING([whether to support compressed files])
 289 AC_MSG_RESULT($use_compression)
 290
 291
 292 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 293 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 294 dnl We aim to remove this eventually, since we should test as much as
 295 dnl possible with the compiler which will use the functions (JMarc)
 296 AC_LANG_PUSH(C)
 297 AC_CHECK_FUNCS(close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 298 AC_LANG_POP(C)
 299
 300 LYX_CHECK_SPELL_ENGINES
 301
 302 lyx_client_subdir=true
 303 AC_LANG_PUSH(C)
 304 AC_CHECK_FUNCS(fcntl,, [lyx_client_subdir=false])
 305 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 306 AC_LANG_POP(C)
 307
 308 AC_FUNC_SELECT_ARGTYPES
 309
 310 ### Some information on what just happened
 311 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 312 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 313 VERSION_INFO="Configuration\n\
 314   Host type:                      ${host}\n\
 315   Special build flags:            ${lyx_flags}\n\
 316   C   Compiler:                   ${CC} ${CC_VERSION}\n\
 317   C   Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 318   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 319   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 320   C++ Compiler LyX flags:         ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 321   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 322   Linker flags:                   ${AM_LDFLAGS}\n\
 323   Linker user flags:              ${LDFLAGS}\n\
 324 ${FRONTEND_INFO}\
 325   Packaging:                      ${lyx_use_packaging}\n\
 326   LyX binary dir:                 ${real_bindir}\n\
 327   LyX files dir:                  ${real_datadir}\n"
 328
 329 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 330 MSYS_AC_CANONICAL_PATH(LYX_ABS_TOP_SRCDIR, ${srcdir})
 331 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_LOCALEDIR, ${real_localedir})
 332 MSYS_AC_CANONICAL_PATH(LYX_ABS_INSTALLED_DATADIR, ${real_datadir})
 333
 334 AC_SUBST(VERSION_INFO)
 335 AC_SUBST(RPM_FRONTEND)
 336 AC_SUBST(AM_CPPFLAGS)
 337 AC_SUBST(AM_CXXFLAGS)
 338 AC_SUBST(AM_CFLAGS)
 339 AC_SUBST(AM_LDFLAGS)
 340 AC_SUBST(LYX_ABS_TOP_SRCDIR)
 341 AC_SUBST(LYX_ABS_INSTALLED_LOCALEDIR)
 342 AC_SUBST(LYX_ABS_INSTALLED_DATADIR)
 343
 344 ## Some config.h stuff
 345
 346 AH_TOP([
 347 /* -*- C++ -*- */
 348 /*
 349  * \file config.h
 350  * This file is part of LyX, the document processor.
 351  * Licence details can be found in the file COPYING.
 352  *
 353  * This is the compilation configuration file for LyX.
 354  * It was generated by autoconfs configure.
 355  * You might want to change some of the defaults if something goes wrong
 356  * during the compilation.
 357  */
 358
 359 #ifndef _CONFIG_H
 360 #define _CONFIG_H
 361 ])
 362
 363 AH_BOTTOM([
 364 /************************************************************
 365  ** You should not need to change anything beyond this point */
 366
 367 #ifndef HAVE_STRERROR
 368 #if defined(__cplusplus)
 369 extern "C"
 370 #endif
 371 char * strerror(int n);
 372 #endif
 373
 374 #ifdef HAVE_MKSTEMP
 375 #ifndef HAVE_DECL_MKSTEMP
 376 #if defined(__cplusplus)
 377 extern "C"
 378 #endif
 379 int mkstemp(char*);
 380 #endif
 381 #endif
 382
 383 #ifdef __EMX__
 384 #include "support/os2_defines.h"
 385 #endif
 386
 387 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 388 #define USE_BOOST_FORMAT 1
 389 #else
 390 #define USE_BOOST_FORMAT 0
 391 #endif
 392
 393 #define BOOST_USER_CONFIG <config.h>
 394
 395 #if defined(ENABLE_ASSERTIONS)
 396 #define BOOST_ENABLE_ASSERT_HANDLER 1
 397 #else
 398 #define BOOST_DISABLE_ASSERTS 1
 399 #endif
 400
 401 #define BOOST_DISABLE_THREADS 1
 402 #define BOOST_NO_WREGEX 1
 403 #define BOOST_NO_WSTRING 1
 404
 405 #ifdef __CYGWIN__
 406 #define BOOST_POSIX 1
 407 #endif
 408
 409 #if defined(HAVE_NEWAPIS_H)
 410 #define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 411 #endif
 412
 413 #endif
 414 ])
 415
 416 ### Finish the work.
 417 AC_CONFIG_SUBDIRS(lib)
 418 AC_CONFIG_FILES([Makefile  m4/Makefile \
 419        boost/Makefile \
 420        boost/libs/Makefile \
 421        boost/libs/filesystem/Makefile \
 422        boost/libs/filesystem/src/Makefile \
 423        boost/libs/regex/Makefile \
 424        boost/libs/regex/src/Makefile \
 425        boost/libs/signals/Makefile \
 426        boost/libs/signals/src/Makefile \
 427        config/Makefile \
 428        development/Makefile \
 429        development/lyx.spec \
 430        lib/Makefile \
 431        lib/doc/Makefile \
 432        lib/lyx2lyx/Makefile \
 433        intl/Makefile \
 434        po/Makefile.in \
 435        sourcedoc/Doxyfile \
 436        sourcedoc/Makefile \
 437        src/client/Makefile \
 438        src/Makefile \
 439        src/version.C-tmp:src/version.C.in \
 440        src/tex2lyx/Makefile \
 441        src/mathed/Makefile \
 442        src/graphics/Makefile \
 443        src/insets/Makefile \
 444        src/support/Makefile \
 445        src/support/tests/Makefile \
 446        src/frontends/Makefile \
 447        src/frontends/controllers/Makefile \
 448        src/frontends/xforms/Makefile \
 449        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 450        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 451        src/frontends/xforms/forms/Makefile \
 452        src/frontends/gtk/Makefile \
 453        src/frontends/gtk/gimages/Makefile \
 454        src/frontends/gtk/glade/Makefile \
 455        src/frontends/qt2/Makefile \
 456        src/frontends/qt2/moc/Makefile \
 457        src/frontends/qt2/ui/Makefile \
 458        src/frontends/qt2/ui/moc/Makefile \
 459 ])
 460
 461 AC_OUTPUT
 462 # show version information
 463 echo
 464 printf "$VERSION_INFO"
 465 echo
 466
 467 # Display a final warning if there has been a LYX_ERROR
 468 LYX_CHECK_ERRORS