configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.1.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2013-07-13"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 # Check how the files should be packaged
  17 AC_CANONICAL_TARGET
  18 LYX_USE_PACKAGING
  19 # We need to define these variables here and the no-define option of
  20 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  22
  23 dnl Default maintainer mode to true for development versions
  24 if test "${enable_maintainer_mode+set}" != set; then
  25   enable_maintainer_mode=$lyx_devel_version
  26 fi
  27 AM_MAINTAINER_MODE
  28
  29 save_PACKAGE=$PACKAGE
  30 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8])
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32 PACKAGE=$save_PACKAGE
  33
  34 # Allow to build some parts of the code as one big chunk
  35 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt4])
  36 AC_ARG_ENABLE(monolithic-build,
  37   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  38                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  39   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  40    test "$enable_monolithic_build" = no && enable_monolithic_build=
  41    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  42    for i in $enable_monolithic_build ; do
  43        eval "enable_monolithic_$i=yes"
  44    done
  45    IFS="$ac_save_ifs"],
  46   [enable_monolithic_build=])
  47
  48 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  49 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  50 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  51 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  52 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  53 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  54 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT4, test "x$enable_monolithic_frontend_qt4" = "xyes")
  55
  56 ### Set the execute permissions of the various scripts correctly
  57 for file in config/install-sh ; do
  58   chmod 755 ${srcdir}/${file}
  59 done
  60
  61 AM_PATH_PYTHON(2.4.0,, :)
  62 AC_PROG_RANLIB
  63
  64 ### we need to know the byte order for unicode conversions
  65 AC_C_BIGENDIAN
  66
  67 ### Check for a C++ compiler
  68 LYX_PROG_CXX
  69
  70 ### Objective-C compiler
  71 AC_PROG_OBJC
  72 _AM_DEPENDENCIES([OBJC])
  73
  74 ### Add extra directories to check for libraries.
  75 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  76 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  77 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  78
  79 ### Add extra directories to check for include files.
  80 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  81 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  82 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  83
  84 ### Add both includes and libraries
  85 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  86 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  87 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
  88   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
  89
  90 ### These are needed in windows
  91 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
  92 AC_SUBST(LIBSHLWAPI)
  93 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
  94 AC_SUBST(LIBPSAPI)
  95 AC_CHECK_LIB(gdi32, main)
  96
  97 LYX_USE_INCLUDED_BOOST
  98 LYX_USE_INCLUDED_MYTHES
  99
 100 # Needed for our char_type
 101 AC_CHECK_SIZEOF(wchar_t)
 102
 103 ### We need iconv for unicode support (Qt4 frontend requires it too)
 104 AM_ICONV
 105 if test "$am_cv_func_iconv" = no; then
 106   AC_MSG_ERROR([cannot find required library iconv.])
 107 else
 108   LIBS="$LIBS $LIBICONV"
 109 fi
 110
 111 ### check for compression support
 112 AC_CHECK_HEADERS(zlib.h,
 113  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 114  [LYX_LIB_ERROR(zlib.h,zlib)])
 115
 116 ### check for file magic support (currently optional)
 117 AC_CHECK_HEADERS(magic.h,
 118  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 119   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 120    is correctly installed on your system.
 121    Falling back to builtin file format detection.]))],
 122  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 123    is correctly installed on your system.
 124    Falling back to builtin file format detection.])])
 125
 126 ### setup the qt4 frontend.
 127 dnl The code below is not in a macro, because this would cause big
 128 dnl problems with the AC_REQUIRE contained in QT4_DO_IT_ALL.
 129 QT4_DO_IT_ALL([4.5.0])
 130 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 131 FRONTEND_INFO="${FRONTEND_INFO}\
 132   Qt 4 Frontend:\n\
 133       Qt 4 version:\t\t${QT4_VERSION}\n"
 134
 135 # fix the value of the prefixes.
 136 test "x$prefix" = xNONE && prefix=$default_prefix
 137 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 138 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 139   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 140    causes problems with the Makefiles. The installation will be done in
 141    directory \"`pwd`/installprefix\" instead. Please move its contents to
 142    the right place after installation.])
 143   prefix=`pwd`/installprefix
 144 fi
 145
 146 ### Setup po directory
 147 AM_PO_SUBDIRS
 148 AM_NLS
 149 if test $USE_NLS = "yes" ; then
 150   AC_DEFINE(ENABLE_NLS, 1,
 151     [Define to 1 if translation of program messages to the user's native language
 152    is requested.])dnl'
 153 fi
 154
 155 # some standard header files
 156 AC_HEADER_MAJOR
 157 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 158
 159 # some standard types
 160 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 161 AC_TYPE_OFF_T
 162 AC_TYPE_PID_T
 163 AC_TYPE_SIZE_T
 164 AC_TYPE_UID_T
 165 # Taken from gettext
 166 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 167    [AC_TRY_COMPILE([#include <stddef.h>
 168       wchar_t foo = (wchar_t)'\0';], ,
 169       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 170 if test $gt_cv_c_wchar_t = yes; then
 171   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 172 fi
 173
 174 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 175
 176 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lstat mkfifo open _open pclose _pclose popen _popen readlink setenv strerror unsetenv)
 177 # Check the form of mkdir()
 178 AC_FUNC_MKDIR
 179 AC_FUNC_SELECT_ARGTYPES
 180
 181 LYX_CHECK_SPELL_ENGINES
 182
 183 lyx_client_subdir=true
 184 AC_LANG_PUSH(C)
 185 dnl LIBS already contains some X extra libs that may interfere.
 186 save_LIBS="$LIBS"
 187 LIBS=
 188 AC_CHECK_FUNCS(fcntl,
 189   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 190    AC_SEARCH_LIBS([socket], [socket], [],
 191      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 192                 [], [-lnsl])])],
 193   [lyx_client_subdir=false])
 194 AC_SUBST(SOCKET_LIBS,$LIBS)
 195 LIBS="$save_LIBS"
 196 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 197 AC_LANG_POP(C)
 198
 199 lyx_win_res=false;
 200 case ${host} in
 201     *mingw*|*cygwin*) lyx_win_res=true;;
 202 esac
 203 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 204 LYX_SET_VERSION_INFO
 205
 206
 207 ### Some information on what just happened
 208 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 209 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 210 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 211 VERSION_INFO="Configuration\n\
 212   Host type:                    ${host}\n\
 213   Special build flags:         ${lyx_flags}\n\
 214   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 215   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 216   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 217   Linker flags:                 ${AM_LDFLAGS}\n\
 218   Linker user flags:            ${LDFLAGS}\n\
 219 ${FRONTEND_INFO}\
 220   Packaging:                    ${lyx_use_packaging}\n\
 221   LyX binary dir:               ${real_bindir}\n\
 222   LyX files dir:                ${real_pkgdatadir}\n"
 223
 224 AC_SUBST(VERSION_INFO)
 225 AC_SUBST(AM_CPPFLAGS)
 226 AC_SUBST(AM_CXXFLAGS)
 227 AC_SUBST(AM_CFLAGS)
 228 AC_SUBST(AM_LDFLAGS)
 229 AC_SUBST(real_pkgdatadir)
 230
 231 ## Some config.h stuff
 232
 233 AH_TOP([
 234 /* -*- C++ -*- */
 235 /*
 236  * \file config.h
 237  * This file is part of LyX, the document processor.
 238  * Licence details can be found in the file COPYING.
 239  *
 240  * This is the compilation configuration file for LyX.
 241  * It was generated by autoconfs configure.
 242  * You might want to change some of the defaults if something goes wrong
 243  * during the compilation.
 244  */
 245
 246 #ifndef _CONFIG_H
 247 #define _CONFIG_H
 248 ])
 249
 250 AH_BOTTOM([
 251 /************************************************************
 252  ** You should not need to change anything beyond this point */
 253
 254 #ifndef HAVE_STRERROR
 255 #if defined(__cplusplus)
 256 extern "C"
 257 #endif
 258 char * strerror(int n);
 259 #endif
 260
 261 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 262 #  define USE_BOOST_FORMAT 1
 263 #else
 264 #  define USE_BOOST_FORMAT 0
 265 #endif
 266
 267 #define BOOST_USER_CONFIG <config.h>
 268
 269 #if !defined(ENABLE_ASSERTIONS)
 270 #  define BOOST_DISABLE_ASSERTS 1
 271 #endif
 272 #define BOOST_ENABLE_ASSERT_HANDLER 1
 273
 274 #define BOOST_DISABLE_THREADS 1
 275 #define BOOST_NO_WREGEX 1
 276 #define BOOST_NO_WSTRING 1
 277
 278 // TR1 regex not supported in GCC <= 4.5
 279 #ifndef LYX_USE_TR1
 280 #  if __GNUC__ == 4
 281 #    define LYX_USE_TR1
 282 #  endif
 283 #endif
 284
 285 #ifdef __CYGWIN__
 286 #  define NOMINMAX
 287 #  define BOOST_POSIX 1
 288 #  define BOOST_POSIX_API 1
 289 #  define BOOST_POSIX_PATH 1
 290 #endif
 291
 292 /*
 293  * the FreeBSD libc uses UCS4, but libstdc++ has no proper wchar_t
 294  * support compiled in:
 295  * http://gcc.gnu.org/onlinedocs/libstdc++/faq/index.html#3_9
 296  * And we are not interested at all what libc
 297  * does: What we need is a 32bit wide wchar_t, and a libstdc++ that
 298  * has the needed wchar_t support and uses UCS4. Whether it
 299  * implements this with the help of libc, or whether it has own code
 300  * does not matter for us, because we do not use libc directly (Georg)
 301 */
 302 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4 && !defined(__FreeBSD__) && !defined(__FreeBSD_kernel__)
 303 #  define USE_WCHAR_T
 304 #endif
 305
 306 #endif
 307 ])
 308
 309 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 310 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 311 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 312
 313 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 314         "${lyx_abs_top_srcdir}", [Top source directory])
 315 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 316         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 317 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 318         "${lyx_abs_installed_datadir}",[Hard system support directory])
 319 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 320         "${version_suffix}",[Program version suffix])
 321
 322 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 323 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 324 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 325 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 326 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 327 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 328 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 329 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 330
 331 AC_CONFIG_FILES([Makefile \
 332       lyx.1:lyx.1in \
 333       boost/Makefile \
 334       config/Makefile \
 335       development/Makefile \
 336       development/MacOSX/Makefile \
 337       development/MacOSX/Info.plist \
 338       development/MacOSX/lyxrc.dist \
 339       development/MacOSX/spotlight/Makefile \
 340       development/cygwin/Makefile \
 341       development/cygwin/lyxrc.dist \
 342       development/lyx.spec \
 343       lib/lyx.desktop-temp:lib/lyx.desktop.in
 344       lib/Makefile \
 345       lib/doc/Makefile \
 346       lib/lyx2lyx/lyx2lyx_version.py \
 347       lib/lyx2lyx/Makefile \
 348       m4/Makefile \
 349       po/Makefile.in \
 350       sourcedoc/Doxyfile \
 351       sourcedoc/Makefile \
 352       src/client/Makefile \
 353       src/client/lyxclient.1:src/client/lyxclient.1in \
 354       src/Makefile \
 355       src/tex2lyx/Makefile \
 356       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 357       src/support/Makefile \
 358       src/frontends/Makefile \
 359       src/frontends/qt4/Makefile
 360 ])
 361
 362
 363 AC_OUTPUT
 364
 365 # show version information
 366 echo
 367 printf "$VERSION_INFO"
 368 echo
 369
 370 # Display a final warning if there has been a LYX_WARNING
 371 LYX_CHECK_WARNINGS
 372
 373 cat <<EOF
 374 Configuration of LyX was successful.
 375 Type 'make' to compile the program,
 376 and then 'make install' to install it.
 377 EOF