configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(lyx,1.4.0cvs,lyx-devel@lists.lyx.org)
   4 AC_PREREQ(2.52)
   5 AC_CONFIG_SRCDIR(src/main.C)
   6 AM_CONFIG_HEADER([src/config.h])
   7
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.4.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 dnl default maintainer mode to true for development versions
  15 if test "${enable_maintainer_mode+set}" != set; then
  16   enable_maintainer_mode=$lyx_devel_version
  17 fi
  18 AM_MAINTAINER_MODE
  19 AC_CANONICAL_TARGET
  20
  21 LYX_VERSION_SUFFIX
  22
  23 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  24
  25 ### Set the execute permissions of the various scripts correctly
  26 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  27   chmod 755 ${srcdir}/${file}
  28 done
  29
  30 ### Check for programs
  31 AC_PROG_MAKE_SET
  32 AC_PROG_INSTALL
  33 #AC_PROG_RANLIB
  34 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  35 if test "x$KPSEWHICH" = xkpsewhich ; then
  36     AC_DEFINE(HAVE_KPSEWHICH, 1,
  37     [Define this if you have the kpsewhich program working on your system.])
  38 fi
  39 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  40
  41 # Work around a problem in automake 1.4: when invoking install-strip,
  42 # INSTALL_PROGRAM is changed to 'install -s', and since
  43 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  44 # which returns an error condition when stripping fails.
  45 INSTALL_SCRIPT='${INSTALL}'
  46
  47 ### we will also need a C compiler to compile GNU gettext
  48 AC_PROG_CC
  49
  50 ### check for special systems
  51 AC_ISC_POSIX
  52 AC_AIX
  53
  54 ### check which frontend we want to use
  55 LYX_USE_FRONTENDS
  56
  57 ### Check for a C++ compiler
  58 LYX_PROG_CXX
  59 ### Some checks on what the C++ compiler can(not) do
  60 AC_LANG(C++)
  61 dnl we do not need that currently (and probably all our supported
  62 dnl compiler allow that)
  63 dnl LYX_CXX_PARTIAL
  64 LYX_CXX_EXPLICIT
  65 LYX_CXX_GLOBAL_CSTD
  66 LYX_STD_COUNT
  67 dnl we disable rtti for now
  68 dnl LYX_CXX_RTTI
  69 AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  70 LYX_CXX_STL_MODERN_STREAMS
  71
  72 ### and now some special lyx flags.
  73 AC_ARG_ENABLE(assertions,
  74   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  75   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  76         enable_assertions=yes;
  77     else
  78         enable_assertions=no;
  79     fi;])
  80 if test "x$enable_assertions" = xyes ; then
  81    lyx_flags="$lyx_flags assertions"
  82    AC_DEFINE(ENABLE_ASSERTIONS,1,
  83     [Define if you want assertions to be enabled in the code])
  84 fi
  85
  86 ### Library Files
  87 dnl by testing these we check if it is ok to have
  88 dnl -lc and -lm as args to the compiler
  89 AC_CHECK_LIB(m, sin)
  90 AC_CHECK_LIB(c, fopen)
  91
  92 ### Add extra directories to check for libraries.
  93 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  94 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  95 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  96
  97 ### Add extra directories to check for include files.
  98 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  99 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 100 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 101
 102 ### Add both includes and libraries
 103 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 104 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 105 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 106   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 107
 108 AC_ARG_WITH(aiksaurus,
 109   [  --without-aiksaurus     do not use the Aiksaurus library],
 110   [lyx_use_aiksaurus=$withval])
 111 if test x$lyx_use_aiksaurus != xno; then
 112 AC_CHECK_LIB(Aiksaurus, main,
 113         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 114          AIKSAURUS_LIBS="-lAiksaurus"
 115          lyx_flags="$lyx_flags aiksaurus"
 116         ])
 117 AC_CHECK_HEADER(Aiksaurus.h,[
 118   ac_cv_header_aiksaurus_h=yes
 119   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 120 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 121   ac_cv_header_aiksaurus_h=yes
 122   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 123 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 124 fi
 125 AC_SUBST(AIKSAURUS_LIBS)
 126
 127 LYX_USE_INCLUDED_BOOST
 128
 129 ### Setup libtool
 130 AC_DISABLE_SHARED
 131 AC_LIBTOOL_WIN32_DLL
 132 #AM_PROG_LIBTOOL
 133 LYX_PROG_LIBTOOL
 134
 135 ### Check if we want spell libraries, prefer new aspell
 136 CHECK_WITH_ASPELL
 137 if test "$USING_ASPELL" != "yes"; then
 138         CHECK_WITH_PSPELL
 139 fi
 140
 141 ### Check for some Cygwin-specific details.
 142 CHECK_WITH_CYGWIN
 143
 144 ### Check for X libraries
 145 AC_PATH_XTRA
 146 case $have_x in
 147   yes) LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 148        CPPFLAGS="$CPPFLAGS $X_CFLAGS";;
 149   no) LYX_ERROR(dnl
 150 [Cannot find X window libraries and/or headers. Check your installation.
 151   If you use a Linux system, check that you have installed
 152   the development tools.]);;
 153   disable) ;;
 154 esac
 155
 156 ### check which frontend we want to use
 157
 158 dnl if the gtk frontend has been specified, then xforms is needed too
 159 if echo $FRONTENDS | grep gtk | grep -v xforms ; then
 160   FRONTENDS="xforms $FRONTENDS"
 161 fi
 162
 163 dnl The code below is not in a macro, because this would cause big
 164 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 165 for frontend in $FRONTENDS ; do
 166   case "$frontend" in
 167     xforms)
 168           XFORMS_DO_IT_ALL
 169           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-xforms\$(EXEEXT)"
 170           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS xforms"
 171           RPM_FRONTEND="xforms"
 172           FRONTEND_INFO="${FRONTEND_INFO}\
 173   XForms Frontend:\n\
 174       libXpm version:\t\t${XPM_VERSION}\n\
 175       libforms version:\t\t${XFORMS_VERSION}\n"
 176           ;;
 177   dnl   gnome)
 178   dnl     XFORMS_DO_IT_ALL
 179   dnl     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 180   dnl     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 181   dnl     AC_SUBST(GNOME_FRONTEND_LIBS)
 182
 183   dnl     FRONTEND="xforms gnome"
 184   dnl     FRONTEND_GUILIB="gnome/*.lo"
 185   dnl     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 186   dnl     FRONTEND_INCLUDES="${GNOME_FRONTEND_CFLAGS}"
 187   dnl     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}"
 188   dnl   ;;
 189     gtk)
 190           PKG_CHECK_MODULES(GTK_FRONTEND, gtkmm-2.4 libglademm-2.4)
 191           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-gtk\$(EXEEXT)"
 192           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS gtk"
 193           RPM_FRONTEND="gtk"
 194           GTKMM_VERSION=`pkg-config --modversion gtkmm-2.4`
 195           LIBGLADEMM_VERSION=`pkg-config --modversion libglademm-2.4`
 196           FRONTEND_INFO="${FRONTEND_INFO}\
 197   GTK Frontend:\n\
 198     libgtkmm version:\t\t${GTKMM_VERSION}\n\
 199     libglademm version:\t\t${LIBGLADEMM_VERSION}\n"
 200           ;;
 201
 202     qt)
 203           QT_DO_IT_ALL
 204           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt\$(EXEEXT)"
 205           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt2"
 206           RPM_FRONTEND="qt"
 207           FRONTEND_INFO="${FRONTEND_INFO}\
 208   Qt Frontend:\n\
 209       Qt version:\t\t${QT_VERSION}\n"
 210 dnl qt build will fail without moc or uic
 211           if test -z "$MOC"; then
 212             LYX_ERROR([moc binary not found !])
 213           fi
 214           if test -z "$UIC"; then
 215             LYX_ERROR([uic binary not found !])
 216           fi
 217       ;;
 218     *)
 219           LYX_ERROR(Unknown frontend '$frontend');;
 220   esac
 221 done
 222
 223 ### Check how the files should be packaged
 224 LYX_USE_PACKAGING
 225 # fix the value of the prefixes.
 226 test "x$prefix" = xNONE && prefix=$default_prefix
 227 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 228 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 229   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 230    causes problems with the Makefiles. The installation will be done in
 231    directory \"`pwd`/installprefix\" instead. Please move its contents to
 232    the right place after installation.])
 233   prefix=`pwd`/installprefix
 234 fi
 235
 236 ### Setup GNU gettext
 237 dnl GNU gettext is written in C
 238 AC_LANG_PUSH(C)
 239 AM_GNU_GETTEXT
 240 AC_LANG_POP(C)
 241
 242 # some standard header files
 243 AC_HEADER_DIRENT
 244 AC_HEADER_MAJOR
 245 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 246
 247 # some standard structures
 248 AC_HEADER_STAT
 249 AC_HEADER_TIME
 250
 251 # some standard types
 252 AC_TYPE_MODE_T
 253 AC_TYPE_OFF_T
 254 AC_TYPE_PID_T
 255 AC_TYPE_SIGNAL
 256 AC_TYPE_SIZE_T
 257 AC_TYPE_UID_T
 258
 259 AC_CHECK_FUNCS(strerror)
 260 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 261 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 262
 263 # Check the form of mkdir()
 264 AC_FUNC_MKDIR
 265
 266 AC_ARG_ENABLE(compression-support, AC_HELP_STRING([--enable-compression-support],[Support for compressed files.]),[
 267     case "${enableval}" in
 268         yes) use_compression=true ;;
 269         no) use_compression=false ;;
 270         *) AC_MSG_ERROR(bad value ${enableval} for --enable-compression-support) ;;
 271     esac
 272 ],[use_compression=true])
 273 if test $use_compression=true ; then
 274         AC_CHECK_HEADERS(zlib.h, use_compression=true, use_compression=false)
 275         AC_CHECK_LIB(z, gzopen,[use_compression=true;LIBS="$LIBS -lz"], use_compression=false)
 276         if test $use_compression = true ; then
 277                 AC_DEFINE(USE_COMPRESSION, 1, [Define as 1 if you want to support compressed files.])
 278                 lyx_flags="$lyx_flags compression"
 279         fi
 280 fi
 281 AM_CONDITIONAL(USE_COMPRESSION, test x$use_compression = xtrue)
 282 AC_MSG_CHECKING([whether to support compressed files])
 283 AC_MSG_RESULT($use_compression)
 284
 285
 286 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 287 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 288 dnl We aim to remove this eventually, since we should test as much as
 289 dnl possible with the compiler which will use the functions (JMarc)
 290 AC_LANG_PUSH(C)
 291 AC_CHECK_FUNCS(mkfifo mkstemp mktemp lstat readlink)
 292 AC_LANG_POP(C)
 293
 294 AC_FUNC_SELECT_ARGTYPES
 295
 296 ### Some information on what just happened
 297 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 298 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 299 VERSION_INFO="Configuration\n\
 300   Host type:                      ${host}\n\
 301   Special build flags:           ${lyx_flags}\n\
 302   C   Compiler:                   ${CC}\n\
 303   C   Compiler flags:             ${CPPFLAGS} ${CFLAGS}\n\
 304   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 305   C++ Compiler flags:             ${CPPFLAGS} ${CXXFLAGS}\n\
 306   Linker flags:                   ${LDFLAGS}\n\
 307 ${FRONTEND_INFO}\
 308   Packaging:                      ${lyx_use_packaging}\n\
 309   LyX binary dir:                 ${real_bindir}\n\
 310   LyX files dir:                  ${real_datadir}\n"
 311
 312
 313 AC_SUBST(VERSION_INFO)
 314 AC_SUBST(RPM_FRONTEND)
 315
 316 ## Some config.h stuff
 317
 318 AH_TOP([
 319 /* -*- C++ -*- */
 320 /*
 321  * \file config.h
 322  * This file is part of LyX, the document processor.
 323  * Licence details can be found in the file COPYING.
 324  *
 325  * This is the compilation configuration file for LyX.
 326  * It was generated by autoconfs configure.
 327  * You might want to change some of the defaults if something goes wrong
 328  * during the compilation.
 329  */
 330
 331 #ifndef _CONFIG_H
 332 #define _CONFIG_H
 333 ])
 334
 335 AH_BOTTOM([
 336 /************************************************************
 337  ** You should not need to change anything beyond this point */
 338
 339 #ifndef HAVE_STRERROR
 340 #if defined(__cplusplus)
 341 extern "C"
 342 #endif
 343 char * strerror(int n);
 344 #endif
 345
 346 #ifdef HAVE_MKSTEMP
 347 #ifndef HAVE_DECL_MKSTEMP
 348 #if defined(__cplusplus)
 349 extern "C"
 350 #endif
 351 int mkstemp(char*);
 352 #endif
 353 #endif
 354
 355 #ifdef __EMX__
 356 #include "support/os2_defines.h"
 357 #endif
 358
 359 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 360 #define USE_BOOST_FORMAT 1
 361 #else
 362 #define USE_BOOST_FORMAT 0
 363 #endif
 364
 365 #define BOOST_USER_CONFIG <config.h>
 366
 367 #if defined(ENABLE_ASSERTIONS)
 368 #define BOOST_ENABLE_ASSERT_HANDLER 1
 369 #else
 370 #define BOOST_DISABLE_ASSERTS 1
 371 #endif
 372
 373 #define BOOST_DISABLE_THREADS 1
 374 #define BOOST_NO_WREGEX 1
 375 #define BOOST_NO_WSTRING 1
 376
 377 #ifdef __CYGWIN__
 378 #define BOOST_POSIX 1
 379 #endif
 380
 381 #endif
 382 ])
 383
 384 ### Finish the work.
 385 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 386 AC_CONFIG_FILES([Makefile  m4/Makefile \
 387        boost/Makefile \
 388        boost/libs/Makefile \
 389        boost/libs/filesystem/Makefile \
 390        boost/libs/filesystem/src/Makefile \
 391        boost/libs/regex/Makefile \
 392        boost/libs/regex/src/Makefile \
 393        boost/libs/signals/Makefile \
 394        boost/libs/signals/src/Makefile \
 395        config/Makefile \
 396        development/Makefile \
 397        development/lyx.spec \
 398        lib/Makefile \
 399        lib/doc/Makefile \
 400        intl/Makefile \
 401        po/Makefile.in \
 402        sourcedoc/Doxyfile \
 403        sourcedoc/Makefile \
 404        src/client/Makefile \
 405        src/Makefile \
 406        src/version.C-tmp:src/version.C.in \
 407        src/tex2lyx/Makefile \
 408        src/mathed/Makefile \
 409        src/graphics/Makefile \
 410        src/insets/Makefile \
 411        src/support/Makefile \
 412        src/support/tests/Makefile \
 413        src/frontends/Makefile \
 414        src/frontends/controllers/Makefile \
 415        src/frontends/xforms/Makefile \
 416        src/frontends/xforms/lyx_forms.h-tmp:src/frontends/xforms/lyx_forms.h.in \
 417        src/frontends/xforms/lyx_xpm.h-tmp:src/frontends/xforms/lyx_xpm.h.in \
 418        src/frontends/xforms/forms/Makefile \
 419        src/frontends/gtk/Makefile \
 420        src/frontends/gtk/gimages/Makefile \
 421        src/frontends/gtk/glade/Makefile \
 422        src/frontends/qt2/Makefile \
 423        src/frontends/qt2/moc/Makefile \
 424        src/frontends/qt2/ui/Makefile \
 425        src/frontends/qt2/ui/moc/Makefile \
 426 ])
 427
 428 AC_OUTPUT
 429 # show version information
 430 echo
 431 printf "$VERSION_INFO"
 432 echo
 433
 434 # Display a final warning if there has been a LYX_ERROR
 435 LYX_CHECK_ERRORS