configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.2.2dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2016-05-23"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 # Automake is pulling the historical V7 format. This tar format supports
  36 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  37 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  39 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  40 PACKAGE=$save_PACKAGE
  41
  42 # Allow to build some parts of the code as one big chunk
  43 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  44 AC_ARG_ENABLE(monolithic-build,
  45   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  46                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  47   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  48    test "$enable_monolithic_build" = no && enable_monolithic_build=
  49    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  50    for i in $enable_monolithic_build ; do
  51        eval "enable_monolithic_$i=yes"
  52    done
  53    IFS="$ac_save_ifs"],
  54   [enable_monolithic_build=])
  55
  56 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  63
  64 ### Set the execute permissions of the various scripts correctly
  65 for file in config/install-sh ; do
  66   chmod 755 ${srcdir}/${file}
  67 done
  68
  69 # Find a suitable python interpreter
  70 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  71 # do the usual python setup stuff
  72 AM_PATH_PYTHON
  73
  74 # Tools for creating libraries (note that we do not use libtool)
  75 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  76 AC_PROG_RANLIB
  77 dnl Recent debian/ubuntu (at least) have built 'ar' so that deterministic mode is the default.
  78 dnl This means that it does not make sense to use the 'u' flag (default ARFLAGS is 'cru').
  79 AC_SUBST([ARFLAGS], [cr])
  80
  81 ### Check for a C++ compiler
  82 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  83 dnl if it is not set. We do not use autoconf defaults.
  84 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  85 if ! test "$lyx_has_CXXFLAGS" = yes; then
  86   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  87   CXXFLAGS=" "
  88 fi
  89 LYX_PROG_CXX
  90 if ! test "$lyx_has_CXXFLAGS" = yes; then
  91   unset CXXFLAGS
  92 fi
  93 AC_LANG(C++)
  94
  95 ### Objective-C compiler
  96 AC_PROG_OBJC
  97 _AM_DEPENDENCIES([OBJC])
  98
  99 ### Add extra directories to check for libraries.
 100 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 101 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 102 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 103
 104 ### Add extra directories to check for include files.
 105 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 107 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 108
 109 ### Add both includes and libraries
 110 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 111 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 112   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 113   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 114 ])
 115
 116 ### These are needed in windows
 117 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 118 AC_SUBST(LIBSHLWAPI)
 119 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 120 AC_SUBST(LIBPSAPI)
 121 AC_CHECK_LIB(gdi32, main)
 122
 123 LYX_USE_INCLUDED_BOOST
 124 LYX_USE_INCLUDED_MYTHES
 125
 126 ### we need to know the byte order for unicode conversions
 127 AC_C_BIGENDIAN
 128
 129 # Nice to have when an assertion triggers
 130 LYX_CHECK_CALLSTACK_PRINTING
 131
 132 # Needed for our char_type
 133 AC_CHECK_SIZEOF(wchar_t)
 134
 135 ### We need iconv for unicode support (Qt4 frontend requires it too)
 136 AM_ICONV
 137 if test "$am_cv_func_iconv" = no; then
 138   AC_MSG_ERROR([cannot find required library iconv.])
 139 else
 140   LIBS="$LIBS $LIBICONV"
 141 fi
 142
 143 ### check for compression support
 144 AC_CHECK_HEADERS(zlib.h,
 145  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 146  [LYX_LIB_ERROR(zlib.h,zlib)])
 147
 148 ### check for file magic support (currently optional)
 149 AC_CHECK_HEADERS(magic.h,
 150  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 151   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 152    is correctly installed on your system.
 153    Falling back to builtin file format detection.]))],
 154  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 155    is correctly installed on your system.
 156    Falling back to builtin file format detection.])])
 157
 158 ### setup the qt frontend.
 159 dnl The code below is not in a macro, because this would cause big
 160 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 161 QT_DO_IT_ALL([4.5.0])
 162 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 163 FRONTEND_INFO="${FRONTEND_INFO}\
 164   Qt Frontend:\n\
 165       Qt version:\t   ${QTLIB_VERSION}\n"
 166
 167 # fix the value of the prefixes.
 168 test "x$prefix" = xNONE && prefix=$default_prefix
 169 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 170 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 171   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 172    causes problems with the Makefiles. The installation will be done in
 173    directory \"`pwd`/installprefix\" instead. Please move its contents to
 174    the right place after installation.])
 175   prefix=`pwd`/installprefix
 176 fi
 177
 178 ### Setup po directory
 179 AM_NLS
 180 if test $USE_NLS = "yes" ; then
 181   AC_DEFINE(ENABLE_NLS, 1,
 182     [Define to 1 if translation of program messages to the user's native language
 183    is requested.])dnl'
 184 fi
 185 AM_PO_SUBDIRS
 186
 187 # some standard header files
 188 AC_HEADER_MAJOR
 189 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 190
 191 # some standard types
 192 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 193 AC_TYPE_OFF_T
 194 AC_TYPE_PID_T
 195 AC_TYPE_SIZE_T
 196 AC_TYPE_UID_T
 197 # Taken from gettext
 198 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 199    [AC_TRY_COMPILE([#include <stddef.h>
 200       wchar_t foo = (wchar_t)'\0';], ,
 201       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 202 if test $gt_cv_c_wchar_t = yes; then
 203   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 204 fi
 205
 206 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 207
 208 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 209 # Check the form of mkdir()
 210 AC_FUNC_MKDIR
 211 AC_FUNC_SELECT_ARGTYPES
 212
 213 LYX_CHECK_SPELL_ENGINES
 214
 215 lyx_client_subdir=true
 216 dnl AC_LANG_PUSH(C)
 217 dnl LIBS already contains some X extra libs that may interfere.
 218 save_LIBS="$LIBS"
 219 LIBS=
 220 AC_CHECK_FUNCS(fcntl,
 221   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 222    AC_SEARCH_LIBS([socket], [socket network], [],
 223      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 224                 [], [-lnsl])])],
 225   [lyx_client_subdir=false])
 226 AC_SUBST(SOCKET_LIBS,$LIBS)
 227 LIBS="$save_LIBS"
 228 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 229 dnl AC_LANG_POP(C)
 230
 231 lyx_win_res=false;
 232 case ${host} in
 233     *mingw*|*cygwin*) lyx_win_res=true;;
 234 esac
 235 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 236 LYX_SET_VERSION_INFO
 237
 238
 239 ### Some information on what just happened
 240 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 241 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 242 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 243 VERSION_INFO="Configuration\n\
 244   Host type:               ${host}\n\
 245   Special build flags:     ${lyx_flags}\n\
 246   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 247   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 248   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 249   Linker flags:            ${AM_LDFLAGS}\n\
 250   Linker user flags:       ${LDFLAGS}\n\
 251 ${FRONTEND_INFO}\
 252   Packaging:               ${lyx_use_packaging}\n\
 253   LyX binary dir:          ${real_bindir}\n\
 254   LyX files dir:           ${real_pkgdatadir}\n"
 255
 256 AC_SUBST(VERSION_INFO)
 257 AC_SUBST(AM_CPPFLAGS)
 258 AC_SUBST(AM_CXXFLAGS)
 259 AC_SUBST(AM_LDFLAGS)
 260 AC_SUBST(real_pkgdatadir)
 261
 262 ## Some config.h stuff
 263
 264 AH_TOP([
 265 /* -*- C++ -*- */
 266 /*
 267  * \file config.h
 268  * This file is part of LyX, the document processor.
 269  * Licence details can be found in the file COPYING.
 270  *
 271  * This is the compilation configuration file for LyX.
 272  * It was generated by autoconfs configure.
 273  * You might want to change some of the defaults if something goes wrong
 274  * during the compilation.
 275  */
 276
 277 #ifndef _CONFIG_H
 278 #define _CONFIG_H
 279 ])
 280
 281 AH_BOTTOM([
 282 /************************************************************
 283  ** You should not need to change anything beyond this point */
 284
 285 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 286 #define LYX_USE_CXX11
 287 #endif
 288
 289 #ifndef HAVE_STRERROR
 290 #if defined(__cplusplus)
 291 extern "C"
 292 #endif
 293 char * strerror(int n);
 294 #endif
 295
 296 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 297 #  define USE_BOOST_FORMAT 1
 298 #else
 299 #  define USE_BOOST_FORMAT 0
 300 #endif
 301
 302 #define BOOST_USER_CONFIG <config.h>
 303
 304 #if !defined(ENABLE_ASSERTIONS)
 305 #  define BOOST_DISABLE_ASSERTS 1
 306 #endif
 307 #define BOOST_ENABLE_ASSERT_HANDLER 1
 308
 309 #define BOOST_DISABLE_THREADS 1
 310 #define BOOST_NO_WREGEX 1
 311 #define BOOST_NO_WSTRING 1
 312 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 313
 314 #ifdef __CYGWIN__
 315 #  define NOMINMAX
 316 #  define BOOST_POSIX 1
 317 #  define BOOST_POSIX_API 1
 318 #  define BOOST_POSIX_PATH 1
 319 #endif
 320
 321 #ifdef __sparc__
 322 #  ifndef __BIG_ENDIAN__
 323 #    define __BIG_ENDIAN__ 1
 324 #  endif
 325 #endif
 326
 327 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 328 #  define USE_WCHAR_T
 329 #endif
 330
 331 #endif
 332 ])
 333
 334 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 335 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 336 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 337
 338 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 339         "${lyx_abs_top_srcdir}", [Top source directory])
 340 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 341         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 342 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 343         "${lyx_abs_installed_datadir}",[Hard system support directory])
 344 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 345         "${version_suffix}",[Program version suffix])
 346
 347 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 348 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 349 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 350 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 351 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 352 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 353 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 354 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 355
 356 AC_CONFIG_FILES([Makefile \
 357       lyx.1:lyx.1in \
 358       3rdparty/Makefile \
 359       3rdparty/boost/Makefile \
 360       3rdparty/hunspell/Makefile \
 361       3rdparty/libiconv/Makefile \
 362       3rdparty/zlib/Makefile \
 363       autotests/Makefile \
 364       config/Makefile \
 365       development/Makefile \
 366       development/MacOSX/Makefile \
 367       development/MacOSX/Info.plist \
 368       development/MacOSX/lyxrc.dist \
 369       development/MacOSX/spotlight/Makefile \
 370       development/cygwin/Makefile \
 371       development/cygwin/lyxrc.dist \
 372       development/lyx.spec \
 373       lib/lyx.desktop-temp:lib/lyx.desktop.in
 374       lib/Makefile \
 375       lib/doc/Makefile \
 376       lib/lyx2lyx/lyx2lyx_version.py \
 377       lib/lyx2lyx/Makefile \
 378       m4/Makefile \
 379       po/Makefile.in \
 380       sourcedoc/Doxyfile \
 381       sourcedoc/Makefile \
 382       src/client/Makefile \
 383       src/client/lyxclient.1:src/client/lyxclient.1in \
 384       src/Makefile \
 385       src/tex2lyx/Makefile \
 386       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 387       src/support/Makefile \
 388       src/frontends/Makefile \
 389       src/frontends/qt4/Makefile
 390 ])
 391
 392
 393 AC_OUTPUT
 394
 395 # show version information
 396 echo
 397 printf "$VERSION_INFO"
 398 echo
 399
 400 # Display a final warning if there has been a LYX_WARNING
 401 LYX_CHECK_WARNINGS
 402
 403 cat <<EOF
 404 Configuration of LyX was successful.
 405 Type 'make' to compile the program,
 406 and then 'make install' to install it.
 407 EOF